함수를 사용한 여러 열으로 텍스트 나누기

함수를 사용한 여러 열으로 텍스트 나누기

참고:  사용자 언어로 가능한 한 빨리 가장 최신의 도움말 콘텐츠를 제공하고자 합니다. 이 페이지는 자동화를 통해 번역되었으며 문법 오류나 부정확한 설명을 포함할 수 있습니다. 이 목적은 콘텐츠가 사용자에게 유용하다는 것입니다. 이 페이지 하단의 정보가 도움이 되었다면 알려주세요. 쉽게 참조할 수 있는 영어 문서 가 여기 있습니다.

LEFT, MID, RIGHT, SEARCH 및 LEN 텍스트 함수를 사용하여 데이터에 있는 텍스트 문자열을 조작할 수 있습니다. 예를 들어 단일 셀에 있는 이름, 중간 이름 및 성을 세 개의 별도 열로 분할할 수 있습니다.

텍스트 함수를 사용하여 이름 구성 요소를 분할할 때는 텍스트 문자열 내에 있는 각 문자의 위치가 중요하며, 문자열에서 이름 구성 요소의 시작과 끝을 나타내는 텍스트 문자열 내 공백의 위치도 중요합니다.

예를 들어 이름과 성만 포함된 셀에서 성은 첫 번째 공백 다음에 시작합니다. 목록의 일부 이름에는 중간 이름이 있을 수 있으며 이러한 경우 성은 두 번째 공백 다음에 시작합니다.

이 문서는 다양 한 이러한 유용한 함수를 사용 하 여 이름 형식에서에서 여러 구성 요소를 추출 하는 방법을 보여 줍니다. 여러 열으로 텍스트 나누기 마법사를 변환 된 텍스트를 분할할 수도 있습니다.

예제 이름

설명

이름

중간 이름

호칭

1

Jeff Smith

중간 이름 없음

Jeff

Smith

2

Eric S. Kurjan

중간 이름 이니셜 한 개

Eric

S.

Kurjan

3

Janaina b에 없습니다. G. Bueno

중간 이름 이니셜 두 개

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

성 먼저(쉼표로 구분)

Wendy

Beth

Kahn

5

Mary Kay 채워졌습니다. 백화점 ㈜

이름이 두 부분으로 이루어짐

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

성이 세 부분으로 이루어짐

Paula

Barreto de Mattos

7

James van Eaton

성이 두 부분으로 이루어짐

James

van Eaton

8

Bacon Jr., Dan k.

성과 호칭 먼저(쉼표로 구분)

Dan

K.

Bacon

Jr.

9

Gary Altman III

호칭 있음

Gary

Altman

III

10

씨 주진 Ihrig

호칭 있음

Ryan

Ihrig

11

Julie Taft-rider

성이 하이픈으로 연결됨

Julie

Taft-Rider

참고: 다음 예제에서 그래픽을 전체 이름에서 강조 된 부분은 해당 SEARCH 수식에서 찾고 있는 문자를 보여 줍니다.

이 예제에서는 두 가지 구성 요소를 구분: 이름, 성을 합니다. 단일 공백 두 이름을 구분합니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Jeff Smith

중간 이름 없음

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름은 문자열에서 첫 번째 문자(J)로 시작하여 5번째 문자(공백)에서 끝납니다. 수식은 셀 A2에서 왼쪽부터 5개 문자를 반환합니다.

    이름을 추출하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2에서 왼쪽부터 계산한 공백의 숫자 위치를 검색합니다.

  2. 이름  

    성은 오른쪽 5개 문자이며 공백에서 시작하여 오른쪽의 마지막 문자(h)에서 끝납니다. 수식은 A2에서 오른쪽부터 5개 문자를 추출합니다.

    성을 추출하는 수식

    SEARCH 및 LEN 함수를 사용하여 num_chars 값을 찾습니다.

    A2에서 왼쪽부터 계산한 공백의 숫자 위치를 검색합니다. (5)

  3. 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 1단계에서 찾은 첫 번째 공백까지의 문자 수를 뺍니다.

이 예제에서는 이름, 중간 이름 이니셜, 성을 사용합니다. 각 이름 구성 요소는 공백으로 구분됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Eric S. Kurjan

중간 이름 이니셜 한 개

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(중간 이름 이니셜)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

수식

