TEXT 関数

注: 最新のヘルプ コンテンツをできるだけ早く、お客様がお使いの言語で提供したいと考えております。このページは、自動翻訳によって翻訳されているため、文章校正のエラーや不正確な情報が含まれている可能性があります。私たちの目的は、このコンテンツがお客様の役に立つようにすることです。お客様にとって役立つ情報であったかどうかを、このページの下部でお知らせください。簡単に参照できるように、こちらに英語の記事があります。

TEXT 関数を使用すると、表示形式コードを使用して数値に書式設定を適用することで、数値の表示方法を変更することができます。これは、数値をより読みやすい形式で表示する場合や、数値を文字列または記号と組み合わせる場合に便利です。

注: TEXT 関数は、数値を文字列に変換します。そのため、後の計算で参照するのが困難になる可能性があります。1 つのセルに元の値を保持し、別のセルで TEXT 関数を使用することをお勧めします。この後、他の数式を作成する必要がある場合は必ず、TEXT 関数の結果ではなく、元の値を参照するようにします。

構文

TEXT(value, format_text)

TEXT 関数の構文には、次の引数があります。

引数名

説明

value

テキストに変換する数値。

format_text

指定された値に適用する書式を定義するテキスト文字列。

概要

その最も簡単な形式で、TEXT 関数は次のようになります。

  • =TEXT(書式設定する値, "適用する表示形式コード")

次に、よく使われている例をいくつか紹介します。これを Excel に直接コピーして、自分で試してみることができます。表示形式コードを引用符で囲む必要があることにご注意ください。

数式

説明

=TEXT(1234.567,"$#,##0.00")

桁区切り記号と小数点以下 2 桁を設定した通貨 (例: $1,234.57)。Excel は、値を小数点以下 2 桁に四捨五入することにご注意ください。

=TEXT(TODAY(),"MM/DD/YY")

月/日/年の形式の今日の日付 (例: 03/14/12)

=TEXT(TODAY(),"DDDD")

今日の曜日 (例: Monday)

=TEXT(NOW(),"H:MM AM/PM")

現在の時刻 (例: 1:29 PM)

=TEXT(0.285,"0.0%")

パーセンテージ (例: 28.5%)

= TEXT ("# ?/?")

分数 (例: 4 1/3)

=TRIM(TEXT(0.34,"# ?/?"))

分数 (例: 1/3)。これは、TRIM 関数を使用して小数点の先頭のスペースと 10 進数を削除することにご注意ください。

=TEXT(12200000,"0.00E+00")

指数表記 (例: 1.22E+07)

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

その他 (電話番号) (例: (123) 456-7898)

=TEXT(1234,"0000000")

先頭のゼロ (0) を追加 (例: 0001234)

=TEXT(123456,"##0° 00' 00''")

ユーザー設定 - 緯度/経度

注: テキスト関数を使用して書式設定を変更することはできますが、これは唯一の方法ではありません。数式を使わずに書式を変更するには、CTRL キーを押しながら1 (または Mac で MAC のコマンド ボタン アイコンの画像 + 1 ) を押すと、[セルの書式設定]、[数値] ダイアログから目的の書式を選ぶことができます。

サンプルをダウンロードする

この記事に記載されているすべてのテキスト関数の例を使用して、サンプルブックをダウンロードすることができます。フォローすることも、独自のテキスト関数形式コードを作成することもできます。Excel のテキスト関数の例をダウンロードする

使用可能なその他の表示形式コード

[セルの書式設定] ダイアログには、他にも使用可能な表示形式コードがあります。

  1. Ctrl + 1 キー (Mac の場合は、 MAC のコマンド ボタン アイコンの画像 + 1 キー) を押して、[セルの書式設定] ダイアログを表示します。

  2. [表示形式] タブで目的の表示形式を選びます。

  3. [ユーザー定義] オプションを選びます。

  4. 目的の表示形式コードが [種類] ボックスに表示されます。ここでは、[種類] ボックスで、セミコロン (;) と @ 記号を除くすべての文字を選択します。次の図は、mm/dd/yy のみを選んでコピーした時点の画面を示しています。

  5. Ctrl + C キーを押して表示形式コードをコピーし、[キャンセル] を押すと、[セルの書式設定] ダイアログが消えます。

  6. 後は、Ctrl + V キーを押して表示形式コードを TEXT 関数の数式に貼り付けるだけです。たとえば、=TEXT(B2,"mm/dd/yy") となります。必ず、引用符の中に表示形式コードを貼り付けてください。そうしなれば、Excel でエラー メッセージが表示されます。

[書式]、[セルの書式設定]、[数値]、[ユーザー定義] ダイアログ ボックスの順に選択し、Excel に自動的に書式設定文字列を作成させる例。

