SUM (Fungsi SUM)

Fungsi SUM, salah satu dari fungsi matematika dan trigonometri, menambahkan nilai. Anda dapat menambahkan nilai individual, referensi sel atau rentang, atau campuran ketiganya.

Misalnya:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Browser Anda tidak mendukung video. Instal Microsoft Silverlight, Adobe Flash Player, atau Internet Explorer 9.

Video ini merupakan bagian dari kursus pelatihan yang disebut Menambahkan angka di Excel 2013.

SUM(angka1,[angka2],...)

Nama argumen

Deskripsi

angka1    (Diperlukan)

Angka pertama yang ingin Anda tambahkan. Angkanya dapat seperti 4, referensi sel seperti B6, atau sel rentang seperti B2:B8.

angka2-255    (Opsional)

Inilah angka kedua yang ingin Anda tambahkan. Anda dapat menentukan hingga 255 angka dengan cara ini.

Jika ingin langsung mendapatkan Jumlah rentang sel, Anda hanya perlu memilih rentang dan lihatlah sisi kanan bawah jendela Excel.

Tangkapan layar memilih rentang sel, lalu mencari di Bilah Status
Bilah Status


Inilah Bilah Status yang menampilkan semua informasi terkait hal-hal yang Anda pilih, terlepas itu hanya satu atau beberapa sel. Jika mengklik kanan Bilah Status, kotak dialog fitur akan muncul dan menampilkan semua opsi yang dapat Anda pilih. Perlu diketahui bahwa bilah status juga menampilkan nilai untuk rentang terpilih jika atribut tersebut dicentang. Pelajari selengkapnya tentang Bilah Status.

Cara termudah untuk menambahkan rumus SUM dalam lembar kerja adalah menggunakan Panduan AutoJumlah. Pilih sel kosong apa pun yang berada langsung di atas atau di bawah rentang yang ingin dijumlahkan, lalu di tab Beranda atau Rumus dalam Pita, tekan AutoJumlah > Jumlahkan. Panduan AutoJumlah akan secara otomatis mengetahui rentang yang ingin dijumlahkan, kemudian menyusun rumusnya. AutoJumlah juga dapat berfungsi secara horizontal jika Anda memilih sel di sisi kiri atau kanan rentang yang akan dijumlahkan. Perlu diketahui bahwa fitur ini tidak akan berfungsi pada rentang yang tidak bersebelahan, namun kami akan membahasnya di bagian berikutnya.

Anda dapat menggunakan Panduan AutoJumlah untuk membuat rumus Sum secara otomatis.  Pilih rentang di atas/bawah atau kiri/kanan dari rentang yang akan dijumlahkan, lalu masuk ke tab Rumus di Pita, kemudian pilih AutoJumlah & SUM.
Menggunakan Panduan AutoJumlah untuk dengan cepat menjumlahkan rentang yang berdekatan


Dialog AutoJumlah juga memungkinkan Anda memilih fungsi umum lainnya seperti:

AutoJumlah secara vertikal

Sel B6 memperlihatkan rumus Sum AutoJumlah: =SUM(B2:B5)

Panduan AutoJumlah telah secara otomatis mendeteksi sel B2:B5 sebagai rentang yang akan dijumlahkan. Anda cukup menekan Enter untuk mengonfirmasinya. Jika perlu menambahkan/mengeluarkan beberapa sel, Anda bisa menahan Tombol Shift > Tombol panah yang dipilih hingga cocok dengan pilihan yang diinginkan, lalu tekan Enter ketika selesai.

Panduan fungsi Intellisense: tag mengambang SUM (angka1, [angka2], …) di bawah fungsi adalah panduan Intellisense-nya. Jika Anda mengklik SUM atau nama fungsi, itu akan berubah menjadi hyperlink berwarna biru yang akan membawa Anda ke topik Bantuan mengenai fungsi tersebut. Jika Anda mengklik elemen fungsi individual, potongan representatif mereka dalam rumus tersebut akan disorot. Dalam kasus ini hanya B2:B5 yang disorot karena hanya ada satu referensi angka dalam rumus ini. Tag Intellisense akan muncul untuk fungsi apa pun.

AutoJumlah secara horizontal