실시간 결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 이름은 왼쪽의 첫 번째 문자(E)로 시작하여 5번째 문자(첫 번째 공백)에서 끝납니다. 수식은 A2에서 왼쪽부터 처음 5개 문자를 추출합니다.

    성, 이름, 중간 이름 이니셜을 구분 하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2에서 왼쪽부터 공백의 숫자 위치(5)를 검색합니다.

  2. 중간 이름

    중간 이름은 6번째 문자 위치(S)에서 시작하여 8번째 위치(두 번째 공백)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 두 번째 공백을 찾습니다.

    수식은 6번째 위치부터 3개 문자를 추출합니다.

    이름, 중간 이름, 성을 구분하는 수식의 세부 정보

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5).

  3. 1을 더하여 첫 번째 공백 다음 문자(S)의 위치를 구합니다. 이 숫자 위치는 중간 이름의 시작 위치입니다. (5 + 1 = 6)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  4. 1을 더하여 첫 번째 공백 다음 문자(S)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (5 + 1 = 6)

  5. 4단계에서 찾은 6번째 위치(S)부터 A2에서 두 번째 공백을 검색합니다. 이 문자 번호는 중간 이름의 끝 위치(8)입니다.

  6. A2의 왼쪽 첫 번째 문자부터 계산한 공백의 숫자 위치를 검색합니다. (5)

  7. 5단계에서 찾은 두 번째 공백의 문자 번호에서 6단계에서 찾은 첫 번째 공백의 문자 번호를 뺍니다. 결과는 2단계에서 찾은 6번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (8 ? 5 = 3)

  8. 이름  

    성은 오른쪽에서 6번째 문자(K)에서 시작하여 오른쪽에서 첫 번째 문자(n)에서 끝납니다. 이 수식은 SEARCH 함수를 중첩해서 사용하여 두 번째와 세 번째 공백(왼쪽에서 5번째와 8번째 위치)을 찾습니다.

    수식은 A2에서 오른쪽부터 6개 문자를 추출합니다.

    이름 첫 번째, 중간 이름, 성을 구분 하는 수식에서 두 번째 SEARCH 함수
  9. LEN 함수와 함께 SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 공백의 숫자 위치를 검색합니다. (5)

  10. 1을 더하여 첫 번째 공백 다음 문자(S)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (5 + 1 = 6)

  11. 2단계에서 찾은 6번째 위치(S)부터 A2에서 두 번째 공백을 검색합니다. 이 문자 번호는 중간 이름의 끝 위치입니다. (8)

  12. A 2에서 텍스트 문자열의 전체 길이 계산 하 고 3 단계에서 찾은 공백의 두 번째 인스턴스 올림 왼쪽의 문자 수를 뺍니다. 결과 전체 이름의 오른쪽부터 추출 하는 문자 수입니다. (14-8 = 6).

다음은 중간 이름 이니셜 두 개를 추출하는 방법을 보여 주는 예제입니다. 이름 구성 요소는 첫 번째 공백과 세 번째 공백으로 구분됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Janaina B. G Bueno

중간 이름 이니셜 두 개

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(중간 이름 이니셜)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

수식

