AllowBypassKey プロパティを使用して、スタートアップ プロパティと AutoExec マクロのバイパスに対して、SHIFT キーを有効にするかどうかを指定することができます。 たとえば、ユーザーがスタートアップ プロパティや AutoExec マクロをバイパスしないように、AllowBypassKey プロパティを False に設定することができます。
設定
AllowBypassKey プロパティでは、次の設定が使用されます。
|
設定 |
説明 |
|
True |
ユーザーが Shift キーを使用して、スタートアップ プロパティおよび AutoExec マクロの読み込みを回避できるようにします。 |
|
False |
ユーザーが Shift キーを使用して、スタートアップ プロパティおよび AutoExec マクロの読み込みを回避することを禁止します。 |
このプロパティは、マクロ または Visual Basic for Applications (VBA) コードを使用して設定できます。
マクロまたは Visual Basic for Applications (VBA) コードを使用して、AllowBypassKey プロパティを設定するには、次の方法でプロパティを作成する必要があります。
-
Microsoft Access データベース (.mdb または .accdb) で、CreateProperty メソッドを使用してプロパティを作成し、Database オブジェクトの Properties コレクションにその作成したプロパティを追加することで、プロパティを追加できます。
-
Microsoft Access プロジェクト (.adp) で、Add メソッドを使用することで、CurrentProject オブジェクトの AccessObjectProperties コレクションにプロパティを追加できます。
解説
アプリケーションをデバッグするときは、AllowBypassKey プロパティを True に設定していることを確認する必要があります。
AllowBypassKey プロパティの設定は、次にアプリケーション データベースを開くときまで有効になりません。
例
次の例では、設定されるプロパティの名前、そのデータ型、および設定を渡す、SetBypassProperty という名前のプロシージャを示しています。 一般的な手順のプロシージャの ChangeProperty では、AllowBypassKey プロパティを設定しようとして、プロパティが見つからない場合は、CreateProperty メソッドを使用して、プロパティを Properties コレクションに追加します。 AllowBypassKey プロパティは追加されるまで Properties コレクションに表示されないため、これは重要です。
Sub SetBypassProperty()
Const DB_Boolean As Long = 1
ChangeProperty "AllowBypassKey", DB_Boolean, False
End Sub
Function ChangeProperty(strPropName As String, _
varPropType As Variant, _
varPropValue As Variant) As Integer
Dim dbs As Object, prp As Variant
Const conPropNotFoundError = 3270
Set dbs = CurrentDb
On Error GoTo Change_Err
dbs.Properties(strPropName) = varPropValue
ChangeProperty = True
Change_Bye:
Exit Function
Change_Err:
If Err = conPropNotFoundError Then ' Property not found.
Set prp = dbs.CreateProperty(strPropName, _
varPropType, varPropValue)
dbs.Properties.Append prp
Resume Next
Else
' Unknown error.
ChangeProperty = False
Resume Change_Bye
End If
End Function
