Properti FileDialog

Berlaku untuk

Objek Application

Mengembalikan objek FileDialogyang mewakili sebuah contoh dari kotak dialog file.

ekspresi.FileDialog(Tipedialog)

ekspresi Diperlukan. Suatu ekspresi yang mengembalikan salah satu objek dalam daftar Berlaku Untuk.

Tipedialog    Diperlukan MsoFileDialogType . Tipe kotak dialog file.

MsoFileDialogType dapat berupa salah satu konstanta MsoFileDialogType ini.

msoFileDialogFilePicker

msoFileDialogFolderPicker

msoFileDialogOpen Tidak didukung di Microsoft Access.

msoFileDialogSaveAs Tidak didukung di Microsoft Access.

Keterangan

Konstanta MsoFileDialogOpen dan msoFileDialogSaveAs tidak didukung di Microsoft Office Access 2007.

Contoh

Contoh ini menggambarkan cara menggunakan objek FileDialog untuk menampilkan kotak dialog yang memungkinkan pengguna memilih satu atau beberapa file. File yang dipilih lalu ditambahkan ke kotak daftar bernama FileList.

Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
Kembangkan keterampilan Anda
Jelajahi pelatihan
Dapatkan fitur baru terlebih dahulu
Gabung ke Office Insiders

Apakah informasi ini bermanfaat?

Terima kasih atas umpan balik Anda!

Terima kasih atas umpan balik Anda! Sepertinya menghubungkan Anda ke salah satu agen dukungan Office kami akan sangat membantu.

×