SUMIFS (Fungsi SUMIFS)

Artikel ini menguraikan sintaks rumus dan penggunaan fungsiSUMIFS dalam Microsoft Excel.

Deskripsi

Menambahkan sel dalam rentang yang memenuhi beberapa kriteria. Misalnya, jika Anda ingin menambahkan angka dalam rentang A1:A20 hanya jika angka yang terkait dalam B1:B20 lebih besar dari nol (0) dan angka yang terkait dalam C1:C20 kurang dari 10, Anda bisa menggunakan rumus berikut:

=SUMIFS(A1:A20, B1:B20, ">0", C1:C20, "<10")

Penting   Susunan argumen berbeda antara fungsi SUMIFS dan SUMIF. Secara khusus, argumen sum_range adalah argumen pertama dalam SUMIFS, tapi merupakan argumen ketiga dalam SUMIF. Jika Anda menyalin dan mengedit fungsi serupa tersebut, pastikan Anda meletakkan argumen dalam urutan yang benar.

Sintaks

SUMIFS( sum_range , criteria_range1, criteria1, [criteria_range2, criteria2], ...)

Sintaks fungsi SUMIFS memiliki argumen berikut:

  • Sum_range    Diperlukan. Satu atau beberapa sel yang akan ditambahkan, termasuk angka atau nama, rentang, atau referensi sel yang berisi angka. Sel kosong atau nilai teks diabaikan.

  • Criteria_range1    Diperlukan. Rentang pertama untuk mengevaluasi kriteria yang terkait.

  • Criteria1    Diperlukan. Kriteria dalam bentuk angka, ekspresi, referensi sel, atau teks yang menentukan sel mana saja dalam argumen Criteria_range1 yang akan ditambahkan. Misalnya, kriteria dapat diekspresikan sebagai 32, ">32", B4, "apples", atau "32."

  • Criteria_range2, criteria2, …    Opsional. Rentang tambahan dan kriteria yang terkait. Hingga 127 pasangan rentang/kriteria yang diperbolehkan.

Keterangan

  • Tiap sel dalam argumen Sum_range dijumlahkan hanya jika semua kriteria yang terkait yang ditentukan benar untuk sel itu. Misalnya, anggaplah bahwa sebuah rumus berisi dua argumen Criteria_range. Jika sel pertama dari Criteria_range1 memenuhi Criteria1, dan sel pertama dari Criteria_range2 memenuhi Critera2, sel pertama dari Sum_range ditambahkan ke penjumlahan tersebut, dan seterusnya, untuk sel lainnya dalam rentang yang ditentukan.

  • Sel dalam argumen Sum_range yang berisi TRUE mengevaluasi ke 1; sel dalam Sum_range yang berisi FALSE mengevaluasi ke 0 (nol).

  • Tidak seperti argumen rentang dan kriteria dalam fungsi SUMIF, dalam fungsi SUMIFS, tiap argumen Criteria_range harus berisi jumlah baris dan kolom yang sama dengan argumen Sum_range.

  • Anda dapat menggunakan karakter wildcard — tanda tanya (?) dan tanda bintang (*) — dalam kriteria. Tanda tanya cocok dengan karakter tunggal apa pun; tanda bintang cocok dengan urutan karakter apa pun. Jika Anda ingin menemukan tanda tanya atau tanda bintang, ketikkan tilde (~) sebelum karakter.

Contoh

Buku kerja di bawah ini memperlihatkan contoh fungsi ini. Periksalah contohnya, ubah rumus yang ada, atau masukkan rumus Anda sendiri untuk mempelajari cara kerja fungsi ini.

Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan lebar kolom untuk melihat semua data.

Kuantitas Terjual

Produk

Penjual

5

Apel

1

4

Apel

2

15

Artichoke

1

3

Artichoke

2

22

Pisang

1

12

Pisang

2

10

Wortel

1

33

Wortel

2

Rumus

Deskripsi

Hasil

=SUMIFS(A2:A9, B2:B9, "=A*", C2:C9, 1)

Menambahkan total jumlah produk yang terjual yang dimulai dengan"A" dan yang dijual oleh Tenaga Penjual 1.

20

=SUMIFS(A2:A9, B2:B9, "<>Pisang", C2:C9, 1)

Menambahkan total jumlah produk (tidak termasuk Pisang) yang dijual oleh Tenaga penjual 1.

30

Untuk bekerja secara lebih mendalam dengan data contoh di Excel, unduh buku kerja yang disematkan ke komputer Anda, lalu buka di Excel.

Contoh 2

Total

Rekening 1

Rekening 2

Rekening 3

Rekening 4

Jumlah dalam dolar

$100,00

$390,00

$8.321,00

$500,00

Suku bunga (2000)

1%

0,5%

3%

4%

Suku bunga (2001)

1%

1,3%

2,1%

2%

Suku bunga (2002)

0,5%

3%

1%

4%

Rumus

Deskripsi

Hasil

=SUMIFS(B2:E2, B3:E3, ">3%", B4:E4, ">=2%")

