Excel の数式の概要

Excel の数式の概要

Excel を初めて使用すると、列や行に数値を入力するだけのただのグリッドではないことに気付きます。Excel を使用して、行または列の数値の合計を求めることができるほか、住宅ローンの返済額を計算することも、数学や工学上の問題を解決したり、組み込む変数値に基づいて最適なケースのシナリオを見つけたりすることもできます。

そのためにはセルの数式を使用します。数式は、ワークシートのデータに対して計算またはその他のアクションを実行します。数式は常に等号 (=) で始まり、その後に数値、算術演算子 (加算または減算の + または - 記号など)、および数式の機能を拡張する組み込み Excel 関数が続きます。

たとえば、次の数式は 2 と 3 を乗算し、その結果に 5 を加算して、11 という解を求めます。

=2*3+5

ここに、ワークシートに入力できる数式について、その他の例をいくつか示します。

  • =A1+A2+A3    セル A1、A2、A3 の値を加算します。

  • =SUM(A1:A10)    SUM 関数を使用して A1 ~ A10 の値の合計を返します。

  • =TODAY()    現在の日付を返します。

  • =UPPER("hello")   UPPER 関数を使って、"hello" という文字列を "HELLO" に変換します。

  • =IF(A1>0)    IF 関数を使用して、セル A1 に 0 より大きい値が含まれているかどうかをテストします。

数式には、関数セル参照演算子定数のいずれか、またはすべてを含めることもできます。

数式のパーツ   

数式のパーツ

1. 関数: PI() 関数は円周率 (3.142...) の値を返します。

2. セル参照: A2 はセル A2 の値を返します。

3. 定数: 数式に直接入力される数値や文字列の値です (例: 2 など)。

4. 演算子: ^ (キャレット) 演算子はべき算を実行し、* (アスタリスク) 演算子は乗算を実行します。

定数とは計算されない値です。常に同じままです。たとえば、日付 10/9/2008、値 210、文字列 "四半期の収益" などはすべて定数です。式 または式の結果の値は定数ではありません。セル参照ではなく定数を数式で使用した場合 (たとえば、=30+70+110)、結果は数式を変更した場合にのみ変化します。一般に、必要に応じて簡単に変更できる個々のセルに定数を置き、数式でそれらのセルを参照するのが最善です。

演算子は、数式の要素に対して実行する計算の種類を指定します。Excel は、かっこ指数乗算と除算加算と減算、つまり、頭字語 PEMDAS の一般的な計算順序に従います。かっこを使用すると計算の順序を変更できます。

演算子の種類。計算演算子は、算術比較テキスト連結参照の 4 種類です。

  • 算術演算子

    次に挙げる算術演算子は、加算、減算、乗算、除算などの基本的な計算を実行し、数値を組み合わせて、計算結果として数値を返します。

    算術演算子

    意味

    + (正符号)

    加算

    =3+3

    - (負符号)

    減算
    負の数

    =3–3
    =-3

    * (アスタリスク)

    乗算

    =3*3

    / (スラッシュ)

    除算

    =3/3

    % (パーセント記号)

    パーセント

    30%

    ^ (キャレット)

    べき算

    =3^3

  • 比較演算子

    2 つの値を比較する場合は、次の比較演算子を使います。これらの演算子を使って 2 つの値を比較すると、計算結果として論理値 TRUE または FALSE を返します。

    比較演算子

    意味

    = (等号)

    等しい

    =A1=B1

    > (大なり記号)

    より大きい

    =A1>B1

    < (小なり記号)

    より小さい

    =A1<B1

    >= (より大か等しい記号)

    以上

    =A1>=B1

    <= (より小か等しい記号)

    以下

    =A1<=B1

    <> (不等号)

    等しくない

    =A1<>B1

  • テキスト連結演算子

    文字列演算子のアンパサンド (&) を使って、1 つ以上の文字列を連結 (結合) して、1 つの文字列を作成します。

    文字列演算子

    意味

    & (アンパサンド)

    2 つの文字列を結合、または連結して、1 つの連続する文字列の値を作成する

    ="North"&"wind" は "Northwind" になります。
    A1 の内容が "Last name" で B1 の内容が "First name" の場合、=A1&", "&B1 の結果は "Last name, First name" になります。

  • 参照演算子

    次の演算子を使用して、計算するセル範囲を結合します。

    参照演算子

    意味

    : (コロン)

    セル範囲の参照演算子。指定した 2 つのセル参照と、その間に含まれるすべてのセルによって構成される 1 つの参照を作成する

    B5:B15

    , (コンマ)

    複数の範囲を表す参照演算子。複数の参照を 1 つの参照に結合する

    =SUM(B5:B15,D5:D15)

    (スペース)

    共通部分を示す参照演算子。2 つの参照に共通する 1 つのセル参照を作成する

    B7:D7 C6:C8

