Menggunakan fitur lain untuk mengidentifikasi tipe data yang ditautkan

Rumus

Anda selalu bisa menulis rumus yang mereferensikan tipe data. Namun, jika ingin mengekstrak teks sel dengan tipe data yang ditautkan menggunakan fungsi TEXT, Anda akan mendapatkan #VALUE! .

Solusinya adalah dengan menggunakan fungsi FIELDVALUE dan menentukan bidang Name untuk field_name argumen. Dalam contoh berikut, jika sel A1 berisi tipe data saham, rumus akan mengembalikan nama saham.

=FIELDVALUE(A1,"Nama")

Namun, jika sel A1 tidak berisi tipe data yang ditautkan, fungsi FIELDVALUE akan mengembalikan #FIELD!. Jika Anda ingin mengevaluasi apakah sel berisi tipe data yang ditautkan atau tidak, Anda dapat menggunakan rumus berikut, yang menggunakan fungsi ISERROR untuk menguji apakah fungsi FIELDVALUE akan mengembalikan kesalahan.

=IF(ISERROR(FIELDVALUE(A2,"Nama")),"Sel ini tidak memiliki tipe data yang ditautkan","Sel ini memiliki tipe data yang ditautkan")

Jika rumus mengevaluasi kesalahan, rumus akan mengembalikan teks "Sel ini tidak memiliki tipe data yang ditautkan", jika tidak, rumus akan mengembalikan "Sel ini memiliki tipe data yang ditautkan".

Jika Anda hanya ingin menyembunyikan #FIELD! , Anda dapat menggunakan:

=IFERROR(FIELDVALUE(A1,"Name"),"")

Yang akan mengembalikan sel kosong jika ada kesalahan.

Pemformatan bersyarat

Anda dapat memformat sel bersyarat berdasarkan tipe data yang ditautkan atau tidak. Anda terlebih dahulu memilih sel yang memerlukan pemformatan bersyarat, lalu masuk ke Beranda >Pemformatan Bersyarat > Aturan >Menggunakan rumus... Untuk rumus, Anda harus menggunakan hal berikut:

=NOT(ISERROR(FIELDVALUE(A1,"Name")))

Ketika sel A1 adalah sel teratas dalam rentang yang ingin dievaluasi. Lalu terapkan format yang Anda inginkan.

Dalam contoh ini, jika sel A1 berisi nama bidang yang valid untuk "Nama", rumus mengembalikan TRUE dan pemformatan akan diterapkan. Jika sel A1 tidak berisi tipe data yang ditautkan, rumus mengembalikan FALSE, dan tidak ada pemformatan yang akan diterapkan. Anda bisa menghapus NOT jika Anda ingin menyoroti sel mana pun yang tidak berisi tipe data tertaut yang valid sebagai gantinya.

VBA

Ada beberapa metode VBA (Visual Basic untuk Aplikasi) yang dapat digunakan untuk mengidentifikasi jika sel atau rentang berisi tipe data yang ditautkan. Prosedur pertama ini menggunakan properti HasRichDataType. 

Kedua prosedur ini akan meminta Anda memilih rentang sel untuk dievaluasi, lalu mengembalikan kotak pesan dengan hasilnya.

Sub IsLinkedDataType()
    Dim c As Range
    Dim rng As Range
    Dim strResults As String
    
    Set rng = Application.InputBox("Select a range to check for linked data types", Type:=8)
    
    For Each c In rng
      '    Check if the HasRichDataType is TRUE or FALSE
        If c.HasRichDataType = True Then
        '   The cell holds a linked data type
            strResults = strResults & c.Text & " - Linked data type" & vbCrLf
        Else
            strResults = strResults & c.Text & " - Not a linked data type" & vbCrLf
        End If
    Next c

    MsgBox "Your range contains the following details" & vbCrLf & vbCrLf & strResults, vbInformation + vbOKOnly, "Results"
    
End Sub

Prosedur berikutnya ini menggunakan properti LinkedDataTypeState.

Sub IsLinkedDataTypeState()
    Dim c As Range
    Dim rng As Range
    Dim strResults As String
    
    Set rng = Application.InputBox("Select a range to check for linked data types", Type:=8)
    
    For Each c In rng
   '    Check if the LinkedDataTypeState is 1 (TRUE) or 0 (FALSE)
        If c.LinkedDataTypeState = 1 Then
        '   The cell holds a linked data type
            strResults = strResults & c.Text & " - Linked data type" & vbCrLf
        Else
            strResults = strResults & c.Text & " - Not a linked data type" & vbCrLf
        End If
    Next c
    
   MsgBox "Your range contains the following details" & vbCrLf & vbCrLf & strResults, vbInformation + vbOKOnly, "Results"

End Sub

Snippet kode akhir ini adalah fungsi yang ditentukan pengguna (UDF), dan Anda mereferensikannya sama seperti fungsi Excel rumus. Cukup masukkan =fn_IsLinkedDataType(A1),di mana A1 adalah sel yang ingin Anda evaluasi.

Public Function fn_IsLinkedDataType(c As Range)
'   Function will return TRUE if a referenced cell contains a linked data type
    If c.HasRichDataType = True Then
      fn_IsLinkedDataType = "Linked data type"
    Else
        fn_IsLinkedDataType = "Not a linked data type"
    End If
End Function

Untuk menggunakan salah satu contoh ini, tekan Alt+F11 untuk membuka Editor Visual Basic (VBE), lalu masuk ke Sisipkan Modul> ,dan tempelkan kode di jendela baru yang terbuka di sebelah kanan. Anda dapat menggunakan Alt+Q untuk keluar Excel kembali jika sudah selesai. Untuk menjalankan salah satu dari dua contoh pertama, masuk ke tab Pengembang > Kode > makro> pilih makro yang ingin Anda jalankan dari daftar, lalu pilih Jalankan.

Perlu bantuan lainnya?

Anda selalu dapat bertanya kepada ahli di Komunitas Teknologi Excel atau mendapatkan dukungan di Komunitas.