Total jumlah dari setiap rekening bank yang bunganya lebih besar dari 3% untuk tahun 2000 dan lebih besar atau sama dengan 2% untuk tahun 2001. Hanya Rekening 4 yang memenuhi kedua kondisi.

$500,00

=SUMIFS(B2:E2, B5:E5, ">=1%", B5:E5, "<=3%", B4:E4, ">1%")

Total jumlah dari setiap rekening bank saat bunganya berada antara 1% dan 3% untuk tahun 2002 dan lebih besar dari 1% untuk tahun 2001. Rekening 2 dan Rekening 3 memenuhi kedua kondisi.

$8.711,00

Contoh 3

Pengukuran Harian

Hari 1

Hari 2

Hari 3

Hari 4

Hujan (total inci)

3,3

0,8

5,5

5,5

Suhu rata-rata (derajat)

55

39

39

58

Rata-rata kecepatan angin (mil per jam)

6,5

19,5

6

6,5

Rumus

Deskripsi

Hasil

=SUMIFS(B2:E2, B3:E3, ">=40", B4:E4, "<10")

Menambahkan total jumlah curah hujan untuk hari yang suhu rata-ratanya minimum 40 derajat Fahrenheit dan rata-rata kecepatan angin kurang dari 10 mil per jam.

8,8

Catatan

Hanya Sel B2 dan E2 yang dijumlahkan karena, untuk masing-masing kolom (B hingga E), nilai di kedua baris 3 dan 4 harus memenuhi criteria1 dan criteria2, secara berurutan. Sel B3 dan B4 memenuhi kedua kriteria, begitu juga E3 dan E4. Namun, tidak satu pun dari C3 atau C4 yang memenuhi kriteria. Terakhir, meskipun D4 memenuhi criteria2, D3 gagal memenuhi criteria1.

Contoh 4

Pengukuran Pagi dan Malam

Hari 1

Hari 2

Hari 3

Hari 4

Pagi: hujan (total inci)

1,3

0

1,5

3

Malam: hujan (total inci)

2

0,8

4

2,5

Pagi: suhu rata-rata (derajat)

56

44

40

38

Malam: suhu rata-rata (derajat)

54

34

38

77

Pagi: rata-rata kecepatan angin (mil per jam)

13

6

8

1

Malam: rata-rata kecepatan angin (mil per jam)

0

33

4

12

Rumus

Deskripsi

Hasil

=SUMIFS(B2:E3, B4:E5, ">=40", B6:E7, "<10")

Menambahkan total jumlah curah hujan untuk periode 12 hari saat suhu rata-rata sedikitnya 40 derajat Fahrenheit dan rata-rata kecepatan angin kurang dari 10 mil per jam.

3,5

Catatan

Hanya sel B3, C2, dan D2 yang dijumlahkan, karena sel yang terkait memenuhi kedua kriteria. Sel yang terkait untuk B3 adalah B5 dan B7, sel yang terkait untuk C2 adalah C4 dan C6, dan sel yang terkait untuk D2 adalah D4 dan D6.

Sebagai contoh data yang dikecualikan dari operasi, sel B2 yang terkait (B4 dan B6) tidak memenuhi kedua kriteria; secara khusus, sel B6 gagal karena nilainya (13) lebih besar dari criteria2 (10).

Contoh 5

Rumah

Kaki Persegi

Kamar tidur

Kamar mandi

Garasi

Tahun dibangun

Harga

Rumah1

1200

2

1

ya

1940

$125.000

Rumah2

1580

3

1,5

tidak

1965

$217.000

Rumah3

2200

4

3

ya

2003

$376.000

Rumah4

1750

3

2,5

ya

2001

$249.000

Rumah5

2140

4

3

ya

1998

$199.000

>2

ya

y*

Rumus

Deskripsi

Hasil

=SUMIFS(G2:G6,C2:C6,A7,E2:E6,B7,F2:F6,">1999",F2:F6,"<2004")

Menjumlahkan harga rumah-rumah tersebut yang memiliki sedikitnya 3 kamar tidur, sebuah garasi, dan berusia antara 5 dan 10 tahun pada tahun 2009.

$625.000

=AVERAGEIFS(G2:G6,C2:C6,">2",E2:E6,C7,F2:F6,">1999",F2:F6,"<2004")

Mengembalikan rata-rata harga untuk rumah-rumah yang memiliki sedikitnya 3 kamar tidur, sebuah garasi, dan berusia antara 5 dan 10 tahun pada tahun 2009. Selain "2" dan "1999," rumus menggunakan C7 (y*) sebagai kriteria wildcard.

$312.500

Bagian Atas Halaman

Terapkan Ke: Excel 2013, Excel Online



Apakah informasi ini bermanfaat?

Ya Tidak

Bagaimana kami dapat meningkatkannya?

255 karakter tersisa

Untuk memproteksi privasi Anda, jangan menyertakan informasi kontak dalam umpan balik Anda. Tinjau kebijakan privasi.

Terima kasih atas umpan balik Anda!

Sumber daya dukungan

Ganti bahasa