ページの先頭へ

計算が実行される順序が数式の戻り値に影響することがあるため、演算の実行順序の決定方法、および必要な結果を得るための実行順序の変更方法を理解しておくことは重要です。

  • 計算の順序

    数式では、特定の順序で値が計算されます。Excel の数式は、常に等号 (=) で開始します。Excel では、等号の後に続く文字を数式として解釈します。等号の後に、定数やセル参照など、計算対象の要素 (オペランド) が続きます。これらの要素を演算子で区切ります。Excel では、数式内のそれぞれの演算子の優先順位に基づいて、左から順に数式が計算されます。

  • Excel の数式での演算子の優先順位

    1 つの数式で複数の演算子を使用する場合、次の表に示した順序で計算が実行されます。数式に同順位の演算子が含まれる場合 (たとえば、乗算演算子と除算演算子が含まれる場合)、左から右の順に計算が実行されます。

    演算子

    説明

    : (コロン)

    (スペース 1 つ)

    , (コンマ)

    参照演算子

    負の値 (-1 など)

    %

    パーセント

    ^

    べき算

    *、/

    乗算または除算

    + または -

    加算または減算

    &

    文字列の結合または連結

    =
    < >
    <=
    >=
    <>

    比較

  • Excel の数式でのかっこの使用

    計算順序を変更するには、最初に計算を実行する必要のある数式の要素をかっこで囲みます。たとえば、次の数式では、加算の前に乗算が実行されるため、結果として 11 が返されます。つまり、この数式ではまず 2 と 3 が乗算され、その結果に 5 が加算されます。

    =5+2*3

    上の数式にかっこを使用して構文を次のように変更すると、まず 5 に 2 が加算され、その結果に 3 が乗算されるため、計算結果は 21 になります。

    =(5+2)*3

    次の例では、式の最初の部分を囲むかっこにより、セル B4 の値に 25 が加算され、その結果がセル D5、E5、および F5 の合計値で除算されます。

    =(B4+25)/SUM(D5:F5)

    ページの先頭へ

関数は、引数と呼ばれる特定の値を特定の順序または構造で使用して計算を実行するあらかじめ定義された数式です。関数を使用して、単純な計算や複雑な計算を実行できます。Excel のすべての関数はリボンの [数式] タブで確認できます。