실시간 결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. 이름은 왼쪽에서 첫 번째 문자(J)로 시작하여 8번째 문자(첫 번째 공백)에서 끝납니다. 수식은 A2에서 왼쪽부터 처음 8개 문자를 추출합니다.

    이름, 성, 두 개의 중간 이름 이니셜을 구분하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  2. 중간 이름

    중간 이름은 9번째 위치(B)에서 시작하여 14번째 위치(세 번째 공백)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 8번째, 11번째 및 14번째 위치에서 첫 번째, 두 번째 및 세 번째 공백을 찾습니다.

    수식은 9번째 위치부터 5개 문자를 추출합니다.

    이름, 성, 두 개의 중간 이름 이니셜을 구분하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  3. 1을 더하여 첫 번째 공백 다음 문자(B)의 위치를 구합니다. 이 숫자 위치는 중간 이름의 시작 위치입니다. (8 + 1 = 9)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  4. 1을 더하여 첫 번째 공백 다음 문자(B)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (8 + 1 = 9)

  5. 4 단계에서 찾은 9 번째 위치 (B)부터 a 2에서 두 번째 공백에 대 한 검색 합니다. (11)입니다.

  6. 1을 더하여 두 번째 공백 다음 문자(G)의 위치를 구합니다. 이 문자 번호는 세 번째 공백 검색을 시작할 시작 위치입니다. (11 + 1 = 12)

  7. 6단계에서 찾은 12번째 위치부터 A2의 세 번째 공백을 검색합니다. (14)

  8. A2에서 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  9. 7단계에서 찾은 세 번째 공백의 문자 번호에서 6단계에서 찾은 첫 번째 공백의 문자 번호를 뺍니다. 결과는 2단계에서 찾은 9번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다.

  10. 이름  

    성은 오른쪽에서 5번째 문자(B)에서 시작하여 오른쪽에서 첫 번째 문자(o)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 첫 번째, 두 번째 및 세 번째 공백을 찾습니다.

    수식은 A2에서 전체 이름의 오른쪽부터 5개 문자를 추출합니다.

    이름, 성, 두 개의 중간 이름 이니셜을 구분하는 수식

    LEN 함수와 함께 SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (8)

  11. 1을 더하여 첫 번째 공백 다음 문자(B)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (8 + 1 = 9)

  12. 2단계에서 찾은 9번째 위치(B)부터 A2의 두 번째 공백을 검색합니다. (11)

  13. 1을 더하여 두 번째 공백 다음 문자(G)의 위치를 구합니다. 이 문자 번호는 세 번째 공백을 검색하기 시작할 시작 위치입니다. (11 + 1 = 12)

  14. 6단계에서 찾은 12번째 위치(G)부터 A2의 세 번째 공백을 검색합니다. (14)

  15. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 5단계에서 찾은 세 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (19 - 14 = 5)

이 예제에서는 성이 이름 앞에 오고 중간 이름이 끝에 나타납니다. 성의 끝은 쉼표로 표시되고 각 이름 구성 요소는 공백으로 구분됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Kahn, Wendy Beth

성 먼저(쉼표로 구분)

수식

결과(이름)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

수식

결과(중간 이름)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

수식

실시간 결과(성)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. 이름은 왼쪽에서 7번째 문자(W)로 시작하여 12번째 문자(두 번째 공백)에서 끝납니다. 이름이 전체 이름의 중간에 표시되므로 MID 함수를 사용하여 이름을 추출해야 합니다.

    수식은 7번째 위치부터 6개 문자를 추출합니다.

    이름과 중간 이름이 이어지는 성을 구분하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  2. 1을 더하여 첫 번째 공백 다음 문자(W)의 위치를 구합니다. 이 숫자 위치는 이름의 시작 위치입니다. (6 + 1 = 7)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  3. 1을 더하여 첫 번째 공백 다음 문자(W)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (6 + 1 = 7)

    4단계에서 찾은 7번째 위치(W)부터 A2의 두 번째 공백을 검색합니다. (12)

  4. A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  5. 5단계에서 찾은 두 번째 공백의 문자 번호에서 6단계에서 찾은 첫 번째 공백의 문자 번호를 뺍니다. 결과는 2단계에서 찾은 7번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (12 - 6 = 6)

  6. 중간 이름

    중간 이름은 오른쪽에서 4번째 문자(B)에서 시작하여 오른쪽에서 첫 번째 문자(h)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 왼쪽에서 6번째와 12번째 위치에서 첫 번째와 두 번째 공백을 찾습니다.

    수식은 오른쪽부터 4개 문자를 추출합니다.

    이름과 중간 이름이 이어지는 성을 구분하는 수식

    LEN 함수와 함께 SEARCH 함수를 중첩해서 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  7. 1을 더하여 첫 번째 공백 다음 문자(W)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (6 + 1 = 7)

  8. 2단계에서 찾은 7번째 위치(W)부터 A2의 두 번째 공백을 검색합니다. (12)

  9. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 3단계에서 찾은 두 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (16 - 12 = 4)

  10. 이름  

    성은 왼쪽에서 첫 번째 문자(K)로 시작하여 네 번째 문자(n)에서 끝납니다. 수식은 왼쪽부터 4개 문자를 추출합니다.

    이름과 중간 이름이 이어지는 성을 구분하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  11. 2를 빼서 성의 마지막 문자(n)의 숫자 위치를 구합니다. 결과는 LEFT가 추출할 문자 수입니다. (6 - 2 =4)

이 예제에서는 두 부분으로 이루어진 이름인 Mary Kay를 사용합니다. 각 이름 구성 요소는 두 번째 공백과 세 번째 공백으로 구분됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Mary Kay D. Andersen

