Mengatur label data kustom dalam bagan

Prosedur VBA (Visual Basic for Applications) berikut ini akan memungkinkan Anda menggunakan nilai sel sebagai label data dalam bagan di Excel untuk Mac. Untuk menggunakan prosedur, lakukan hal berikut:

1. Di Excel, klik Alat > Makro > Rekam Makro Baru.

2. Dalam kotak turun bawah Simpan Makro di: , pilih Buku Kerja Makro Pribadi.

   Catatan: Dengan menyimpan prosedur VBA di Buku Kerja Makro Pribadi, Anda kemudian bisa menggunakannya dalam contoh Excel apa pun. Ini berarti tidak hanya sebatas penggunaan dalam satu buku kerja.

3. Tekan OK.

4. Masuk ke Alat > Makro > Hentikan Perekaman.

5. Masuk ke Alat > Makro > Visual Basic Editor.

6. Visual Basic Editor (VBE) akan terbuka di atas Excel. Di panel navigasi di sebelah kiri, perluas VBAProject (PERSONAL. XLSB) folder untuk memperlihatkan Module1.

7. Klik dua kali modul1 untuk menampilkan panel Kode, yang akan terbuka di sisi kanan jendela VBE.

8. Kode VBA yang dibuat saat Anda merekam makro baru tidak diperlukan, jadi pilih semuanya, lalu tekan Delete. 

9. Berikutnya, pilih kode VBA dalam kotak teks di bawah ini, tekan CMD+C untuk menyalinnya, lalu tempelkan kembali di panel Kode dengan CMD+V. Sekarang Anda bisa keluar dari Visual Basic Editor dan kembali ke Excel.

10. Uji makro dengan membuat bagan dengan label data. Berikutnya, pilih label data apa pun di bagan, dan jalankan makro dengan mengklik Alat > Makro > Makro. Pilih SetCustomDataLabels, lalu tekan Jalankan. Anda akan secara otomatis diminta untuk memilih rentang label data Anda, jadi lakukanlah, lalu tekan OK.  

    Catatan: Prosedur VBA tidak bisa dibatalkan, jadi pastikan untuk mencoba ini pada salinan buku kerja. Jika Anda menjalankan kode dan tidak ingin menyimpan hasilnya, Anda harus menutup buku kerja tanpa menyimpannya.

11. Saat Anda keluar dari Excel, pastikan Anda memilih untuk menyimpan perubahan di PERSONAL. XLSB sehingga makro akan tersedia di masa mendatang.

12. Kapan saja Anda ingin menambahkan atau menghapus label data dari bagan, pilih label data dan jalankan makro.

13. Anda bisa menggunakan Preferensi > Excel> Pita & Toolbar untuk menambahkan tombol untuk menjalankan makro dari pita atau toolbar.

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub