Microsoft로 로그인
로그인하거나 계정을 만듭니다.
안녕하세요.
다른 계정을 선택합니다.
계정이 여러 개 있음
로그인할 계정을 선택합니다.

Excel 테이블을 만들 때 Excel은 테이블과 테이블의 각 열 머리글에 이름을 할당합니다. Excel 표에 수식을 추가하는 경우, 수식을 입력할 때 이 이름이 자동으로 표시되므로 수동으로 입력하는 대신 표에서 셀 참조를 선택할 수 있습니다. 다음은 Excel에서 수행하는 작업의 예입니다.

명시적 셀 참조 사용

표 및 열 이름 사용

=Sum(C2:C7)

=SUM(부서판매액[판매액])

이러한 표 및 열 이름의 조합을 구조적 참조라고 합니다. 구조적 참조의 이름은 표에서 데이터를 추가하거나 제거할 때마다 조정됩니다.

Excel 표 외부에 표 데이터를 참조하는 수식을 만들 때에도 구조적 참조가 표시됩니다. 참조를 사용하면 큰 통합 문서에서 표를 더 쉽게 찾을 수 있습니다.

수식에 구조적 참조를 포함하려면 수식에 셀 참조를 입력하는 대신 참조하려는 표 셀을 클릭합니다. 다음 예제 데이터를 사용하여 구조화된 참조를 사용하여 판매 수수료의 양을 계산하는 수식을 입력해 보겠습니다.

영업 사원

지역

판매

수수료율

수수료 금액

조영일

북부

260

10%

문용만

남부

660

15%

황영순

동부

940

15%

정석규

서부

410

12%

최소라

북부

800

15%

김주형

남부

900

15%

  1. 열 머리글을 포함하여 위의 표에 있는 샘플 데이터를 복사하여 새 Excel 워크시트의 A1 셀에 붙여넣습니다.

  2. 테이블을 만들려면 데이터 범위 내의 셀을 선택하고 Ctrl+T를 누릅니다.

  3. 내 테이블에 머리글이 있는지 확인란이 선택되어 있는지 확인하고 확인을 클릭합니다.

  4. E2 셀에 등호(=)를 입력하고 C2 셀을 클릭합니다.

    수식 입력줄에서 구조적 참조 [@[판매액]]이 등호 뒤에 나타납니다.

  5. 닫는 대괄호 바로 다음에 별표(*)를 입력하고 D2 셀을 클릭합니다.

    수식 입력줄에서 구조적 참조 [@[수수료율]]이 별표 뒤에 나타납니다.

  6. Enter키를 누릅니다.

    Excel 에서 자동으로 계산된 열이 만들어지고 수식이 전체 열에서 아래로 복사되며 각 행에 맞게 조정됩니다.

명시적 셀 참조를 사용하는 경우

계산된 열에 명시적 셀 참조를 입력하는 경우 수식에서 무엇을 계산하는지 알기 어려울 수 있습니다.

  1. 샘플 워크시트에서 셀 E2를 클릭합니다.

  2. 수식 입력줄에서 =C2*D2를 입력하고 Enter 키를 누릅니다.

Excel에서 수식을 열 아래쪽으로 복사할 때는 구조적 참조를 사용하지 않습니다. 예를 들어 기존 열 C와 D 사이에 열을 추가하는 경우 수식을 수정해야 합니다.

표 이름을 어떻게 변경할 수 있나요?

Excel 표를 만들면 표1, 표2와 같은 기본 표 이름이 만들어집니다. 하지만 표 이름을 보다 의미 있는 이름으로 변경할 수 있습니다.

  1. 표에서 셀을 선택하여 리본 메뉴에 테이블 도구 > 디자인 탭을 표시합니다.

  2. 테이블 이름 상자에 원하는 이름을 입력하고 Enter 키를 누릅니.

예제 데이터에서는 부서판매액이라는 이름을 사용했습니다.

표 이름에 다음 규칙을 사용합니다.

  • 유효한 문자 사용  항상 문자, 밑줄 문자(_) 또는 백슬래시(\)로 이름을 시작합니다. 이름의 나머지 부분에는 문자, 숫자, 마침표 및 밑줄을 사용합니다. "C", "c", "R" 또는 "r"은 이름 또는 이동 상자에 입력할 경우 활성 셀의 열 또는 행을 선택하는 바로 가기로 이미 지정되어 있으므로 이름에 사용할 수 없습니다.

  • 셀 참조 사용 안 함  이름이 Z$100 또는 R1C1과 같이 셀 참조와 동일하지 않아야 합니다.

  • 공백을 사용하여 단어를 구분하지 마세요.  이름에는 공백을 사용할 수 없습니다. 밑줄 문자(_) 및 마침표()를 사용할 수 있습니다.)을 단어 구분 기호로 지정합니다. 예를 들어 DeptSales, Sales_Tax 또는 First.Quarter입니다.

  • 255자 이하 사용 테이블 이름은 최대 255개의 문자까지 입력할 수 있습니다.

  • 고유한 테이블 이름 사용 중복된 이름은 사용할 수 없습니다. Excel은 이름의 대문자와 소문자를 구분하지 않으므로 "Sales"를 입력하지만 동일한 통합 문서에 "SALES"라는 다른 이름이 이미 있는 경우 고유한 이름을 선택하라는 메시지가 표시됩니다.

  • 개체 식별자 사용  테이블, 피벗 테이블 및 차트를 혼합하려는 경우 이름을 개체 형식으로 접두사로 지정하는 것이 좋습니다. 예: 판매 테이블의 tbl_Sales, 판매 피벗 테이블의 pt_Sales, 판매 차트의 경우 chrt_Sales 또는 판매 피벗 차트의 ptchrt_Sales. 이렇게 하면 이름 관리자의 순서가 지정된 목록에 모든 이름이 유지됩니다.

구조적 참조 구문 규칙

수식에서 구조화된 참조를 수동으로 입력하거나 변경할 수도 있지만 이렇게 하려면 구조화된 참조 구문을 이해하는 데 도움이 됩니다. 다음 수식 예제를 살펴보겠습니다.