Sel D2 memperlihatkan rumus Sum AutoJumlah: =SUM(B2:C2)

Menggunakan SUM dengan rentang yang tidak bersebelahan.  Rumus sel C8 adalah =SUM(C2:C3,C5:C6). Anda juga dapat menggunakan Rentang Bernama, sehingga rumus menjadi =SUM(Minggu1,Minggu2).

Panduan AutoJumlah biasanya hanya bekerja untuk rentang yang bersebelahan, jadi jika terdapat baris atau kolom kosong dalam rentang sum, Excel akan berhenti di jarak pertama. Jika demikian, Anda perlu menggunakan SUM dengan cara memilih, di mana Anda menambahkan rentang individual satu per satu. Dalam contoh ini, jika Anda memiliki data di sel B4, Excel akan menghasilkan =SUM(C2:C6) karena Excel akan mengenali rentang yang bersebelahan.

Anda dapat langsung memilih beberapa rentang yang tidak bersebelahan dengan Ctrl+Klik Kiri. Pertama, masukkan “=SUM(“, lalu pilih rentang yang berlainan. Excel akan secara otomatis menambahkan pemisah koma di antara rentang. Tekan enter jika sudah selesai.

TIPS: Anda dapat menggunakan ALT+ = untuk langsung menambahkan fungsi SUM ke suatu sel. Selanjutnya, Anda hanya perlu memilih rentang.

Catatan: Anda mungkin melihat Excel telah menyoroti rentang fungsi yang berbeda menurut warna, dan mereka sesuai dengan srumus itu sendiri, sehingga C2:C3 berwarna sama, dan C5:C6 berwarna lainnya. Excel akan melakukan ini untuk semua fungsi, kecuali rentang yang direferensikan ada di lembar kerja atau buku kerja yang berbeda. Untuk aksesibilitas yang disempurnakan dengan teknologi bantu, Anda dapat menggunakan Rentang Bernama, seperti “Minggu1”, “Minggu2”, dsb. lalu mereferensikannya ke dalam rumus Anda:

=SUM(Minggu1,Minggu2)

Anda dapat dengan mudah melakukan operasi matematika di Excel dengan sendirinya, dan bersama dengan fungsi Excel seperti SUM. Tabel berikut ini mencantumkan operator yang dapat Anda gunakan beserta beberapa fungsi terkait. Anda dapat memasukkan operator baik dari baris angka di keyboard maupun pad 10 tombol jika memilikinya. Sebagai contoh, Shift+8 akan memasukkan tanda bintang (*) untuk perkalian.

Operator

Operasi

Contoh

+

Penambahan

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Pengurangan

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Perkalian

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - Fungsi PRODUCT

/

Pembagian

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) - Fungsi QUOTIENT

^

Perpangkatan

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) - Fungsi POWER

Untuk informasi selengkapnya, lihat Menggunakan Excel sebagai kalkulator Anda.

Contoh Lainnya

  1. Anggap saja Anda ingin menerapkan Diskon Persentase ke rentang sel yang telah dijumlahkan.

    Gunakan Operator dengan SUM.  Rumus di sel B16 adalah =SUM(A2:A14)*-25%.  Rumus tersebut akan dibangun dengan benar jika -25% adalah referensi sel, seperti = SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Akan memberi Anda 25% dari rentang yang dijumlahkan, namun akan mengode paksa 25% tersebut dalam rumus, dan mungkin sulit ditemukan nantinya jika Anda perlu mengubahnya. Jauh lebih baik untuk menempatkan 25% tersebut dalam sel dan mereferensikannya, karena ada di luar dan mudah diubah, seperti ini:

    • =SUM(A2:A14)*E2

    Untuk membagi, dan bukan mengalikan, cukup ganti “*” dengan “/”: =SUM(A2:A14)/E2

  2. Menambahkan atau Mengurangi dari SUM

    i. Anda dapat dengan mudah Menambahkan atau Mengurangi dari Sum menggunakan + atau - seperti ini:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

Bagian ini akan membahas beberapa praktik terbaik yang berfungsi dengan fungsi SUM. Sebagian besar praktik ini juga dapat diterapkan untuk bekerja dengan fungsi-fungsi lain.

