Funzione SOMMA

La funzione SOMMA, una delle funzioni matematiche e trigonometriche, somma i valori. È possibile sommare singoli valori, riferimenti o intervalli di celle o una combinazione dei tre.

Ad esempio:

  • =SOMMA(A2:A10)

  • =SOMMA(A2:A10; C2:C10)

Il browser in uso non supporta le funzionalità video. Installare Microsoft Silverlight, Adobe Flash Player o Internet Explorer 9.

Questo video fa parte di un corso di formazione intitolato Sommare numeri in Excel 2013.

SOMMA(num1;[num2];...)

Nome argomento

Descrizione

num1    (obbligatorio)

Primo numero da sommare. Il numero può essere ad esempio 4, un riferimento di cella come B6 o un intervallo di celle come B2:B8.

num2-255    (facoltativo)

Secondo numero da sommare. È possibile specificare fino a 255 numeri in questo modo.

Se si vuole ottenere rapidamente la somma di un intervallo di celle, basta selezionare l'intervallo e osservare l'angolo in basso a destra della finestra di Excel.

Screenshot che mostra la selezione di un intervallo di celle, con la barra di stato evidenziata
Barra di stato


Questa è la barra di stato, e contiene informazioni relative a qualsiasi elemento selezionato, che sia una singola cella o un intervallo di celle. Se si fa clic con il pulsante destro del mouse sulla barra di stato, viene visualizzato un menu con tutte le opzioni che è possibile selezionare. Vengono visualizzati anche i valori dell'intervallo selezionato, se tali attributi sono attivati. Altre informazioni sulla barra di stato.

Il modo più semplice di aggiungere una formula SOMMA al foglio di lavoro consiste nell'usare la procedura guidata Somma automatica. Selezionare una cella vuota direttamente sopra o sotto l'intervallo che si vuole sommare, quindi nella scheda Home o Formule sulla barra multifunzione selezionare Somma automatica > Somma. La procedura guidata Somma automatica rileva automaticamente l'intervallo da sommare e crea la formula. Funziona anche in orizzontale se si seleziona una cella a sinistra o a destra dell'intervallo da sommare. Non funziona invece con gli intervalli non contigui, ma questo argomento verrà affrontato nella prossima sezione.

È possibile usare la procedura guidata Somma automatica per creare automaticamente una formula SOMMA.  Selezionare un intervallo sopra/sotto o a sinistra/destra dell'intervallo da sommare e quindi scegliere la scheda Formule sulla barra multifunzione e selezionare Somma automatica > Somma.
Usare la procedura guidata Somma automatica per sommare rapidamente intervalli contigui


La finestra di dialogo Somma automatica consente anche di selezionare altre funzioni comuni, come:

Somma automatica in verticale

La cella B6 mostra la formula SOMMA con Somma automatica: =SOMMA(B2:B5)

La procedura guidata Somma automatica ha individuato automaticamente le celle B2:B5 come l'intervallo da sommare. Non resta che premere INVIO per confermare. Se occorre aggiungere/escludere altre celle, è possibile tenere premuto MAIUSC e il tasto di direzione appropriato finché la selezione non corrisponde a quella desiderata, quindi premere INVIO.

Guida IntelliSense per le funzioni: la casella mobile SOMMA(num1;[num2]; …) sotto la funzione è la relativa guida IntelliSense. Se si fa clic sul nome della funzione, questa diventa un collegamento ipertestuale blu che consente di accedere all'argomento della Guida relativo alla funzione. Se si fa clic sui singoli elementi della funzione, vengono evidenziate le parti rappresentative nella formula. In questo caso viene evidenziato solo l'intervallo B2:B5 perché è presente un solo riferimento numerico in questa formula. La casella della guida IntelliSense viene visualizzata per qualsiasi funzione.

Somma automatica in orizzontale

La cella D2 mostra la formula SOMMA con Somma automatica: =SOMMA(B2:C2)

