Fungsi IF – rumus bertumpuk dan menghindari kesalahan

Fungsi IF – rumus bertumpuk dan menghindari kesalahan

Fungsi IF memungkinkan Anda untuk membuat perbandingan logis antara nilai dan apa yang diharapkan dengan menguji kondisi dan mengembalikan hasil jika True atau False.

  • =IF(Sesuatu adalah Benar, lakukanlah sesuatu, jika tidak lakukanlah hal lain)

Oleh karena itu, pernyataan IF dapat memiliki dua hasil. Hasil pertama jika perbandingan Anda Benar dan hasil kedua jika perbandingan Salah.

Pernyataan IF sangat kuat, dan membentuk dasar dari banyak model lembar bentang, namun pernyataan ini juga merupakan penyebab utama dari banyak masalah lembar bentang. Secara ideal, pernyataan IF harus berlaku terhadap kondisi minimal, seperti Pria/Wanita, Ya/Tidak/Mungkin, misalnya, namun terkadang Anda mungkin perlu mengevaluasi skenario lebih kompleks yang membutuhkan penumpukan* lebih dari 3 fungsi IF secara bersamaan.

* “Penumpukan” mengacu kepada praktik penggabungan beberapa fungsi secara bersamaan dalam satu rumus.

Gunakan fungsi IF, salah satu dari fungsi logika, untuk mengembalikan satu nilai jika kondisi benar dan nilai lain jika kondisi salah.

Sintaks

IF(logical_test, value_if_true, [value_if_false])

Misalnya:

  • =IF(A2>B2,"Melebihi Budget","OK")

  • =IF(A2=B2,B4-A4,"")

Nama argumen

Deskripsi

logical_test   

(diperlukan)

Kondisi yang ingin Anda uji.

value_if_true   

(diperlukan)

Nilai yang ingin Anda kembalikan jika hasil logical_test adalah TRUE.

value_if_false   

(opsional)

Nilai yang ingin Anda kembalikan jika hasil logical_test adalah False.

Keterangan

Meskipun Excel memperbolehkan Anda untuk menumpuk hingga 64 fungsi IF yang berbeda, Anda sangat tidak disarankan untuk melakukannya. Mengapa?

  • Beberapa pernyataan IF memerlukan pemikiran mendalam agar tersusun dengan benar dan memastikan bahwa logika tersebut dapat menghitung setiap kondisi dengan benar hingga selesai. Jika Anda tidak menumpuk rumus dengan benar 100%, rumus mungkin akan berfungsi 75%, namun akan mengembalikan hasil yang tidak diharapkan 25%. Sayangnya, kemungkinan Anda mendapatkan 25% sangat kecil.

  • Beberapa pernyataan IF dapat menjadi sangat sulit untuk dipertahankan, terutama ketika kembali beberapa waktu kemudian lalu mencoba mencari tahu apa yang pernah Anda, atau lebih buruk lagi, orang lain, coba lakukan.

Jika Anda menemukan pernyataan IF yang tampaknya hanya terus berkembang tanpa terlihat bagian akhirnya, waktunya untuk meletakkan mouse dan memikirkan strategi kembali.

Mari kita lihat cara membuat pernyataan IF bertumpuk yang kompleks dengan benar, menggunakan beberapa IF, dan kapan mengenali waktu untuk menggunakan alat lain dalam gudang Excel Anda.

Contoh

Berikut adalah contoh pernyataan IF bertumpuk yang relatif standar untuk mengonversi nilai ujian siswa menjadi peringkat huruf yang setara.

Pernyataan IF bertumpuk yang kompleks - Rumus dalam E2 adalah =IF(B2>97,"A+",IF(B2>93,"A",IF(B2>89,"A-",IF(B2>87,"B+",IF(B2>83,"B",IF(B2>79,"B-",IF(B2>77,"C+",IF(B2>73,"C",IF(B2>69,"C-",IF(B2>57,"D+",IF(B2>53,"D",IF(B2>49,"D-","F"))))))))))))
  • =IF(D2>89,"A",IF(D2>79,"B",IF(D2>69,"C",IF(D2>59,"D","F"))))

    Pernyataan IF bertumpuk yang kompleks ini mengikuti logika sederhana:

  1. Jika Skor Ujian (di sel D2) lebih besar dari 89, siswa akan mendapatkan A

  2. Jika Skor Ujian lebih besar dari 79, siswa akan mendapatkan B

  3. Jika Skor Ujian lebih besar dari 69, siswa akan mendapatkan C

  4. Jika Skor Ujian lebih besar dari 59, siswa akan mendapatkan D

  5. Jika tidak siswa akan mendapatkan F

