Panduan dan contoh rumus array

Panduan dan contoh rumus array

Catatan: Kami ingin secepatnya menyediakan konten bantuan terbaru dalam bahasa Anda. Halaman ini diterjemahkan menggunakan mesin dan mungkin terdapat kesalahan tata bahasa atau masalah keakuratan. Kami bertujuan menyediakan konten yang bermanfaat untuk Anda. Dapatkah Anda memberi tahu kami apakah informasi ini bermanfaat untuk Anda di bagian bawah halaman ini? Berikut artikel dalam bahasa Inggris untuk referensi.

Rumus array adalah rumus yang bisa melakukan beberapa perhitungan pada satu atau beberapa item dalam satu array. Anda bisa menganggap array sebagai baris atau kolom nilai, atau kombinasi baris dan kolom nilai. Rumus array bisa kembali beberapa hasil, atau satu hasil.

Dimulai dengan pembaruan September 2018 untuk Office 365, apa pun rumus yang bisa menampilkan hasil beberapa akan secara otomatis mengembalikan luapan mereka baik ke bawah, atau seluruh ke tetangga sel. Perubahan ini dalam perilaku juga dilengkapi dengan beberapa baru fungsi array dinamis. Rumus array dinamis, baik mereka menggunakan fungsi yang sudah ada atau fungsi array dinamis, hanya perlu masukkan ke dalam satu sel, lalu dikonfirmasi dengan menekan Enter. Rumus array yang lebih lama, warisan memerlukan memilih seluruh output rentang terlebih dahulu lalu mengonfirmasikan rumus dengan Ctrl + Shift + Enter. Mereka sedang sering disebut rumus CSE .

Anda dapat menggunakan rumus array untuk melakukan tugas kompleks, seperti:

  • Dengan cepat membuat sampel kumpulan data.

  • Menghitung jumlah karakter yang terdapat di dalam rentang sel.

  • Menjumlahkan angka hanya yang memenuhi kondisi tertentu, misalnya nilai terendah dalam rentang, atau angka yang terletak di antara batas atas dan bawah.

  • Menjumlahkan setiap nilai ke-n dalam serangkaian nilai.

Dalam contoh berikut ini memperlihatkan kepada Anda cara membuat rumus array multisel dan sel tunggal. Jika memungkinkan, kami telah disertakan contoh dengan beberapa fungsi array dinamis, serta rumus array yang ada dimasukkan sebagai larik dinamis dan warisan.

Mengunduh contoh kami

Mengunduh buku kerja contoh dengan semua rumus contoh-contoh array dalam artikel ini.

Latihan ini menunjukkan cara menggunakan rumus array multisel dan sel tunggal untuk menghitung serangkaian angka penjualan. Rangkaian langkah pertama menggunakan rumus multisel untuk menghitung rangkaian subtotal. Rangkaian kedua menggunakan rumus sel tunggal untuk menghitung jumlah total.

  • Rumus array multisel

    Fungsi array multisel dalam sel H10 = F10:F19 * G10:G19 untuk menghitung jumlah mobil dijual oleh harga satuan

  • Di sini kami sedang menghitung penjualan Total dari Coupe dan sedan untuk tiap tenaga penjualan dengan memasukkan = F10:F19 * G10:G19 dalam sel H10.

    Saat Anda menekan Enter, Anda akan melihat hasil mengembalikan luapan ke bawah ke sel H10:H19. Perhatikan bahwa rentang tumpahan disorot dengan batas saat Anda memilih sel mana pun dalam rentang tumpahan. Anda juga mungkin menyadari bahwa rumus di sel H10:H19 berwarna abu-abu. Mereka sedang hanya ada untuk referensi, jadi jika Anda ingin menyesuaikan rumus, Anda perlu untuk memilih sel H10, tempat rumus master berada.

  • Rumus array sel tunggal

    Rumus array sel tunggal untuk menghitung total keseluruhan dengan =SUM(F10:F19*G10:G19)

    Dalam sel H20 buku kerja contoh, ketik atau salin dan tempelkan =SUM(F10:F19*G10:G19), dan lalu tekan Enter.

    Dalam kasus ini, Excel mengalikan nilai dalam array (rentang sel F10 melalui G19), dan lalu menggunakan fungsi SUM untuk menambahkan Total bersama-sama. Hasilnya adalah jumlah total penjualan $1.590.000,00.

    Contoh ini menunjukkan betapa canggihnya tipe rumus ini. Sebagai contoh, misalnya Anda memiliki 1.000 baris data. Anda dapat menjumlahkan sebagian atau semua data itu dengan membuat rumus array di sel tunggal sebagai ganti menyeret rumus menuruni 1.000 baris. Juga, perhatikan bahwa rumus sel tunggal di sel H20 benar-benar terpisah dari rumus multisel (rumus dalam sel H10 melalui H19). Ini adalah keunggulan lain menggunakan rumus array — fleksibilitas. Anda bisa mengubah rumus lain dalam kolom H tanpa mempengaruhi rumus dalam H20. Juga dapat praktik yang baik agar independen Total seperti ini, seperti ini membantu memvalidasi akurasi hasil Anda.

  • Rumus array dinamis juga menawarkan keunggulan berikut:

    • Konsistensi    Jika Anda mengklik salah satu sel dari H10 ke bawah, Anda melihat rumus yang sama. Konsistensi ini dapat membantu memastikan akurasi yang lebih tinggi.

    • Keselamatan    Anda tidak dapat menimpa komponen dari rumus array multisel. Misalnya, klik sel H11 dan tekan Delete. Excel tidak akan mengubah array yang output. Untuk mengubahnya, Anda perlu pilih sel kiri atas dalam array, atau sel H10.

    • Ukuran file lebih kecil    Anda bisa sering menggunakan rumus array tunggal daripada beberapa rumus menengah. Misalnya, contoh penjualan mobil menggunakan satu rumus array untuk menghitung hasil di kolom E. Jika Anda telah digunakan standar rumus seperti = F10 * G10, F11 * G11, F12 * G12, dll, Anda akan digunakan 11 rumus yang berbeda untuk menghitung hasil yang sama. Yang bukan besar, namun bagaimana jika Anda telah ribuan baris Total? Kemudian dapat membuat perbedaan besar.

    • Efisiensi    Fungsi array dapat berupa cara yang efisien untuk menyusun rumus yang kompleks. Array =SUM(F10:F19*G10:G19) rumus yang sama seperti ini: = SUM(F10*G10,F11*G11,F12*G12,F13*G13,F14*G14,F15*G15,F16*G16,F17*G17,F18*G18,F19*G19).

    • Lebarnya    Rumus array dinamis secara otomatis akan mengembalikan luapan ke rentang output. Jika sumber data Anda berada dalam tabel Excel, lalu rumus array dinamis Anda akan secara otomatis mengubah ukuran saat Anda menambahkan atau menghapus data.

    • #SPILL! kesalahan    Larik dinamis diperkenalkan #SPILL! kesalahan, yang menunjukkan bahwa rentang dimaksudkan tumpahan diblokir karena beberapa alasan. Saat Anda mengatasi penyumbatan, rumus akan secara otomatis mengembalikan luapan.

Konstanta array adalah komponen dari rumus array. Anda membuat konstanta array dengan memasukkan daftar item lalu menutup daftar itu secara manual dengan kurung kurawal ({ }), seperti ini:

= {1,2,3,4,5} atau = {"Januari", "Februari", "Maret"}

Jika memisahkan item dengan koma, Anda membuat array horizontal (baris). Jika memisahkan item dengan titik koma, Anda membuat array vertikal (kolom). Untuk membuat array dua dimensi, Anda sebagai pembatas item dalam setiap baris dengan tanda koma, dan sebagai pembatas setiap baris dengan titik koma.