Uso di SOMMA con intervalli non contigui.  La formula della cella C8 è =SOMMA(C2:C3;C5:C6). Si possono usare anche intervalli denominati, nel qual caso la formula sarebbe =SOMMA(Settimana1;Settimana2).

La procedura guidata Somma automatica funziona in genere solo con gli intervalli contigui, quindi se l'intervallo da sommare contiene righe o colonne vuote, Excel si interrompe appena ne incontra una. In questo caso è necessario aggiungere i singoli intervalli da sommare uno per uno. In questo esempio, se la cella B4 contenesse dati, Excel genererebbe =SOMMA(C2:C6) in quanto riconoscerebbe un intervallo contiguo.

È possibile selezionare rapidamente più intervalli non contigui premendo CTRL e facendo clic su ognuno. Immettere prima di tutto "=SOMMA(", quindi selezionare i diversi intervalli. Excel aggiungerà automaticamente il punto e virgola separatore tra gli intervalli. Al termine premere INVIO.

SUGGERIMENTO: è possibile premere ALT+= per aggiungere rapidamente la funzione SOMMA a una cella. Quindi non resta che selezionare gli intervalli.

Nota: come si può notare, Excel ha evidenziato con un colore diverso i diversi intervalli della funzione, corrispondenti alla formula stessa, quindi C2:C3 è di un colore e C5:C6 è di un altro colore. Excel esegue questa operazione per tutte le funzioni, a meno che l'intervallo a cui si fa riferimento non sia in un foglio di lavoro diverso o in una cartella di lavoro diversa. Per migliorare l'accessibilità con gli strumenti di assistive technology, è possibile usare intervalli denominati, come "Settimana1", "Settimana2" e così via, e quindi fare riferimento a essi nella formula:

=SOMMA(Settimana1;Settimana2)

È possibile eseguire facilmente operazioni matematiche con Excel, da sole o insieme a funzioni di Excel come SOMMA. La tabella seguente contiene gli operatori che è possibile usare, insieme ad alcune funzioni correlate. È possibile immettere gli operatori usando la fila dei numeri nella parte alta della tastiera oppure il tastierino numerico, se disponibile. Ad esempio, MAIUSC+8 inserisce l'asterisco (*) per la moltiplicazione.

Operatore

Operazione

Esempi

+

Addizione

=1+1

=A1+B1

=SOMMA(A1:A10)+10

=SOMMA(A1:A10)+B1

-

Sottrazione

=1-1

=A1-B1

=SOMMA(A1:A10)-10

=SOMMA(A1:A10)-B1

*

Moltiplicazione

=1*1

=A1*B1

=SOMMA(A1:A10)*10

=SOMMA(A1:A10)*B1

=PRODOTTO(1;1) - funzione PRODOTTO

/

Divisione

=1/1

=A1/B1

=SOMMA(A1:A10)/10

=SOMMA(A1:A10)/B1

=QUOZIENTE(1;1) - funzione QUOZIENTE

^

Elevamento a potenza

=1^1

=A1^B1

=SOMMA(A1:A10)^10

=SOMMA(A1:A10)^B1

=POTENZA(1;1) - funzione POTENZA

Per altre informazioni, vedere Usare Excel come calcolatrice.

Altri esempi

  1. Supponiamo di voler applicare uno sconto in percentuale a un intervallo di celle sommate.

    Uso di operatori con SOMMA.  La formula nella cella B16 è =SOMMA(A2:A14)*-25%.  La formula sarebbe costruita correttamente se il valore -25% fosse un riferimento di cella, come =SOMMA(A2:A14)*E2
    • =SOMMA(A2:A14)*-25%

    Restituisce il 25% dell'intervallo sommato, ma codifica il valore 25% nella formula, rendendolo quindi difficile da trovare in seguito se dovesse essere necessario cambiarlo. È invece consigliabile inserire il valore 25% in una cella e fare riferimento a tale cella, che è ben distinguibile e può essere facilmente modificata, come in questa formula:

    • =SOMMA(A2:A14)*E2

    Per dividere invece di moltiplicare, basta sostituire l'operatore "*" con "/": =SOMMA(A2:A14)/E2

  2. Aggiunta o sottrazione da una funzione SOMMA

    i. È possibile eseguire facilmente operazioni di somma o sottrazione usando + o - in questo modo:

    • =SOMMA(A1:A10)+E2

    • =SOMMA(A1:A10)-E2