Metode =1+2 atau =A+B – Meskipun Anda dapat memasukkan =1+2+3 atau =A1+B1+C2 dan mendapatkan hasil akurat sepenuhnya, metode ini rentan akan kesalahan karena beberapa alasan:

  1. Kesalahan Ketik – Bayangkan Anda mencoba memasukkan nilai yang lebih banyak dan/atau jauh lebih besar seperti ini:

    • =14598,93+65437,90+78496,23

    Lalu cobalah untuk memvalidasi bahwa entri Anda sudah benar. Jauh lebih mudah untuk memasukkan nilai-nilai ini di sel individual dan menggunakan rumus SUM. Selain itu, nilai juga dapat diformat saat mereka berada dalam sel, membuatnya jauh lebih mudah dibaca saat berada di dalam rumus.

    Gunakan fungsi SUM, dan bukan mengode paksa nilai dalam rumus.  Rumus di sel D5 adalah =SUM(D2:D4)
  2. Kesalahan #VALUE! karena mereferensi teks, bukan angka.

    Jika Anda menggunakan rumus seperti:

    • =A1+B1+C1 or =A1+A2+A3

    Contoh konstruksi rumus yang buruk.  Rumus di sel D2 adalah =A2+B2+C2

    Rumus Anda dapat tidak berfungsi jika ada nilai non-numerik (teks) apa pun dalam sel yang direferensikan, yang akan mengembalikan kesalahan #VALUE!. SUM akan mengabaikan nilai teks lalu memberi Anda jumlah nilai numerik saja.

    Konstruksi rumus yang tepat.  Bukannya =A2+B2+C2, rumus sel D2 adalah =SUM(A2:C2)
  3. Kesalahan #REF! karena menghapus baris atau kolom

    Kesalahan #REF! akibat menghapus kolom.  Rumus telah berubah menjadi =A2+#REF!+B2

    Jika Anda menghapus baris atau kolom, rumus tidak akan diperbarui untuk tidak memasukkan rumus yang dihapus dan akan kembali pada kesalahan #REF!, di mana fungsi SUM akan diperbarui secara otomatis.

    Fungsi SUM akan secara otomatis menyesuaikan untuk baris dan kolom yang disisipkan atau dihapus
  4. Rumus tidak akan memperbarui referensi saat menyisipkan baris atau kolom

    Rumus =A+B+C tidak akan diperbarui jika Anda menambahkan baris

    Jika menyisipkan baris atau kolom, rumus tidak akan diperbarui untuk menyertakan baris tambahan, walau rumus SUM akan diperbarui secara otomatis (selama Anda tidak berada di luar rentang yang direferensikan dalam rumus). Hal ini sangat penting terutama jika Anda berharap suatu rumus untuk diperbarui tetapi tidak, karena Anda bisa saja tidak menerima hasil yang tidak lengkap.

    Contoh menggambarkan rumus SUM secara otomatis meluas dari =SUM(A2:C2) ke =SUM(A2:D2) saat sebuah kolom disisipkan
  5. SUM dengan Referensi Sel individual vs. Rentang

    Menggunakan rumus seperti:

    • =SUM(A1,A2,A3,B1,B2,B3)

    Sama saja rentan akan kesalahan saat menyisipkan atau menghapus baris dalam rentang yang direferensikan, untuk alasan yang sama. Jauh lebih baik menggunakan rentang individual, seperti:

    • =SUM(A1:A3,B1:B3)

    Yang akan diperbarui ketika menambah atau menghapus baris.

  1. Tentunya, Anda bisa menggunakan SUM dengan fungsi lain. Berikut adalah contoh yang membuat kalkulasi rata-rata bulanan:

    Menggunakan SUM dengan fungsi yang lain.  Rumus di sel M2 adalah =SUM(A2:L2)/COUNTA(A2:L2).  Catatan: kolom Mei-November disembunyikan untuk kejelasan.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Yang akan membawa SUM A2:L2 dibagi dengan jumlah sel tidak kosong di A2:L2 (Mei hingga Desember kosong).

  1. Terkadang, Anda perlu menjumlahkan sel tertentu di beberapa lembar kerja. Mungkin Anda ingin mengklik setiap lembar dan sel yang diinginkan lalu cukup menggunakan “+” untuk menambahkan nilai sel, tetapi rasanya melelahkan dan dapat rentan akan kesalahan.

    • =Sheet1!A1+Sheet2!A1+Sheet3!A1

    Anda dapat menyelesaikan ini dengan lebih mudah menggunakan 3D SUM atau SUM 3 Dimensi:

    3D Sum - Rumus di sel D2 adalah =SUM(Sheet1:Sheet3!A2)
    • =SUM(Sheet1:Sheet3!A1)

    Yang akan menjumlahkan sel A1 di semua lembar dari Lembar 1 hingga Lembar 3.

    Hal ini sangat membantu saat Anda memiliki satu lembar untuk setiap bulan (Januari-Desember) dan perlu menjumlahkannya pada lembar ringkasan.

    3d SUM di seluruh Lembar Bernama.  Rumus di D2 adalah =SUM(Januari:Desember!A2)
    • =SUM(Januari:Desember!A2)

    Yang akan menjumlahkan sel A2 di setiap lembar dari Januari sampai Desember.

    Catatan: Jika lembar kerja Anda memiliki spasi dalam nama mereka, seperti “Penjualan Januari”, maka Anda perlu menggunakan apostrof saat mereferensikan nama lembar tersebut di dalam rumus: Perhatikan apostrof SEBELUM nama lembar kerja pertama, dan lagi SETELAH nama lembar kerja terakhir.

    • =SUM(‘Penjualan Januari:Penjualan Desember’!A2)

    Metode 3D juga akan berfungsi dengan fungsi lain seperti AVERAGE, MIN, MAX, dsb:

    • =AVERAGE(Sheet1:Sheet3!A1)

    • =MIN(Sheet1:Sheet3!A1)

    • =MAX(Sheet1:Sheet3!A1)

