PrtDevMode 속성

적용 대상

Form 개체

Report 개체

PrtDevMode 속성을 사용하여 인쇄 대화 상자에서 폼 또는 보고서에 대해 지정된 인쇄 장치 모드 정보를 설정하거나 반환할 수 있습니다. 읽기/쓰기 Variant입니다.

expression.PrtDevMode

expression은 필수입니다. 적용 대상 목록에서 개체 중 하나를 반환하는 식입니다.

주의

PrtDevMode, PrtDevNamesPrtMip 속성에 대한 전체 설명서는 Win32 소프트웨어 개발 키트를 참조하는 것이 좋습니다.

PrtDevMode 속성 설정은 Win32 소프트웨어 개발 키트에 정의된 DEVMODE 구조체를 미러링하는 94바이트 구조체입니다. PrtDevMode 속성 멤버에 대한 자세한 내용은 Win32 소프트웨어 개발 키트를 참조하세요.

PrtDev Mode 속성은 다음 멤버를 사용합니다.

멤버

설명

DeviceName

드라이버가 지원하는 장치 이름을 지정하는 최대 32바이트의 문자열입니다. 예를 들어 Hewlett-Packard LaserJet IIISi가 지정된 프린터인 경우 "HP LaserJet IIISi"입니다. 각 프린터 드라이버에 고유 문자열이 있습니다.

SpecVersion

Win32 소프트웨어 개발 키트의 DEVMODE 구조체 버전 번호를 지정하는 Integer입니다.

DriverVersion

프린터 드라이버 개발자가 지정한 프린터 드라이버 버전 번호를 지정하는 Integer입니다.

Size

DEVMODE 구조체의 크기(바이트)를 지정하는 Integer입니다. 이 값에는 이 구조체를 따를 수 있는 장치별 데이터의 선택적 dmDriverData 멤버가 포함되지 않습니다. 응용 프로그램이 데이터의 드라이버 독립 부분만 조작하는 경우 다른 버전을 고려하지 않고 이 멤버를 사용하여 이 구조체의 길이를 찾을 수 있습니다.

DriverExtra

이 구조체를 따를 수 있는 장치별 데이터의 선택적 dmDriverData 멤버 크기(바이트)를 지정하는 Integer입니다. 응용 프로그램이 장치별 정보를 사용하지 않는 경우 이 멤버를 0으로 설정합니다.

필드

DEVMODE 구조체의 나머지 멤버 중 초기화된 멤버를 지정하는 Long 값입니다.

Orientation

용지 방향을 지정하는 Integer입니다. 1(세로) 또는 2(가로)일 수 있습니다.

PaperSize

인쇄할 용지 크기를 지정하는 Integer입니다. 이 멤버를 0 또는 256으로 설정할 경우 용지의 길이와 너비가 각각 PaperLength 및 PaperWidth 멤버로 지정됩니다. 그렇지 않으면 PaperSize 멤버를 미리 정의된 값으로 설정할 수 있습니다.

PaperLength

용지 길이를 1밀리미터의 1/10 단위로 지정하는 Integer입니다. 이 멤버는 사용자 지정 용지 크기 또는 다양한 용지 크기에 인쇄할 수 있는 도트 매트릭스 프린터 같은 장치에 대해 PaperSize 멤버로 지정된 용지 길이를 재정의합니다.

PaperWidth

용지 너비를 1밀리미터의 1/10 단위로 지정하는 Integer입니다. 이 멤버는 PaperSize 멤버로 지정된 용지 너비를 재정의합니다.

Scale

인쇄된 출력의 크기를 조정할 배율을 지정하는 Integer입니다. 표시되는 페이지 크기는 실제 페이지 크기에서 scale/100 배율만큼 조정됩니다. 예를 들어 Scale 값이 50인 8.5 x 11 인치(Letter 크기) 용지는 출력 텍스트와 그래픽이 원래 높이와 너비의 절반이 되므로 17 x 22 인치 용지와 동일한 데이터를 포함합니다.

Copies

인쇄 장치가 여러 인쇄 매수를 지원하는 경우 인쇄 매수를 지정하는 Integer입니다.