Questa sezione illustra alcune procedure consigliate per l'uso della funzione SOMMA. Molte possono essere applicate anche ad altre funzioni.

Metodo =1+2 o =A+B. È possibile immettere =1+2+3 o =A1+B1+C2 e ottenere risultati del tutto corretti, tuttavia questi metodi sono soggetti a errori per diversi motivi:

  1. Errori di digitazione. Supponiamo di dover immettere diversi valori di questo tipo:

    • =14598,93+65437,90+78496,23

    E quindi di dover verificare che le immissioni siano corrette. È molto più semplice inserire questi valori in singole celle e usare una formula SOMMA. Inoltre, quando sono all'interno di celle questi valori possono essere formattati, rendendoli più facilmente leggibili rispetto a una formula.

    Usare la funzione SOMMA invece di codificare i valori nelle formule.  La formula nella cella D5 è =SOMMA(D2:D4)
  2. Errori #VALORE! generati quando si fa riferimento a testo invece che a numeri

    Se si usa una formula di questo tipo:

    • =A1+B1+C1 o =A1+A2+A3

    Esempio di costruzione non corretta della formula.  La formula nella cella D2 è =A2+B2+C2

    Se le celle a cui si fa riferimento contengono valori non numerici (testo), la formula restituirà un errore #VALORE!. SOMMA ignora invece i valori di testo e restituisce la somma dei soli valori numerici.

    Costruzione corretta della formula.  Invece di =A2+B2+C2, la formula della cella D2 è =SOMMA(A2:C2)
  3. Errore #RIF! generato quando si eliminano righe o colonne

    Errore #RIF! causato dall'eliminazione di una colonna.  La formula è cambiata in =A2+#REF!+B2

    Se si elimina una riga o una colonna, la formula non viene aggiornata per escludere la riga o colonna eliminata e restituisce quindi un errore #RIF!, mentre una funzione SOMMA viene aggiornata automaticamente.

    La funzione SOMMA viene regolata automaticamente in base alle righe e colonne inserite o eliminate
  4. Le formule non aggiornano i riferimenti quando si inseriscono righe o colonne

    Le formule =A+B+C non vengono aggiornate se si aggiungono righe

    Se si inserisce una riga o una colonna, la formula non viene aggiornata per includere la riga o colonna aggiunta, mentre una funzione SOMMA viene aggiornata automaticamente (purché si rimanga all'interno dell'intervallo a cui viene fatto riferimento nella formula). Questo è particolarmente importante quando ci si aspetta che la formula venga aggiornata ma ciò non accade, producendo risultati incompleti che potrebbero non essere identificati.

    L'esempio ritrae una formula SOMMA che si espande automaticamente da =SOMMA(A2:C2) a =SOMMA(A2:D2) dopo l'inserimento di una colonna
  5. SOMMA con singoli riferimenti di cella o intervalli

    L'uso di una formula di questo tipo:

    • =SOMMA(A1;A2;A3;B1;B2;B3)

    È ugualmente soggetta a errori quando si inseriscono o eliminano righe all'interno dell'intervallo a cui si fa riferimento, per gli stessi motivi. È decisamente meglio usare singoli intervalli, come:

    • =SOMMA(A1:A3;B1:B3)

    Che vengono aggiornati quando si aggiungono e eliminano righe.

  1. È possibile usare la funzione SOMMA con altre funzioni. Ecco un esempio che crea un calcolo di media mensile:

    Uso di SOMMA con altre funzioni.  La formula nella cella M2 è =SOMMA(A2:L2)/CONTA.VALORI(A2:L2).  Nota: le colonne Maggio-Novembre sono nascoste per maggiore chiarezza.
    • =SOMMA(A2:L2)/CONTA.VALORI(A2:L2)

  2. Questa formula divide la somma di A2:L2 per il numero di celle non vuote in A2:L2 (le celle da Maggio a Dicembre sono vuote).

  1. A volte può essere necessario sommare una determinata cella in più fogli di lavoro. Si potrebbe fare clic su ogni foglio e sulla cella desiderata e quindi usare "+" per sommare i valori delle celle, ma si tratta di un'operazione noiosa e soggetta a errori.

    • =Foglio1!A1+Foglio2!A1+Foglio3!A1

    È possibile ottenere lo stesso risultato in modo molto più semplice, con una funzione SOMMA 3D o tridimensionale:

    SOMMA 3D - La formula nella cella D2 è =SOMMA(Foglio1:Foglio3!A2)
    • =SOMMA(Foglio1:Foglio3!A1)

    Che somma la cella A1 in tutti i fogli da Foglio1 a Foglio3.

    Questa funzione è particolarmente utile ad esempio quando si ha un foglio per ogni mese (Gennaio-Dicembre) e si vuole ottenerne il totale in un foglio di riepilogo.

    SOMMA 3D tra fogli denominati.  La formula in D2 è =SOMMA(Gennaio:Dicembre!A2)
    • =SOMMA(Gennaio:Dicembre!A2)

    Questa funzione somma la cella A2 di ogni foglio da Gennaio a Dicembre.

    Note : se i nomi dei fogli di lavoro contengono spazi, ad esempio "Vendite gennaio", occorre usare un apostrofo per fare riferimento ai nomi dei fogli in una formula. Si noti l'apostrofo PRIMA del nome del primo foglio di lavoro e DOPO il nome dell'ultimo.

    • =SOMMA('Vendite gennaio:Vendite dicembre'!A2)

    Il metodo 3D funziona anche con altre funzioni, come MEDIA, MIN, MAX e altre:

    • =MEDIA(Foglio1:Foglio3!A1)

    • =MIN(Foglio1:Foglio3!A1)

    • =MAX(Foglio1:Foglio3!A1)

