Accedi con Microsoft
Accedi o crea un account.
Salve,
Seleziona un altro account.
Hai più account
Scegli l'account con cui vuoi accedere.

La funzione TESTO permette di modificare il modo di visualizzare un numero tramite l'applicazione di formattazione con codici formato. È una funzione utile in situazioni in cui si vuole visualizzare i numeri in un formato più leggibile o combinarli con testo o simboli.

Nota: La funzione TESTO converte i numeri in testo, il che può rendere difficile fare riferimento a calcoli successivi. È consigliabile mantenere il valore originale in una cella e quindi usare la funzione TESTO in un'altra cella. Quindi, se è necessario creare altre formule, fare sempre riferimento al valore originale e non al risultato della funzione TESTO.

Sintassi

TESTO(val; formato)

Gli argomenti della sintassi della funzione TESTO sono i seguenti:

Nome argomento

Descrizione

valore

Valore numerico da convertire in testo.

formato

Stringa di testo che definisce la formattazione da applicare al valore specificato.

Panoramica

Nella sua forma più semplice, la funzione TESTO è:

  • =TESTO(Valore da formattare;"Codice formato da applicare")

Ecco alcuni esempi comuni, che è possibile copiare direttamente in Excel per sperimentare la funzione. Notare i codici formato tra virgolette.

Formula

Descrizione

=TESTO(1234,567;"€ #,##0,00")

Valuta con separatore delle migliaia e 2 decimali, ad esempio € 1.234,57. Notare che Excel arrotonda il valore a 2 posizioni decimali.

=TESTO(OGGI();"GG/MM/AA")

Data odierna in formato GG/MM/AA, ad esempio 14/03/12

=TESTO(OGGI();"GGGG")

Giorno odierno della settimana, ad esempio lunedì

=TESTO(ADESSO();"H.MM")

Ora attuale, ad esempio 1.29

=TESTO(0,285;"0,0%")

Percentuale, ad esempio 28,5%

=TEXT(4,34 ,"# ?/?")

Frazione, ad esempio 4 1/3

=ANNULLA.SPAZI(TESTO(0,34;"# ?/?"))

Frazione, ad esempio 1/3. Questo esempio usa la funzione ANNULLA.SPAZI per rimuovere lo spazio iniziale con un valore decimale.

=TESTO(12200000;"0,00E+00")

Notazione scientifica, ad esempio 1,22E+07

=TESTO(1234567890;"[<=9999999]###-####;(###) ###-####")

Speciale (numero di telefono), ad esempio (123) 456-7890

=TESTO(1234;"0000000")

Aggiunta di zero (0) iniziali, ad esempio 0001234

=TESTO(123456;"##0° 00' 00''")

Formula personalizzata - Latitudine/Longitudine

Nota: Benché sia possibile usare la funzione TESTO per modificare la formattazione, non è l'unico modo. È possibile modificare il formato senza una formula premendo CTRL+1 (o Icona del tasto Comando del Mac+1 nel Mac), quindi selezionare il formato desiderato nella finestra di dialogo Formato celle > numero .

Scaricare questi esempi

È possibile scaricare una cartella di lavoro di esempio con tutti gli esempi della funzione TESTO inclusi in questo articolo, oltre ad alcuni aggiuntivi. È possibile seguire gli esempi oppure creare codici formato personalizzati per la funzione TESTO.

Scarica gli esempi della funzione TESTO di Excel

Altri codici formato disponibili

È possibile usare la finestra di dialogo Formato celle per trovare gli altri codici formato disponibili:

  1. Premere CTRL+1 (Icona del tasto Comando del Mac+1 nel Mac) per visualizzare la finestra di dialogo Formato celle .

  2. Selezionare il formato desiderato nella scheda Numero.

  3. Selezionare l'opzione Personalizzato .

  4. Il codice formato desiderato è ora visualizzato nella casella Tipo. In questo caso, selezionare qualsiasi opzione nella casella Tipo tranne la virgola (,) e il simbolo @. Nell'esempio di seguito è stato selezionato e copiato gg/mm/aa.

  5. Premere CTRL+C per copiare il codice formato e quindi premere Annulla per chiudere la finestra di dialogo Formato celle .

  6. A questo punto, è sufficiente premere CTRL+V per incollare il codice formato nella formula con la funzione TESTO, ad esempio: =TESTO(B2;"gg/mm/aa"). Assicurarsi di incollare il codice formato tra virgolette ("codice formato"), altrimenti Excel invierà un messaggio di errore.

Esempio d'uso della finestra di dialogo Formato > Celle > Numero > Personalizzato per la creazione automatica di stringhe di formato in Excel.

Codici formato per categoria

Ecco alcuni esempi di come è possibile applicare formati numerici diversi ai valori usando la finestra di dialogo Formato celle e quindi usare l'opzione Personalizzato per copiare i codici formato nella funzione TESTO .

Perché Excel elimina gli zeri iniziali?