Masalah

Apa yang salah

Fungsi SUM saya memperlihatkan #####, bukan hasilnya.

Periksa lebar kolom. ##### biasanya berarti bahwa kolom terlalu sempit untuk menampilkan hasil rumus.

Fungsi SUM saya memperlihatkan rumus sebagai teks, bukan hasilnya.

Pastikan sel tersebut tidak diformat sebagai teks. Pilih sel atau rentang yang terkait dan gunakan Ctrl+1 untuk menampilkan dialog Format sel, lalu klik tab Angka dan pilih format yang Anda inginkan. Jika sel diformat sebagai teks dan tidak berubah setelah Anda mengubah format, Anda mungkin perlu menggunakan F2 > Enter untuk mendorong format agar berubah.

Fungsi SUM saya tidak diperbarui.

Pastikan bahwa Penghitungan diatur ke Otomatis. Di Tab Rumus masuk ke Opsi Penghitungan. Anda juga dapat menggunakan F9 untuk mendorong lembar kerja melakukan penghitungan.

Pastikan bahwa penghitungan diatur ke Otomatis.  Di Tab Rumus masuk ke Opsi Penghitungan.

Beberapa nilai tidak ditambahkan.

Hanya nilai numerik dalam referensi fungsi atau rentang yang dapat ditambahkan. Sel kosong, nilai logika seperti TRUE, atau teks akan diabaikan.

Nilai kesalahan #NAME? muncul dan bukan hasil yang diharapkan.

Hal ini biasanya berarti bahwa terdapat kesalahan eja dalam rumus tersebut, seperti =sume(A1:A10) bukannya =SUM(A1:A10).

Fungsi SUM saya memperlihatkan angka bulat, yang seharusnya desimal