Problema

Descrizione dell'errore

La funzione SOMMA visualizza ##### invece del risultato.

Controllare la larghezza delle colonne. ##### indica in genere che la colonna è troppo stretta per visualizzare il risultato della formula.

La funzione SOMMA visualizza la formula come testo invece del risultato.

Verificare che la cella non sia formattata come testo. Selezionare la cella o l'intervallo in questione e premere CTRL+1 per visualizzare la finestra di dialogo Formato celle, quindi fare clic sulla scheda Numero e selezionare il formato desiderato. Se la cella era formattata come testo e non cambia dopo l'impostazione di un altro formato, potrebbe essere necessario premere F2 > INVIO per forzare la modifica del formato.

La funzione SOMMA non viene aggiornata.

Verificare che Opzioni di calcolo sia impostato su Automatico. Nella scheda Formule passare a Opzioni di calcolo. È anche possibile premere F9 per forzare il calcolo del foglio di lavoro.

Verificare che Opzioni di calcolo sia impostato su Automatico.  Nella scheda Formule passare a Opzioni di calcolo.

Alcuni valori non vengono sommati.

È possibile sommare solo i valori numerici nel riferimento o nell'intervallo della funzione. Le celle vuote, i valori logici come VERO o i valori di testo vengono ignorati.

Al posto del risultato previsto viene visualizzato l'errore #NOME?.

Questo errore indica in genere che la formula non è stata digitata correttamente, ad esempio =soma(A1:A10) invece di =SOMMA(A1:A10).

La funzione SOMMA visualizza un numero intero, ma dovrebbe visualizzare anche i decimali

