SUMIF 関数

指定した条件を満たす範囲内の値を合計するには、SUMIF 関数を使用します。たとえば、数値を含む列で、5 より大きい値のみを合計するとします。次の数式を使用できます: =SUMIF(B2:B25,">5")

お使いのブラウザーではビデオがサポートされていません。 Microsoft Silverlight、Adobe Flash Player、Internet Explorer 9 のいずれかをインストールしてください。

これは、「Excel 2013 で数値を加算する」というトレーニング コースに含まれているビデオです。

ヒント: 

  • 必要に応じて、任意の範囲に条件を適用し、別の範囲にある対応値を合計することもできます。たとえば、数式 =SUMIF(B2:B5, "John", C2:C5) は、C2:C5 の範囲で、対応する B2:B5 の範囲のセルが "John" の値のみを合計します。

  • 複数の条件に基づいてセルを合計する場合は、「SUMIFS 関数」を参照してください。

データを簡単に分析するための SUMIF、COUNTIF、および関連する関数の使用に関する詳細情報

LinkedIn Learning で SUMIFCOUNTIF、および関連する関数の知識を身につけます。SUMIF 関数を使用して、データを簡単に分析する方法については、こちらを参照してください。

無料のプレビューを見る >

構文

SUMIF(範囲, 検索条件, [合計範囲])

SUMIF 関数の書式には、次の引数があります。

  • 範囲   必ず指定します。条件によって評価するセル範囲を指定します。各範囲のセルには、数値か、数値を含む名前、配列、または参照が含まれている必要があります。空白と文字列は無視されます。選択した範囲には標準の Excel 形式の日付 (下記の例を参照) が含まれる場合があります。

  • 検索条件   必ず指定します。計算の対象となるセルを定義する条件を、数値、式、セル範囲、文字列、または関数で指定します。たとえば、条件を ">32"、B5、32、"32"、"apples"、または TODAY() で表すことができます。

    重要: 文字列条件や、論理記号または数学記号を含む条件は、二重引用符 (") で囲む必要があります。条件が数値の場合、二重引用符は不要です。

  • 合計範囲   省略可能です。範囲引数で指定したセル以外のセルを加算する場合は、加算する実際のセルを指定します。"合計範囲"を省略すると、"範囲"で指定したセル (条件が適用されるセル) が加算されます。

  • "検索条件" には、半角の疑問符 (?) または半角のアスタリスク (*) をワイルドカード文字として使うことができます。ワイルドカード文字の疑問符は任意の 1 文字を表し、アスタリスクは 1 文字以上の任意の文字列を表します。ワイルドカード文字ではなく、通常の文字として疑問符やアスタリスクを検索する場合は、その文字の前に、"~*" のように半角のチルダ (~) を付けます。

解説

  • SUMIF 関数で 255 文字より長い文字列、または文字列 #VALUE! を照合すると、間違った結果が返されます。

  • "合計範囲" に含まれるセルのサイズと形状は、必ずしも "範囲" と一致している必要はありません。加算の対象となる実際のセルは、"合計範囲" の左上のセルを基準にして決定され、サイズと形状が "範囲" に対応するセルが含まれます。次に例を示します。

範囲の指定

合計範囲の指定

実際に加算されるセル

A1:A5

B1:B5

B1:B5

A1:A5

B1:B3

B1:B5

A1:B4

C1:D4

C1:D4

A1:B4

C1:C2

C1:D4

ただし、SUMIF関数の範囲合計範囲でセルの数が異なる場合、ワークシートの再計算に予想以上に時間がかかることがあります。

使用例 1

次の表のデータの例をコピーし、新しい Excel ワークシートのセル A1 に貼り付けます。数式を選択して、F2 キーを押し、さらに Enter キーを押すと、結果が表示されます。必要に応じて、列幅を調整してすべてのデータを表示してください。

資産価格

手数料

データ

¥ 10,000,000

¥ 700,000

¥ 25,000,000

¥ 20,000,000

¥ 1,400,000

¥ 30,000,000

¥ 2,100,000

¥ 40,000,000

¥ 2,800,000

数式

説明

結果

=SUMIF(A2:A5,">16000000",B2:B5)

価格が ¥ 16,000,000 を超えるエアコンに対しての取り付け手数料の合計を計算します。

¥ 6,300,000

=SUMIF(A2:A5,">16000000")

¥ 16,000,000 を超えるエアコン価格の合計を計算します。

¥ 90,000,000

=SUMIF(A2:A5,30000000,B2:B5)

価格が ¥ 30,000,000 であるエアコンに対しての取り付け手数料の合計を計算します。

¥ 2,100,000

=SUMIF(A2:A5,">" & C2,B2:B5)

価格が C2 の値を超えるエアコンに対しての取り付け手数料の合計を計算します。

¥ 4,900,000

使用例 2

次の表のサンプル データをコピーし、新しい Excel ワークシートのセル A1 に貼り付けます。 数式を選択して、F2 キーを押し、さらに Enter キーを押すと、結果が表示されます。 必要に応じて、列幅を調整してすべてのデータを表示してください。

カテゴリ

食材

売上

野菜

トマト - 箱

¥ 230,000

野菜

セロリ

¥ 550,000

くだもの

オレンジ - 箱

¥ 80,000

バター

¥ 40,000

野菜

ニンジン

¥ 420,000

くだもの

リンゴ - 箱

¥ 120,000

数式

説明

結果

=SUMIF(A2:A7,"くだもの",C2:C7)

"くだもの" カテゴリのすべての食品の売上合計を計算します。

¥ 200,000

=SUMIF(A2:A7,"野菜",C2:C7)

"野菜" カテゴリのすべての食品の売上合計を計算します。

¥ 1,200,000

=SUMIF(B2:B7,"*箱",C2:C7)

"箱" で終わるすべての食品 (トマト - 箱、オレンジ - 箱、およびリンゴ - 箱) の売上合計を計算します。

¥ 430,000

=SUMIF(A2:A7,"",C2:C7)

カテゴリが指定されていない食品すべての売上合計を計算します。

¥ 40,000

ページの先頭へ

特定の関数について質問がある場合

Excel のコミュニティ フォーラムに質問を投稿してください

Excel の機能を向上させるためのお願い

次のバージョンの Excel の改善に関して、ご提案はございませんか。提案がありましたら、Excel UserVoice (Excel ユーザー ボイス) のトピックをご覧ください。

関連項目

SUMIFS 関数は、複数の検索条件に一致するすべての引数を加算する

SUMSQ 関数は、複数の各値に対して 2 乗演算を実行した後、それらを合計する

COUNTIF 関数は、1 つの検索条件に一致する値のみをカウントする

COUNTIFS 関数は、複数の検索条件に一致する値のみをカウントする

IFS 関数 (Office 365、Excel 2016 以降)

Excel の数式の概要

壊れた数式のエラーを回避する方法

数式のエラーをエラー チェックで修正する

数学/三角関数 (リファレンス)

Excel 関数 (アルファベット順)

Excel 関数 (機能別)

データを簡単に分析するために SUMIF、COUNTIF、および関連する関数を使用する (無料のプレビュー)

スキルを磨く
トレーニングの探索
新機能を最初に入手
Office Insider に参加する

この情報は役に立ちましたか?

ご意見をいただきありがとうございます。

フィードバックをお寄せいただき、ありがとうございます。Office サポートの担当者におつなぎいたします。

×