Uso di riferimenti strutturati con le tabelle di Excel

Nota: Riteniamo importante fornire il contenuto della Guida più recente non appena possibile, nella lingua dell'utente. Questa pagina è stata tradotta automaticamente e potrebbe contenere errori di grammatica o imprecisioni. L'intento è quello di rendere fruibile il contenuto. Nella parte inferiore della pagina è possibile indicare se le informazioni sono risultate utili. Questo è l'articolo in lingua inglese per riferimento.

Quando si Crea una tabella di Excel, Excel assegna un nome alla tabella e a ogni intestazione di colonna nella tabella. Quando si aggiungono formule a una tabella di Excel, questi nomi possono essere visualizzati automaticamente durante l'immissione della formula e selezionare i riferimenti di cella nella tabella invece di immetterli manualmente. Ecco un esempio di cosa fa Excel:

Invece di usare riferimenti di cella espliciti

Excel usa nomi di tabella e colonne

=SOMMA(C2:C7)

=SOMMA(RepVendite[Importo vendite])

Questa combinazione di nomi di tabella e colonne è detta riferimento strutturato. I nomi nei riferimenti strutturati vengono modificati ogni volta che si aggiungono o si rimuovono dati dalla tabella.

I riferimenti strutturati vengono visualizzati anche quando si crea una formula all'esterno di una tabella di Excel che fa riferimento ai dati della tabella. I riferimenti possono semplificare l'individuazione delle tabelle in una cartella di lavoro grande.

Per usare riferimenti strutturati nella formula, fare clic sulle celle della tabella per cui si vuole creare un riferimento invece di digitare il riferimento di cella nella formula. In questo esempio si immette una formula che usa automaticamente i riferimenti strutturati per calcolare l'importo di una commissione di vendita.

Vendite Persona

Area

Importo vendite

% commissione

Importo della Commissione

Luca

Nord

260

10%

Roberto

Sud

660

15%

Raffaella

Est

940

15%

Diego

Ovest

410

12%

Rebecca

Nord

800

15%

Gerardino

Sud

900

15%

  1. Copiare i dati di esempio nella tabella precedente, incluse le intestazioni di colonna, e incollarli nella cella a1 di un nuovo foglio di lavoro di Excel.

  2. Per creare la tabella, selezionare una cella all'interno dell'intervallo di dati e premere CTRL + T.

  3. Verificare che la casella tabella con intestazioni sia selezionata e quindi fare clic su OK.

  4. Fare clic sulla cella E2, digitare un segno di uguale (=) e fare clic sulla cella C2.

    Nella barra della formula il riferimento strutturato [@[Importo vendite]] è visualizzato dopo il segno di uguale.

  5. Digitare un asterisco (*) direttamente dopo la parentesi quadra di chiusura e fare clic sulla cella D2.

    Nella barra della formula il riferimento strutturato [@[% commissione]] è visualizzato dopo l'asterisco.

  6. Premere Invio.

    Excel crea automaticamente una colonna calcolata e copia la formula nell'intera colonna, adattandola per ogni riga.

Cosa accade quando si usano riferimenti di cella espliciti

Se si immettono riferimenti di cella espliciti in una colonna calcolata, può essere difficile capire quali elementi vengono calcolati dalla formula.

  1. Nel foglio di lavoro di esempio fare clic sulla cella E2

  2. Nella barra della formula immettere = C2 * D2 e premere invio.

Notare che mentre Excel copia la formula nella colonna, non usa i riferimenti incrociati. Se ad esempio si aggiunge una colonna tra le colonne esistenti C e D, è necessario rivedere la formula.

Come si modifica un nome di tabella

Ogni volta che si crea una tabella di Excel, viene creato automaticamente un nome di tabella predefinito, come Tabella1, Tabella2 e così via. È possibile modificare il nome della tabella per renderlo più significativo.

  1. Selezionare una cella qualsiasi della tabella per visualizzare la scheda Strumenti tabella > progettazione sulla barra multifunzione.

  2. Digitare il nome desiderato nella casella nome tabella e premere invio.

Nei dati di esempio è stato usato il nome DeptSales.

