HYPERLINK (Fungsi HYPERLINK)

Artikel ini menguraikan sintaks rumus dan penggunaan fungsi HYPERLINK di Microsoft Excel.

Deskripsi

Fungsi HYPERLINK akan membuat pintasan yang menuju ke lokasi lain dalam buku kerja saat ini, atau membuka dokumen yang disimpan di server jaringan, intranet, atau Internet. Saat mengklik sel yang berisi fungsi HYPERLINK, Excel akan berpindah ke lokasi yang tercantum, atau membuka dokumen yang ditentukan.

Sintaks

HYPERLINK(lokasi_tautan, [nama_familier])

Sintaks fungsi HYPERLINK memiliki argumen berikut:

  • Link_location    Jalur dan nama file ke dokumen untuk dibuka. Link_location bisa mengacu pada tempat dalam dokumen— seperti sel spesifik atau rentang nama dalam lembar kerja atau buku kerja Excel, atau ke bookmark dalam dokumen Microsoft Word. Jalur bisa ke file yang disimpan pada drive hard disk. Jalur bisa berupa jalur konvensi penamaan universal (UNC) pada server (dalam Excel atau Uniform Resource Locator (URL) pada internet atau intranet.

    Ingat   Excel Online fungsi HYPERLINK valid untuk alamat web (URL) saja. Link_location bisa berupa string teks yang diapit tanda kutip untuk rujukan ke sel yang berisi link sebagai string teks.

    Jika pintasan yang ditentukan di link_location tidak ada atau tidak bisa dinavigasi, kesalahan muncul saat Anda mengklik sel tersebut.

  • Friendly_name    Opsional. Teks pintasan atau nilai numerik yang ditampilkan di sel. Friendly_name ditampilkan dengan warna biru dan digarisbawahi. Jika friendly_name diabaikan, sel menampilkan link_location sebagai teks pintasan.

    Friendly_name bisa berupa nilai, string teks, nama, atau sel yang berisi teks pintasan atau nilai.

    Jika friendly_name mengembalikan nilai kesalahan (misalnya, #VALUE!), sel tersebut menampilkan kesalahan, bukannya teks pintasan.

Keterangan

Dalam aplikasi desktop Excel, untuk memilih sel yang berisi hyperlink tanpa harus menuju ke tujuan hyperlink, klik sel dan tahan tombol mouse hingga bentuk penunjuk menjadi tanda silang Kursor pilihan Excel , lalu lepaskan tombol mouse. Di Excel Online, pilih sel dengan mengkliknya saat penunjuk berbentuk panah; lalu masuk ke tujuan hyperlink dengan mengklik sel saat penunjuk berbentuk tangan yang menunjuk.

Contoh

Contoh

Hasil

=HYPERLINK("http://example.microsoft.com/report/budget report.xlsx", "Klik untuk mendapatkan laporan")

Membuka buku kerja yang disimpan di http://example.microsoft.com/report. Sel menampilkan "Klik untuk mendapatkan laporan" sebagai teks pintasannya.

=HYPERLINK("[http://example.microsoft.com/report/budget report.xlsx]Annual!F10", D1)

Membuat hyperlink ke sel F10 di lembar kerja Tahunan di buku kerja yang disimpan di http://example.microsoft.com/report. Sel di lembar kerja yang berisi hyperlink menampilkan konten sel D1 sebagai teks pintasannya.

=HYPERLINK("[http://example.microsoft.com/report/budget report.xlsx]'First Quarter'!DeptTotal", "Klik untuk melihat Total Departemen Kuartal Pertama")

Membuat hyperlink ke rentang bernama DeptTotal di lembar kerja Kuartal Pertama di buku kerja yang disimpan di http://example.microsoft.com/report. Sel di lembar kerja yang berisi hyperlink menampilkan "Klik untuk melihat Total Departemen Kuartal Pertama" sebagai teks pintasannya.

=HYPERLINK("http://example.microsoft.com/Annual Report.docx]QrtlyProfits", "Laporan Laba Per Kuartal")

Untuk membuat hyperlink ke lokasi tertentu di file Word, Anda menggunakan bookmark untuk menetapkan lokasi yang ingin Anda pintasi di file tersebut. Contoh ini membuat hyperlink ke bookmark QrtlyProfits di file Annual Report.doc yang disimpan di http://example.microsoft.com.

=HYPERLINK("\\FINANCE\Statements\1stqtr.xlsx", D5)

Menampilkan konten sel D5 sebagai teks pintasan di sel dan membuka buku kerja yang disimpan di server FINANCE di berbagi Laporan. Contoh ini menggunakan jalur UNC.

=HYPERLINK("D:\FINANCE\1stqtr.xlsx", H10)

Membuka buku kerja 1stqtr.xlsx yang disimpan di direktori Finance di drive D, dan menampilkan nilai numerik yang disimpan di sel H10.

=HYPERLINK("[C:\My Documents\Mybook.xlsx]Totals")

Membuat hyperlink ke area Total di buku kerja (eksternal) lainnya, Mybook.xlsx.

=HYPERLINK("[Book1.xlsx]Sheet1!A10","Go to Sheet1 > A10")

Untuk berpindah ke lokasi lain dalam lembar kerja saat ini, sertakan nama buku kerja, dan nama lembar kerja seperti ini, dengan Sheet1 adalah lembar kerja saat ini.

=HYPERLINK("[Book1.xlsx]January!A10","Go to January > A10")

Untuk berpindah ke lokasi lain dalam lembar kerja saat ini, sertakan nama buku kerja, dan nama lembar kerja seperti ini, dengan January adalah lembar kerja lain dalam buku kerja.

=HYPERLINK(CELL("alamat",January!A1),"Go to January > A1")

Untuk berpindah ke lokasi lain dalam lembar kerja saat ini tanpa menggunakan referensi lembar kerja yang sepenuhnya memenuhi syarat ([Book1.xlsx]), Anda dapat menggunakan rumus ini, dengan CELL("alamat") yang akan mengembalikan nama buku kerja saat ini.

=HYPERLINK($Z$1)

Untuk memperbarui dengan cepat semua rumus di lembar kerja yang menggunakan fungsi HYPERLINK dengan argumen yang sama, Anda bisa meletakkan target link di sel lain di lembar kerja yang sama atau berbeda, lalu gunakan referensi mutlak ke sel itu sebagai link_location dalam rumus HYPERLINK. Perubahan yang Anda lakukan ke target link segera ditampilkan di rumus HYPERLINK.

Kembangkan keterampilan Office Anda
Jelajahi pelatihan
Dapatkan fitur baru terlebih dahulu
Gabung ke Office Insiders

Apakah informasi ini bermanfaat?

Terima kasih atas umpan balik Anda!

Terima kasih atas umpan balik Anda! Sepertinya menghubungkan Anda ke salah satu agen dukungan Office kami akan sangat membantu.

×