Menggunakan IF dengan fungsi AND, OR dan NOT

Fungsi IF memungkinkan Anda membuat perbandingan logika antara nilai dan apa yang diharapkan dengan menguji kondisi dan mengembalikan hasil jika kondisi tersebut True atau False.

  • =IF(Sesuatu adalah Benar, lakukanlah sesuatu, jika tidak lakukanlah hal lain)

Namun bagaimana jika Anda perlu untuk menguji beberapa kondisi, ketika anggaplah semua kondisi harus True atau False (AND), atau hanya satu kondisi harus True atau False (OR), atau jika ingin memeriksa jika suatu kondisi NOT (tidak) memenuhi kriteria Anda? Ketiga fungsi dapat digunakan sendiri-sendiri, tetapi rumus-rumus tersebut lebih umum dipasangkan dengan fungsi IF.

Gunakan fungsi IF dengan AND, OR dan NOT untuk menjalankan beberapa evaluasi jika kondisi adalah True atau False.

Sintaks

  • IF(AND()) - IF(AND(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(OR()) - IF(OR(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(NOT()) - IF(NOT(logical1), value_if_true, [value_if_false]))

Nama argumen

Deskripsi

logical_test (diperlukan)

Kondisi yang ingin Anda uji.

value_if_true (diperlukan)

Nilai yang ingin Anda kembalikan jika hasil logical_test adalah TRUE.

value_if_false (opsional)

Nilai yang ingin Anda kembalikan jika hasil logical_test adalah FALSE.

Berikut gambaran umum tentang cara menyusun fungsi AND, OR dan NOT secara individu. Ketika Anda menggabungkan masing-masing rumus dengan pernyataan IF, rumus dibaca seperti ini:

  • AND – =IF(AND(Sesuatu adalah True, Sesuatu yang lain adalah True), Nilai jika True, Nilai jika False)

  • OR – =IF(OR(Sesuatu adalah True, Sesuatu yang lain adalah True), Nilai jika True, Nilai jika False)

  • NOT – =IF(NOT(Sesuatu adalah True), Nilai jika True, Nilai jika False)

Contoh

Berikut contoh beberapa pernyataan IF(AND()), IF(OR()) dan IF(NOT()) bertumpuk yang umum. Fungsi AND dan OR dapat mendukung hingga 255 kondisi individu, tetapi hal ini bukan merupakan praktik yang baik untuk menggunakan lebih dari beberapa karena menjadi kompleks, rumus bertumpuk akan sangat sulit dibuat, diujikan dan dipertahankan. Fungsi NOT hanya mengambil satu kondisi.

Contoh penggunaan IF dengan AND, OR dan NOT untuk mengevaluasi nilai numerik dan teks

Berikut rumus yang dieja sesuai dengan logikanya:

Rumus

Deskripsi

=IF(AND(A2>0,B2<100),TRUE, FALSE)

IF A2 (25) lebih besar dari 0, AND (dan) B2 (75) lebih kecil dari 100, lalu mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam ha ini, kedua kondisi adalah benar, sehingga TRUE dikembalikan.

=IF(AND(A3="Red",B3="Green"),TRUE,FALSE)

Jika A3 (“Biru”) = “Merah”, AND (dan) B3 (“Hijau”) sama dengan “Hijau” lalu mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam hal ini hanya kondisi pertama yang benar, maka FALSE dikembalikan.

=IF(OR(A4>0,B4<50),TRUE, FALSE)

IF A4 (25) lebih besar dari 0, OR (atau) B4 (75) lebih kecil dari 50, lalu mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam hal ini, hanya kondisi pertama yang TRUE, namun karena OR hanya memerlukan satu argumen yang benar, rumus mengembalikan TRUE.

=IF(OR(A5="Red",B5="Green"),TRUE,FALSE)

IF A5 (“Biru”) sama dengan “Merah”, OR (atau) B5 (“Hijau”) sama dengan “Hijau” lalu mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam hal ini, argumen kedua adalah True, sehingga rumus mengembalikan TRUE.

=IF(NOT(A6>50),TRUE,FALSE)

IF A6 (25) NOT (tidak) lebih besar dari 50, lalu mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam hal ini, 25 tidak lebih besar dari 50, sehingga rumus mengembalikan TRUE.

=IF(NOT(A7="Red"),TRUE,FALSE)

IF A7 (“Biru”) NOT (tidak) sama dengan “Merah”, lalu mengembalikan TRUE, jika tidak mengembalikan FALSE.

Perhatikan bahwa semua contoh memiliki tanda kurung tutup setelah kondisi rumus masing-masing dimasukkan. Sisa argumen True/False disisakan sebagai bagian dari pernyataan IF luar. Anda juga dapat mengganti Teks atau nilai Numerik agar nilai TRUE/FALSE dikembalikan dalam contoh.

Berikut beberapa contoh penggunaan AND, OR dan NOT untuk mengevaluasi tanggal.

Contoh penggunaan IF dengan AND, OR dan NOT untuk mengevaluasi tanggal

Berikut rumus yang dieja sesuai dengan logikanya:

Rumus

Deskripsi

=IF(A2>B2,TRUE,FALSE)

IF A2 lebih besar dari B2, mengembalikan TRUE, jika tidak mengembalikan FALSE. 12/03/14 tidak lebih besar dari 01/01/14, sehingga rumus mengembalikan TRUE.

=IF(AND(A3>B2,A3<C2),TRUE,FALSE)

IF A3 lebih besar B2 AND (dan) A3 lebih kecil dari C2, mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam kedua kasus ini argumen adalah benar, sehingga rumus mengembalikan TRUE.

=IF(OR(A4>B2,A4<B2+60),TRUE,FALSE)

IF A4 lebih besar dari B2 OR (atau) A4 lebih kecil dari B2 + 60, mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam hal ini argumen pertama adalah benar, namun yang kedua adalah salah. Karena OR hanya memerlukan satu argumen benar, rumus mengembalikan TRUE. Jika menggunakan Panduan Mengevaluasi Rumus dari tab Rumus, Anda akan melihat cara Excel mengevaluasi rumus.

=IF(NOT(A5>B2),TRUE,FALSE)

IF A5 tidak lebih besar dari B2, lalu mengembalikan TRUE, jika tidak mengembalikan FALSE. Dalam hal ini, A5 lebih besar dari B2, sehingga rumus mengembalikan FALSE.

Contoh Panduan Mengevaluasi Rumus

Menggunakan AND, OR dan NOT dengan Pemformatan Bersyarat

Anda juga dapat menggunakan AND, OR dan NOT untuk menetapkan kriteria Pemformatan Bersyarat dengan opsi rumus. Ketika melakukan hal ini Anda dapat menghilangkan fungsi IF dan menggunakan AND, OR dan NOT sendiri.

Dari tab Beranda, klik Pemformatan Bersyarat > Aturan Baru. Berikutnya, pilih opsi “Gunakan rumus untuk menentukan sel yang diformat”, masukkan rumus dan terapkan format pilihan Anda.

Dialog Pemformatan Bersyarat > Edit Aturan menampilkan metode Rumus

Menggunakan contoh Tanggal sebelumnya, berikut hasil rumusnya.

Contoh penggunaan AND, OR dan NOT sebagai pengujian Pemformatan Bersyarat


Rumus

Deskripsi

=A2>B2

Jika A2 lebih besar dari B2, format sel, jika tidak, tidak melakukan apa-apa.

=AND(A3>B2,A3<C2)

Jika A3 lebih besar dari B2 AND (dan) A3 lebih kecil dari C2, format sel, jika tidak, tidak melakukan apa-apa.

=OR(A4>B2,A4<B2+60)

Jika A4 lebih besar dari B2 OR (atau) A4 lebih kecil dari B2 ditambah 60 (hari), lalu format sel, jika tidak, tidak melakukan apa-apa.

=NOT(A5>B2)

Jika A5 NOT (tidak) lebih besar dari B2, format sel, jika tidak, tidak melakukan apa-apa. Dalam hal ini, A5 lebih besar dari B2, sehingga hasil mengembalikan FALSE. Jika Anda akan mengubah rumus menjadi =NOT(B2>A5) rumus akan mengembalikan TRUE dan sel akan diformat.

Catatan: Kesalahan umum adalah memasukkan rumus Anda ke dalam Pemformatan Bersyarat tanpa tanda sama dengan (=). Jika melakukan hal ini, Anda akan melihat dialog Pemformatan Bersyarat menambahkan tanda sama dengan dan tanda kutip di rumus, ="OR(A4>B2,A4<B2+60)", sehingga Anda harus menghapus tanda kutip sebelum rumus merespons dengan baik.

Atas Halaman

Perlu bantuan lainnya?

Anda selalu dapat bertanya kepada pakar di Komunitas Teknologi Excel, mendapatkan dukungan di Komunitas Jawaban, atau menyarankan fitur maupun fitur baru di Suara Pengguna Excel.

Lihat Juga

Tonton video tentang cara menggunakan fungsi IF

Pelajari cara menggunakan fungsi bertumpuk dalam rumus

Fungsi IF

Fungsi AND

Fungsi OR

Fungsi NOT

Gambaran umum rumus di Excel

Cara menghindari rumus yang rusak

Menggunakan pemeriksaan kesalahan untuk mendeteksi kesalahan dalam rumus

Pintasan keyboard di Excel untuk Windows

Pintasan keyboard di Excel untuk Mac

Fungsi logika (referensi)

Fungsi Excel (alfabetis)

Fungsi Excel (menurut kategori)

Kembangkan keterampilan Office Anda
Jelajahi pelatihan
Dapatkan fitur baru terlebih dahulu
Gabung ke Office Insiders

Apakah informasi ini bermanfaat?

Terima kasih atas umpan balik Anda!

Terima kasih atas umpan balik Anda! Sepertinya menghubungkan Anda ke salah satu agen dukungan Office kami akan sangat membantu.

×