Excel のリボンにある [数式] タブ
  • Excel の関数の構文

    セル A10 の数値を四捨五入する ROUND 関数の次の例で関数の構文を示します。

    関数の構造

    1. 構造。関数の構造は、等号 (=) で始まり、関数名、左かっこ、コンマで区切られた関数の引数、右かっこが続きます。

    2. 関数名。使用可能な関数の一覧を表示するには、セルをクリックし、Shift + F3 キーを押します。[関数の挿入] ダイアログが開きます。

    Excel の数式 - [関数の挿入] ダイアログ

    3. 引数。引数は、数値、文字列、論理値 (TRUE または FALSE)、配列、エラー値 (#N/A など)、セル参照などです。指定する引数は、その引数の有効な値を生成する必要があります。引数は、定数、数式、他の関数でもかまいません。

    4. 引数のヒント。関数を入力すると、構文と引数のヒントが表示されます。たとえば、「=ROUND(」と入力すると、ヒントが表示されます。ヒントは、組み込み関数に対してのみ表示されます。

    注: 関数をすべて大文字で入力する必要はありません (=ROUND など)。Enter キーを押すと関数名は自動的に大文字になります。関数名にスペル ミスがあると (=SUM(A1:A10) ではなく =SUME(A1:A10) など)、#NAME? エラーが返されます。

  • Excel 関数の入力

    関数を含む数式を作成するときは、[関数の挿入] ダイアログ ボックスを使用してワークシート関数を入力できます。[関数の挿入] ダイアログで関数を選択すると、関数ウィザードが起動され、関数の名前、各引数、関数と各引数の説明、関数の現在の結果、および数式全体の現在の結果が表示されます。

    Excel の関数ウィザード

    数式の作成と編集を容易にし、入力ミスや構文エラーを最小限に抑えるには、数式オートコンプリートを使用します。= (等号) を入力して関数の文字の入力を始めると、有効な関数、引数、および文字と一致する名前の動的なドロップダウン リストが表示されます。ドロップダウン リストから 1 つを選択すると、後は自動的に入力されます。

    Excel の数式オートコンプリート

  • Excel 関数のネスト

    ある関数を、別の関数の引数として使用することもできます。たとえば、次の数式は、ネストした AVERAGE 関数を使って、その結果を値 50 と比較します。

    入れ子になった関数

    1. AVERAGE 関数と SUM 関数が IF 関数内にネストされています。

    有効な戻り値   ネストした関数を引数として使用する場合は、ネストした関数が返す値の型と引数の型が同一であることが必要です。たとえば、引数が TRUE または FALSE の値を返す場合は、TRUE または FALSE の値を返す関数をネストすることができます。ネストした関数が正しい型の値を返さない場合は、#VALUE! が表示されます。エラー値が返されます。

    ネスト レベルの制限   数式には、7 レベルまでのネストした関数を含めることができます。ある関数 (関数 B とします) を別の関数 (関数 A とします) の引数として指定する場合、関数 B は、第 2 レベルの関数として機能します。たとえば、AVERAGE 関数と SUM 関数は IF 関数の引数として指定されている場合、第 2 レベルの関数となります。さらに、ネストした AVERAGE 関数にネストする関数があった場合、その関数は第 3 レベルの関数になります。

    ページの先頭へ

参照は、ワークシートのセルまたはセル範囲を識別し、数式で使う値やデータの位置を Excel に示します。参照を使うと、ワークシート上の異なる場所に格納されている複数のデータを 1 つの数式内で使用したり、ある 1 つのセルの値を複数の数式で使用したりすることができます。また、同じブックにある他のシートのセルや、他のブックにあるセルの参照を行うこともできます。他のブックにあるセルの参照は、リンクまたは外部参照と呼びます。

  • A1 参照スタイル

    既定では、Excel は A1 参照スタイルを使用します。つまり、文字で列を参照し (A ~ XFD、合計 16,384 列)、数字で行を参照します (1 ~ 1,048, 576)。これらの文字と数字は、列見出しおよび行見出しと呼ばれます。セルを参照するには、列の文字に続けて行の数字を入力します。たとえば、B2 は、列 B と行 2 の交差するセルを参照します。

    参照セル (またはセル範囲)

    入力する文字列

    列 A、行 10 のセル

    A10

    列 A、行 10 ~ 行 20 のセル範囲

    A10:A20

    行 15、列 B ~ 列 E のセル範囲

    B15:E15

    行 5 のすべてのセル

    5:5

    行 5 ~ 10 のすべてのセル

    5:10

    列 H のすべてのセル

    H:H

    列 H ~ J のすべてのセル

    H:J

    列 A ~ E、行 10 ~ 20 のセル範囲

    A10:E20

  • 同じブック内の別のワークシート上のセルまたはセル範囲の参照を作成する

    次の例の AVERAGE 関数は、同じブックの "Marketing" というワークシートのセル範囲 B1:B10 の平均値を計算します。

    シート参照の例

    1. "マーケティング" という名前のワークシートを参照する

    2. B1 ~ B10 のセル範囲を参照します

    3. 感嘆符 (!) はワークシート参照とセル範囲参照を分離します

    注: 参照されているワークシートの名前にスペースまたは数字が含まれる場合は、ワークシート名を単一引用符 (') で囲む必要があります (例: ='123'!A1、='January Revenue'!A1)。

  • 絶対参照、相対参照、複合参照の違い

    1. 相対参照   数式の中の相対セル参照 (たとえば A1) は、数式が入力されているセルと参照されるセルの相対位置に基づいています。数式を含むセルの位置を変更した場合、参照も変更されます。数式を他の行や列にコピーまたはオートフィルによりコピーした場合、参照も自動的に調整されます。既定では、新しく作成した数式には相対参照が使われます。たとえば、セル B2 にある相対参照をセル B3 にコピーまたはオートフィルによりコピーすると、=A1 は自動的に =A2 に変更されます。

      相対参照を使用した数式のコピー   

      相対参照を使用した数式のコピー

    2. 絶対参照    $A$1 などの絶対セル参照を数式で使用すると、必ず特定の位置にあるセルが参照されます。数式を含むセルの位置を変更しても、絶対参照で参照するセルは変更されません。その数式を他の行や列にコピーまたはオートフィルによりコピーしても、絶対参照は変わりません。既定では、新しく作成した数式には相対参照が使用されるため、絶対参照を使用するには切り替えが必要になる場合があります。たとえば、セル B2 にある絶対参照をセル B3 にコピーまたはオートフィルによりコピーした場合、どちらの参照も =$A$1 になります。

      絶対参照を使用した数式のコピー   

      絶対参照を使用した数式のコピー
    3. 複合参照   複合参照では、絶対列参照と相対行参照、または絶対行参照と相対列参照を組み合わせて使用します。絶対列参照は、$A1 や $B1 のように指定します。また、絶対行参照は、A$1 や B$1 のように指定します。数式を含むセルの位置を変更した場合、相対参照は変更されますが、絶対参照はそのままです。数式を他の行や列にコピーまたはオートフィルによりコピーした場合も、相対参照は自動的に調整されますが、絶対参照はそのままです。たとえば、複合参照をセル A2 から B3 にコピーまたはオートフィルによりコピーすると、数式の =A$1 は =B$1 に変更されます。

      複合参照を使用した数式のコピー   

      複合参照を使用した数式のコピー

  • 3-D 参照スタイル

    複数のワークシートを簡単に参照する   ブック内の複数のワークシートの同一セルまたは同一セル範囲のデータを分析する場合は、3-D 参照を使います。3-D 参照では、ワークシート範囲の後にセル参照またはセル範囲の参照を指定します。指定した先頭のシート名と末尾のシート名の間のすべてのワークシートが参照に使用されます。たとえば、3-D 参照を使用して「=SUM(Sheet2:Sheet13!B5)」という数式を入力すると、Sheet 2 から Sheet 13 までのすべてのワークシートのセル B5 の値が合計されます。

    • 3-D 参照を使うと、他のシートのセルを参照したり、名前を定義したり、次のような関数を使用して数式を作成したりすることができます。使用できる関数には、SUM、AVERAGE、AVERAGEA、COUNT、COUNTA、MAX、MAXA、MIN、MINA、PRODUCT、STDEV.P、STDEV.S、STDEVA、STDEVPA、VAR.P、VAR.S、VARA および VARPA があります。

    • 3-D 参照は、配列数式では使用できません。

    • 3-D 参照は、共通部分の演算子 (スペース 1 つ) の引数として使用したり、共通部分を使用する数式内で使用したりすることはできません。

    ワークシートを移動、コピー、挿入、または削除した場合   次の例は、3-D 参照に含まれるワークシートの移動、コピー、挿入、削除を行ったときの結果を示しています。この例では、ワークシート 2 ~ 6 (Sheet2 ~ Sheet6) のセル A2 ~ A5 を合計する数式 =SUM(Sheet2:Sheet6!A2:A5) を使います。

    • 挿入またはコピー    Sheet2 と Sheet6 (この例の両端のシート) の間にシートを挿入またはコピーすると、追加したシートのセル A2 ~ A5 に入力されている値も計算に使用されます。

    • 削除    Sheet2 と Sheet6 の間のシートを削除すると、削除したシートの値は計算から除外されます。

    • 移動    Sheet2 と Sheet6 の間にあるシートを、参照されているシート範囲の外に移動すると、移動したシートの値は計算から除外されます。

    • 両端のシートの移動    Sheet2 と Sheet6 のいずれかを同じブック内の他の位置に移動すると、移動後の Sheet2 と Sheet6 の間にあるシートの値が計算されます。

    • 両端のシートの削除    Sheet2 と Sheet6 のいずれかを削除すると、削除したシートを除くシートの値が計算されます。

  • R1C1 参照スタイル

    ワークシートの行と列の両方に番号を指定する参照形式を使うこともできます。R1C1 参照形式は、マクロを使って行と列の位置を計算する場合に便利です。R1C1 参照形式では、Excel は「R <行番号> C <列番号>」の形式でセルの位置を表します。

    参照

    意味

    R[-2]C

    同じ列で 2 行上のセルを表す相対参照

    R[2]C[2]

    2 行下で 2 列右のセルを表す相対参照

    R2C2

    行 2 の列 2 にあるセルを表す絶対参照

    R[-1]

    アクティブ セルの 1 つ上の行全体を表す相対参照

    R

    アクティブ セルのある行を表す絶対参照

    マクロを記録した場合、R1C1 参照形式が使われるコマンドがあります。たとえば、マクロの記録を開始してから、[オート SUM] をクリックしてセル範囲の値を合計する数式を挿入すると、A1 形式ではなく R1C1 形式を使用してマクロが記録されます。

    R1C1 参照形式を使用するかどうかを指定するには、[オプション] ダイアログ ボックスの [数式] カテゴリにある [数式の処理] セクションで、[R1C1 参照形式を使用する] チェック ボックスをオンまたはオフにします。このダイアログ ボックスを表示するには、[ファイル] タブをクリックします。

    ページの先頭へ

セル、セル範囲、数式、定数、または Excel テーブルを表すために、定義された名前を作成できます。名前は、見ただけでは内容を把握するのが難しいセル参照、定数、数式、テーブルなどの用途を簡単に理解できるようにするための、わかりやすい簡潔な表現です。以下は、名前の一般的な例を示しており、名前を数式で使用することによって数式の用途が明確かつ理解しやすくなっていることがわかります。

使用例 1

種類

名前の代わりに範囲を使用する例

名前を使用する例

参照

=SUM(A16:A20)

=SUM(売上)

定数

=PRODUCT(A12,9.5%)

=PRODUCT(価格,TaxRate)

数式

=TEXT(VLOOKUP(MAX(A16,A20),A16:B20,2,FALSE),"yyyy/m/dd")

=TEXT(VLOOKUP(MAX(売上),売上情報,2,FALSE),"yyyy/m/dd")

テーブル

A22:B25

=PRODUCT(価格,Table1[@Tax Rate])

使用例 2

次の表のサンプル データをコピーし、新しい Excel ワークシートのセル A1 に貼り付けます。 数式を選択して、F2 キーを押し、さらに Enter キーを押すと、結果が表示されます。 必要に応じて、列幅を調整してすべてのデータを表示してください。

注:  C、D 列の数式では、定義された名前 "売上" が (範囲) A9:A13 への参照に置き換えられ、名前 "売上情報" が範囲 A9:B13 に置き換えられます。テスト用ブックにこれらの名前を作成しないと、D2:D3 の数式は #NAME? エラーを返します。

種類の例

名前を使わない例

名前を使った例

名前を使った数式と結果

参照

'=SUM(A9:A13)

'=SUM(売上)

=SUM(売上)

数式

'=TEXT(VLOOKUP(MAX(A9:13),A9:B13,2,FALSE),"yyyy/m/dd")

'=TEXT(VLOOKUP(MAX(売上),売上情報,2,FALSE),"yyyy/m/dd")

=TEXT(VLOOKUP(MAX(売上),売上情報,2,FALSE),"yyyy/m/dd")

価格

¥99,500

売上高

販売日

¥24,900

2011 年 3 月 17 日

¥39,900

2011 年 4 月 2 日

¥64,300

2011 年 4 月 23 日

¥27,500

2011 年 4 月 30 日

¥44,700

2011 年 5 月 4 日

  • 名前の種類

    作成および使用できる名前にはいくつかの種類があります。

    • 定義された名前   セル、セル範囲、数式、または定数値を表す名前です。定義された名前は独自に作成できます。また、印刷範囲を設定したときなど、定義された名前が自動的に作成される場合もあります。

    • テーブル名    Excel テーブルの名前です。Excel テーブルとは、特定のテーマに関するデータを集めて、レコード (行) とフィールド (列) の形式で格納したものです。Excel テーブルを挿入するたびに、"Table1"、"Table2" という順番で既定の Excel テーブル名が作成されますが、よりわかりやすい名前に変更することもできます。

      Excel のテーブルの詳細については、「Excel テーブルでの構造化参照の使い方」を参照してください。

  • 名前の作成と入力

    名前は次の方法で作成できます。

    • 数式バーの名前ボックス   この方法は、選択した範囲のブック レベルの名前の作成に最も適しています。

    • 選択範囲からの作成   ワークシートの選択セルから、既存の行および列のラベルに基づいて名前を作成できます

    • [新しい名前] ダイアログ ボックス   ローカルのワークシート レベルで範囲を指定する場合や名前のコメントを作成する場合など、柔軟に名前を作成する必要がある場合に最も適しています。

    注: 既定では、名前には絶対参照が使われます。

    次のような方法で名前を入力します。

    • キーボード入力   数式に対する引数などとして、名前を直接入力します。

    • 数式オートコンプリートの使用   有効な名前が自動的に一覧表示される [数式オートコンプリート] ボックスを使います。

    • [数式で使用] からの選択    [数式] タブの [定義された名前] で、[数式で使用] の一覧から定義された名前を選択します。

詳細については、「数式で名前を定義し使用する」を参照してください。

ページの先頭へ

配列数式では、複数の計算を行って 1 つまたは複数の結果を返すことができます。配列数式は、配列引数と呼ばれる複数の値のセットで実行されます。各配列引数には、同じ数の行と列を指定する必要があります。配列数式の作成方法は他の数式とほぼ同じですが、数式の入力時に、Ctrl キーと Shift キーを押しながら Enter キーを押します。一部の組み込み関数は配列数式になっているため、こうした関数で正しい結果を得るには、配列として入力する必要があります。

ワークシート上のセルに各定数の値を入力しなくても、配列定数を参照の代わりに使用できます。

配列数式を使用した 1 つの結果または複数の結果の計算

注: 配列数式を入力すると、{ } (中かっこ) の間に数式が自動的に挿入されます。中かっこを手動で入力しようとすると、数式が文字列として表示されます。

  • 1 つの結果を生成する配列数式    この種の配列数式を使用して複数の異なる数式を 1 つの配列数式に置き換えることにより、ワークシート モデルを簡素化できます。

    たとえば次の例では、株価と株数の配列の集計値を計算していますが、各セルの行を使用した銘柄ごとの値の計算や表示は行っていません。

    1 つの計算結果を返す配列数式

    配列数式として数式 ={SUM(B2:D2*B3:D3)} を入力すると、各銘柄の株数と株価を乗算した後、その計算結果が合算されます。

  • 複数の結果を生成する配列数式    ワークシート関数の中には、値の配列を返すものや、引数として値の配列を必要とするものがあります。配列数式を使用して複数の結果を計算するには、配列引数と同じ数の行と列を含むセルの範囲に配列を入力する必要があります。

    たとえば、3 か月の月 (列 A) ごとの売上高 (列 B) を入力して TREND 関数を使うと、売上高の直線方式での値を返すことができます。式のすべての結果を表示するには、列 C の 3 つのセル (C1:C3) に配列数式を入力します。

    複数の計算結果を返す配列数式

    配列数式として数式「=TREND(B1:B3,A1:A3)」を入力すると、3 つの売上高と 3 つの月から 3 つの別々の結果 (22196、17079、11962) が返されます。

配列定数を使用する

通常の数式には、値を含むセル参照か、または値そのものを表す定数を入力することができます。同様に配列数式では、配列への参照か、またはセル内に含まれる値の配列を表す配列定数を入力することができます。配列数式では、配列数式以外の数式と同様に、定数を処理しますが、特定の形式に従って配列定数を入力する必要があります。

配列定数には、数値、文字列、論理値 (TRUE、FALSE など)、またはエラー値 (#N/A など) を格納できます。異なる種類の値を同じ配列定数に格納できます (たとえば、{1,3,4;TRUE,FALSE,TRUE})。配列定数の数値として、整数、小数、または指数を格納できます。文字列は、"Tuesday" のように二重引用符で囲む必要があります。

配列定数では、セル参照、長さが異なる行または列、数式、特殊文字である $ (ドル記号)、かっこ、% (パーセント記号) を使用することはできません。

配列定数を指定する場合は、次の点にご注意ください。

  • 配列定数は、中かっこ ({ }) で囲みます。

  • 異なる列の値はカンマ (,) で区切りをつけます。たとえば、値 10、20、30、40 を表すには、「{10,20,30,40}」と入力します。この配列定数は、1 × 4 配列と呼ばれ、1 行 × 4 列のセル範囲の参照と同じ動作になります。

  • 異なる行の値はセミコロン (;) で区切ります。たとえば、ある行の値 10、20、30、40 とそのすぐ下の行の値 50、60、70、80 を表すには、2 × 4 配列の配列定数「{10,20,30,40;50,60,70,80}」を入力します。

ページの先頭へ

数式を削除すると、数式の結果の値も削除されます。ただし、数式だけを削除し、セルに表示されている数式の結果の値をそのままにすることができます。

  • 数式と結果の値を削除するには、次のようにします。

    1. 数式が含まれているセルまたはセル範囲を選びます。

    2. Del キーを押します。

  • 数式だけ削除し、結果の値は残すには、次のようにします。

    1. 数式が含まれているセルまたはセル範囲を選択します。

      数式が配列数式の場合は、数式が入力されているセル範囲を選択します。

      配列数式を含むセルの範囲を選択する方法

      1. 配列数式内のセルを 1 つクリックします。

      2. [ホーム] タブの [編集] グループで [検索と選択] をクリックし、[ジャンプ] をクリックします。

      3. [セル選択] をクリックします。

      4. [アクティブ セルの配列] をクリックします。

    2. [ホーム] タブの [クリップボード] グループで、[コピー] ボタンの画像 をクリックします。
      Excel のリボン イメージ

      キーボード ショートカット    Ctrl + C キーを押してもかまいません。

    3. [ホーム] タブの [クリップボード] グループで、 ボタンの画像 (貼り付け) の下にある矢印をクリックし、[値の貼り付け] をクリックします。

ページの先頭へ

次の表は、数式を入力するときに最も多く発生するエラーの一部と、数式のエラーを回避する方法をまとめたものです。

確認事項

詳細情報

数式の開くかっこと閉じるかっこをすべて一致させる   

すべてのかっこは、数式で一致するペアの一部です。数式を作成しているときにかっこを入力すると色付きで表示されます。

数式に入力する範囲を指定するにはコロンを使用する   

範囲の最初と最後のセルの参照を区切るには、コロン (:) を使用します。たとえば、A1:A5 のようにします。

必要な引数をすべて入力する   

関数には必須の引数と省略可能な引数 (構文では角かっこで示されます) があります。必須の引数はすべて入力する必要があります。また、引数の数が多すぎないかを確認します。

1 つの数式で 64 を超える関数をネストしない   

数式内での関数のネストは 64 レベルに制限されています。

ブック名またはワークシート名を単一引用符で囲む    

名前に英数字以外の文字を含む他のワークシートまたはブックの値またはセルを参照するときは、名前を単一引用符 (') で囲む必要があります。

外部参照先のブックへのパスを含める   

外部参照には、ブック名とそのブックへのパスが含まれている必要があります。

数値を書式なしで入力する   

数式に入力する数値を、桁区切り記号やドル記号 ($) で書式設定してはいけません。コンマは数式で引数の区切り記号として既に使用されており、ドル記号は絶対参照を指定するために使用されます。たとえば、数式には「$1,000」ではなく「1000」と入力します。

ページの先頭へ

重要: x86 または x86-64 アーキテクチャの Windows PC と、ARM アーキテクチャの Windows RT PC との間で、Excel の数式やワークシート関数の計算結果が異なる場合があります。この相違の詳細については、こちらを参照してください

特定の関数について質問がある場合

Excel のコミュニティ フォーラムに質問を投稿してください

Excel の機能を向上させるためのお願い

次のバージョンの Excel の改善に関して、ご提案はございませんか。提案がありましたら、Excel UserVoice のトピックを参照してください。

関連項目

Excel の数式の概要

壊れた数式のエラーを回避する方法

数式のエラーを検出する

Excel キーボード ショートカットとファンクション キー

Excel 関数 (アルファベット順)

Excel 関数 (機能別)

スキルを磨く
トレーニングの探索
新機能を最初に入手
Office Insider に参加する

この情報は役に立ちましたか?

ご意見をいただきありがとうございます。

フィードバックをお寄せいただき、ありがとうございます。Office サポートの担当者におつなぎいたします。

×