カテゴリ別の表示形式コード

次に、[セルの書式設定] ダイアログの [ユーザー定義] オプションを使用して、表示形式コードTEXT 関数にコピーすることで、数値のさまざまな表示形式を値に適用する方法の例をいくつか示します。

Excel で先頭の 0 が削除されるのはなぜですか。

Excel では、セルに入力されている数値ではなく、数値や SKU のように、テキストのように見えます。先頭の0を保持するには、値を貼り付けるか入力する前に、入力範囲をテキストとして書式設定します。値を配置する列または範囲を選択し、 CTRL キーを押しながら 1を使用して [書式]、[セル] の順にクリックし、[数値] タブの [テキスト] を選択します。これで、Excel では先頭の0が維持されます。

データを既に入力し、Excel によって、先頭の 0 が削除された場合、TEXT 関数を使用して、先頭の 0 をもう一度追加することができます。値のある 1 番上のセルを参照して、=TEXT(value,"00000") を使用できます。ここで数式内の 0 の個数は、目的の合計文字数を表します。次に、この TEXT 関数をコピーして、範囲の残りの部分に貼り付けます。

TEXT を使用して、先頭のゼロを書式設定する例。=TEXT(A2,"00000")

何らかの理由で、文字列の値を数値に戻す必要がある場合は、1 を乗算するか (例: =D4*1)、二重単項演算子 (--) を使用することができます (例: =--D4)。