Controllare la formattazione delle celle per assicurarsi di visualizzare i decimali. Selezionare la cella o l'intervallo in questione e premere CTRL+1 per visualizzare la finestra di dialogo Formato celle, quindi fare clic sulla scheda Numero e selezionare il formato desiderato, indicando il numero di posizioni decimali da visualizzare.

  1. Come si sommano/sottraggono/moltiplicano/dividono numeri? Vedere questa serie di video in Eseguire semplici operazioni matematiche in Excel o Usare Excel come calcolatrice.

  2. Cosa occorre fare per visualizzare più/meno posizioni decimali? È possibile cambiare il formato numerico. Selezionare la cella o l'intervallo in questione e premere CTRL+1 per visualizzare la finestra di dialogo Formato celle, quindi fare clic sulla scheda Numero e selezionare il formato desiderato, indicando il numero di posizioni decimali da visualizzare.

  3. Come si sommano o sottraggono le ore? È possibile sommare e sottrarre valori di ora in diversi modi. Ad esempio, per ottenere la differenza tra 8:00 AM - 12:00 PM per il pagamento delle retribuzioni, usare: =("12:00 PM"-"8:00 AM")*24, ossia l'ora di fine meno l'ora di inizio. Tenere presente che Excel calcola le ore come frazione di un giorno, quindi è necessario moltiplicare per 24 per ottenere le ore totali. Il primo esempio usa =((B2-A2)+(D2-C2))*24 per ottenere la somma delle ore dall'inizio alla fine, meno la pausa pranzo (8,50 ore totali).

    Se si vogliono semplicemente sommare ore e minuti, non è necessario moltiplicare per 24. Il secondo esempio quindi usa =SOMMA(A6:C6) poiché occorre calcolare solo il numero totale di ore e minuti per le attività assegnate (5:36 o 5 ore e 36 minuti).

    Calcolo delle ore

    Per altre informazioni, vedere: Sommare o sottrarre tempo.

  4. Come si calcola la differenza tra date? È possibile sommare e sottrarre date allo stesso modo delle ore. Ecco un esempio molto comune di conteggio del numero di giorni tra due date. È una semplice formula di tipo =B2-A2. Il metodo chiave da usare con le date e ore è partire dalla data/ora di fine e sottrarre la data/ora di inizio.

    Calcolo delle differenze tra date

    Per altri esempi di utilizzo delle date, vedere: Calcolare il numero di giorni tra due date.

  5. Come si sommano solo le celle visibili? Se, dopo aver nascosto manualmente alcune righe o aver usato il filtro automatico per visualizzare solo determinati dati, si vogliono sommare solo le celle visibili, è possibile usare la funzione SUBTOTALE. Se si usa una riga Totale in una tabella di Excel, qualsiasi funzione selezionata nell'elenco a discesa Totale viene immessa automaticamente come subtotale. Per altre informazioni, vedere Calcolare i totali in una tabella di Excel.

Servono altre informazioni?

È sempre possibile rivolgersi a un esperto nella Tech Community di Excel, ottenere supporto nella community Microsoft o suggerire una nuova caratteristica o un miglioramento in Excel UserVoice.

Vedere anche

Guardare un video che illustra come usare la funzione SOMMA

La funzione SOMMA.SE somma solo i valori che soddisfano un singolo criterio

La funzione SOMMA.PIÙ.SE somma solo i valori che soddisfano più criteri

La funzione CONTA.SE conta solo i valori che soddisfano un singolo criterio

La funzione CONTA.PIÙ.SE conta solo i valori che soddisfano più criteri

Panoramica delle formule in Excel

Come evitare errori nelle formule

Trovare e correggere errori nelle formule

Scelte rapide da tastiera di Excel per Windows

Scelte rapide da tastiera di Excel per Mac

Funzioni matematiche e trigonometriche

Funzioni di Excel (in ordine alfabetico)

Funzioni di Excel (in base alla categoria)

Aggiungere formule e funzioni (anteprima gratuita)

Amplia le tue competenze
Esplora i corsi di formazione
Ottieni in anticipo le nuove caratteristiche
Partecipa al programma Office Insider

Queste informazioni sono risultate utili?

Grazie per i tuoi commenti e suggerimenti

Grazie per il tuo feedback! Potrebbe essere utile metterti in contatto con uno dei nostri operatori del supporto di Office.

×