이름이 두 부분으로 이루어짐

수식

결과(이름)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

수식

결과(중간 이름 이니셜)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

수식

실시간 결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. 이름은 왼쪽에서 첫 번째 문자로 시작하여 9번째 문자(두 번째 공백)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 왼쪽에서 두 번째 공백을 찾습니다.

    수식은 왼쪽부터 9개 문자를 추출합니다.

    이름, 중간 이름, 중간 이름 이니셜, 성을 구분하는 수식

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  2. 1을 더하여 첫 번째 공백 다음 문자(K)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (5 + 1 = 6)

  3. 2단계에서 찾은 6번째 위치(K)부터 A2에서 두 번째 공백을 검색합니다. 결과는 LEFT가 텍스트 문자열에서 추출하는 문자 수(9)입니다.

  4. 중간 이름

    중간 이름은 10번째 위치(D)에서 시작하여 12번째 위치(세 번째 공백)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 첫 번째, 두 번째 및 세 번째 공백을 찾습니다.

    수식은 10번째 위치부터 중간에서 2개 문자를 추출합니다.

    이름, 중간 이름, 중간 이름 이니셜, 성을 구분하는 수식

    SEARCH 함수를 중첩해서 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽 첫 번째 문자부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  5. 1을 더하여 첫 번째 공백 다음 문자(K)를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (5 + 1 = 6)

  6. 2단계에서 찾은 6번째 위치(K)부터 A2에서 두 번째 공백의 위치를 검색합니다. 결과는 LEFT가 왼쪽에서 추출하는 문자 수(9)입니다.

  7. 1을 더하여 두 번째 공백 다음 문자(D)를 구합니다. 결과는 중간 이름의 시작 위치입니다. (9 + 1 = 10)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    두 번째 공백 다음 문자(D)의 숫자 위치를 검색합니다. 결과는 세 번째 공백 검색을 시작할 문자 번호(10)입니다.

  8. A2에서 왼쪽부터 세 번째 공백의 숫자 위치를 검색합니다. 결과는 중간 이름의 끝 위치(12)입니다.

  9. 두 번째 공백 다음 문자(D)의 숫자 위치를 검색합니다. 결과는 중간 이름의 시작 위치(10)입니다.

  10. 6단계에서 찾은 세 번째 공백의 문자 번호에서 7단계에서 찾은 “D”의 문자 번호를 뺍니다. 결과는 4단계에서 찾은 10번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (12 - 10 = 2)

  11. 이름  

    성은 오른쪽에서 8번째 문자에서 시작합니다. 이 수식은 SEARCH를 중첩해서 사용하여 5번째, 9번째 및 12번째 위치에서 첫 번째, 두 번째 및 세 번째 공백을 찾습니다.

    수식은 오른쪽부터 8개 문자를 추출합니다.

    이름, 중간 이름, 중간 이름 이니셜, 성을 구분하는 수식

    LEN 함수와 함께 SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  12. 1을 더하여 첫 번째 공백 다음 문자(K)를 구합니다. 결과는 공백 검색을 시작할 문자 번호입니다. (5 + 1 = 6)

  13. 2단계에서 찾은 6번째 위치(K)부터 A2의 두 번째 공백을 검색합니다. (9)

  14. 1을 더하여 두 번째 공백 다음 문자(D)의 위치를 구합니다. 결과는 중간 이름의 시작 위치입니다. (9 + 1 = 10)

  15. A2에서 왼쪽부터 세 번째 공백의 숫자 위치를 검색합니다. 결과는 중간 이름의 끝 위치(12)입니다.

  16. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 5단계에서 찾은 세 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (20 - 12 = 8)

이 예제에서는 성이 세 부분으로 이루어진 Barreto de Mattos를 사용합니다. 이름의 끝과 성의 시작은 첫 번째 공백으로 표시됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Paula Barreto de Mattos

성이 세 부분으로 이루어짐

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름은 왼쪽에서 첫 번째 문자(P)로 시작하여 6번째 문자(첫 번째 공백)에서 끝납니다. 수식은 왼쪽부터 6개 문자를 추출합니다.

    첫 번째 이름과 3 부 성을 구분 하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  2. 이름  

    성은 오른쪽에서 17번째 문자(B)에서 시작하여 오른쪽에서 첫 번째 문자(s)로 끝납니다. 수식은 오른쪽부터 17개 문자를 추출합니다.

    첫 번째 이름과 3 부 성을 구분 하는 수식

    LEN 및 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  3. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 1단계에서 찾은 첫 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (23 - 6 = 17)