Excel è in grado di individuare i numeri immessi nelle celle, non i numeri simili a testo, ad esempio numeri di parte o SKU. Per mantenere gli zeri iniziali, formattare l'intervallo di input come Testo prima di incollare o immettere i valori. Selezionare la colonna o l'intervallo in cui verranno inseriti i valori e premere CTRL+1 per visualizzare la finestra di dialogo Formato celle, quindi fare clic su Testo nella scheda Numero. Ora Excel manterrà gli zeri iniziali.

Se dopo aver immesso i dati Excel ha rimosso gli zeri iniziali, è possibile usare la funzione TESTO per aggiungerli di nuovo. È possibile fare riferimento alla cella più in alto con i valori e usare =TESTO(val;"0000"), dove il numero di zeri nella formula rappresenta il numero totale di caratteri desiderati, quindi copiare e incollare nel resto dell'intervallo.

Esempi d'uso della funzione TESTO per formattare gli zeri iniziali.  =TESTO(A2,"00000")

Se per qualsiasi motivo è necessario riconvertire valori di testo in numeri, è possibile moltiplicarli per 1, come =D4*1, oppure usare l'operatore unario doppio (--), ad esempio =--D4.

Excel separa le migliaia con il punto se il formato contiene un punto (.) racchiuso tra simboli di cancelletto (#) o tra zeri. Ad esempio, se la stringa di formato è "#.###, Excel visualizza il numero 12200000 come 12.200,000.

Una virgola che segue un segnaposto di cifra, riduce il numero di 1.000. Ad esempio, se la stringa di formato è "#.###,0,", Excel visualizza il numero 12200000 come 12.200,0.

Esempi della funzione TESTO con il separatore delle migliaia

Note: 

  • Il separatore delle migliaia dipende dalle impostazioni internazionali. In Italia è un punto, ma in altre impostazioni locali può essere una virgola (,).

  • Il separatore delle migliaia è disponibile per i formati numero, valuta e contabilità.

Quelli che seguono sono esempi di formati numero (solo separatore delle migliaia e decimali), valuta e contabilità standard. Il formato valuta permette di inserire il simbolo di valuta desiderato, allineato accanto al valore, mentre il formato contabilità allinea il simbolo valuta a sinistra della cella e il valore a destra. Notare la differenza tra i codici formato valuta e contabilità di seguito, in cui la contabilità usa un asterisco (*) per creare la separazione tra il simbolo e la valuta.

Esempi della funzione TESTO con formati numero, valuta e contabilità

Per trovare il codice formato per un simbolo di valuta, premere prima di tutto CTRL+1 (o Icona del tasto Comando del Mac+1 nel Mac), selezionare il formato desiderato e quindi scegliere un simbolo nell'elenco a discesa Simbolo:

Selezione dei simboli di valuta dalla finestra di dialogo Formato celle

Quindi fare clic su Personalizzato a sinistra della sezione Categoria e copiare il codice formato, incluso il simbolo di valuta.

Funzione TESTO - Personalizzare la valuta con un simbolo

Nota: Poiché la funzione TESTO non supporta la formattazione con colori, se dalla finestra di dialogo Formato celle si copia un formato numero che include un colore, ad esempio € #.##0,00_);[Rosso]($ #.##0,00), la funzione TESTO accetterà il codice formato, ma non visualizzerà il colore.

È possibile modificare il modo di visualizzare una data usando una combinazione di "G" per il giorno, "M" per il mese e "A" per l'anno.

Codici formato per mese, giorno e anno

Poiché i codici formato nella funzione TESTO non fanno distinzione tra maiuscole e minuscole, è possibile usare "G" o "g", "M" o "m" e "A" o "a".

Mynda Treacy, MVP di Excel

Mynda consiglia...

Se si condividono file e report di Excel con utenti di diversi paesi, è possibile offrire a ognuno un report nella sua lingua. Mynda Treacy, MVP di Excel, illustra la sua soluzione per la visualizzazione delle date di Excel in lingue diverse. L'articolo include anche una cartella di lavoro di esempio che può essere scaricata.

È possibile modificare il modo di visualizzare le ore usando una combinazione di "H" per le ore, "M" per i minuti, "S" per i secondi ed eventualmente "AM/PM" per il formato 12 ore.

Formati ora per ore, minuti e secondi

Se non si usa "AM/PM" o "A/P", l'ora verrà visualizzata in base al formato 24 ore.

Poiché i codici formato nella funzione TESTO non fanno distinzione tra maiuscole e minuscole, è possibile usare "H" o "h", "M" o "m", "S" o "s" e "AM/PM" o "am/pm".

È possibile modificare il modo di visualizzare i valori decimali con i formati percentuale (%).

Codici formato per le percentuali

È possibile modificare il modo di visualizzare i valori decimali con i formati (?/?) frazione.

Codici formato per le frazioni

La notazione scientifica è un modo di visualizzare un numero come decimale compreso tra 1 e 10, moltiplicato per una potenza di 10. Viene spesso usata per accorciare la visualizzazione di numeri molto lunghi.

Codici formato per la notazione scientifica

Excel offre quattro formati speciali:

  • C.A.P. - "00000"

  • Codice fiscale - "00000-0000"

  • Numero telefonico - "[<=9999999]###-####;(###) ###-####"

  • Numero Previdenza Sociale - "000-00-0000"

Formati speciali per la funzione TESTO

I formati speciali sono diversi a seconda delle impostazioni locali, ma se non sono disponibili formati speciali per le impostazioni locali specifiche o se quelli disponibili non soddisfano le esigenze, è possibile crearne di personalizzati nella finestra di dialogo Formato celle > Personalizzato.

Scenario comune

Raramente la funzione TESTO viene usata da sola, ma di solito viene usata insieme a qualcos'altro. Si supponga di voler combinare testo con un valore numerico, ad esempio "Report stampato in data: 14/03/12" oppure "Ricavi settimanali: € 66.348,72". Si potrebbe immettere tutto manualmente in Excel, ma è più comodo farlo automaticamente. Sfortunatamente, quando si combina testo e numero formattati, come date, ore, valute e così via, Excel non è in grado di identificare come visualizzarli e quindi elimina la formattazione dei numeri. È in questi casi che è utile la funzione TESTO, che indica a Excel di formattare i valori nel modo desiderato usando un codice formato, ad esempio "GG/MM/AA", per il formato data.

L'esempio seguente mostra cosa accade se si prova a unire testo e un numero senza usare la funzione TESTO. In questo caso, viene usato l'operatore e commerciale (&) per concatenare una stringa di testo, uno spazio e un valore con =A2&" "&B2.

Esempio di unione del testo senza la funzione TESTO

Come si può osservare, Excel ha rimosso la formattazione dalla data nella cella B2. Il prossimo esempio mostra il modo in cui la funzione TESTO permette di applicare il formato desiderato.

Esempio di unione del testo con la funzione TESTO

La formula aggiornata è:

  • Cella C2:=A2&" "&TESTO(B2;"gg/mm/aa") - Formato data

Domande frequenti

Purtroppo, non è possibile farlo con la funzione TESTO; è necessario usare codice Visual Basic, Applications Edition (VBA). Il collegamento seguente contiene un metodo: Come convertire un valore numerico in parole inglesi in Excel.

Sì, è possibile usare le funzioni MAIUSC, MINUSC e MAIUSC.INIZ. Ad esempio, =MAIUSC("hello") restituisce "HELLO".

Sì, ma sono necessari alcuni passaggi. Selezionare prima di tutto la cella o le celle in cui si vuole eseguire questa operazione e premere CTRL+1 per visualizzare la finestra di dialogo Formato > celle , quindi Allineamento > controllo Testo > selezionare l'opzione Testo a capo . Modificare quindi la funzione TESTO completata per includere la funzione CAR(10) nel punto in cui si vuole inserire l'interruzione di riga. Potrebbe essere necessario regolare la larghezza delle colonne a seconda dell'allineamento del risultato finale.

Esempio d'uso della funzione TESTO con CHAR(10) per inserire un'interruzione di riga. = "Oggi è:"&CHAR(10))&TESTO(OGGI(),"MM/GG/AA")