Prosedur berikut akan memberi Anda latihan membuat konstanta horizontal, vertikal, dan dua dimensi. Kami akan memperlihatkan contoh yang menggunakan fungsi SEQUENCE untuk secara otomatis menghasilkan konstanta array, serta secara manual memasukkan konstanta array.

  • Membuat konstanta horizontal

    Gunakan buku kerja dari contoh sebelumnya, atau buat buku kerja baru. Pilih sel kosong mana saja dan masukkan =SEQUENCE(1,5). Fungsi SEQUENCE Build baris 1 oleh 5 kolom array sama dengan = {1,2,3,4,5}. Hasil berikut akan ditampilkan:

    Membuat konstanta horizontal array dengan =SEQUENCE(1,5) atau = {1,2,3,4,5}

  • Membuat konstanta vertikal

    Pilih sel kosong mana saja dengan ruang di bawahnya, dan masukkan =SEQUENCE(5), atau = {1; 2; 3; 4; 5}. Hasil berikut akan ditampilkan:

    Membuat konstanta array vertikal dengan = SEQUENCE(5), atau = {1; 2; 3; 4; 5}

  • Membuat konstanta dua dimensi

    Pilih sel kosong mana saja dengan ruang di sebelah kanan dan di bawahnya, dan masukkan =SEQUENCE(3,4). Anda akan melihat hasil berikut:

    Membuat baris 3 dengan 4 kolom konstanta array dengan =SEQUENCE(3,4)

    Anda juga dapat memasukkan: atau = {1,2,3,4 5,6,7,8; 9,10,11,12}, namun Anda akan ingin membayar perhatian ke mana Anda menaruh semi titik versus koma.

    Saat Anda melihat, opsi urutan menawarkan signifikan keuntungan atas memasukkan nilai konstanta array Anda secara manual. Terutama, menghemat waktu Anda, tetapi juga dapat membantu mengurangi kesalahan dari entri manual. Mudah juga untuk membaca, terutama sebagai titik koma dapat sulit dibedakan dari pemisah koma.

Berikut adalah contoh yang menggunakan array konstanta sebagai bagian dari rumus lebih besar. Di contoh buku kerja, masuk ke lembar kerja konstanta dalam rumus , atau buat lembar kerja baru.

Di sel D9, kami dimasukkan =SEQUENCE(1,5,3,1), tetapi Anda juga bisa memasukkan 3, 4, 5, 6 dan 7 di sel A9:H9. Tidak ada yang khusus tentang pilihan angka tersebut tertentu, kami hanya memilih sesuatu selain 1-5 untuk perbedaan.

Dalam sel E11, masukkan = SUM (D9:H9*SEQUENCE(1,5)), atau = SUM (D9:H9* {1,2,3,4,5}). Rumus mengembalikan 85.