이 예제에서는 성이 두 부분으로 이루어진 van Eaton을 사용합니다. 이름의 끝과 성의 시작은 첫 번째 공백으로 표시됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

James van Eaton

성이 두 부분으로 이루어짐

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름은 왼쪽에서 첫 번째 문자(J)로 시작하여 8번째 문자(첫 번째 공백)에서 끝납니다. 수식은 왼쪽부터 6개 문자를 추출합니다.

    이름, 성의 두 부분을 구분하는 수식

    SEARCH 함수를 사용 하 여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  2. 이름  

    성은 오른쪽에서 9번째 문자(v)로 시작하여 오른쪽에서 첫 번째 문자(n)에서 끝납니다. 수식은 전체 이름의 오른쪽부터 9개 문자를 추출합니다.

    이름, 성의 두 부분을 구분하는 수식

    LEN 및 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  3. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 1단계에서 찾은 첫 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (15 - 6 = 9)

이 예제에서는 성과 호칭이 앞에 옵니다. 성 및 호칭과 이름 및 중간 이름 이니셜은 쉼표로 구분됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Bacon Jr., Dan K.

성과 호칭 먼저(쉼표로 구분)

수식

결과(이름)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

수식

결과(중간 이름 이니셜)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

수식

결과(성)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(호칭)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. 이름은 12번째 문자(D)로 시작하여 15번째 문자(세 번째 공백)로 끝납니다. 수식은 12번째 위치부터 3개 문자를 추출합니다.

    마지막 구분 하는 수식 이름을 지정 하 고 호칭 먼저 쉼표로 구분

    SEARCH 함수를 중첩해서 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  2. 1을 더하여 첫 번째 공백 다음 문자(J)를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (6 + 1 = 7)

  3. 2단계에서 찾은 7번째 위치(J)부터 A2의 두 번째 공백(11)을 검색합니다. (11)

  4. 1을 더하여 두 번째 공백 다음 문자(D)를 구합니다. 결과는 이름의 시작 위치입니다. (11 + 1 = 12)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    두 번째 공백 다음 문자(D)의 숫자 위치를 검색합니다. 결과는 세 번째 공백을 검색하기 시작할 문자 번호입니다. (12)

  5. A2에서 왼쪽부터 세 번째 공백의 숫자 위치를 검색합니다. 결과는 이름의 끝 위치(15)입니다.

  6. 두 번째 공백 다음 문자(D)의 숫자 위치를 검색합니다. 결과는 이름의 시작 위치(12)입니다.

  7. 6단계에서 찾은 세 번째 공백의 문자 번호에서 7단계에서 찾은 “D”의 문자 번호를 뺍니다. 결과는 4단계에서 찾은 12번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (15 - 12 = 3)

  8. 중간 이름

    중간 이름은 오른쪽에서 두 번째 문자(K)로 시작합니다. 수식은 오른쪽부터 2개 문자를 추출합니다.

    마지막 구분 하는 수식 이름을 지정 하 고 호칭 먼저 쉼표로 구분

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  9. 1을 더하여 첫 번째 공백 다음 문자(J)를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (6 + 1 = 7)

  10. 2단계에서 찾은 7번째 위치(J)부터 A2의 두 번째 공백(11)을 검색합니다. (11)

  11. 1을 더하여 두 번째 공백 다음 문자(D)를 구합니다. 결과는 이름의 시작 위치입니다. (11 + 1 = 12)

  12. 왼쪽부터 a 2에서 세 번째 공백의 숫자 위치를 검색 합니다. 결과 중간 이름의 끝 위치입니다. (15).

  13. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 5단계에서 찾은 세 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (17 - 15 = 2)

  14. 이름  

    성은 왼쪽에서 첫 번째 문자(B)에서 시작하여 6번째 문자(첫 번째 공백)에서 끝납니다. 따라서 수식은 왼쪽부터 6개 문자를 추출합니다.

    마지막 구분 하는 수식 이름을 지정 하 고 호칭 먼저 쉼표로 구분

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  15. 호칭

    호칭은 왼쪽 7번째 문자(J)에서 시작하여 왼쪽 9번째 문자(.)에서 끝납니다. 수식은 7번째 문자부터 3개 문자를 추출합니다.

    마지막 구분 하는 수식 이름을 지정 하 고 호칭 먼저 쉼표로 구분

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  16. 1을 더하여 첫 번째 공백 다음 문자(J)를 구합니다. 결과는 접미사의 시작 위치입니다. (6 + 1 = 7)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  17. 1을 더하여 첫 번째 공백 다음 문자(J)의 숫자 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호(7)입니다.

  18. 4단계에서 찾은 7번째 문자부터 A2의 두 번째 공백에 해당하는 숫자 위치(11)를 검색합니다. (11)

  19. 4단계에서 찾은 두 번째 공백의 문자 번호에서 1을 빼서 “,”의 문자 번호를 구합니다. 결과는 호칭의 끝 위치입니다. (11 - 1 = 10)

  20. 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  21. 첫 번째 공백을 찾은 후에 1을 더하여 3단계와 4단계에도 있는 다음 문자(J)를 찾습니다. (7)

  22. 6단계에서 찾은 “,”의 문자 번호에서 3단계와 4단계에서 찾은 “J”의 문자 번호를 뺍니다. 결과는 2단계에서 찾은 7번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (10 - 7 = 3)