DefaultSource

용지를 공급하는 기본 용지함을 지정하는 Integer입니다.

PrintQuality

프린터 해상도를 지정하는 Integer입니다. 값은 -4(높음), -3(중간), -2(낮음), -1(초안)입니다.

Color

Integer입니다. 컬러 프린터의 경우 출력의 컬러 인쇄 여부를 지정합니다. 값은 1(컬러)과 2(흑백)입니다.

Duplex

Integer입니다. 양면 인쇄를 지원하는 프린터의 경우 출력의 양면 인쇄 여부를 지정합니다. 값은 1(단면), 2(가로), 3(세로)입니다.

YResolution

프린터의 Y 해상도를 dpi(인치당 도트 수) 단위로 지정하는 Integer입니다. 프린터가 이 멤버를 초기화하는 경우 PrintQuality 멤버는 프린터의 X 해상도를 dpt 단위로 지정합니다.

TTOption

트루타입 글꼴의 인쇄 방법을 지정하는 Integer입니다.

Collate

여러 복사본을 인쇄할 때 한 부씩 인쇄할지 여부를 지정하는 Integer입니다. 한 부씩 인쇄를 사용하지 않을 경우 데이터가 한 번만 프린터로 전송되므로 더 빠르고 효율적인 출력이 제공됩니다.

FormName

사용할 용지 크기를 지정하는 최대 16자의 문자열입니다(예: "Letter" 또는 "Legal").

Pad

이후 버전에서 공백, 문자 또는 값을 채우는 데 사용되는 Long 값입니다.

Bits

디스플레이 장치의 컬러 해상도를 픽셀당 비트 수로 지정하는 Long 값입니다.

PW

표시되는 장치 화면(화면 또는 프린터)의 너비(픽셀)를 지정하는 Long 값입니다.

PH

표시되는 장치 화면(화면 또는 프린터)의 길이(픽셀)를 지정하는 Long 값입니다.

DFI

장치의 표시 모드를 지정하는 Long 값입니다.

DFR

특정 모드에서 디스플레이 장치의 주파수를 Hz(초당 주기 수) 단위로 지정하는 Long 값입니다.


참고: VBA(Visual Basic for Applications) 코드를 사용하여 PrtDevMode 속성을 설정할 수 있습니다.

이 속성 설정은 디자인 보기 또는 레이아웃 보기에서는 읽기/쓰기, 다른 보기에서는 읽기 전용입니다.

프린터 드라이버는 DEVMODE 구조체의 94바이트 바로 뒤에 데이터를 추가할 수 있습니다. 이러한 이유로 위에 요약된 DEVMODE 데이터가 94바이트를 초과하지 않도록 하는 것이 중요합니다.

ExtDeviceMode 함수를 내보내는 프린터 드라이버만 DEVMODE 구조체를 사용합니다.

응용 프로그램은 DC_PAPERS, DC_PAPERSIZE 및 DC_PAPERNAMES 값을 사용해서 DeviceCapabilities 함수를 호출하여 프린터가 지원하는 용지 크기와 이름을 검색할 수 있습니다.

TTOption 멤버의 값을 설정하기 전에 응용 프로그램이 DC_TRUETYPE 값을 사용해서 DeviceCapabilities 함수를 호출하여 프린터 드라이버가 트루타입 글꼴을 사용할 수 있는 방법을 확인해야 합니다.

예제

다음 예제에서는 PrtDevMode 속성을 사용하여 보고서의 사용자 정의 페이지 크기를 확인합니다.

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

다음 예제는 보고서의 방향을 변경하는 방법을 보여 줍니다. 이 예제에서는 보고서의 현재 방향에 따라 세로 방향에서 가로 방향으로 또는 가로 방향에서 세로 방향으로 방향을 전환합니다.

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub
Office 기술 확장
교육 살펴보기
새로운 기능 우선 가져오기
Office Insider 참여

이 정보가 유용한가요?

의견 주셔서 감사합니다!

피드백을 주셔서 감사합니다. Office 지원 에이전트와 연락하는 것이 도움이 될 것 같습니다.

×