Menggunakan konstanta array dalam rumus. Dalam contoh ini, kami menggunakan = SUM (D9:H(*SEQUENCE(1,5))

Fungsi SEQUENCE Build setara dengan array konstanta {1,2,3,4,5}. Karena Excel menjalankan operasi pada ekspresi yang dimasukkan dalam tanda kurung terlebih dahulu, elemen berikutnya dua yang masuk ke play adalah nilai sel di D9:H9, dan operator perkalian (*). Pada titik ini, rumus mengalikan nilai dalam array yang tersimpan dengan nilai yang terkait dalam konstanta. Ini ekuivalen dengan:

=Sum(D9*1,E9*2,F9*3,G9*4,H9*5), atau =SUM(3*1,4*2,5*3,6*4,7*5)

Akhirnya, fungsi SUM menambahkan nilai, dan mengembalikan 85.

Untuk menghindari menggunakan array tersimpan dan menjaga operasi seluruhnya di memori, Anda bisa menggantinya dengan konstanta array yang lain:

=Sum(SEQUENCE(1,5,3,1)*SEQUENCE(1,5)), atau =SUM({3,4,5,6,7}*{1,2,3,4,5})

Elemen yang bisa Anda gunakan dalam konstanta array

  • Konstanta array bisa berisi angka, teks, nilai logika (seperti TRUE dan FALSE), dan nilai kesalahan seperti #N/A. Anda bisa menggunakan angka dalam format bilangan bulat, desimal, dan ilmiah. Jika Anda menyertakan teks, Anda perlu mengelilingi dengan tanda kutip ("teks").

  • Konstanta array tidak boleh berisi array, rumus, atau fungsi tambahan. Dengan kata lain, konstanta array hanya boleh berisi teks atau angka yang dipisahkan dengan koma atau titik koma. Excel menampilkan pesan peringatan apabila Anda memasukkan rumus seperti {1,2,A1:D4} atau {1,2,SUM(Q2:Z8)}. Nilai numerik juga tidak boleh berisi tanda persen, tanda dolar, koma, atau kurung.

Salah satu cara terbaik menggunakan konstanta array adalah nama mereka. Konstanta bernama lebih mudah digunakan, dan dapat menyembunyikan kerumitan rumus array Anda dari orang lain. Untuk memberi nama konstanta array dan menggunakannya dalam rumus, lakukan hal berikut:

Masuk ke rumus > ditentukan nama > Tetapkan nama. Di kotak nama , ketikkan Quarter1. Di kotak Merujuk ke, masukkan konstanta berikut (ingatlah untuk mengetikkan tanda kurung kurawal secara manual):

={"January","February","March"}

Kotak dialog sekarang akan terlihat seperti ini:

Tambahkan konstanta array bernama dari rumus > nama yang ditentukan > > pengatur nama baru

Klik OK, lalu pilih baris mana pun dengan tiga sel kosong, dan masukkan = Quarter1.

Hasil berikut akan ditampilkan:

Menggunakan konstanta array yang diberi nama dalam rumus, seperti = Quarter1, tempat Quarter1 telah ditetapkan = {"Januari", "Februari", "Maret"}

Jika Anda menginginkan hasil mengembalikan luapan secara vertikal dan bukan secara horizontal, Anda bisa menggunakan =TRANSPOSE(Quarter1).

Jika Anda ingin menampilkan daftar 12 bulan, seperti yang mungkin Anda gunakan ketika menyusun pernyataan keuangan, Anda dapat mendasarkan salah menonaktifkan tahun saat ini dengan fungsi SEQUENCE. Hal yang rapi tentang fungsi ini adalah meskipun hanya bulan yang ditampilkan, ada yang tanggal yang valid belakangnya yang bisa Anda gunakan dalam perhitungan lain. Anda akan menemukan contoh ini di lembar kerja bernama konstanta array dan cepat sampel kumpulan data di buku kerja contoh.

=Text(date(year(Today()),SEQUENCE(1,12),1),"mmm")

Gunakan kombinasi fungsi teks, tanggal, tahun, hari ini, dan urutan untuk menyusun daftar dinamis 12 bulan

Ini menggunakan fungsi DATE membuat tanggal berdasarkan tahun saat ini, urutan membuat konstanta array dari 1 hingga 12 untuk Januari sampai Desember, maka fungsi TEXT mengonversi format tampilan untuk "mmm" (Jan, Feb, Mar, dll.). Jika Anda ingin menampilkan nama bulan lengkap, seperti Januari, Anda akan menggunakan "mmmm".

Ketika Anda menggunakan konstanta yang bernama sebagai rumus array, ingat untuk memasukkan tanda sama dengan, sebagai di = Quarter1, bukan hanya Quarter1. Jika tidak, Excel akan menafsirkan array itu sebagai string teks dan rumus Anda tidak akan bekerja seperti yang diharapkan. Akhirnya, ingatlah bahwa Anda bisa menggunakan kombinasi fungsi, teks dan angka. Semua ini bergantung pada bagaimana kreatif Anda ingin mendapatkan.

Contoh berikut menggambarkan beberapa cara penempatan konstanta array untuk digunakan dalam rumus array. Beberapa contoh gunakan fungsi TRANSPOSE untuk mengonversi baris ke kolom dan sebaliknya.

  • Beberapa setiap item dalam satu array

    Masukkan = urutan (1,12) * 2, atau = {1,2,3,4; 5,6,7,8; 9,10,11,12} * 2

    Anda juga dapat membagi dengan (/), tambahkan dengan (+), dan mengurangi dengan (-).

  • Memangkatkan item dalam satu array

    Masukkan = urutan (1,12) ^ 2, atau = {1,2,3,4; 5,6,7,8; 9,10,11,12} ^ 2

  • Menemukan akar kuadrat dari kuadrat item dalam satu array

    Masukkan =SQRT(SEQUENCE(1,12)^2), atau =SQRT({1,2,3,4;5,6,7,8;9,10,11,12}^2)

  • Mengubah urutan baris satu dimensi

    Masukkan =TRANSPOSE(SEQUENCE(1,5)), atau =TRANSPOSE({1,2,3,4,5})

    Meskipun Anda memasukkan konstanta array horizontal, fungsi TRANSPOSE akan mengonversi konstanta array tersebut menjadi kolom.

  • Mengubah urutan kolom satu dimensi

    Masukkan =TRANSPOSE(SEQUENCE(5,1)), atau = TRANSPOSE ({1; 2; 3; 4; 5})

    Meskipun Anda memasukkan konstanta array vertikal, fungsi TRANSPOSE akan mengonversi konstanta array tersebut menjadi baris.

  • Mengubah urutan konstanta dua dimensi

    Masukkan =TRANSPOSE(SEQUENCE(3,4)), atau = TRANSPOSE ({1,2,3,4; 5,6,7,8; 9,10,11,12})

    Fungsi TRANSPOSE mengonversi setiap baris menjadi serangkaian kolom.

Bagian ini menyediakan contoh rumus array dasar.

  • Membuat array dari nilai yang ada

    Contoh berikut ini menjelaskan cara menggunakan rumus array untuk membuat array baru dari array yang sudah ada.

    Masukkan =SEQUENCE(3,6,10,10), atau = {10,20,30,40,50,60; 70,80,90,100,110,120; 130,140,150,160,170,180}

    Pastikan mengetikkan {(kurung kurawal buka) sebelum Anda mengetikkan 10, dan} (kurung kurawal tutup) setelah Anda mengetikkan 180, karena Anda sedang membuat array angka.

    Berikutnya, masukkan = D9 #, atau = D9:I11 di sel kosong. Array sel 3 x 6 muncul dengan nilai yang sama yang Anda lihat di D9:D11. Tanda # disebut tumpah operator rentang, dan cara Excel dari referensi rentang seluruh array daripada mengetik keluar.

    Menggunakan operator rentang luapan (#) untuk referensi array yang sudah ada

  • Membuat konstanta array dari nilai yang ada

    Anda dapat mengambil hasil rumus luapan larik dan mengonversi yang menjadi komponen-komponen. Pilih sel D9, lalu tekan F2 untuk beralih ke edit mode. Berikutnya, tekan F9 untuk mengonversi referensi sel untuk nilai, yang Excel lalu akan mengonversi konstanta array. Saat Anda menekan Enter, rumus, = D9 #, sekarang akan = {10,20,30; 40,50,60; 70,80,90}.

  • Menghitung karakter dalam satu rentang sel

    Contoh berikut menunjukkan cara menghitung jumlah karakter dalam satu rentang sel. Ini termasuk spasi.

    Menghitung jumlah total karakter di rentang, dan array lainnya untuk bekerja dengan string teks

    = MENJUMLAHKAN (LEN(C9:C13))

    Dalam kasus ini, fungsi LEN mengembalikan panjang setiap string teks di setiap sel dalam rentang. Fungsi SUM menjumlahkan nilai tersebut bersamaan lalu Menampilkan hasil (66). Jika Anda ingin mendapatkan rata-rata jumlah karakter, Anda bisa menggunakan:

    = RATA-RATA (LEN(C9:C13))

  • Konten sel terpanjang dalam rentang C9:C13

    =INDEX(C9:C13,MATCH(MAX(LEN(C9:C13)),LEN(C9:C13),0),1)

    Rumus ini hanya bekerja apabila rentang data hanya berisi satu kolom sel.

    Mari kita periksa lebih dekat rumus ini, mulai dari elemen dalam dan ke arah luar. Fungsi LEN mengembalikan panjang setiap item di rentang sel D2:D6. Fungsi MAX menghitung nilai terbesar di antara item tersebut, yang terkait dengan string teks terpanjang, yang berada di sel D3.

    Di sini akan mulai terlihat sedikit kompleks. Fungsi MATCH menghitung offset (posisi relatif) dari sel yang berisi string teks terpanjang. Untuk melakukannya, diperlukan tiga argumen: nilai pencarian, array pencarian, dan tipe yang cocok. Fungsi MATCH mencari array pencarian untuk nilai pencarian yang ditetapkan. Dalam kasus ini, nilai pencarian adalah string teks terpanjang:

    MAX(LEN(C9:C13)

    dan bahwa string itu terdapat dalam array ini:

    LEN(C9:C13)

    Cocok dengan tipe argumen dalam kasus ini adalah 0. Jenis pencocokan dapat 0, nilai-1 atau 1.

    • 1 - mengembalikan nilai terbesar yang kurang dari atau sama dengan pencarian val

    • 0 - mengembalikan nilai pertama sama persis sama dengan nilai pencarian

    • -1 - mengembalikan nilai terkecil yang lebih besar dari atau sama dengan nilai pencarian yang ditentukan

    • Jika Anda menghilangkan tipe yang cocok, Excel mengasumsikan 1.

    Akhirnya, fungsi INDEX mengambil argumen ini: array, dan angka di baris dan kolom dalam array tersebut. Rentang sel C9:C13 menyediakan array, fungsi MATCH menyediakan alamat sel, dan argumen final (1) menentukan bahwa nilai berasal dari kolom pertama dalam array.

    Jika Anda ingin mendapatkan konten terkecil string teks, Anda akan mengganti MAX dalam contoh di atas dengan MIN.

  • Menemukan nilai terkecil n dalam satu rentang

    Contoh ini memperlihatkan cara menemukan tiga nilai terkecil di rentang sel, tempat beberapa contoh data dalam sel B9:B18has telah dibuat dengan: = INT (RANDARRAY(10,1) * 100). Perhatikan bahwa RANDARRAY fungsi tidak tetap and, sehingga Anda akan mendapatkan sekumpulan baru angka acak setiap kali Excel menghitung.

    Excel rumus array untuk menemukan nilai terkecil ke-n: =SMALL(B9#,SEQUENCE(D9))

    Masukkan =SMALL(B9#,SEQUENCE(D9), = kecil (B9:B18, {1; 2; 3})

    Rumus ini menggunakan konstanta array untuk mengevaluasi fungsi SMALL tiga kali dan kembali anggota 3 terkecil dalam array yang ada dalam sel B9:B18, tempat 3 adalah nilai variabel di sel D9. Untuk menemukan lebih banyak nilai, Anda bisa meningkatkan nilai dalam fungsi SEQUENCE, atau menambahkan lebih banyak argumen ke konstanta. Anda juga dapat menggunakan fungsi tambahan dengan rumus ini, seperti SUM atau AVERAGE. Misalnya:

    =SUM(SMALL(B9#,SEQUENCE(D9))

    =AVERAGE(SMALL(B9#,SEQUENCE(D9))

  • Menemukan nilai terbesar n dalam satu rentang

    Untuk menemukan nilai terbesar dalam rentang, Anda bisa mengganti fungsi SMALL dengan fungsi LARGE. Selain itu, contoh berikut ini menggunakan fungsi ROW dan INDIRECT.

    Masukkan = besar (B9 #, baris (INDIRECT ("1:3"))), atau = besar (B9:B18,ROW(INDIRECT("1:3")))

    Pada titik ini, mungkin membantu untuk mengetahui sedikit tentang fungsi ROW dan INDIRECT. Anda bisa menggunakan fungsi ROW untuk membuat array bilangan bulat berurutan. Sebagai contoh, pilih kosong dan masukkan:

    =ROW(1:10)

    Rumus ini membuat kolom 10 bilangan bulat berurutan. Untuk melihat kemungkinan masalah, sisipkan satu baris di atas rentang yang memuat rumus array (yaitu, di atas baris 1). Excel menyesuaikan referensi baris, dan rumus sekarang akan menghasilkan bilangan bulat dari 2 ke 11. Untuk mengatasinya, tambahkan fungsi INDIRECT pada rumus:

    =ROW(INDIRECT("1:10"))

    Fungsi INDIRECT menggunakan string teks sebagai argumen (yang merupakan mengapa rentang 1:10 dikelilingi oleh tanda kutip). Excel tidak menyesuaikan nilai teks apabila Anda menyisipkan baris atau memindahkan rumus array. Hasilnya, fungsi ROW akan selalu mengembalikan array bilangan bulat yang Anda inginkan. Anda bisa dengan mudah menggunakan urutan:

    =SEQUENCE(10)

    Mari kita lihat rumus yang digunakan lebih lama — = besar (B9 #, baris (INDIRECT ("1:3"))) — dimulai dari tanda kurung gabungan dan bekerja oleh: fungsi INDIRECT mengembalikan sekumpulan nilai teks, dalam hal ini nilai 1 sampai 3. Fungsi ROW secara bergiliran menghasilkan array sel tiga kolom. Fungsi LARGE menggunakan nilai dalam rentang sel B9:B18, dan dievaluasi tiga kali, satu kali untuk setiap referensi yang dikembalikan oleh fungsi ROW. Jika ingin mencari nilai lainnya, Anda dapat menambahkan rentang sel yang lebih besar ke fungsi INDIRECT. Akhirnya, dengan contoh kecil, Anda dapat menggunakan rumus ini dengan fungsi lain, seperti SUM dan AVERAGE.

  • Menjumlahkan rentang yang berisi nilai kesalahan

    Fungsi SUM dalam Excel tidak berfungsi ketika Anda mencoba untuk menjumlahkan rentang yang berisi nilai kesalahan, seperti #VALUE! atau #N/A. Contoh ini memperlihatkan kepada Anda cara menjumlahkan nilai dalam rentang yang bernama Data yang berisi kesalahan:

    Gunakan array untuk menangani kesalahan. Misalnya, =SUM(IF(ISERROR(Data),"",Data) akan menjumlahkan rentang yang bernama Data bahkan jika dokumen menyertakan kesalahan, seperti #VALUE! atau #NA!.

  • =SUM(IF(ISERROR(Data),"",Data))

    Rumus ini membuat array baru yang berisi nilai aslinya dikurangi setiap nilai kesalahan. Dimulai dari fungsi dalam ke arah luar, fungsi ISERROR mencari rentang sel (Data) untuk kesalahan. Fungsi IF mengembalikan nilai tertentu jika kondisi yang Anda tetapkan dievaluasi TRUE dan nilai lain jika dievaluasi FALSE. Dalam kasus ini, fungsi akan mengembalikan string kosong ("") untuk semua nilai kesalahan karena dievaluasi ke TRUE, dan mengembalikan nilai yang tersisa dari rentang (Data) karena dievaluasi ke FALSE, yang berarti tidak berisi nilai kesalahan. Fungsi SUM kemudian menghitung jumlah total untuk array yang difilter.

  • Menghitung jumlah nilai kesalahan dalam satu rentang

    Contoh ini adalah seperti rumus sebelumnya, tetapi mengembalikan jumlah nilai kesalahan dalam rentang yang bernama Data sebagai ganti memfilternya:

    =SUM(IF(ISERROR(Data),1,0))

    Rumus ini membuat array yang berisi nilai 1 untuk sel yang berisi kesalahan dan nilai 0 untuk sel yang tidak berisi kesalahan. Anda dapat menyederhanakan rumus dan mendapatkan hasil yang sama dengan menghapus argumen ketiga untuk fungsi IF, seperti ini:

    =SUM(IF(ISERROR(Data),1))

    Jika Anda tidak menetapkan argumen, fungsi IF mengembalikan FALSE jika sel tidak berisi nilai kesalahan. Anda dapat menyederhanakan lagi rumus tersebut:

    =SUM(IF(ISERROR(Data)*1))

    Versi ini bekerja karena TRUE*1=1 dan FALSE*1=0.

Anda mungkin perlu menjumlahkan nilai berdasarkan kondisi.

Anda bisa menggunakan array untuk menghitung berdasarkan kondisi tertentu. =Sum(if(Sales>0,Sales)) akan menjumlahkan semua nilai lebih besar dari 0 dalam rentang bernama penjualan.

Misalnya, rumus array ini menjumlahkan positif bilangan bulat dalam rentang yang bernama penjualan, yang mewakili sel E9:E24 dalam contoh di atas:

=SUM(IF(Sales>0,Sales))

Fungsi IF membuat array nilai positif dan false. Fungsi SUM pada dasarnya mengabaikan nilai salah karena 0+0=0. Rentang sel yang Anda gunakan dalam rumus ini dapat terdiri dari jumlah baris dan kolom berapa pun.

Anda juga dapat menjumlahkan nilai yang memenuhi lebih dari satu kondisi. Misalnya, rumus array ini menghitung nilai lebih besar dari 0 dan kurang dari 2500:

=Sum((Sales>0)*(Sales<2500)*(Sales))

Perhatikan bahwa rumus ini mengembalikan kesalahan jika rentang berisi satu atau beberapa sel nonnumerik.

Anda juga dapat membuat rumus array yang menggunakan tipe atau kondisi OR. Misalnya, Anda bisa menjumlahkan nilai yang lebih besar dari 0 atau kurang dari 2500:

=Sum(if((Sales>0)+(Sales<2500),Sales))

Anda tidak dapat menggunakan fungsi AND dan OR langsung dalam rumus array karena fungsi itu memberi hasil tunggal, baik TRUE maupun FALSE, dan fungsi array memerlukan array hasil. Anda dapat mengatasinya dengan menggunakan logika yang ditampilkan dalam rumus sebelumnya. Dengan kata lain, Anda melakukan operasi matematika, seperti penambahan atau perkalian pada nilai yang memenuhi atau atau dan kondisi.

Contoh ini menunjukkan cara mengeluarkan nol dari rentang apabila Anda perlu menghitung nilai rata-rata dalam rentang tersebut. Rumus ini menggunakan rentang data bernama Sales:

=AVERAGE(IF(Sales<>0,Sales))

Fungsi IF membuat array nilai yang tidak sama dengan 0 lalu meneruskan nilai itu ke fungsi AVERAGE.

Rumus array ini membandingkan nilai dalam dua rentang sel bernama MyData dan YourData dan mengembalikan jumlah perbedaan antara keduanya. Jika konten kedua rentang itu identik, rumus ini akan mengembalikan 0. Untuk menggunakan rumus ini, rentang sel harus sama ukuran dan dimensi yang sama. Misalnya, jika MyData rentang 3 baris dengan 5 kolom, YourData juga harus 3 baris dengan 5 kolom:

=SUM(IF(MyData=YourData,0,1))

Rumus ini membuat array baru dengan ukuran yang sama sebagai rentang yang dibandingkan. Fungsi IF mengisi array dengan nilai 0 dan nilai 1 (0 bila tidak cocok dan 1 untuk sel yang identik). Fungsi SUM kemudian mengembalikan jumlah nilai dalam array tersebut.

Anda dapat menyederhanakan rumus seperti ini:

=Sum(1*(MyData<>YourData))

Seperti rumus yang menghitung nilai kesalahan dalam satu rentang, rumus ini bekerja karena TRUE*1=1, dan FALSE*1=0.

Rumus array ini mengembalikan nomor baris nilai maksimum dalam rentang kolom tunggal yang bernama Data:

=MIN(IF(Data=MAX(Data),ROW(Data),""))

Fungsi IF menciptakan array baru yang terkait dengan rentang yang bernama Data. Jika sel yang terkait berisi nilai maksimum dalam rentang, array akan berisi nomor baris. Jika tidak, array berisi string kosong (""). Fungsi MIN menggunakan array baru sebagai argumen kedua dan mengembalikan nilai terkecil, yang terkait dengan nomor baris dari nilai maksimum dalam Data. Jika rentang yang bernama Data berisi nilai maksimum yang identik, rumus akan mengembalikan baris nilai pertama.

Jika Anda ingin mengembalikan alamat sel sebenarnya dari nilai maksimum, gunakan rumus ini:

=ADDRESS(MIN(IF(Data=MAX(Data),ROW(Data),"")),COLUMN(Data))

Anda akan menemukan contoh sama seperti di contoh buku kerja pada perbedaan antara himpunan data lembar kerja.

Latihan ini menunjukkan cara menggunakan rumus array multisel dan sel tunggal untuk menghitung serangkaian angka penjualan. Rangkaian langkah pertama menggunakan rumus multisel untuk menghitung rangkaian subtotal. Rangkaian kedua menggunakan rumus sel tunggal untuk menghitung jumlah total.

  • Rumus array multisel

Salin seluruh tabel di bawah ini dan menempelkannya ke sel A1 di lembar kerja kosong.

Penjualan Orang

Mobil Tipe

Nomor Terjual

Unit Harga

Total Penjualan

Barnhill

Sedan

5

33000

Coupe

4

37000

Ingle

Sedan

6

24000

Coupe

8

21000

Jordan

Sedan

3

29000

Coupe

1

31000

Pica

Sedan

9

24000

Coupe

5

37000

Sanchez

Sedan

6

33000

Coupe

8

31000

Rumus (Jumlah Total)

Jumlah Total

'=SUM(C2:C11*D2:D11)

=SUM(C2:C11*D2:D11)

  1. Untuk melihat penjualan Total dari Coupe dan sedan untuk tiap tenaga penjualan, pilih sel E2: E11, masukkan rumus = C2: C11 * D2:D11, lalu tekan Ctrl + Shift + Enter.

  2. Untuk melihat jumlah Total semua penjualan, pilih sel F11, masukkan rumus =SUM(C2:C11*D2:D11), dan lalu tekan Ctrl + Shift + Enter.

Saat Anda menekan Ctrl + Shift + Enter, Excel mengelilingi rumus dengan kurung kurawal ({}) dan menyisipkan contoh rumus di tiap sel dari rentang yang dipilih. Hal ini terjadi sangat cepat, sehingga yang Anda lihat di kolom E adalah jumlah total penjualan untuk setiap jenis mobil untuk setiap tenaga penjualan. Jika Anda memilih E2, lalu E3, E4, dan seterusnya, Anda akan melihat bahwa rumus yang sama diperlihatkan: {=C2:C11*D2:D11}

Jumlah total di kolom E dihitung dengan rumus array

  • Membuat rumus array sel tunggal

Dalam sel D13 buku kerja, ketikkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

=SUM(C2:C11*D2:D11)

Dalam kasus ini, Excel mengalikan nilai dalam array (rentang sel C2 melalui D11) dan lalu menggunakan fungsi SUMuntuk menambahkan Total bersama-sama. Hasilnya adalah jumlah total penjualan $1.590.000,00. Contoh ini menunjukkan betapa canggihnya tipe rumus ini. Sebagai contoh, misalnya Anda memiliki 1.000 baris data. Anda dapat menjumlahkan sebagian atau semua data itu dengan membuat rumus array di sel tunggal sebagai ganti menyeret rumus menuruni 1.000 baris.

Juga, perhatikan bahwa rumus sel tunggal di sel D13 benar-benar terpisah dari rumus multisel (rumus di sel E2 hingga E11). Ini adalah keunggulan lain menggunakan rumus array — fleksibilitas. Anda bisa mengubah rumus di kolom E atau menghapus kolom yang sama sekali, tanpa mempengaruhi rumus dalam D13.

Rumus array juga menawarkan keunggulan berikut:

  • Konsistensi    Jika Anda mengklik salah satu sel dari E2 ke bawah, Anda melihat rumus yang sama. Konsistensi ini dapat membantu memastikan akurasi yang lebih tinggi.

  • Keselamatan    Anda tidak bisa menimpa komponen rumus array multi sel. Misalnya, klik sel E3 dan tekan Hapus. Anda harus memilih seluruh rentang sel (E2 sampai E11) dan mengubah rumus untuk seluruh array, atau membiarkan array seperti itu. Sebagai pengukuran keamanan ditambahkan, Anda harus menekan Ctrl + Shift + Enter untuk mengonfirmasi perubahan apa pun rumus.

  • Ukuran file lebih kecil    Anda bisa sering menggunakan rumus array tunggal daripada beberapa rumus menengah. Sebagai contoh, buku kerja ini menggunakan satu rumus array untuk menghitung hasil di kolom E. Jika menggunakan rumus standar (misalnya =C2*D2, C3*D3, C4*D4…), Anda akan harus menggunakan 11 rumus yang berbeda untuk mendapatkan hasil yang sama.

Secara umum, rumus array menggunakan sintaks rumus standar. Semuanya dimulai dengan tanda sama dengan (=), dan Anda dapat menggunakan sebagian besar fungsi bawaan Excel dalam rumus array Anda. Perbedaan utama adalah saat menggunakan rumus array, Anda menekan Ctrl + Shift + Enter untuk memasukkan rumus Anda. Apabila Anda melakukannya, Excel akan menutup rumus array Anda dengan kurung kurawal — jika Anda mengetikkan kurung kurawal secara manual, rumus Anda akan dikonversi menjadi string teks, dan tidak akan bekerja.

Fungsi array dapat berupa cara yang efisien untuk menyusun rumus yang kompleks. Rumus array =SUM(C2:C11*D2:D11) sama dengan: =SUM(C2*D2,C3*D3,C4*D4,C5*D5,C6*D6,C7*D7,C8*D8,C9*D9,C10*D10,C11*D11).

Penting: Tekan Ctrl + Shift + Enter setiap kali Anda perlu memasukkan rumus array. Hal ini berlaku untuk rumus sel tunggal dan multisel.

Setiap kali Anda bekerja dengan rumus multisel, perhatikan juga:

  • Pilih rentang sel untuk menampung hasil sebelum memasukkan rumus. Anda melakukannya apabila membuat rumus array multisel dengan memilih sel E2 sampai E11.

  • Anda tidak dapat mengubah isi setiap sel dalam satu rumus array. Untuk melakukannya, pilih sel E3 dalam buku kerja dan tekan Delete. Excel akan menampilkan pesan bahwa Anda tidak dapat mengubah sebagian array.

  • Anda dapat memindahkan atau menghapus seluruh rumus array, tetapi Anda tidak dapat memindahkan atau menghapus sebagian. Dengan kata lain, untuk menyusutkan rumus array, Anda harus menghapus rumus yang ada lalu memulai ulang.

  • Untuk menghapus rumus array, pilih seluruh rumus rentang (misalnya, E2: E11), lalu tekan Hapus.

  • Anda tidak bisa menyisipkan sel kosong, atau menghapus sel dari rumus array multisel.

Ada kalanya, Anda mungkin perlu memperluas rumus array. Pilih sel pertama dalam rentang larik yang sudah ada, lalu lanjutkan hingga Anda telah memilih seluruh rentang yang Anda inginkan untuk memperluas rumus agar. Tekan F2 untuk mengedit rumus, lalu tekan CTRL + SHIFT + ENTER untuk mengonfirmasi rumus setelah Anda telah disesuaikan rentang rumus. Tombol adalah pilih seluruh rentang, dimulai dengan sel kiri atas dalam array. Kiri atas sel yang diedit.

Rumus array memang hebat, tetapi ada kelemahannya:

  • Anda mungkin terkadang lupa untuk menekan Ctrl + Shift + Enter. Hal ini bisa terjadi bahkan pada pengguna Excel yang paling berpengalaman. Ingatlah untuk menekan kombinasi tombol ini setiap kali memasukkan atau mengedit rumus array.

  • Pengguna lain buku kerja Anda tidak mungkin dipahami rumus Anda. Dalam praktiknya, rumus array yang biasanya tidak dijelaskan dalam lembar kerja. Oleh karena itu, jika orang lain perlu mengubah buku kerja Anda, Anda harus baik menghindari rumus array atau memastikan bahwa orang tersebut mengetahui tentang rumus array apa pun dan memahami bagaimana cara mengubahnya, jika mereka perlu.

  • Tergantung kecepatan pemrosesan dan memori komputer Anda, rumus array yang besar dapat memperlambat perhitungan.

Konstanta array adalah komponen dari rumus array. Anda membuat konstanta array dengan memasukkan daftar item lalu menutup daftar itu secara manual dengan kurung kurawal ({ }), seperti ini:

={1,2,3,4,5}

Sekarang, Anda tahu Anda perlu tekan Ctrl + Shift + Enter ketika Anda membuat rumus array. Karena konstanta array adalah komponen dari rumus array, tutup konstanta dengan kurung kurawal dengan mengetikkannya secara manual. Anda lalu menggunakan Ctrl + Shift + Enter untuk memasukkan seluruh rumus.

Jika memisahkan item dengan koma, Anda membuat array horizontal (baris). Jika memisahkan item dengan titik koma, Anda membuat array vertikal (kolom). Untuk membuat array dua dimensi, batasi item di setiap baris dengan koma, dan batasi setiap baris dengan titik koma.

Berikut adalah larik dalam baris tunggal: {1,2,3,4}. Ini adalah array di satu kolom: {1,2,3,4}. Dan ini adalah array dua baris dan empat kolom: {1,2,3,4;5,6,7,8}. Dalam dua baris array, baris pertama adalah 1, 2, 3, dan 4, dan baris kedua adalah 5, 6, 7, dan 8. Satu titik koma memisahkan kedua baris, antara 4 dan 5.

Seperti halnya rumus array, Anda dapat menggunakan konstanta array dengan sebagian besar fungsi bawaan Excel. Bagian berikut menjelaskan cara membuat setiap konstanta dan cara menggunakannya dengan fungsi di Excel.

Prosedur berikut akan memberi Anda latihan membuat konstanta horizontal, vertikal, dan dua dimensi.

Membuat konstanta horizontal

  1. Di lembar kerja kosong, pilih sel A1 sampai E1.

  2. Di bilah rumus, masukkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    ={1,2,3,4,5}

    Dalam kasus ini, Anda harus mengetik kurawal pembuka dan penutup ({}), dan Excel akan menambahkan set untuk Anda.

    Hasil berikut akan ditampilkan.

    Konstanta larik horizontal dalam rumus

Membuat konstanta vertikal

  1. Dalam buku kerja Anda, pilih satu kolom lima sel.

  2. Di bilah rumus, masukkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    ={1;2;3;4;5}

    Hasil berikut akan ditampilkan.

    Konstanta array vertikal dalam rumus array

Membuat konstanta dua dimensi

  1. Dalam buku kerja Anda, pilih satu blok sel lebar tiga kolom kali tinggi tiga baris.

  2. Di bilah rumus, masukkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    ={1,2,3,4;5,6,7,8;9,10,11,12}

    Anda akan melihat hasil berikut:

    Konstanta larik dua dimensi dalam rumus array

Menggunakan konstanta dalam rumus

Ini adalah contoh sederhana yang menggunakan konstanta:

  1. Dalam buku kerja contoh, buat lembar kerja baru.

  2. Di sel A1, ketikkan 3, lalu ketikkan 4 di B1, 5 di C1, 6 di D1, dan 7 di E1.

  3. Di sel A3, ketikkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    =SUM(A1:E1*{1,2,3,4,5})

    Perhatikan bahwa Excel menutup konstanta dengan sepasang kurung kurawal, karena Anda memasukkannya sebagai rumus array.

    Rumus array dengan konstanta array

    Nilai 85 muncul di sel A3.

Bagian berikutnya menjelaskan cara kerja rumus.

Rumus yang baru saja Anda gunakan terdiri dari beberapa bagian.

Sintaks rumus array dengan konstanta array

1. Fungsi

2. Array tersimpan

3. Operator

4. Konstanta array

Elemen terakhir dalam tanda kurung adalah konstanta array: {1,2,3,4,5}. Ingatlah bahwa Excel tidak menutup konstanta array dengan kurung kurawal; Anda yang mengetikkannya. Juga ingat bahwa setelah Anda menambahkan konstanta ke rumus array, Anda menekan Ctrl + Shift + Enter untuk memasukkan rumus.

Karena Excel menjalankan operasi dalam tanda kurung terlebih dahulu, kedua elemen berikutnya adalah nilai yang tersimpan di buku kerja (A1:E1) dan operator. Pada titik ini, rumus mengalikan nilai dalam array yang tersimpan dengan nilai yang terkait dalam konstanta. Ini ekuivalen dengan:

=SUM(A1*1,B1*2,C1*3,D1*4,E1*5)

Terakhir, fungsi SUM menambahkan nilai-nilai, dan jumlah 85 ditampilkan di sel A3.

Untuk menghindari menggunakan array tersimpan dan menjaga operasi seluruhnya di memori, ganti array tersimpan dengan konstanta array yang lain:

=SUM({3,4,5,6,7}*{1,2,3,4,5})

Untuk mencoba ini, Salin fungsi, pilih sel kosong dalam buku kerja Anda, menempelkan rumus ke dalam bilah rumus, dan lalu tekan Ctrl + Shift + Enter. Anda akan melihat hasil yang sama seperti dalam latihan sebelumnya yang menggunakan rumus array:

=SUM(A1:E1*{1,2,3,4,5})

Konstanta array dapat berisi angka, teks, nilai logika (seperti TRUE dan FALSE), dan nilai kesalahan (seperti #N/A). Anda dapat menggunakan angka dalam format bilangan bulat, desimal, dan ilmiah. Jika menyertakan teks, Anda perlu menutup teks dengan tanda kutip (").

Konstanta array tidak boleh berisi array, rumus, atau fungsi tambahan. Dengan kata lain, konstanta array hanya boleh berisi teks atau angka yang dipisahkan dengan koma atau titik koma. Excel menampilkan pesan peringatan apabila Anda memasukkan rumus seperti {1,2,A1:D4} atau {1,2,SUM(Q2:Z8)}. Nilai numerik juga tidak boleh berisi tanda persen, tanda dolar, koma, atau kurung.

Salah satu cara terbaik untuk menggunakan konstanta array adalah nama mereka. Konstanta bernama lebih mudah digunakan, dan dapat menyembunyikan kerumitan rumus array Anda dari orang lain. Untuk memberi nama konstanta array dan menggunakannya dalam rumus, lakukan hal berikut:

  1. Pada tab Rumus, dalam grup Nama yang Ditentukan, klik Tentukan Nama.
    Kotak dialog Tetapkan nama muncul.

  2. Di kotak Nama, ketikkan Quarter1.

  3. Di kotak Merujuk ke, masukkan konstanta berikut (ingatlah untuk mengetikkan tanda kurung kurawal secara manual):

    ={"January","February","March"}

    Konten kotak dialog sekarang terlihat seperti ini:

    Kotak dialog Edit Nama dengan rumus

  4. Klik OK, lalu pilih satu baris tiga sel kosong.

  5. Ketikkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter.

    =Quarter1

    Hasil berikut akan ditampilkan.

    Array yang diberi nama yang dimasukkan sebagai rumus

Ketika Anda menggunakan konstanta bernama seperti rumus array, ingatlah untuk memasukkan tanda sama dengan. Jika tidak, Excel akan menafsirkan array itu sebagai string teks dan rumus Anda tidak akan bekerja seperti yang diharapkan. Terakhir, ingatlah bahwa Anda dapat menggunakan kombinasi teks dan angka.

Perhatikan masalah berikut apabila konstanta array Anda tidak bekerja:

  • Beberapa elemen mungkin tidak dipisahkan dengan karakter yang benar. Jika Anda menghilangkan koma atau titik koma, atau jika Anda menempatkan satu di tempat yang salah, konstanta array tersebut mungkin tidak dapat dibuat dengan benar, atau Anda mungkin melihat pesan peringatan.

  • Anda mungkin memilih rentang sel yang tidak cocok dengan jumlah elemen dalam konstanta Anda. Misalnya, jika Anda memilih satu kolom enam sel untuk digunakan dengan konstanta lima sel, nilai kesalahan #N/A akan ditampilkan di sel yang kosong. Sebaliknya, jika Anda memilih terlalu sedikit sel, Excel akan menghilangkan nilai yang tidak memiliki sel yang terkait.

Contoh berikut menggambarkan beberapa cara penempatan konstanta array untuk digunakan dalam rumus array. Beberapa contoh gunakan fungsi TRANSPOSE untuk mengonversi baris ke kolom dan sebaliknya.

Mengalikan setiap item dalam satu array

  1. Buat lembar kerja baru, lalu pilih satu blok sel kosong lebar empat kolom kali tinggi tiga baris.

  2. Ketikkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    ={1,2,3,4;5,6,7,8;9,10,11,12}*2

Memangkatkan item dalam satu array

  1. Pilih satu blok sel kosong lebar empat kolom kali tinggi tiga baris.

  2. Ketikkan rumus array berikut, dan lalu tekan Ctrl + Shift + Enter:

    ={1,2,3,4;5,6,7,8;9,10,11,12}*{1,2,3,4;5,6,7,8;9,10,11,12}

    Atau alternatifnya, masukkan rumus array ini, yang menggunakan operator caret (^):

    ={1,2,3,4;5,6,7,8;9,10,11,12}^2

Mengubah urutan baris satu dimensi

  1. Pilih satu kolom lima sel kosong.

  2. Ketikkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    =TRANSPOSE({1,2,3,4,5})

    Meskipun Anda memasukkan konstanta array horizontal, fungsi TRANSPOSE akan mengonversi konstanta array tersebut menjadi kolom.

Mengubah urutan kolom satu dimensi

  1. Pilih satu kolom lima sel kosong.

  2. Masukkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    =TRANSPOSE({1;2;3;4;5})

Meskipun Anda memasukkan konstanta array vertikal, fungsi TRANSPOSE akan mengonversi konstanta array tersebut menjadi baris.

Mengubah urutan konstanta dua dimensi

  1. Pilih satu blok sel lebar tiga kolom kali tinggi empat baris.

  2. Masukkan konstanta berikut, dan lalu tekan Ctrl + Shift + Enter:

    =TRANSPOSE({1,2,3,4;5,6,7,8;9,10,11,12})

    Fungsi TRANSPOSE mengonversi setiap baris menjadi serangkaian kolom.

Bagian ini menyediakan contoh rumus array dasar.

Membuat array dan konstanta array dari nilai yang ada

Contoh berikut ini menjelaskan cara menggunakan rumus array untuk membuat link antar rentang sel di lembar kerja yang berbeda. Contoh ini juga menunjukkan cara membuat konstanta array dari rangkaian nilai yang sama.

Membuat array dari nilai yang ada

  1. Di lembar kerja di Excel, pilih sel C8:E10, dan masukkan rumus ini:

    ={10,20,30;40,50,60;70,80,90}

    Pastikan mengetikkan { (kurung kurawal buka) sebelum Anda mengetikkan 10, dan } (kurung kurawal tutup) setelah Anda mengetikkan 90, karena Anda sedang membuat array angka.

  2. Tekan Ctrl + Shift + Enter, yang memasukkan ini larik angka dalam rentang sel C8: E10 dengan menggunakan rumus array. Di lembar kerja Anda, C8 hingga E10 akan terlihat seperti ini:

    10

    20

    30

    40

    50

    60

    70

    80

    90

  3. Pilih rentang sel C1 hingga E3.

  4. Masukkan rumus berikut di bilah rumus, dan lalu tekan Ctrl + Shift + Enter:

    =C8:E10

    Array sel 3 x 3 muncul di sel C1 hingga E3 dengan nilai yang sama yang Anda lihat di C8 hingga E10.

Membuat konstanta array dari nilai yang ada

  1. Dengan sel C1:C3 dipilih, tekan F2 untuk beralih ke edit mode. 

  2. Tekan F9 untuk mengonversi referensi sel ke nilai. Excel mengonversi nilai tersebut menjadi satu konstanta array. Rumus sekarang akan = {10,20,30; 40,50,60; 70,80,90}.

  3. Tekan Ctrl + Shift + Enter untuk memasukkan konstanta array tersebut sebagai rumus array.

Menghitung karakter dalam satu rentang sel

Contoh berikut ini menunjukkan cara menghitung jumlah karakter, termasuk spasi, dalam satu rentang sel.

  1. Salin seluruh tabel ini dan tempelkan ke lembar kerja di sel A1.

    Data

    This is a

    bunch of cells that

    come together

    to form a

    single sentence.

    Karakter total di A2:A6

    =SUM(LEN(A2:A6))

    Konten sel terpanjang (A3)

    =INDEX(A2:A6,MATCH(MAX(LEN(A2:A6)),LEN(A2:A6),0),1)

  2. Pilih sel A8, dan lalu tekan Ctrl + Shift + Enter untuk melihat jumlah total karakter dalam sel A2: A6 (66).

  3. Pilih sel A10, dan lalu tekan Ctrl + Shift + Enter untuk melihat konten terpanjang dari sel A2: A6 (sel A3).

Rumus berikut digunakan dalam sel A8 menghitung jumlah total karakter (66) dalam sel A2 hingga A6.

=SUM(LEN(A2:A6))

Dalam kasus ini, fungsi LEN mengembalikan panjang setiap string teks di setiap sel dalam rentang tersebut. Fungsi SUM menjumlahkan nilai tersebut bersamaan lalu Menampilkan hasil (66).

Menemukan nilai terkecil n dalam satu rentang

Contoh ini menunjukkan cara menemukan tiga nilai terkecil dalam satu rentang sel.

  1. Masukkan beberapa angka acak dalam sel A1:A11.

  2. Pilih sel C1 hingga C3. Kumpulan sel ini akan menampung hasil yang dikembalikan oleh rumus array.

  3. Masukkan rumus berikut, dan lalu tekan Ctrl + Shift + Enter:

    = SMALL(A1:A11,{1;2;3})

Rumus ini menggunakan konstanta array untuk mengevaluasi fungsi SMALL tiga kali dan kembali terkecil (1), kedua terkecil (2), dan ketiga terkecil (3) anggota di array yang dimuat dalam sel A1:A10 untuk menemukan lebih banyak nilai, Anda menambahkan lebih banyak argumen untuk konstanta. Anda juga dapat menggunakan fungsi tambahan dengan rumus ini, seperti SUM atau AVERAGE. Misalnya:

= SUM (KECIL (A1:A10, {1,2,3})

= AVERAGE (KECIL (A1:A10, {1,2,3})

Menemukan nilai terbesar n dalam satu rentang

Untuk mencari nilai terbesar dalam satu rentang, Anda dapat mengganti fungsi SMALL dengan fungsi LARGE. Selain itu, contoh berikut ini menggunakan fungsi ROW dan INDIRECT.

  1. Pilih sel D1 sampai D3.

  2. Di bilah rumus, masukkan rumus ini, dan lalu tekan Ctrl + Shift + Enter:

    = LARGE(A1:A10,ROW(INDIRECT("1:3")))

Pada titik ini, mungkin membantu untuk mengetahui sedikit tentang fungsi ROW dan INDIRECT. Anda bisa menggunakan fungsi ROW untuk membuat array bilangan bulat berurutan. Sebagai contoh, pilih kolom kosong 10 sel dalam buku kerja latihan Anda, masukkan rumus array ini, dan lalu tekan Ctrl + Shift + Enter:

=ROW(1:10)

Rumus ini membuat kolom 10 bilangan bulat berurutan. Untuk melihat kemungkinan masalah, sisipkan satu baris di atas rentang yang memuat rumus array (yaitu, di atas baris 1). Excel menyesuaikan referensi baris, dan rumus mengembalikan bilangan bulat dari 2 sampai 11. Untuk mengatasinya, tambahkan fungsi INDIRECT pada rumus:

=ROW(INDIRECT("1:10"))

Fungsi INDIRECT menggunakan string teks sebagai argumennya (itulah sebabnya rentang 1:10 ditutup dengan tanda kutip ganda). Excel tidak menyesuaikan nilai teks apabila Anda menyisipkan baris atau memindahkan rumus array. Hasilnya, fungsi ROW akan selalu mengembalikan array bilangan bulat yang Anda inginkan.

Mari kita lihat rumus yang digunakan lebih lama — = besar (A5:A14,ROW(INDIRECT("1:3"))) — dimulai dari tanda kurung gabungan dan bekerja oleh: fungsi INDIRECT mengembalikan sekumpulan nilai teks, dalam hal ini nilai 1 sampai 3. Fungsi ROW kemudian mengembalikan array kolom tiga sel. Fungsi LARGE menggunakan nilai dalam rentang sel A5:A14, dan dievaluasi tiga kali, sekali untuk setiap referensi yang dikembalikan oleh fungsi ROW. Nilai 3200, 2700, dan 2000 dikembalikan ke array kolom tiga sel. Jika ingin mencari nilai lainnya, Anda dapat menambahkan rentang sel yang lebih besar ke fungsi INDIRECT.

Sebagai dengan contoh yang lebih lama, Anda dapat menggunakan rumus ini dengan fungsi lain, seperti SUM dan rata-rata.

Menemukan string teks terpanjang dalam satu rentang sel

Masuk kembali ke contoh string teks yang lebih lama, masukkan rumus berikut di sel kosong, tekan Ctrl + Shift + Enter:

=INDEX(A2:A6,MATCH(MAX(LEN(A2:A6)),LEN(A2:A6),0),1)

Teks "bunch of cells that" akan muncul.

Mari kita periksa lebih dekat rumus ini, mulai dari elemen dalam dan ke arah luar. Fungsi LEN mengembalikan panjang setiap item di rentang sel A2: A6. Fungsi MAX menghitung nilai terbesar di antara item tersebut, yang terkait dengan string teks terpanjang, yang berada di sel A3.

Di sini akan mulai terlihat sedikit kompleks. Fungsi MATCH menghitung offset (posisi relatif) sel yang berisi string teks terpanjang. Untuk melakukannya, diperlukan tiga argumen: nilai pencarian, array pencarian, dan tipe yang cocok. Fungsi MATCH mencari array pencarian untuk nilai pencarian yang ditetapkan. Dalam kasus ini, nilai pencarian adalah string teks terpanjang:

(MAX (LEN(A2:A6))

dan bahwa string itu terdapat dalam array ini:

LEN(A2:A6)

Argumen tipe yang cocok adalah 0. Tipe yang cocok dapat berupa nilai 1, 0, atau -1. Jika Anda menetapkan 1, MATCH mengembalikan nilai terbesar yang kurang dari atau sama dengan nilai pencarian. Jika Anda menetapkan 0, MATCH mengembalikan nilai pertama yang tepat sama dengan nilai pencarian. Jika Anda menetapkan -1, MATCH menemukan nilai terkecil yang lebih besar dari atau sama dengan nilai pencarian yang ditetapkan. Jika Anda menghilangkan tipe yang cocok, Excel mengasumsikan 1.

Terakhir, fungsi INDEX memperhitungkan argumen ini: array, serta nomor baris dan kolom dalam array tersebut. Rentang sel A2: A6 menyediakan array, fungsi MATCH menyediakan alamat sel, dan argumen final (1) menentukan bahwa nilai berasal dari kolom pertama dalam array.

Bagian ini menyediakan contoh rumus array tingkat lanjut.

Menjumlahkan rentang yang berisi nilai kesalahan

Fungsi SUM di Excel tidak bekerja apabila Anda mencoba menjumlahkan rentang yang berisi nilai kesalahan, misalnya #N/A. Contoh ini menunjukkan cara menjumlahkan nilai dalam rentang bernama Data yang berisi kesalahan.

=SUM(IF(ISERROR(Data),"",Data))

Rumus ini membuat array baru yang berisi nilai aslinya dikurangi setiap nilai kesalahan. Dimulai dari fungsi dalam ke arah luar, fungsi ISERROR mencari rentang sel (Data) untuk kesalahan. Fungsi IF mengembalikan nilai tertentu jika kondisi yang Anda tetapkan dievaluasi TRUE dan nilai lain jika dievaluasi FALSE. Dalam kasus ini, fungsi akan mengembalikan string kosong ("") untuk semua nilai kesalahan karena dievaluasi ke TRUE, dan mengembalikan nilai yang tersisa dari rentang (Data) karena dievaluasi ke FALSE, yang berarti tidak berisi nilai kesalahan. Fungsi SUM kemudian menghitung jumlah total untuk array yang difilter.

Menghitung jumlah nilai kesalahan dalam satu rentang

Contoh ini serupa dengan rumus sebelumnya, tetapi mengembalikan jumlah nilai kesalahan dalam rentang yang bernama Data sebagai ganti memfilternya:

=SUM(IF(ISERROR(Data),1,0))

Rumus ini membuat array yang berisi nilai 1 untuk sel yang berisi kesalahan dan nilai 0 untuk sel yang tidak berisi kesalahan. Anda dapat menyederhanakan rumus dan mendapatkan hasil yang sama dengan menghapus argumen ketiga untuk fungsi IF, seperti ini:

=SUM(IF(ISERROR(Data),1))

Jika Anda tidak menetapkan argumen, fungsi IF mengembalikan FALSE jika sel tidak berisi nilai kesalahan. Anda dapat menyederhanakan lagi rumus tersebut:

=SUM(IF(ISERROR(Data)*1))

Versi ini bekerja karena TRUE*1=1 dan FALSE*1=0.

Menjumlahkan nilai berdasarkan kondisi

Anda mungkin perlu menjumlahkan nilai berdasarkan kondisi. Sebagai contoh, rumus array ini menjumlahkan hanya bilangan bulat positif dalam rentang yang bernama Sales:

=SUM(IF(Sales>0,Sales))

Fungsi IF membuat array nilai positif dan nilai salah. Fungsi SUM pada dasarnya mengabaikan nilai salah karena 0+0=0. Rentang sel yang Anda gunakan dalam rumus ini dapat terdiri dari jumlah baris dan kolom berapa pun.

Anda juga dapat menjumlahkan nilai yang memenuhi lebih dari satu kondisi. Misalnya, rumus array ini menghitung nilai yang lebih besar dari 0 dan kurang dari atau sama dengan 5:

=SUM((Sales>0)*(Sales<=5)*(Sales))

Perhatikan bahwa rumus ini mengembalikan kesalahan jika rentang berisi satu atau beberapa sel nonnumerik.

Anda juga dapat membuat rumus array yang menggunakan tipe atau kondisi OR. Misalnya, Anda dapat menjumlahkan nilai yang kurang dari 5 dan lebih besar dari 15:

=SUM(IF((Sales<5)+(Sales>15),Sales))

Fungsi IF menemukan semua nilai yang lebih kecil dari 5 dan lebih besar dari 15 lalu meneruskan nilai itu ke fungsi SUM.

Anda tidak dapat menggunakan fungsi AND dan OR langsung dalam rumus array karena fungsi itu memberi hasil tunggal, baik TRUE maupun FALSE, dan fungsi array memerlukan array hasil. Anda dapat mengatasinya dengan menggunakan logika yang ditampilkan dalam rumus sebelumnya. Dengan kata lain, Anda menjalankan operasi matematika, seperti penambahan atau perkalian, pada nilai yang memenuhi kondisi OR dan AND.

Menghitung rata-rata tanpa nol

Contoh ini menunjukkan cara mengeluarkan nol dari rentang apabila Anda perlu menghitung nilai rata-rata dalam rentang tersebut. Rumus ini menggunakan rentang data bernama Sales:

=AVERAGE(IF(Sales<>0,Sales))

Fungsi IF membuat array nilai yang tidak sama dengan 0 lalu meneruskan nilai itu ke fungsi AVERAGE.

Menghitung jumlah selisih antara dua rentang sel

Rumus array ini membandingkan nilai dalam dua rentang sel bernama MyData dan YourData dan mengembalikan jumlah perbedaan antara keduanya. Jika konten kedua rentang itu identik, rumus ini akan mengembalikan 0. Untuk menggunakan rumus ini, rentang sel harus berukuran sama dengan dimensi yang sama (misalnya, jika MyData adalah rentang 3 baris kali 5 kolom, YourData juga harus 3 baris kali 5 kolom):

=SUM(IF(MyData=YourData,0,1))

Rumus ini membuat array baru dengan ukuran yang sama sebagai rentang yang dibandingkan. Fungsi IF mengisi array dengan nilai 0 dan nilai 1 (0 bila tidak cocok dan 1 untuk sel yang identik). Fungsi SUM kemudian mengembalikan jumlah nilai dalam array tersebut.

Anda dapat menyederhanakan rumus seperti ini:

=Sum(1*(MyData<>YourData))

Seperti rumus yang menghitung nilai kesalahan dalam satu rentang, rumus ini bekerja karena TRUE*1=1, dan FALSE*1=0.

Menemukan lokasi nilai maksimum dalam satu rentang

Rumus array ini mengembalikan nomor baris nilai maksimum dalam rentang kolom tunggal yang bernama Data:

=MIN(IF(Data=MAX(Data),ROW(Data),""))

Fungsi IF menciptakan array baru yang terkait dengan rentang yang bernama Data. Jika sel yang terkait berisi nilai maksimum dalam rentang, array akan berisi nomor baris. Jika tidak, array berisi string kosong (""). Fungsi MIN menggunakan array baru sebagai argumen kedua dan mengembalikan nilai terkecil, yang terkait dengan nomor baris dari nilai maksimum dalam Data. Jika rentang yang bernama Data berisi nilai maksimum yang identik, rumus akan mengembalikan baris nilai pertama.

Jika Anda ingin mengembalikan alamat sel sebenarnya dari nilai maksimum, gunakan rumus ini:

=ADDRESS(MIN(IF(Data=MAX(Data),ROW(Data),"")),COLUMN(Data))

Pemberitahuan pada

Bagian dari artikel ini berdasarkan seri kolom Excel Power pengguna ditulis oleh Colin Wilcox, dan disesuaikan dari bab 14 dan 15 rumus 2002 Excel, buku yang ditulis John Walkenbach, MVP Excel mantan.

Perlu bantuan lainnya?

Anda selalu dapat bertanya kepada pakar di Komunitas Teknologi Excel, mendapatkan dukungan di Komunitas Jawaban, atau menyarankan fitur maupun fitur baru di Suara Pengguna Excel.

Lihat Juga

Larik dinamis dan perilaku luapan larik

Rumus array dinamis vs warisan CSE rumus array

Fungsi FILTER

Fungsi RANDARRAY

Fungsi SEQUENCE

Fungsi SINGLE

Fungsi SORT

Fungsi SORTBY

Fungsi UNIQUE

Kesalahan #LUAPAN! di Excel

Gambaran umum rumus

Kembangkan keterampilan Office Anda
Jelajahi pelatihan
Dapatkan fitur baru terlebih dahulu
Gabung ke Office Insiders

Apakah informasi ini bermanfaat?

Terima kasih atas umpan balik Anda!

Terima kasih atas umpan balik Anda! Sepertinya menghubungkan Anda ke salah satu agen dukungan Office kami akan sangat membantu.

×