이 예제에서는 이름이 문자열 시작 부분에 있고 호칭이 이름 끝에 있습니다. 따라서 예제 2와 비슷한 수식을 사용할 수 있습니다. 즉, LEFT 함수를 사용하여 이름을 추출하고, MID 함수를 사용하여 성을 추출하고, RIGHT 함수를 사용하여 호칭을 추출할 수 있습니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Gary Altman III

호칭이 있는 이름과 성

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

수식

결과(호칭)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 이름은 왼쪽에서 첫 번째 문자(G)에서 시작하여 5번째 문자(첫 번째 공백)에서 끝납니다. 따라서 수식은 전체 이름의 왼쪽부터 5개 문자를 추출합니다.

    먼저, 뒤에 접미사가 성을 구분 하는 수식

    왼쪽부터 a 2에서 첫 번째 공백의 숫자 위치를 검색 합니다. (5).

  2. 이름  

    성은 왼쪽에서 6번째 문자(A)에서 시작하여 11번째 문자(두 번째 공백)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 공백의 위치를 찾습니다.

    수식은 6번째 문자부터 중간에서 6개 문자를 추출합니다.

    먼저, 뒤에 접미사가 성을 구분 하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  3. 1을 더하여 첫 번째 공백 다음 문자(A)의 위치를 구합니다. 결과는 성의 시작 위치입니다. (5 + 1 = 6)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  4. 1을 더하여 첫 번째 공백 다음 문자(A)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (5 + 1 = 6)

  5. 4단계에서 찾은 6번째 문자부터 A2에서 두 번째 공백의 숫자 위치를 검색합니다. 이 문자 번호는 성의 끝 위치(12)입니다.

  6. 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  7. 1을 더하여 3단계와 4단계에도 있는 첫 번째 공백 다음 문자(A)의 숫자 위치를 찾습니다. (6)

  8. 5단계에서 찾은 두 번째 공백의 문자 번호에서 6단계와 7단계에서 찾은 “A”의 문자 번호를 뺍니다. 결과는 2단계에서 찾은 6번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (12 - 6 = 6)

  9. 호칭

    호칭은 오른쪽에서 3번째 문자에서 시작합니다. 이 수식은 SEARCH를 중첩해서 사용하여 공백의 위치를 찾습니다.

    먼저, 뒤에 접미사가 성을 구분 하는 수식

    LEN 함수와 함께 SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (5)

  10. 1을 더하여 첫 번째 공백 다음 문자(A)를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (5 + 1 = 6)

  11. 2단계에서 찾은 6번째 위치(A)부터 A2의 두 번째 공백을 검색합니다. (12)

  12. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 3단계에서 찾은 두 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (15 - 12 = 3)

이 예제에서는 전체 이름 앞에 호칭이 있습니다. 따라서 예제 2와 비슷한 수식을 사용합니다. 즉, MID 함수를 사용하여 이름을 추출하고 RIGHT 함수를 사용하여 성을 추출합니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Mr. Ryan Ihrig

호칭 있음

수식