Per i nomi di tabella, usare le regole seguenti:

  • Usare caratteri validi  Iniziare sempre un nome con una lettera, un carattere di sottolineatura (_) o una barra rovesciata (\). Usa lettere, numeri, punti e caratteri di sottolineatura per il resto del nome. Non è possibile usare "C", "c", "R" o "r" per il nome, perché sono già stati designati come collegamento per selezionare la colonna o la riga per la cella attiva quando vengono immessi nella casella nome o Vai a .

  • Non usare riferimenti di cella  I nomi non possono essere uguali a quelli di un riferimento di cella, ad esempio Z $100 o R1C1.

  • Non usare uno spazio per separare le parole  Non è possibile usare gli spazi nel nome. Puoi usare il carattere di sottolineatura (_) e il punto (.) come separatori di Word. Ad esempio, DeptSales, Sales_Tax o First. Quarter.

  • Non usare più di 255 caratteri Un nome di tabella può includere al massimo 255 caratteri.

  • Usare nomi di tabella univoci I nomi duplicati non sono consentiti. Excel non fa distinzione tra maiuscole e minuscole nei nomi, quindi se si immette "Vendite" ma è già presente un altro nome "VENDITE" nella stessa cartella di lavoro, verrà richiesto di scegliere un nome univoco.

  • Usare un identificatore di oggetto  Se si prevede di creare una combinazione di tabelle, tabella pivot e grafici, è consigliabile anteporre i nomi al tipo di oggetto. Ad esempio: tbl_Sales per una tabella Sales, pt_Sales per un istogramma di vendita e chrt_Sales per un grafico vendite oppure ptchrt_Sales per un grafico pivot vendite. Questo consente di mantenere tutti i nomi in un elenco ordinato in Gestione nomi.

Regole della sintassi dei riferimenti strutturati

È anche possibile immettere manualmente o modificare i riferimenti strutturati nella formula, ma per farlo sarà utile comprendere la sintassi dei riferimenti strutturati. Ripassiamo l'esempio di formula seguente:

