Proprietà FileDialog

Si applica a

Oggetto Application

Restituisce un oggetto FileDialog che rappresenta una singola istanza di una finestra di dialogo.

espressione.FileDialog(dialogType)

espressione Obbligatorio. Espressione che restituisce uno degli oggetti inclusi nell'elenco Si applica a.

dialogType    Obbligatorio MsoFileDialogType . Il tipo di finestra di dialogo.

MsoFileDialogType può essere una delle costanti MsoFileDialogType.

msoFileDialogFilePicker

msoFileDialogFolderPicker

msoFileDialogOpen Non supportato in Microsoft Access.

msoFileDialogSaveAs Non supportato in Microsoft Access.

Osservazioni

Le costanti msoFileDialogOpen e msoFileDialogSaveAs non sono supportate in Microsoft Office Access 2007.

Esempio

Questo esempio illustra come usare l'oggetto FileDialog per visualizzare una finestra di dialogo che consenta all'utente di selezionare uno o più file. I file selezionati vengono quindi aggiunti a una casella di riepilogo denominata FileList.

Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
Amplia le tue competenze su Office
Esplora i corsi di formazione
Ottieni in anticipo le nuove caratteristiche
Partecipa al programma Office Insider

Queste informazioni sono risultate utili?

Grazie per il feedback!

Grazie per il tuo feedback! Potrebbe essere utile metterti in contatto con uno dei nostri operatori del supporto di Office.

×