=SUM(부서판매액[[#요약],[판매액]],부서판매액[[#데이터],[수수료 금액]])

이 수식에는 다음과 같은 구조적 참조 구성 요소가 있습니다.

  • 테이블 이름:    DeptSales 는 사용자 지정 테이블 이름입니다. 머리글이나 요약 행을 제외한 표 데이터를 참조합니다. 표1과 같은 기본 표 이름을 사용하거나 사용자 지정 이름을 사용하도록 변경할 수 있습니다.

  • 열 지정자:    [Sales Amount] [Commission Amount]는 나타내는 열의 이름을 사용하는 열 지정자입니다. 열 머리글이나 요약 행을 제외한 열 데이터를 참조합니다. 지정자는 항상 대괄호로 묶습니다.

  • 항목 지정자:    [#Totals][#Data] 은 테이블의 특정 부분(예: 총 행)을 참조하는 특수 항목 지정자입니다.

  • 표 지정자:    [[#요약],[판매액]][[#데이터],[수수료 금액]]은 구조적 참조의 바깥 부분을 나타내는 표 지정자입니다. 외부 참조는 표 이름을 따라 이름이 지정되며 대괄호로 묶습니다.

  • 구조적 참조:    (DeptSales[[#Totals],[Sales Amount]]DeptSales[[#Data],[Commission Amount]]] 는 테이블 이름으로 시작하고 열 지정자로 끝나는 문자열로 표현되는 구조화된 참조입니다.

구조적 참조를 수동으로 만들거나 편집하려면 다음과 같은 구문 규칙을 사용합니다.

  • 지정자 주위에 대괄호 사용    모든 테이블, 열 및 특수 항목 지정자는 일치하는 대괄호([ ])로 묶어야 합니다. 다른 지정자를 포함하는 지정자에는 다른 지정자의 내부 일치 대괄호를 묶기 위해 외부 일치 대괄호가 필요합니다. 예: =DeptSales[[Sales Person]:[Region]]

  • 모든 열 머리글은 텍스트 문자열    그러나 구조화된 참조에서 사용될 때 따옴표가 필요하지 않습니다. 2014 또는 2014-01-01과 같은 숫자나 날짜도 텍스트 문자열로 간주됩니다. 식에는 열 머리글을 사용할 수 없습니다. 예를 들어 부서판매액회계연도요약[[2014]:[2012]]와 같은 식은 작동하지 않습니다.

특수 문자가 있는 열 머리글 주위에 대괄호 사용    특수 문자가 있는 경우 전체 열 머리글은 대괄호로 묶어야 합니다. 즉, 열 지정자에 이중 대괄호가 필요합니다. 예: =DeptSalesFYSummary[[총 $ 금액]]

다음은 수식에 추가 대괄호가 필요한 특수 문자의 목록입니다.

  • Tab 키

  • 줄 바꿈

  • 캐리지 리턴

  • 쉼표(,)

  • 콜론(:)

  • 마침표(.)

  • 왼쪽 대괄호([)

  • 오른쪽 대괄호(])

  • 파운드 기호(#)

  • 작은따옴표(')

  • 큰따옴표(")

  • 왼쪽 중괄호({)

  • 오른쪽 중괄호(})

  • 달러 기호($)

  • 캐럿(^)

  • 앰퍼샌드(&)

  • 별표(*)

  • 더하기 기호(+)

  • 등호(=)

  • 빼기 기호(-)

  • 기호보다 큼(>)

  • 보다 작음 기호(<)

  • 나누기 기호(/)

  • 서명 시(@)

  • 백슬래시(\)

  • 느낌표(!)

  • 왼쪽 괄호(()

  • 오른쪽 괄호())

  • 백분율 기호(%)

  • 물음표(?)

  • 백틱(')

  • 세미콜론(;)

  • 타일드(~)

  • 밑줄(_)

  • 열 머리글의 일부 특수 문자에 이스케이프 문자 사용    일부 문자에는 특별한 의미가 있으며 작은따옴표(')를 이스케이프 문자로 사용해야 합니다. =부서판매액회계연도요약['# 항목]을 예로 들 수 있습니다.

다음은 수식에 이스케이프 문자(')가 필요한 특수 문자 목록입니다.

  • 왼쪽 대괄호([)

  • 오른쪽 대괄호(])

  • 파운드 기호(#)

  • 작은따옴표(')

  • 서명 시(@)

구조적 참조를 보다 쉽게 읽을 수 있도록 공백 문자 사용    구조적 참조를 보다 쉽게 읽을 수 있도록 공백 문자를 사용할 수 있습니다. =부서판매액[ [판매 담당자]:[지역] ] 또는 =부서판매액[[#머리글], [#데이터], [수수료율]]을 예로 들 수 있습니다.

다음 위치에는 공백 하나를 사용하는 것이 좋습니다.

  • 첫 번째 왼쪽 대괄호 뒤([)

  • 마지막 오른쪽 대괄호(]) 앞에 옵니다.

  • 쉼표 후.

참조 연산자

다음과 같은 참조 연산자를 사용하여 열 지정자를 조합하면 보다 유연하게 셀 범위를 지정할 수 있습니다.

구조적 참조

참조 대상

사용 연산자

셀 범위

=부서판매액[[판매 담당자]:[지역]]

둘 이상의 인접한 열에 있는 모든 셀

: (콜론) 범위 연산자

A2:B7

=부서판매액[판매액],부서판매액[수수료 금액]

열 두 개 이상의 조합

, (쉼표) 논리합 연산자

C2:C7, E2:E7

=부서판매액[판매 담당자]:[판매액]] 부서판매액[[지역]:[수수료율]]

열 두 개 이상의 논리곱

 (공백) 논리곱 연산자

B2:C7

특수 항목 지정자

요약 행과 같이 표의 특정 부분을 참조하려면 다음 중 적절한 특수 항목 지정자를 구조적 참조에서 사용하면 됩니다.

특수 항목 지정자

참조 대상

#모두

열 머리글, 데이터 및 요약(있을 경우)을 비롯한 전체 표

#데이터

데이터 행만

#머리글

머리글 행만

#요약

요약 행만. 요약 행이 없을 경우 null이 반환됩니다.

#이 행

또는

@

또는

@[열 이름]

수식으로 같은 행에 있는 셀만. 이 지정자는 다른 특수 항목 지정자와 함께 사용할 수 없습니다. 참조에 대한 암시적 논리곱 동작을 강제로 실행하거나, 암시적 논리곱 동작을 무시하고 열의 단일 값을 참조하는 데 사용합니다.

Excel은 여러 데이터 행이 있는 표에서 #이 행 지정자를 보다 짧은 @ 지정자로 자동으로 변경합니다. 하지만 표에 단 하나의 행만 있는 경우에는 Excel에서 #이 행 지정자를 바꾸지 않기 때문에, 더 많은 행을 추가할 때 예상치 못한 계산 결과가 나올 수 있습니다. 이러한 계산 문제를 피하려면 구조적 참조 수식을 입력하기 전에 표에 여러 행을 입력해야 합니다.

계산된 열에서 구조적 참조 정규화

계산된 열을 만들 때는 일반적으로 구조적 참조를 사용하여 수식을 만듭니다. 이러한 구조적 참조는 비정규화되거나 정규화될 수 있습니다. 예를 들어 수수료 금액을 달러로 계산하는 커미션 금액이라는 계산 열을 만들려면 다음 수식을 사용할 수 있습니다.

구조적 참조 유형

예제

설명

비정규화

=[판매액]*[수수료율]

현재 행의 해당 값을 곱합니다.

정규화

=부서판매액[판매액]*부서판매액[수수료율]

양쪽 열의 각 행에 대한 해당 값을 곱합니다.

다음과 같은 일반 규칙을 따라야 합니다. 계산된 열을 만들 때처럼 표 내에서 구조적 참조를 사용하는 경우 비정규화된 구조적 참조를 사용할 수 있습니다. 그러나 표 외부에서 구조적 참조를 사용하는 경우에는 정규화된 구조적 참조를 사용해야 합니다.

구조적 참조 사용 예제

다음은 구조적 참조를 사용하는 몇 가지 방법입니다.

구조적 참조

참조 대상

셀 범위

=부서판매액[[#모두],[판매액]]

판매액 열의 모든 셀

C1:C8

=부서판매액[[#머리글],[수수료율]]

수수료율 열의 머리글

D1

=부서판매액[[#요약],[지역]]

지역 열의 요약. 요약 행이 없을 경우 null이 반환됩니다.

B8

=부서판매액[[#모두],[판매액]:[수수료율]]

판매액과 수수료율에 있는 모든 셀

C1:D8

=부서판매액[[#데이터],[수수료율]:[수수료 금액]]

수수료율 및 수수료 금액 열의 데이터만

D2:E7

=부서판매액[[#머리글],[지역]:[수수료 금액]]

지역과 수수료 금액 사이에 있는 열의 머리글만

B1:E1

=부서판매액[[#요약],[판매액]:[수수료 금액]]

판매액 열부터 수수료 금액 열까지의 요약. 요약 행이 없을 경우 null이 반환됩니다.

C8:E8

=부서판매액[[#머리글],[#데이터],[수수료율]]

수수료율의 머리글 및 데이터만

D1:D7

=부서판매액[[#이 행], [수수료 금액]]

또는

=부서판매액[@수수료 금액]

현재 행과 수수료 금액 열이 교차하는 셀. 머리글 또는 총 행과 동일한 행에 사용하면 #VALUE! 오류가 반환됩니다.

여러 행의 데이터가 들어 있는 표에 긴 형식의 구조적 참조(#이 행)를 입력하면 Excel에서 이를 자동으로 짧은 형식(@)으로 바꿉니다. 두 가지 모두 동일하게 작동합니다.

E5(현재 행이 5인 경우)

구조적 참조 사용 전략

구조화된 참조를 사용하는 경우 다음을 고려합니다.

  • 수식 자동 완성 사용    정확한 구문을 사용하여 구조적 참조를 입력하려는 경우 수식 자동 완성을 사용하면 매우 편리합니다. 자세한 내용은 수식 자동 완성 사용을 참조하세요.

  • 반선택에서 테이블에 대한 구조적 참조를 생성할지 여부를 결정합니다.    기본적으로 수식을 만들 때 표 내에서 셀 범위를 클릭하면 셀이 반으로 선택되고 수식의 셀 범위 대신 구조화된 참조가 자동으로 입력됩니다. 이러한 반선택 동작을 사용하면 구조적 참조를 훨씬 더 쉽게 입력할 수 있습니다. 파일 > 옵션 > 수식 > 수식 작업 대화 상자에서 식 검사 테이블 이름 사용 상자를 선택하거나 선택 취소하여 이 동작을 켜거나 끌 수 있습니다.

  • 다른 통합 문서에 있는 Excel 표에 대한 외부 링크가 포함된 통합 문서 사용    통합 문서에 다른 통합 문서의 Excel 테이블에 대한 외부 링크가 포함된 경우 링크가 포함된 대상 통합 문서의 #REF! 오류를 방지하려면 연결된 원본 통합 문서를 Excel에서 열어야 합니다. 대상 통합 문서를 먼저 열고 #REF! 오류가 표시되면 원본 통합 문서를 열면 해결됩니다. 원본 통합 문서를 먼저 열면 오류 코드가 표시되지 않습니다.

  • 범위를 표로 또는 표를 범위로 변환    테이블을 범위로 변환하면 모든 셀 참조가 해당 절대 A1 스타일 참조로 변경됩니다. 범위를 테이블로 변환할 때 Excel에서는 이 범위의 셀 참조를 해당 구조화된 참조로 자동으로 변경하지 않습니다.

  • 열 머리글 해제    표 디자인 탭 > 머리글 행에서 테이블 열 머리글을 켜고 끌 수 있습니다. 테이블 열 머리글을 해제하는 경우 열 이름을 사용하는 구조화된 참조는 영향을 받지 않으며 수식에서도 사용할 수 있습니다. 테이블 헤더를 직접 참조하는 구조적 참조(예: =DeptSales[[#Headers],[%Commission]])는 #REF 발생합니다.

  • 표에 열 및 행 추가 또는 삭제    테이블 데이터 범위가 자주 변경되기 때문에 구조화된 참조에 대한 셀 참조가 자동으로 조정됩니다. 예를 들어 수식에 표 이름을 사용하여 표에 있는 모든 데이터 셀의 합계를 구하는 경우 데이터 행을 추가하면 셀 참조가 자동으로 조정됩니다.

  • 표 또는 열 이름 바꾸기    열 또는 표의 이름을 바꾸면 통합 문서에 사용되는 모든 구조적 참조에서 해당 표 및 열 머리글 사용이 자동으로 변경됩니다.

  • 구조적 참조 이동, 복사, 채우기    구조적 참조를 사용하는 수식을 복사하거나 이동할 경우 모든 구조적 참조는 동일하게 유지됩니다.

    참고: 구조화된 참조를 복사하고 구조화된 참조를 채우는 것은 동일하지 않습니다. 복사할 때 모든 구조적 참조는 동일하게 유지되지만 수식을 채울 때 정규화된 구조화된 참조는 다음 표에 요약된 대로 계열과 같은 열 지정자를 조정합니다.

채우기 방향

그리고 채우는 동안 다음을 누릅니다.

결과

위 또는 아래

없음

열 지정자 조정이 없습니다.

위 또는 아래

Ctrl

열 지정자가 계열처럼 조정됩니다.

오른쪽 또는 왼쪽

없음

열 지정자가 계열처럼 조정됩니다.

위, 아래, 오른쪽 또는 왼쪽

Shift

현재 셀의 값을 덮어쓰는 대신 현재 셀 값이 이동하고 열 지정자가 삽입됩니다.

추가 지원

언제든지 Excel 기술 커뮤니티에서 전문가에게 문의하거나 커뮤니티에서 지원을 받을 수 있습니다.

관련 주제

Excel 테이블
개요비디오: Excel 테이블
만들기 및 서식 지정Excel 테이블
의 데이터 합계Excel 표
서식 지정행 및 열을 추가하거나 제거하여 테이블 크기 조정
범위 또는 테이블
의 데이터 필터링테이블을 범위
로 변환Excel 테이블 호환성 문제
Excel 테이블을 SharePoint
로 내보내기Excel의 수식 개요

도움이 더 필요하세요?

더 많은 옵션을 원하세요?

구독 혜택을 살펴보고, 교육 과정을 찾아보고, 디바이스를 보호하는 방법 등을 알아봅니다.

커뮤니티를 통해 질문하고 답변하고, 피드백을 제공하고, 풍부한 지식을 갖춘 전문가의 의견을 들을 수 있습니다.

이 정보가 유용한가요?

언어 품질에 얼마나 만족하시나요?
사용 경험에 어떠한 영향을 주었나요?
제출을 누르면 피드백이 Microsoft 제품과 서비스를 개선하는 데 사용됩니다. IT 관리자는 이 데이터를 수집할 수 있습니다. 개인정보처리방침

의견 주셔서 감사합니다!

×