Contoh khusus ini relatif aman karena tidak mungkin korelasi antara skor ujian dan nilai huruf akan berubah, sehingga tidak memerlukan banyak perbaikan. Namun perhatikan hal berikut: bagaimana jika Anda perlu mengelompokkan nilai A+, A, dan A- (dan seterusnya)? Sekarang pernyataan IF empat kondisi Anda perlu ditulis ulang agar memiliki 12 kondisi! Berikut tampilan rumus sekarang:

  • =IF(B2>97,"A+",IF(B2>93,"A",IF(B2>89,"A-",IF(B2>87,"B+",IF(B2>83,"B",IF(B2>79,"B-", IF(B2>77,"C+",IF(B2>73,"C",IF(B2>69,"C-",IF(B2>57,"D+",IF(B2>53,"D",IF(B2>49,"D-","F"))))))))))))

Rumus ini masih berfungsi dengan benar dan akan berfungsi seperti yang diharapkan, namun akan memakan waktu lama untuk menulis dan lebih lama lagi untuk menguji guna memastikan rumus tersebut berfungsi seperti yang Anda inginkan. Masalah penting lainnya adalah Anda harus memasukkan skor dan nilai huruf yang setara secara manual. Kesalahan pengetikan secara tidak sengaja sangat mungkin terjadi. Bayangkan, Anda harus mencoba melakukan hal ini 64 kali dengan kondisi yang lebih kompleks! Tentu, hal tersebut mungkin dilakukan, tetapi apakah Anda benar-benar ingin melakukan hal tersebut, dengan kemungkinan kesalahan yang sulit ditemukan?

Tips: Setiap fungsi dalam Excel memerlukan kurung buka dan tutup (). Excel akan mencoba membantu Anda mencari tahu suatu rumus termasuk pada kurung yang mana dengan mewarnai berbagai bagian rumus saat Anda mengeditnya. Sebagai contoh, jika Anda ingin mengedit rumus di atas, saat memindahkan kursor melewati setiap tanda kurung tutup “)”, warna tanda kurung buka yang terkait dengannya akan berubah menjadi warna yang sama. Hal ini akan sangat membantu dalam rumus bertumpuk yang kompleks ketika Anda mencoba mencari tahu apakah terdapat cukup tanda kurung yang cocok atau tidak.

Contoh tambahan

Berikut adalah contoh sangat umum dari menghitung Komisi Penjualan berdasarkan tingkat pencapaian Pendapatan.

Rumus di sel D9 adalah IF(C9>15000,20%,IF(C9>12500,17.5%,IF(C9>10000,15%,IF(C9>7500,12.5%,IF(C9>5000,10%,0)))))
  • =IF(C9>15000,20%,IF(C9>12500,17.5%,IF(C9>10000,15%,IF(C9>7500,12.5%,IF(C9>5000,10%,0)))))

