Uso di riferimenti strutturati nelle formule

I riferimenti strutturati rendono molto più facile e più intuitivo usare dati di tabella quando si hanno formule che fanno riferimento ad alcune parti di una tabella o all'intera tabella. Sono particolarmente utili perché gli intervalli di dati delle tabelle cambiano spesso e i riferimenti di cella per i riferimenti strutturati vengono modificati automaticamente. In questo modo si riduce al minimo la necessità di riscrivere le formule quando vengono aggiunte ed eliminate righe e colonne in una tabella o quando vengono aggiornati i dati esterni.

Può essere preferibile questo riferimento strutturato

A questo riferimento di cella

=SOMMA(DailyExercise[CardioTraining])

=SOMMA(C2:C7)

Componenti di un riferimento strutturato

Per usare le tabelle e i riferimenti strutturati in modo efficace, è necessario saper creare la sintassi dei riferimenti strutturati durante la creazione delle formule. Nel seguente esempio di formula, che calcola il numero medio di minuti in CardioTraining, sono illustrati i componenti di un riferimento strutturato:

=MEDIA(DailyExercise[[#Data],[CardioTraining]])

Callout 1 Nome significativo specificato per fare riferimento ai dati della tabella effettiva, ad esempio DailyExercise, ad esclusione delle righe delle intestazioni e dei totali, se presenti.

Callout 2 #Data è uno specificatore di elemento speciale che fa riferimento a parti specifiche della tabella (i dati).

Callout 3   CardioTraining è uno specificatore di colonna derivato dall'intestazione di colonna.

Callout 4  Lo specificatore di tabella è costituito dallo specificatore di elemento speciale e dallo specificatore di colonna racchiusi da un'altra coppia di parentesi quadre. 

Callout 5  Il nome di tabella, lo specificatore di colonna e lo specificatore di elemento speciale formano un riferimento strutturato.

Nota :  Se si usano riferimenti strutturati all'interno di una tabella, non è necessario includere il nome di tabella o le parentesi intorno allo specificatore di tabella. Tale riferimento è detto non qualificato. Per l'esempio precedente il riferimento non qualificato è =MEDIA([#Data],[CardioTraining]). È tuttavia consigliabile usare riferimenti strutturati qualificati, in caso si decida di spostare una formula all'esterno della tabella.

Specificatori di elementi speciali

L'uso di specificatori di elementi speciali consente di fare riferimento esattamente a determinate righe, senza dover conoscere i numeri di riga.

Lo specificatore di elemento speciale

Fa riferimento a

#All

Intera tabella, inclusi intestazioni di colonna, dati e totali.

#Data

Solo le righe di dati.

#Headers

Solo la riga dell'intestazione.

#Totals

Solo la riga dei totali. Se non è presente, verrà restituito un valore Null.

#This Row o @

Solo le celle nella stessa riga della formula. Questo specificatore non può essere combinato con altri specificatori di elementi speciali.

Regole della sintassi dei riferimenti strutturati

Seguire queste regole per essere certi che i riferimenti strutturati vengano interpretati da Excel.

  • Tutti gli specificatori di tabella, colonna e di elementi speciali devono essere racchiusi tra parentesi quadre.

  • Le intestazioni di colonna, e quindi gli specificatori di colonna, sono sempre stringhe di testo, anche se includono numeri. Ciò significa che non è possibile usare espressioni matematiche in queste celle.

  • Se un'intestazione di colonna contiene determinati caratteri speciali, il relativo specificatore di colonna deve essere racchiuso da una coppia aggiuntiva di parentesi quadre. I caratteri speciali sono i seguenti: spazio, tabulazione, avanzamento di riga, ritorno a capo, virgola (,), due punti (:), punto (.), parentesi quadra aperta ([), parentesi quadra chiusa (]), cancelletto (#), virgoletta singola ('), virgolette doppie ("), parentesi graffa aperta ({), parentesi graffa chiusa (}), simbolo del dollaro ($), accento circonflesso (^), e commerciale (&), asterisco (*), segno più (+), segno di uguale (=), segno meno (-), simbolo maggiore di (>), simbolo minore di (<) e segno di divisione (/). La sola eccezione riguarda l'inclusione di uno spazio come unico carattere speciale.

  • I caratteri seguenti hanno un significato speciale e richiedono l'uso di una virgoletta singola (') come carattere di escape: parentesi quadra aperta ([), parentesi quadra chiusa (]), cancelletto (#) e virgoletta singola ('). Ad esempio, una colonna denominata Item# avrà lo specificatore di colonna: [Item'#].: =DeptSalesFYSummary['#OfItems]

  • Per migliorare la leggibilità di un riferimento strutturato, è consentito inserire spazi in tre punti del riferimento: subito dopo la prima parentesi quadra aperta ([), subito prima dell'ultima parentesi quadra chiusa (]) e dopo le virgole.

Esempi di riferimenti strutturati

Questi sono esempi di riferimenti strutturati da usare all'interno di una formula. Non funzioneranno singolarmente.

Il riferimento strutturato seguente

Fa riferimento a

DailyExercise[[#All],[StrengthTraining]]

Tutte le celle nella colonna StrengthTraining, inclusi l'intestazione, i dati e la riga dei totali.

DailyExercise[[#Headers],[CardioTraining]:[StrengthTraining]]

Intestazioni tra le colonne CardioTraining e StrengthTraining comprese.

DailyExercise[[#Totals],[StrengthTraining]]

Totale della colonna StrengthTraining. In assenza di una riga dei totali, verrà restituito #RIF!.

DailyExercise[[#Data],[CardioTraining]:[StrengthTraining]]

Dati tra le colonne CardioTraining e StrengthTraining comprese.

DailyExercise[[#Headers],[#Data],[StrengthTraining]]

Intestazione e dati nella colonna StrengthTraining. Se le intestazioni sono disattivate, verrà restituito #RIF!

DailyExercise[[#This Row],[CardioTraining]]

-oppure-

DailyExercise[@CardioTraining]

Cella all'intersezione della riga corrente e della colonna CardioTraining. Se usato nella stessa riga dell'intestazione o del totale, verrà restituito #VALORE!.

Nota :  Se si digita il formato più lungo di questo riferimento strutturato, Excel lo sostituisce con il formato '@' più breve Il funzionamento è lo stesso.

Vedere anche

Immettere una formula

Utilizzare nomi nelle formule

Creare o eliminare una tabella Excel

Amplia le tue competenze
Esplora i corsi di formazione
Ottieni in anticipo le nuove caratteristiche
Partecipa al programma Office Insider

Queste informazioni sono risultate utili?

Grazie per i tuoi commenti e suggerimenti

Grazie per il tuo feedback! Potrebbe essere utile metterti in contatto con uno dei nostri operatori del supporto di Office.

×