=SOMMA(DeptSales[[#Totals],[Sales Amount]],DeptSales[[#Data],[Commission Amount]])

Questa formula contiene i seguenti componenti di riferimenti strutturati:

  • Nome tabella:   DeptSales è un nome di tabella personalizzato. Fa riferimento ai dati della tabella, senza intestazioni o righe totali. Puoi usare un nome di tabella predefinito, ad esempio Tabella1, o modificarlo in modo da usare un nome personalizzato.

  • Identificatore di colonna:   [Importo vendite]e[Importo provvigione] sono gli specificatori di colonna che usano i nomi delle colonne che rappresentano. Fanno riferimento ai dati della colonna, senza un'intestazione di colonna o una riga totale. Racchiudere sempre gli identificatori tra parentesi quadre, come illustrato.

  • Specificatore di elemento:   [#Totals] e [#Data] sono specificatori di elemento speciali che fanno riferimento a parti specifiche della tabella, ad esempio la riga totale.

  • Specificatore di tabella:   [[#Totals],[Sales Amount]] e [[#Data],[Commission Amount]] sono specificatori di tabella che rappresentano le parti esterne del riferimento strutturato. I riferimenti esterni seguono il nome di tabella e devono essere racchiusi tra parentesi quadre.

  • Riferimento strutturato:   (DeptSales [[#Totals], [Sales Amount]] e DeptSales [[#Data], [Commission Amount]] sono riferimenti strutturati, rappresentati da una stringa che inizia con il nome della tabella e termina con lo specificatore di colonna.

Per creare o modificare manualmente riferimenti strutturati, utilizzare le regole della sintassi seguenti:

  • Usare le parentesi quadre intorno    agli identificatori Tutte le tabelle, le colonne e gli specificatori di elementi speciali devono essere racchiusi tra parentesi quadre ([]). Un identificatore che contiene altri specificatori richiede parentesi quadre esterne per racchiudere le parentesi di corrispondenza interne degli altri specificatori. Ad esempio: = DeptSales [[Sales Person]: [Region]]

  • Le intestazioni di colonna sono stringhe di testo    Non richiedono l'uso delle virgolette quando vengono usate in un riferimento strutturato. Anche numeri o date, ad esempio 2014 o 01/01/2014, sono considerate stringhe di testo. Non è possibile usare espressioni con le intestazioni di colonna. Ad esempio, l'espressione DeptSalesFYSummary[[2014]:[2012]] non funzionerà.

Racchiudere tra parentesi quadre le intestazioni di colonna con caratteri speciali    Se sono presenti caratteri speciali, tutta l'intestazione deve essere racchiusa tra parentesi quadre. Ciò significa che in uno specificatore di colonna sono necessarie parentesi quadre doppie. Ad esempio: =DeptSalesFYSummary[[Total $ Amount]]

Ecco l'elenco dei caratteri speciali che richiedono parentesi quadre aggiuntive nella formula:

  • TAB

  • Avanzamento riga

  • Ritorno a capo

  • Virgola (,)

  • Due punti (:)

  • Punto (.)

  • Parentesi quadra aperta ([)

  • Parentesi quadra chiusa ([)

  • Cancelletto (#)

  • Virgoletta singola (')

  • Virgolette doppie (")

  • Parentesi graffa aperta ({})

  • Parentesi graffa chiusa (})

  • Segno di dollaro ($)

  • Accento circonflesso (^)

  • E commerciale (&)

  • Asterisco (*)

  • Segno di addizione (+)

  • Segno di uguale (=)

  • Segno di sottrazione (-)

  • Segno di maggiore (>)

  • Segno di minore (<)

  • Segno di divisione (/)

  • Usare un carattere di escape per alcuni caratteri speciali nelle intestazioni di colonna    Alcuni caratteri hanno un significato speciale e richiedono l'uso di una virgoletta singola (') come carattere di escape. Ad esempio: =DeptSalesFYSummary['#OfItems]

Ecco l'elenco dei caratteri speciali che richiedono un carattere di escape (') nella formula:

  • Parentesi quadra aperta ([)

  • Parentesi quadra chiusa ([)

  • Cancelletto (#)

  • Virgoletta singola (')

Usare lo spazio per migliorare la leggibilità in un riferimento strutturato    È possibile usare spazi per migliorare la leggibilità di un riferimento strutturato. Ad esempio: =DeptSales[ [Sales Person]:[Region] ] o =DeptSales[[#Headers], [#Data], [% Commission]]

È consigliabile usare uno spazio:

  • Dopo la prima parentesi quadra aperta ([]).

  • Prima l'ultima parentesi quadra chiusa (]).

  • Dopo una virgola.

Operatori di riferimento

Per una maggiore flessibilità nella specifica degli intervalli di celle, è possibile usare gli operatori di riferimento seguenti per combinare specificatori di colonna:

Il riferimento strutturato seguente:

Fa riferimento a:

Usando:

Che è l'intervallo di celle:

=DeptSales[[Sales Person]:[Region]]

Tutte le celle in due o più colonne adiacenti

L'operatore di intervallo : (due punti)

A2:B7

=DeptSales[Sales Amount],DeptSales[Commission Amount]

Una combinazione di due o più colonne

L'operatore di unione ; (punto e virgola)

C2:C7, E2:E7

=DeptSales[[Sales Person]:[Sales Amount]] DeptSales[[Region]:[% Commission]]

L'intersezione di due o più colonne

L'operatore di intersezione  (spazio)

B2:C7

Specificatori di elementi speciali

Per fare riferimento a parti specifiche di una tabella, ad esempio solo la riga dei totali, è possibile usare uno dei seguenti specificatori di elemento speciali nei riferimenti strutturati.

Lo specificatore di elemento speciale seguente:

Fa riferimento a:

#All

L'intera tabella, inclusi intestazioni di colonna, dati e totali, se presenti.

#Data

Solo le righe di dati.

#Headers

Solo la riga dell'intestazione.

#Totals

Solo la riga dei totali. Se non è presente, verrà restituito un valore null.

#This Row

oppure

@

oppure

@[Nome colonna]

Solo le celle nella stessa riga della formula. Questi specificatori non può essere combinati con altri specificatori di elementi speciali. Usarli per forzare il comportamento di intersezione implicita per il riferimento o per ignorare tale comportamento e fare riferimento ai singoli valori di una colonna.

Excel modifica automaticamente gli specificatori #This Row nella forma più breve @ nelle tabelle che contengono più di una riga di dati. Se la tabella contiene solo una riga, Excel non sostituisce lo specificatore #This Row e questo comportamento potrebbe causare risultati di calcolo imprevisti quando si aggiungono più righe. Per evitare problemi di calcolo, inserire più righe nella tabella prima di immettere qualsiasi formula di riferimento strutturato.

Specifica di riferimenti strutturati nelle colonne calcolate

Quando si crea una colonna calcolata, si utilizza spesso un riferimento strutturato per creare la formula. Tale riferimento può essere non qualificato o completo. Per creare, ad esempio, la colonna calcolata denominata Commission Amount che calcola l'importo della commissione in dollari, è possibile utilizzare le formule seguenti:

Tipo di riferimento strutturato

Esempio

Commento

Non qualificato

=[Sales Amount]*[% Commission]

Moltiplica i valori corrispondenti della riga corrente.

Completo

=DeptSales[Sales Amount]*DeptSales[% Commission]

Moltiplica i valori corrispondenti per ogni riga di entrambe le colonne.

In base alla regola generale alla quale è necessario attenersi, se si usano riferimenti strutturati all'interno di una tabella, ad esempio quando si crea una colonna calcolata, è possibile usare un riferimento strutturato non qualificato. Se invece il riferimento strutturato viene usato all'esterno della tabella, è necessario usare un riferimento strutturato completo.

Esempi di utilizzo dei riferimenti strutturati

Di seguito sono riportati alcuni modi di utilizzo dei riferimenti strutturati.

Il riferimento strutturato seguente:

Fa riferimento a:

Che è l'intervallo di celle:

=DeptSales[[#All],[Sales Amount]]

Tutte le celle della colonna Sales Amount.

C1:C8

=DeptSales[[#Headers],[% Commission]]

L'intestazione della colonna % Commission.

D1

=DeptSales[[#Totals];[Region]]

Il totale della colonna Region. In assenza di una riga dei totali, verrà restituito un valore Null.

B8

=DeptSales[[#All],[Sales Amount]:[% Commission]]

Tutte le celle in Sales Amount e % Commission.

C1:D8

=DeptSales[[#Data],[% Commission]:[Commission Amount]]

Solo i dati delle colonne % Commission e Commission Amount.

D2:E7

=DeptSales[[#Headers],[Region]:[Commission Amount]]

Solo le intestazioni delle colonne comprese tra Region e Commission Amount.

B1:E1

=DeptSales[[#Totals],[Sales Amount]:[Commission Amount]]

I totali delle colonne da Sales Amount a Commission Amount. In assenza di una riga dei totali, viene restituito un valore null.

C8:E8

=DeptSales[[#Headers],[#Data],[% Commission]]

Solo l'intestazione e i dati di % Commission.

D1:D7

=DeptSales[[#This Row], [Commission Amount]]

oppure

=DeptSales[@Commission Amount]

La cella all'intersezione della riga corrente e della colonna importo Commissione. Se usato nella stessa riga di un'intestazione o di una riga totale, verrà restituito un #VALUE! Error.

Se si digita la forma più lunga di questo riferimento strutturato (#This Row) in una tabella con più righe di dati, Excel la sostituisce automaticamente con la forma breve (@). Entrambe funzionano allo stesso modo.

E5 (se la riga corrente è 5)

Strategie per l'uso di riferimenti strutturati

Quando si usano riferimenti strutturati, tenere presente quanto segue.

  • Usare Completamento automatico formule    L'uso di Completamento automatico formule può risultare molto utile quando si immettono riferimenti strutturati e per garantire l'uso di una sintassi corretta. Per altre informazioni, vedere Usare Completamento automatico formule.

  • Decidere se generare riferimenti strutturati per le tabelle in semi-selezioni    Per impostazione predefinita, quando si crea una formula, se si fa clic su un intervallo di celle all'interno di una tabella, viene selezionata l'opzione Seleziona le celle e viene automaticamente inserito un riferimento strutturato anziché l'intervallo di celle nella formula. Questo comportamento di selezione semi rende molto più semplice l'immissione di un riferimento strutturato. È possibile attivare o disattivare questo comportamento selezionando o deselezionando la casella di controllo Usa nomi di tabella nelle formule > Opzioni > formule > uso della finestra di dialogo formule.

  • Usare le cartelle di lavoro con collegamenti esterni a tabelle di Excel in altre cartelle di lavoro    Se una cartella di lavoro contiene un collegamento esterno a una tabella di Excel in un'altra cartella di lavoro, la cartella di lavoro di origine collegata deve essere aperta in Excel per evitare #REF. errori nella cartella di lavoro di destinazione che contiene i collegamenti. Se si apre prima la cartella di lavoro di destinazione e viene visualizzato #REF. gli errori verranno risolti se si apre la cartella di lavoro di origine. Se si apre prima la cartella di lavoro di origine, non vengono visualizzati codici di errore.

  • Convertire un intervallo in una tabella e una tabella in un intervallo    Quando si converte una tabella in un intervallo, tutti i riferimenti di cella vengono sostituiti con i riferimenti di tipo A1 assoluti equivalenti. Quando si converte un intervallo in una tabella, Excel non modifica automaticamente i riferimenti di cella di questo intervallo nei riferimenti strutturati equivalenti.

  • Disattivare le intestazioni di colonna    È possibile attivare e disattivare le intestazioni di colonna della tabella dalla riga di intestazione della scheda struttura >. Se si disattivano le intestazioni di colonna della tabella, i riferimenti strutturati che usano nomi di colonna non sono interessati ed è comunque possibile usarli nelle formule. I riferimenti strutturati che si riferiscono direttamente alle intestazioni di tabella (ad esempio = DeptSales [[#Headers], [% Commissione]]) comporteranno #REF.

  • Aggiungere o eliminare colonne e righe nella tabella    Poiché gli intervalli di dati della tabella cambiano spesso, i riferimenti di cella per i riferimenti strutturati vengono modificati automaticamente. Se ad esempio si usa un nome di tabella in una formula per contare tutte le celle dati in una tabella e quindi si aggiunge una riga di dati, il riferimento di cella viene regolato automaticamente.

  • Ridenominare una tabella o una colonna    Se si rinomina una colonna o una tabella, viene automaticamente modificato l'utilizzo dell'intestazione di tale tabella e colonna in tutti i riferimenti strutturati utilizzati nella cartella di lavoro.

  • Spostare, copiare e riempire riferimenti strutturati    Tutti i riferimenti strutturati restano identici quando si copia o si sposta una formula che ne usa uno.

    Nota: La copia di un riferimento strutturato e l'esecuzione di un riempimento in un riferimento strutturato non sono la stessa cosa. Quando si esegue una copia, tutti i riferimenti strutturati restano identici, mentre quando si esegue il riempimento di una formula i riferimenti strutturati completi modificano gli specificatori di colonna sotto forma di una serie, come riepilogato nella tabella seguente.

Direzione del riempimento

Tasto premuto durante il riempimento

Azione eseguita

In alto o in basso

Non consentito

Gli specificatori di colonna non vengono modificati.

In alto o in basso

CTRL

Gli specificatori di colonna vengono modificati sotto forma di una serie.

A destra o a sinistra

Nessuno

Gli specificatori di colonna vengono modificati sotto forma di una serie.

In alto, in basso, a destra o a sinistra

MAIUSC

Anziché sovrascrivere i valori nelle celle correnti, i valori delle celle correnti vengono spostati e vengono inseriti specificatori di colonna.

Servono altre informazioni?

È sempre possibile rivolgersi a un esperto nella Tech Community di Excel, ottenere supporto nella community Microsoft o suggerire una nuova funzionalità o un miglioramento in Excel UserVoice.

Argomenti correlati

Panoramica delle tabelle
di Excelvideo: creare e formattare una tabella
di Exceltotale dati in una tabella di Excel
formattare
una tabelladi Excel ridimensionare una tabella aggiungendo o rimuovendo righe e colonne
Filtrare i dati in un intervallo o in una tabella
convertire una tabella in un intervallo
tra iproblemi
di compatibilità delle tabelle di Excelesportare una tabella di Excel
inanteprime di SharePoint delle formule in Excel

Amplia le tue competenze su Office
Esplora i corsi di formazione
Ottieni in anticipo le nuove caratteristiche
Partecipa al programma Office Insider

Queste informazioni sono risultate utili?

Grazie per il feedback!

Grazie per il tuo feedback! Potrebbe essere utile metterti in contatto con uno dei nostri operatori del supporto di Office.

×