Rumus ini mengatakan IF (C9 Lebih Besar daripada 15.000 lalu kembalikan 20%, IF (C9 Lebih Besar daripada 12.500 lalu kembalikan 17,5%, dan seterusnya...

Walaupun sangat mirip dengan contoh Nilai sebelumnya, rumus ini merupakan contoh tepat yang menggambarkan sulitnya mempertahankan pernyataan IF besar. Apa yang akan Anda lakukan jika organisasi memutuskan untuk menambahkan tingkat kompensasi baru dan bahkan mungkin mengubah nilai persentase atau dolar yang sudah ada? Akan ada banyak sekali pekerjaan yang harus dilakukan!

Tips: Anda dapat menyisipkan hentian baris dalam bilah rumus agar rumus yang panjang lebih mudah dibaca. Cukup tekan ALT+ENTER di depan teks yang ingin Anda bungkus ke baris baru.

Berikut adalah contoh skenario komisi dengan logika tidak beraturan:

Rumus di sel D9 adalah =IF(C9>5000,10%,IF(C9>7500,12.5%,IF(C9>10000,15%,IF(C9>12500,17.5%,IF(C9>15000,20%,0)))))

Dapatkah Anda melihat kesalahannya? Bandingkan urutan perbandingan Pendapatan dengan contoh sebelumnya. Ke mana rumus ini akan berpengaruh? Benar, rumus ini akan berpengaruh dari bawah ke atas ($5.000 ke $15.000), bukan sebaliknya. Namun, mengapa hal ini sangat penting? Hal ini penting karena rumus tidak dapat melewati evaluasi pertama untuk nilai yang lebih dari $5.000. Katakanlah Anda telah mendapatkan pendapatan $12.500, maka pernyataan IF akan mengembalikan 10% karena nilai lebih besar dari $5.000, dan akan berhenti di sana. Hal ini dapat menimbulkan permasalahan karena pada beberapa situasi jenis kesalahan ini dapat tidak diketahui hingga menimbulkan dampak negatif. Saat mengetahui bahwa terdapat beberapa kesalahan serius dengan pernyataan IF bertumpuk yang kompleks, apa yang dapat dilakukan? Pada umumnya, Anda dapat menggunakan fungsi VLOOKUP daripada menyusun rumus kompleks dengan fungsi IF. Dalam menggunakan VLOOKUP, Anda harus terlebih dahulu membuat tabel referensi:

Rumus di sel D2 adalah =VLOOKUP(C2,C5:D17,2,TRUE)
  • =VLOOKUP(C2,C5:D17,2,TRUE)

Rumus ini akan mencari nilai di C2 dalam rentang C5:C17. Jika nilai ditemukan, nilai yang sesuai akan dikembalikan dari baris yang sama di kolom D.

Rumus di sel C9 adalah =VLOOKUP(B9,B2:C6,2,TRUE)
  • =VLOOKUP(B9,B2:C6,2,TRUE)

Demikian pula, rumus ini akan mencari nilai di sel B9 dalam rentang B2:B22. Jika nilai ditemukan, nilai yang sesuai akan dikembalikan dari baris yang sama di kolom C.

Catatan: Kedua VLOOKUP ini menggunakan argumen TRUE di akhir rumus, yang berarti kita ingin agar rumus mencari kecocokan yang sesuai. Dengan kata lain, rumus akan mencocokkan dengan nilai yang tepat dalam tabel pencarian, serta nilai apa pun yang berada di antaranya. Dalam hal ini, tabel pencarian perlu diurutkan dalam urutan Naik, dari yang terkecil ke terbesar.

VLOOKUP dibahas dengan lebih mendetail di sini, namun rumus ini jauh lebih sederhana daripada pernyataan IF bertumpuk 12 tingkat yang kompleks! Terdapat manfaat lain yang tidak benar-benar terpampang:

  • Tabel referensi VLOOKUP mudah untuk diakses dan dilihat.

  • Nilai tabel dapat dengan mudah diperbarui dan Anda tidak harus menyentuh rumus jika kondisi berubah.

  • Jika tidak ingin orang-orang melihat atau mengganggu tabel referensi Anda, cukup letakkan di lembar kerja lain.

Tahukah Anda?

Kini terdapat fungsi IFS yang dapat menggantikan beberapa pernyataan IF bertumpuk dengan fungsi tunggal. Jadi, bukan seperti contoh nilai awal kami, yang memiliki 4 fungsi IF bertumpuk:

  • =IF(D2>89,"A",IF(D2>79,"B",IF(D2>69,"C",IF(D2>59,"D","F"))))

Langkah ini dapat dilakukan dengan lebih sederhana menggunakan fungsi IFS tunggal:

  • =IFS(D2>89,"A",D2>79,"B",D2>69,"C",D2>59,"D",TRUE,"F")

Fungsi IFS adalah fungsi yang hebat karena Anda tidak perlu khawatir tentang semua pernyataan IF tersebut dan tanda kurungnya.

Catatan: Fitur ini hanya tersedia jika memiliki langganan Office 365. Jika merupakan pelanggan Office 365, pastikan Anda sudah memiliki versi terbaru Office.

Coba Office 365 atau versi terbaru Excel

Perlu bantuan lainnya?

Anda selalu dapat bertanya kepada pakar di Komunitas Teknologi Excel, mendapatkan dukungan di Komunitas Jawaban, atau menyarankan fitur maupun fitur baru di Suara Pengguna Excel.

Topik terkait

Video: Fungsi IF tingkat lanjut
Fungsi IFS (Office 365, Excel 2016 dan yang lebih baru)
Fungsi COUNTIF akan menghitung nilai berdasarkan satu kriteria
Fungsi COUNTIFS akan menghitung nilai berdasarkan beberapa kriteria
Fungsi SUMIF akan menjumlahkan nilai berdasarkan satu kriteria
Fungsi SUMIFS akan menjumlahkan nilai berdasarkan beberapa kriteria
Fungsi AND
Fungsi OR
Fungsi VLOOKUP
Gambaran umum rumus di Excel
Cara menghindari kesalahan rumus
Menggunakan pemeriksaan kesalahan untuk mendeteksi kesalahan dalam rumus
Fungsi Logika
Fungsi Excel (sesuai alfabet)
Fungsi Excel (menurut kategori)

Kembangkan keterampilan Office Anda
Jelajahi pelatihan
Dapatkan fitur baru terlebih dahulu
Gabung ke Office Insiders

Apakah informasi ini bermanfaat?

Terima kasih atas umpan balik Anda!

Terima kasih atas umpan balik Anda! Sepertinya menghubungkan Anda ke salah satu agen dukungan Office kami akan sangat membantu.

×