Uso di SE con le funzioni E, O e NON

La funzione SE consente di eseguire un confronto logico tra un valore e il risultato previsto dopo aver eseguito il test di una condizione e aver ottenuto un risultato VERO o FALSO.

  • =SE(qualcosa è Vero, eseguire un'azione, altrimenti eseguire un'altra azione)

Cosa fare però se occorre testare più condizioni, in cui ad esempio tutte le condizioni devono essere vere o false (E) oppure una sola condizione deve essere vera o falsa (O) o ancora se si vuole verificare se una condizione NON soddisfa i criteri specificati? Tutte e 3 le funzioni possono essere usate da sole, ma è molto più frequente vederle abbinate a funzioni SE.

Usare la funzione SE insieme a E, O e NON per valutare se più condizioni sono vere o false.

Sintassi

  • SE(E()) - SE(E(logico1; [logico2]; ...); se_vero; [se_falso]))

  • SE(O()) - SE(O(logico1; [logico2]; ...); se_vero; [se_falso]))

  • SE(NON()) - SE(NON(logico1); se_vero; [se_falso]))

Nome argomento

Descrizione

test (obbligatorio)

Condizione da testare.

se_vero (obbligatorio)

Valore restituito se il risultato di test è VERO.

se_falso (facoltativo)

Valore restituito se il risultato di test è FALSO.