Periksa pemformatan sel untuk memastikan bahwa Anda menampilkan desimal. Pilih sel atau rentang terkait lalu gunakan Ctrl+1 untuk memunculkan dialog Format Sel, lalu klik Tab Angka kemudian pilih format yang diinginkan. Pastikan untuk menyatakan angka posisi desimal yang diinginkan.

  1. Saya hanya ingin Menambahkan/Mengurangi/Mengalikan/Membagi angka Lihat seri video ini tentang Matematika Dasar di Excel, atau Menggunakan Excel sebagai kalkulator Anda.

  2. Bagaimana cara menampilkan lebih banyak/sedikit posisi desimal? Anda dapat mengubah pemformatan angka. Pilih sel atau rentang terkait, lalu gunakan Ctrl+1 untuk memunculkan Dialog Format Sel, lalu klik Tab Angka kemudian pilih format yang diinginkan. Pastikan untuk menyatakan angka posisi desimal yang diinginkan.

  3. Bagaimana cara menambah atau mengurangi Waktu? Anda dapat menambah dan mengurangi waktu dengan berbagai cara. Sebagai contoh, untuk memperoleh selisih antara 8.00 - 12.00 untuk urusan daftar gaji, Anda perlu menggunakan: =("12:00 PM"-"8:00 AM")*24, mengambil waktu akhir dikurangi waktu mulai. Perlu diketahui bahwa Excel menghitung waktu sebagai pecahan hari, sehingga Anda perlu mengalikannya dengan 24 untuk mendapatkan waktu total. Dalam contoh pertama, kita menggunakan =((B2-A2)+(D2-C2))*24 untuk mendapatkan jumlah jam dari mulai hingga akhir, dikurangi istirahat makan siang (total 8,50 jam).

    Jika Anda hanya menambahkan jam dan menit, namun ingin menampilkannya seperti itu saja, Anda dapat melakukan penjumlahan dan tidak perlu mengalikannya dengan 24, sehingga dalam contoh kedua kita menggunakan =SUM(A6:C6) karena hanya memerlukan jumlah total jam dan menit untuk tugas yang ditetapkan (5:36, atau 5 jam, 36 menit).

    Menghitung waktu

    Untuk informasi selengkapnya, lihat: Menambahkan atau mengurangi waktu.

  4. Bagaimana cara mendapatkan perbedaan di antara tanggal? Dengan waktu, Anda dapat menambahkan dan mengurangi tanggal. Berikut adalah contoh yang sangat umum untuk menghitung jumlah hari di antara dua tanggal. Hal ini sesederhana =B2-A2. Kunci untuk bekerja dengan Tanggal dan Waktu adalah memulai dengan Tanggal/Waktu Selesai dan menguranginya dengan Tanggal/Waktu Mulai.

    Menghitung perbedaan antara tanggal

    Untuk cara lain bekerja dengan tanggal, lihat: Menghitung jumlah hari di antara dua tanggal.

  5. Bagaimana cara menjumlahkan sel yang terlihat saja? Terkadang, saat menyembunyikan baris secara manual atau menggunakan Filter Otomatis untuk menampilkan data tertentu saja, Anda juga ingin menjumlahkan sel yang terlihat saja. Anda dapat menggunakan Fungsi SUBTOTAL. Jika menggunakan baris total dalam tabel Excel, fungsi apa pun yang Anda pilih dari menu menurun Total akan secara otomatis dimasukkan sebagai subtotal. Lihat selengkapnya tentang cara Menghitung total data dalam tabel Excel.

Perlu bantuan lainnya?

Anda selalu dapat bertanya kepada pakar di Komunitas Teknologi Excel, mendapatkan dukungan di Komunitas Jawaban, atau menyarankan fitur maupun fitur baru di Suara Pengguna Excel.

Lihat juga

Lihat video tentang cara menggunakan Fungsi SUM

Fungsi SUMIF hanya menambahkan nilai yang memenuhi satu kriteria

Fungsi SUMIFS hanya menambahkan nilai yang memenuhi beberapa kriteria

Fungsi COUNTIF hanya menghitung nilai yang memenuhi satu kriteria

Fungsi COUNTIFS hanya menghitung nilai yang memenuhi beberapa kriteria

Gambaran umum rumus di Excel

Cara menghindari rumus yang rusak

Menemukan dan memperbaiki kesalahan dalam rumus

Pintasan keyboard di Excel untuk Windows

Pintasan keyboard di Excel untuk Mac

Fungsi Matematika & Trigonometri

Fungsi Excel (sesuai alfabet)

Fungsi Excel (menurut Kategori)

Kembangkan keterampilan Anda
Jelajahi pelatihan
Dapatkan fitur baru terlebih dahulu
Gabung ke Office Insiders

Apakah informasi ini bermanfaat?

Terima kasih atas umpan balik Anda!

Terima kasih atas umpan balik Anda! Sepertinya menghubungkan Anda ke salah satu agen dukungan Office kami akan sangat membantu.

×