Excel では、番号記号 (#) またはゼロで囲まれたコンマが表示形式に含まれている場合、数値が 3 桁ごとにコンマで区切られます。たとえば、書式設定文字列が "#,###" の場合、Excel では、数値 12200000 が 12,200,000 として表示されます。

桁プレースホルダーの後に続くコンマは、数値を 3 桁ずつ拡張または縮小します。たとえば、書式設定文字列が "#,###.0," の場合、Excel では、数値 12200000 が 12,200.0 として表示されます。

桁区切り記号を使用した TEXT 関数の例

注: 

  • 桁区切り記号は、ご使用の地域の設定によって異なります。米国ではコンマですが、その他のロケールでは、ピリオド (.) になる場合があります。

  • 桁区切り記号は、数値、通貨、会計の表示形式に使用することができます。

次に、標準の数値 (桁区切り記号と 10 進数)、通貨、および会計の表示形式の例を示します。通貨表示形式を使用すると、選択した通貨記号を挿入して、値の横に配置することができます。一方、会計表示形式では、通貨記号がセル内で左揃えで配置されます。次に示す、通貨表示形式コードと会計表示形式コードの違いにご注意ください。この例の会計表示形式は、アスタリスク (*) を使用してシンボルと値を分離しています。

数値、通貨、および会計の表示形式を使用した TEXT 関数の例

通貨記号の表示形式コードを見つけるには、最初に Ctrl + 1 キー (Mac の場合は MAC のコマンド ボタン アイコンの画像 + 1 キー) を押して、目的の表示形式を選択し、[記号] ドロップダウンで記号を選びます。

[セルの書式設定] ダイアログでの通貨記号の選択

次に、左側にある [分類] セクションで [ユーザー定義] をクリックし、通貨記号を含めて表示形式コードをコピーします。

TEXT 関数 - 記号を使用したカスタム通貨

注: TEXT 関数は色の書式設定をサポートしないので、[セルの書式設定] ダイアログで、$#,##0.00_);[Red]($#,##0.00) のような数値の表示形式コードをコピーすると、TEXT 関数はその表示形式コードを受け入れますが、色は表示されません。

月を表す "M"、日を表す "D"、および年を表す "Y" を組み合わせて使用することで、日付の表示方法を変更できます。

月、日、および年の表示形式コード

TEXT 関数の表示形式コードは大文字と小文字を区別しないので、"M" または "m"、"D" または "d"、"Y" または "y" のいずれも使用できます。

Excel MVP Mynda Treacy

Mynda のお勧め...

さまざまな国のユーザーと Excel ファイルとレポートを共有している場合は、その言語でレポートを作成することをお勧めします。excel MVP、Mynda トレーシーには、さまざまな言語の記事に表示されている excel の日付が含まれています。また、ダウンロードできるサンプルブックも用意されています。

時を表す "H"、分を表す "M"、秒を表す "S"、および 12 時間形式を表す "AM/PM" を組み合わせて使用することで、時刻の表示方法を変更できます。

時、分、および秒の時刻の表示形式

"AM/PM" または "A/P" を省略すると、時刻は 24 時間形式に基づいて表示されます。

TEXT 関数の表示形式コードは大文字と小文字を区別しないので、"H" または "h"、"M" または "m"、"S" または "s"、"AM/PM" または "am/pm" のいずれも使用できます。

パーセンテージ (%) 表示形式を使用して小数値の表示方法を変更できます。

パーセントの表示形式コード

分数 (?/?) 表示形式を使用して小数値の表示方法を変更できます。

分数の表示形式コード

指数表記は、1 から 10 までの 10 進数に 10 の累乗を乗算する形式で数値を表示する方法です。多くの場合、指数表記は、大きな数字を短縮して表示するために使用されます。

指数表記の表示形式コード

Excel には、次の 4 つの特別な表示形式が用意されています。

  • 郵便番号 - "00000"

  • 郵便番号 + 4 - "00000-0000"

  • 電話番号 - "[<=9999999]###-####;(###) ###-####"

  • 社会保障番号 - "000-00-0000"

TEXT 関数の [その他] 表示形式

[その他] 表示形式は、ロケールによって異なります。ご使用のロケールの [その他] 表示形式に何もない場合、または用意されている表示形式がニーズを満たさない場合、[セルの書式設定] ダイアログの [ユーザー定義] オプションを使用して独自の表示形式を作成することができます。

一般的なシナリオ

TEXT関数は単独で使用されることはめったにありません。また、ほとんどの場合、他のものと組み合わせて使用されます。テキストと数値を結合するとします。たとえば、"レポートに印刷された: 03/14/12"、または "週単位の収益: $66348.72" などです。excel を手動で入力することもできますが、excel を使用しているという目的に反しています。残念ながら、日付、時刻、通貨など、テキストと書式設定された数値を組み合わせると、Excel に表示する方法がわからないため、数値の書式が低下します。ここでは、テキスト関数は、日付形式の"MM/DD/YY"のような書式設定コードを使用して、必要に応じて値の書式設定を行うことができるため、非常に効果的です。

次の例では、text 関数を使わずにテキストと数値を結合しようとした場合の動作を確認します。この例では、アンパサンド(&) を使用して、テキスト文字列、スペース ("")、および= A2 & "" & B2の値を連結しています。

TEXT 関数を使用しないで文字列を結合する例

ご覧のとおり、Excel では、セル B2 の日付の書式設定が削除されます。次の例では、TEXT 関数を使用して目的の書式を適用する方法を示しています。

TEXT 関数を使用して文字列を結合する例

更新された数式は次のとおりです。

  • Cell C2:=A2&" "&TEXT(B2,"mm/dd/yy") - 日付表示形式

よく寄せられる質問

残念ながら、この操作を行うことはできません。テキスト関数では、Visual Basic for アプリケーション (VBA) コードを使用する必要があります。次のリンクには、 Excel で数値を英単語に変換する方法があります。

はい。UPPER 関数、LOWER 関数、PROPER 関数を使用できます。たとえば、=UPPER("hello") は、"HELLO" を返します。

はい、いくつかの手順が必要です。最初に、これを実行するセルまたはセルを選択し、 Ctrl キーを押しながら 1を使用して、[書式]、[セル] ダイアログ、[配置]、[テキストコントロール]、[文字列の折り返し] の順にクリックします。次に、完成したテキスト関数を調整して、改行する ASCII 関数CHAR (10)を含めます。最終結果の整列方法に応じて、列幅を調整する必要がある場合があります。

CHAR(10) と TEXT を使用して、改行を挿入する例。="Today is: "&CHAR(10))&TEXT(TODAY(),"MM/DD/YY")

この場合、="Today is: "&CHAR(10)&TEXT(TODAY(),"mm/dd/yy") を使用しています。

これは、指数表記と呼ばれる表示形式です。Excel では、セルを [標準] として書式設定している場合は 12 桁を超える数値、セルを [数値] として書式設定している場合は 15 桁を超える数値を自動的に指数表記に変換します。長い数値文字列を入力する必要があるが、変換したくない場合は、該当するセルを [文字列] として書式設定した後、値を Excel に入力するか、貼り付けます。

Excel MVP Mynda Treacy

Mynda のお勧め...

さまざまな国のユーザーと Excel ファイルとレポートを共有している場合は、その言語でレポートを作成することをお勧めします。excel MVP、Mynda トレーシーには、さまざまな言語の記事に表示されている excel の日付が含まれています。また、ダウンロードできるサンプルブックも用意されています。

関連項目

ユーザー定義の表示形式を作成または削除する

文字列として保存されている数値を数値形式に変換する

全 Excel 関数 (機能別)

Office のスキルを磨く
トレーニングの探索
新機能を最初に入手
Office Insider に参加する

この情報は役に立ちましたか?

ご意見をいただきありがとうございます。

フィードバックをお寄せいただき、ありがとうございます。Office サポートの担当者におつなぎいたします。

×