Ecco alcuni esempi di come strutturare le funzioni E, O e NON singolarmente. Quando si combina ognuna di esse con un'istruzione SE, la struttura è la seguente:

  • E – =SE(E(Una condizione è vera; Un'altra condizione è vera); Valore se Vero; Valore se Falso)

  • O – =SE(O(Una condizione è vera; Un'altra condizione è vera); Valore se Vero; Valore se Falso)

  • NON – =SE(NON(Una condizione è vera); Valore se Vero; Valore se Falso)

Esempi

Ecco alcuni esempi comuni di istruzioni SE(E()), SE(O()) e SE(NON()) annidate. Le funzioni E e O supportano fino a 255 singole condizioni, ma è preferibile usarne poche in quanto le formule annidate complesse possono essere molto difficili da creare, testare e gestire. La funzione NON accetta una sola condizione.

Esempi di utilizzo della funzione SE con E, O e NON per valutare valori numerici e testo

Ecco le formule specificate in base alla relativa logica:

Formula

Descrizione

=SE(E(A2>0;B2<100);VERO; FALSO)

SE A2 (25) è maggiore di 0 E B2 (75) è minore di 100, restituisci VERO, altrimenti FALSO. In questo caso entrambe le condizioni sono vere, quindi viene restituito VERO.

=SE(E(A3="Rosso";B3="Verde");VERO;FALSO)

SE A3 ("Blu") è uguale a "Rosso" E B3 ("Verde") è uguale a "Verde" restituisci VERO, altrimenti FALSO. In questo caso è vera solo la prima condizione, quindi viene restituito FALSO.

=SE(O(A4>0;B4<50);VERO; FALSO)

SE A4 (25) è maggiore di 0 O B4 (75) è minore di 50, restituisci VERO, altrimenti FALSO. In questo caso è vera solo la prima condizione, ma poiché per O è sufficiente che un solo argomento sia vero la formula restituisce VERO.

=SE(O(A5="Rosso";B5="Verde"); VERO;FALSO)

SE A5 ("Blu") è uguale a "Rosso" O B5 ("Verde") è uguale a "Verde" restituisci VERO, altrimenti FALSO. In questo caso il secondo argomento è vero, quindi la formula restituisce VERO.

=SE(NON(A6>50);VERO;FALSO)

SE A6 (25) NON è maggiore di 50 restituisci VERO, altrimenti FALSO. In questo caso 25 non è maggiore di 50, quindi la formula restituisce VERO.

=SE(NON(A7="Rosso");VERO;FALSO)

SE A7 ("Blu") NON è uguale a "Rosso" restituisci VERO, altrimenti FALSO.

Si noti che in tutti gli esempi ogni condizione è seguita da una parentesi chiusa. Gli argomenti Vero/Falso rimanenti fanno quindi parte dell'istruzione SE esterna. È anche possibile sostituire i valori VERO/FALSO con valori di testo o numerici da restituire negli esempi.

Ecco alcuni esempi di utilizzo delle funzioni E, O e NON per valutare date.

Esempi di utilizzo della funzione SE con E, O e NON per valutare date

Ecco le formule specificate in base alla relativa logica:

Formula

Descrizione

=SE(A2>B2;VERO;FALSO)

SE A2 è maggiore di B2 restituisci VERO, altrimenti FALSO. In questo caso 12/03/14 è maggiore di 01/01/14, quindi la formula restituisce VERO.

=SE(E(A3>B2;A3<C2);VERO;FALSO)

SE A3 è maggiore di B2 E A3 è maggiore di C2 restituisci VERO, altrimenti FALSO. In questo caso entrambi gli argomenti sono veri, quindi la formula restituisce VERO.

=SE(O(A4>B2;A4<B2+60);VERO;FALSO)

SE A4 è maggiore di B2 O A4 è minore di B2 + 60 restituisci VERO, altrimenti FALSO. In questo caso il primo argomento è vero, ma il secondo è falso. Poiché per O è sufficiente che solo uno degli argomenti sia vero, la formula restituisce VERO. Per vedere come Excel valuta la formula si può usare la procedura guidata Valuta formula nella scheda Formula.

=SE(NON(A5>B2);VERO;FALSO)

SE A5 NON è maggiore di B2 restituisci VERO, altrimenti FALSO. In questo caso A5 è maggiore di B2, quindi la formula restituisce FALSO.

Esempio della procedura guidata Valuta formula

Uso di E, O e NON con la formattazione condizionale

Si può usare E, O e NON anche per impostare i criteri di formattazione condizionale con l'opzione della formula. In questo caso è possibile omettere la funzione SE e usare E, O e NON da sole.

Nella scheda Home fare clic su Formattazione condizionale > Nuova regola. Selezionare quindi l'opzione Utilizza una formula per determinare le celle da formattare, immettere la formula e applicare il formato desiderato.

Finestra di dialogo Formattazione condizionale > Modifica regola che mostra il metodo Formula

Ecco l'aspetto delle formule con l'esempio delle date precedente.

Esempi di utilizzo di E, O e NON con la formattazione condizionale


Formula

Descrizione

=A2>B2

Se A2 è maggiore di B2, formatta la cella, altrimenti non fare nulla.

=E(A3>B2;A3<C2)

Se A3 è maggiore di B2 E A3 è minore di C2, formatta la cella, altrimenti non fare nulla.

=O(A4>B2;A4<B2+60)

Se A4 è maggiore di B2 O A4 è minore di B2 +60 (giorni), formatta la cella, altrimenti non fare nulla.

=NON(A5>B2)

Se A5 NON è maggiore di B2, formatta la cella, altrimenti non fare nulla. In questo caso A5 è maggiore di B2, quindi la formula restituisce FALSO. Se si modificasse la formula in =NON(B2>A5), verrebbe restituito VERO e la cella verrebbe formattata.

Nota : Molti commettono l'errore di immettere la formula nella finestra Formattazione condizionale senza il segno di uguale (=). In tal caso la finestra di dialogo Formattazione condizionale aggiunge il segno di uguale e racchiude la formula tra virgolette (="O(A4>B2;A4<B2+60)"), quindi sarà necessario rimuovere le virgolette in modo che la formula risponda correttamente.

Inizio pagina

Servono altre informazioni?

È sempre possibile rivolgersi a un esperto nella Tech Community di Excel, ottenere supporto nella community Microsoft o suggerire una nuova caratteristica o un miglioramento in Excel UserVoice.

Vedere anche

Guardare un video che illustra come usare la funzione SE

Informazioni su come usare le formule annidate in una formula

Funzione SE

Funzione E

Funzione O

Funzione NON

Panoramica delle formule in Excel

Come evitare errori nelle formule

Usare il controllo degli errori per trovare gli errori nelle formule

Scelte rapide da tastiera in Excel per Windows

Scelte rapide da tastiera in Excel per Mac

Funzioni logiche (riferimento)

Funzioni di Excel (in ordine alfabetico)

Funzioni di Excel (in base alla categoria)

Amplia le tue competenze
Esplora i corsi di formazione
Ottieni in anticipo le nuove caratteristiche
Partecipa al programma Office Insider

Queste informazioni sono risultate utili?

Grazie per i tuoi commenti e suggerimenti

Grazie per il tuo feedback! Potrebbe essere utile metterti in contatto con uno dei nostri operatori del supporto di Office.

×