결과(이름)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 이름은 왼쪽의 5번째 문자(R)로 시작하여 9번째 문자(두 번째 공백)에서 끝납니다. 이 수식은 SEARCH를 중첩해서 사용하여 공백의 위치를 찾습니다. 수식은 5번째 위치부터 4개 문자를 추출합니다.

    앞에 호칭이 이름을 구분 하는 수식

    SEARCH 함수를 사용하여 start_num 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (4)

  2. 1을 더하여 첫 번째 공백 다음 문자(R)의 위치를 구합니다. 결과는 이름의 시작 위치입니다. (4 + 1 = 5)

    SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (4)

  3. 1을 더하여 첫 번째 공백 다음 문자(R)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (4 + 1 = 5)

  4. 3단계와 4단계에서 찾은 5번째 문자부터 A2에서 두 번째 공백의 숫자 위치를 검색합니다. 이 문자 번호는 이름의 끝 위치(9)입니다.

  5. 첫 번째 공백을 검색합니다. (4)

  6. 1을 더하여 3단계와 4단계에도 있는 첫 번째 공백 다음 문자(R)의 숫자 위치를 찾습니다. (5)

  7. 5단계에서 찾은 두 번째 공백의 문자 번호에서 6단계와 7단계에서 찾은 “R”의 문자 번호를 뺍니다. 결과는 2단계에서 찾은 5번째 위치부터 MID가 텍스트 문자열에서 추출하는 문자 수입니다. (9 - 5 = 4)

  8. 이름  

    성은 오른쪽에서 5번째 문자에서 시작합니다. 이 수식은 SEARCH를 중첩해서 사용하여 공백의 위치를 찾습니다.

    앞에 호칭이 이름을 구분 하는 수식

    LEN 함수와 함께 SEARCH 함수를 중첩해서 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (4)

  9. 1을 더하여 첫 번째 공백 다음 문자(R)의 위치를 구합니다. 결과는 두 번째 공백 검색을 시작할 문자 번호입니다. (4 + 1 = 5)

  10. 2단계에서 찾은 5번째 위치(R)부터 A2의 두 번째 공백을 검색합니다. (9)

  11. A2에 있는 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 3단계에서 찾은 두 번째 공백까지의 문자 수를 뺍니다. 결과는 전체 이름의 오른쪽에서 추출할 문자 수입니다. (14 - 9 = 5)

이 예제에서는 하이픈으로 연결된 성을 사용합니다. 각 이름 구성 요소는 공백으로 구분됩니다.

표의 셀을 복사 하 고 Excel 워크시트의 A1 셀에 붙여 넣습니다. Excel을 적절 한 결과에 오른쪽에서 수식의 자동으로 변환 하는 동안 왼쪽에 표시 하는 수식은 참고로 표시 됩니다.

힌트    워크시트에 데이터를 붙여 넣기 전에 A 및 B 열의 열 너비를 250로 설정하세요.

예제 이름

설명

Julie Taft-Rider

성이 하이픈으로 연결됨

수식

결과(이름)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

수식

결과(성)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 이름은 왼쪽에서 첫 번째 문자에서 시작하여 6번째 위치(첫 번째 공백)에서 끝납니다. 수식은 왼쪽부터 6개 문자를 추출합니다.

    먼저, 하이픈 사용된 성을 구분 하는 수식

    SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    A2의 왼쪽부터 계산한 첫 번째 공백의 숫자 위치를 검색합니다. (6)

  2. 이름  

    전체 성은 오른쪽에서 10번째 문자(T)에서 시작하여 오른쪽에서 첫 번째 문자(r)에서 끝납니다.

    먼저, 하이픈 사용된 성을 구분 하는 수식

    LEN 및 SEARCH 함수를 사용하여 num_chars 값을 찾습니다.

    왼쪽에서 첫 번째 문자부터 A2의 공백에 해당하는 숫자 위치를 검색합니다. (6)

  3. 추출할 텍스트 문자열의 전체 길이를 계산하고 왼쪽부터 1단계에서 찾은 첫 번째 공백까지의 문자 수를 뺍니다. (16 - 6 = 10)

참고 항목

텍스트 나누기 마법사를 변환 된 여러 열으로 텍스트 나누기

Office 기술 확장
교육 살펴보기
새로운 기능 우선 가져오기
Office Insider 참여

이 정보가 유용한가요?

의견 주셔서 감사합니다!

피드백을 주셔서 감사합니다. Office 지원 에이전트와 연락하는 것이 도움이 될 것 같습니다.

×