In questo caso è stato usato: ="Oggi è: "&CODICE.CARATT(10)&TESTO(OGGI();"gg/mm/aa")

Questa caratteristica è detta notazione scientifica ed Excel converte automaticamente i numeri più lunghi di 12 cifre se una o più celle sono formattate come Generale e 15 cifre se una o più celle sono formattate come numero. Se è necessario immettere stringhe numeriche lunghe, ma non si desidera convertirle, formattare le celle in questione come Testo prima di immettere o incollare i valori in Excel.

Mynda Treacy, MVP di Excel

Mynda consiglia...

Se si condividono file e report di Excel con utenti di diversi paesi, è possibile offrire a ognuno un report nella sua lingua. Mynda Treacy, MVP di Excel, illustra la sua soluzione per la visualizzazione delle date di Excel in lingue diverse. L'articolo include anche una cartella di lavoro di esempio che può essere scaricata.

Vedere anche

Creare o eliminare un formato di numero personalizzato

Convertire in numeri i numeri memorizzati come testo

Funzioni di Excel (in base alla categoria)

Serve aiuto?

Vuoi altre opzioni?

Esplorare i vantaggi dell'abbonamento e i corsi di formazione, scoprire come proteggere il dispositivo e molto altro ancora.

Le community aiutano a porre e a rispondere alle domande, a fornire feedback e ad ascoltare gli esperti con approfondite conoscenze.

Queste informazioni sono risultate utili?

Come valuti la qualità della lingua?
Cosa ha influito sulla tua esperienza?
Premendo Inviare, il tuo feedback verrà usato per migliorare i prodotti e i servizi Microsoft. L'amministratore IT potrà raccogliere questi dati. Informativa sulla privacy.

Grazie per il feedback!

×