Proprietà OpenArgs

Si applica a

Oggetto Form

Oggetto Report

Determina l'espressione stringa specificata dall'argomento OpenArgs del metodo OpenForm usato per aprire una maschera. Oggetto Variant di lettura/scrittura.

espressione.OpenArgs

espressione Obbligatorio. Espressione che restituisce uno degli oggetti inclusi nell'elenco Si applica a.

Osservazioni

Questa proprietà è disponibile solo con una macro oppure usando il codice di Visual Basic, Applications Edition (VBA) con il metodo OpenForm dell'oggetto DoCmd. L'impostazione di questa proprietà è di sola lettura in tutte le visualizzazioni.

Per usare la proprietà OpenArgs, aprire una maschera con il metodo OpenForm dell'oggetto DoCmd e impostare l'argomento OpenArgs sull'espressione stringa desiderata. L'impostazione della proprietà OpenArgs può essere quindi usata nel codice della maschera, ad esempio in una routine evento Apri. È anche possibile fare riferimento all'impostazione della proprietà in una macro, ad esempio una macro Apri o un'espressione, ad esempio un'espressione che imposta la proprietà ControlSource proprietà per un controllo nella maschera.

Si supponga, ad esempio, che la maschera aperta sia un elenco a maschera continua di client. Per spostare lo stato attivo su un record cliente specifico all'apertura della maschera, è possibile impostare la proprietà OpenArgs sul nome del client, quindi usare l'azione TrovaRecord in una macro Apri per spostare lo stato attivo sul record del client con il nome specificato.

Esempio

L'esempio seguente usa la proprietà OpenArgs per aprire la maschera Dipendenti sul record di un dipendente specifico e mostra in che modo il metodo OpenForm imposta la proprietà OpenArgs. È possibile eseguire questa routine in base alle esigenze, ad esempio quando si verifica l'evento AfterUpdate per una finestra di dialogo personalizzata usata per immettere nuove informazioni relative a un dipendente.

Sub OpenToCallahan()
DoCmd.OpenForm "Employees", acNormal, , , _
acReadOnly, , "Callahan"
End Sub
Sub Form_Open(Cancel As Integer)
Dim strEmployeeName As String
' If OpenArgs property contains employee name, find
' corresponding employee record and display it on
' form. For example,if the OpenArgs property
' contains "Callahan", move to first "Callahan"
' record.
strEmployeeName = Forms!Employees.OpenArgs
If Len(strEmployeeName) > 0 Then
DoCmd.GoToControl "LastName"
DoCmd.FindRecord strEmployeeName, , True, , _
True, , True
End If
End Sub

L'esempio seguente usa il metodo FindFirst per individuare il dipendente denominato nella proprietà OpenArgs.

Private Sub Form_Open(Cancel As Integer)
If Not IsNull(Me.OpenArgs) Then
Dim strEmployeeName As String
strEmployeeName = Me.OpenArgs
Dim RS As DAO.Recordset
Set RS = Me.RecordsetClone
RS.FindFirst "LastName = '" & _
strEmployeeName & "'"
If Not RS.NoMatch Then
Me.Bookmark = RS.Bookmark
End If
End If
End Sub
Amplia le tue competenze su Office
Esplora i corsi di formazione
Ottieni in anticipo le nuove caratteristiche
Partecipa al programma Office Insider

Queste informazioni sono risultate utili?

Grazie per il feedback!

Grazie per il tuo feedback! Potrebbe essere utile metterti in contatto con uno dei nostri operatori del supporto di Office.

×