Masuk dengan Microsoft
Masuk atau buat akun.
Halo,
Pilih akun lain.
Anda memiliki beberapa akun
Pilih akun yang ingin Anda gunakan untuk masuk.
Membagi teks ke dalam kolom yang berbeda dengan fungsi

Anda dapat menggunakan fungsi teks LEFT, MID, RIGHT, SEARCH, dan LEN untuk memanipulasi string teks dalam data Anda. Misalnya, Anda dapat mendistribusikan nama depan, tengah, dan nama belakang dari satu sel ke dalam tiga kolom terpisah.

Kunci untuk mendistribusikan komponen nama dengan fungsi teks adalah posisi setiap karakter dalam string teks. Posisi spasi dalam string teks juga penting karena mengindikasikan awal atau akhir komponen nama dalam string.

Misalnya, dalam sel yang hanya berisi nama depan dan belakang, nama belakang dimulai setelah contoh spasi pertama. Beberapa nama dalam daftar Anda mungkin berisi nama tengah, dalam hal ini, nama belakang dimulai setelah contoh spasi kedua.

Artikel ini memperlihatkan cara mengekstrak berbagai komponen dari berbagai format nama menggunakan fungsi praktis ini. Anda juga bisa memisahkan teks ke dalam kolom yang berbeda dengan Panduan Konversi Teks ke Kolom

Contoh nama

Deskripsi

Nama depan

Nama tengah

Nama belakang

Suffix

1

Jeff Smith

Tidak ada nama tengah

Jaka

Smith

2

Eric S. Kurjan

Satu inisial tengah

Eric

S.

Kurjan

3

Janaina B. G. Bueno

Dua inisial tengah

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

Nama belakang terlebih dahulu, dengan koma

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

Nama depan dua bagian

Mary Kay

D.

Anggraeni

6

Paula Barreto de Mattos

Nama belakang tiga bagian

Paula

Barreto de Mattos

7

James van Eaton

Nama belakang dua bagian

James

van Eaton

8

Bacon Jr., Dan K.

Nama belakang dan akhiran terlebih dahulu, dengan koma

Dan

K.

Bakon

Jr.

9

Gary Altman III

Dengan akhiran

Gary

Altman

III

10

Tn. Ryan Ihrig

Dengan prefiks

Ryan

Ihrig

11

Julie Taft-Rider

Nama belakang yang dihubungkan

Julie

Taft-Rider

Catatan: Dalam grafik dalam contoh berikut ini, sorotan dalam nama lengkap memperlihatkan karakter yang dicari rumus SEARCH yang cocok.

Contoh ini memisahkan dua komponen: nama depan dan nama belakang. Spasi tunggal memisahkan dua nama.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Jeff Smith

Tidak ada nama tengah

Rumus

Hasil (nama depan)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (nama belakang)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Nama depan

    Nama depan diawali dengan karakter pertama dalam string (J) dan berakhir di karakter kelima (spasi). Rumus mengembalikan lima karakter dalam sel A2, dimulai dari kiri.

    Rumus untuk mengekstrak nama depan

    Gunakan fungsi SEARCH untuk menemukan nilai num_chars:

    Cari posisi numerik spasi dalam A2, dimulai dari kiri.

  2. Nama belakang

    Nama belakang dimulai di spasi, lima karakter dari kanan, dan berakhir di karakter terakhir di sebelah kanan (h). Rumus ini mengekstrak lima karakter dalam A2, dimulai dari kanan.

    Rumus untuk mengekstrak nama belakang

    Gunakan fungsi SEARCH dan LEN untuk menemukan nilai num_chars:

    Cari posisi numerik spasi dalam A2, dimulai dari kiri. (5)

  3. Hitung jumlah total string teks, lalu kurangi jumlah karakter di sebelah kiri spasi, seperti ditemukan di langkah 1.

Contoh ini menggunakan nama depan, inisial tengah, dan nama belakang. Spasi memisahkan setiap komponen nama.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Eric S. Kurjan

Satu inisial tengah

Rumus

Hasil (nama depan)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (inisial tengah)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Rumus

Hasil Langsung (nama belakang)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Nama depan

    Nama depan dimulai dengan karakter pertama dari kiri (E) dan berakhir pada karakter kelima (spasi pertama). Rumus ini mengekstrak lima karakter pertama di A2, dimulai dari kiri.

    Rumus untuk memisahkan nama depan dan belakang, ditambah inisial tengah

    Gunakan fungsi SEARCH untuk menemukan nilai num_chars:

    Cari posisi numerik spasi dalam A2, dimulai dari kiri. (5)

  2. Nama tengah

    Nama tengah dimulai pada posisi karakter keenam (S), dan berakhir pada posisi kedelapan (spasi kedua). Rumus ini melibatkan fungsi SEARCH bertumpuk untuk menemukan contoh spasi kedua.

    Rumus ini mengekstrak tiga karakter, dimulai dari posisi keenam.

    Detail rumus untuk memisahkan nama depan, nama tengah, dan nama belakang

    Gunakan fungsi SEARCH untuk menemukan nilai start_num:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (5).

  3. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (S). Posisi numerik ini adalah posisi awal nama tengah. (5 + 1 = 6)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (5)

  4. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (S). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari contoh spasi kedua. (5 + 1 = 6)

  5. Cari contoh spasi kedua di A2, dimulai dari posisi keenam (S) yang ditemukan di langkah 4. Nomor karakter ini adalah posisi akhir nama tengah. (8)

  6. Cari posisi spasi numerik di A2, dimulai dari karakter pertama dari kiri. (5)

  7. Ambil nomor karakter spasi kedua yang ditemukan di langkah 5 dan kurangi dengan nomor karakter spasi pertama yang ditemukan di langkah 6. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks yang dimulai dari posisi keenam yang ditemukan di langkah 2. (8 – 5 = 3)

  8. Nama belakang

    Nama belakang memulai enam karakter dari kanan (K) dan berakhir di karakter pertama dari kanan (n). Rumus ini melibatkan fungsi SEARCH bertumpuk untuk menemukan instans spasi kedua dan ketiga (yang berada di posisi kelima dan kedelapan dari kiri).

    Rumus ini mengekstrak enam karakter di A2, dimulai dari kanan.

    Fungsi SEARCH kedua dalam rumus untuk memisahkan nama depan, tengah, dan nama belakang
  9. Gunakan fungsi LEN dan SEARCH bertumpuk untuk menemukan nilai untuk num_chars:

    Cari posisi spasi numerik di A2, dimulai dari karakter pertama dari kiri. (5)

  10. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (S). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari contoh spasi kedua. (5 + 1 = 6)

  11. Cari contoh spasi kedua di A2, dimulai dari posisi keenam (S) yang ditemukan di langkah 2. Nomor karakter ini adalah posisi akhir nama tengah. (8)

  12. Hitung panjang total string teks di A2, lalu kurangi jumlah karakter dari kiri ke atas ke contoh spasi kedua yang ditemukan di langkah 3. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (14 – 8 = 6).

Berikut contoh cara mengekstrak dua inisial tengah. Contoh spasi pertama dan ketiga memisahkan komponen nama.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Janaina B. G. Bueno

Dua inisial tengah

Rumus

Hasil (nama depan)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (inisial tengah)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

Rumus

Hasil Langsung (nama belakang)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Nama depan

    Nama depan dimulai dengan karakter pertama dari kiri (J) dan berakhir pada karakter kedelapan (spasi pertama). Rumus ini mengekstrak delapan karakter pertama di A2, dimulai dari kiri.

    Rumus untuk memisahkan nama depan, nama belakang, dan dua inisial tengah

    Gunakan fungsi SEARCH untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (8)

  2. Nama tengah

    Nama tengah dimulai pada posisi kesembilan (B), dan berakhir pada posisi keempat belas (spasi ketiga). Rumus ini melibatkan penumpukan SEARCH untuk menemukan contoh spasi pertama, kedua, dan ketiga dalam posisi kedelapan, kesebelas, dan keempat belas.

    Rumus ini mengekstrak lima karakter, dimulai dari posisi kesembilan.

    Rumus untuk memisahkan nama depan, nama belakang, dan dua inisial tengah

    Gunakan fungsi SEARCH untuk menemukan nilai start_num:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (8)

  3. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (B). Posisi numerik ini adalah posisi awal nama tengah. (8 + 1 = 9)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (8)

  4. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (B). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari contoh spasi kedua. (8 + 1 = 9)

  5. Cari spasi kedua di A2, dimulai dari posisi kesembilan (B) yang ditemukan di langkah 4. (11).

  6. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi kedua (G). Nomor karakter ini adalah posisi awal di mana Anda ingin mulai mencari spasi ketiga. (11 + 1 = 12)

  7. Cari spasi ketiga di A2, dimulai dari posisi kedua belas yang ditemukan di langkah 6. (14)

  8. Cari posisi numerik spasi pertama di A2. (8)

  9. Ambil nomor karakter spasi ketiga yang ditemukan di langkah 7 dan kurangi nomor karakter spasi pertama yang ditemukan di langkah 6. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks yang dimulai dari posisi kesembilan yang ditemukan di langkah 2.

  10. Nama belakang

    Nama belakang memulai lima karakter dari kanan (B) dan berakhir di karakter pertama dari kanan (o). Rumus ini melibatkan SEARCH bertumpuk untuk menemukan contoh spasi pertama, kedua, dan ketiga.

    Rumus ini mengekstrak lima karakter dalam A2, dimulai dari sebelah kanan nama lengkap.

    Rumus untuk memisahkan nama depan, nama belakang, dan dua inisial tengah

    Gunakan fungsi SEARCH bertumpuk dan LEN untuk menemukan nilai bagi num_chars:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (8)

  11. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (B). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari contoh spasi kedua. (8 + 1 = 9)

  12. Cari spasi kedua di A2, dimulai dari posisi kesembilan (B) yang ditemukan di langkah 2. (11)

  13. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi kedua (G). Nomor karakter ini adalah posisi awal di mana Anda ingin mulai mencari contoh spasi ketiga. (11 + 1 = 12)

  14. Cari spasi ketiga di A2, dimulai dari posisi kedua belas (G) yang ditemukan di langkah 6. (14)

  15. Hitung panjang total string teks di A2, lalu kurangi jumlah karakter dari kiri ke spasi ketiga yang ditemukan di langkah 5. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (19 - 14 = 5)

Dalam contoh ini, nama belakang muncul sebelum nama depan, dan nama tengah muncul di akhir. Tanda koma menandai akhir nama belakang, dan spasi memisahkan setiap komponen nama.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Kahn, Wendy Beth

Nama belakang terlebih dahulu, dengan koma

Rumus

Hasil (nama depan)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Rumus

Hasil (nama tengah)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Rumus

Hasil Langsung (nama belakang)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. Nama depan

    Nama depan diawali dengan karakter ketujuh dari kiri (W) dan berakhir di karakter kedua belas (spasi kedua). Karena nama depan muncul di tengah nama lengkap, Anda perlu menggunakan fungsi MID untuk mengekstrak nama depan.

    Rumus ini mengekstrak enam karakter, dimulai dari posisi ketujuh.

    Rumus untuk memisahkan nama belakang yang diikuti dengan nama depan dan nama tengah

    Gunakan fungsi SEARCH untuk menemukan nilai start_num:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (6)

  2. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (W). Posisi numerik ini adalah posisi awal nama depan. (6 + 1 = 7)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (6)

  3. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (W). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (6 + 1 = 7)

    Cari lokasi spasi kedua dalam A2, dimulai dari posisi kedua belas (W) yang ditemukan di langkah 4. (12)

  4. Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (6)

  5. Ambil nomor karakter spasi kedua yang ditemukan di langkah 5 dan kurangi dengan nomor karakter spasi pertama yang ditemukan di langkah 6. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks yang dimulai di posisi ketujuh yang ditemukan di langkah 2. (12 - 6 = 6)

  6. Nama tengah

    Nama tengah dimulai dari empat karakter dari kanan (B) dan berakhir di karakter pertama dari kanan (h). Rumus ini menggunakan SEARCH bertumpuk untuk menemukan lokasi spasi pertama dan kedua di posisi keenam dan kedua belas dari kiri.

    Rumus mengekstrak empat karakter, dimulai dari kanan.

    Rumus untuk memisahkan nama belakang yang diikuti dengan nama depan dan nama tengah

    Gunakan fungsi SEARCH bertumpuk dan LEN untuk menemukan nilai start_num:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (6)

  7. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (W). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (6 + 1 = 7)

  8. Cari lokasi spasi kedua dalam A2, dimulai dari posisi ketujuh (W) yang ditemukan di langkah 2. (12)

  9. Hitung panjang total string teks dalam A2, lalu kurangi dengan jumlah karakter dari kiri sampai spasi kedua yang ditemukan di langkah 3. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (16 - 12 = 4)

  10. Nama belakang

    Nama belakang dimulai dengan karakter pertama dari kiri (K) dan berakhir di karakter keempat (n). Rumus ini mengekstrak empat karakter, dimulai dari kiri.

    Rumus untuk memisahkan nama belakang yang diikuti dengan nama depan dan nama tengah

    Gunakan fungsi SEARCH untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (6)

  11. Kurangi 2 untuk mendapatkan posisi numerik karakter akhir nama belakang (n). Hasilnya adalah jumlah karakter yang akan diekstrak oleh LEFT. (6 - 2 =4)

Contoh ini menggunakan nama depan dua bagian, Mary Kay. Spasi kedua dan ketiga memisahkan setiap komponen nama.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Mary Kay D. Andersen

Nama depan dua bagian

Rumus

Hasil (nama depan)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Rumus

Hasil (inisial tengah)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)))

Rumus

Hasil Langsung (nama belakang)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Nama depan

    Nama depan dimulai dengan karakter pertama dari kiri dan berakhir pada karakter kesembilan (spasi kedua). Rumus ini melibatkan PENCARIAN bertumpuk untuk menemukan contoh spasi kedua dari kiri.

    Rumus mengekstrak sembilan karakter, dimulai dari kiri.

    Rumus untuk memisahkan nama depan, nama tengah, inisial tengah, dan nama belakang

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (5)

  2. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (K). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari contoh spasi kedua. (5 + 1 = 6)

  3. Cari contoh spasi kedua di A2, dimulai dari posisi keenam (K) yang ditemukan di langkah 2. Hasilnya adalah jumlah karakter yang diekstrak LEFT dari string teks. (9)

  4. Nama tengah

    Nama tengah dimulai pada posisi kesepuluh (D), dan berakhir pada posisi kedua belas (spasi ketiga). Rumus ini melibatkan SEARCH bertumpuk untuk menemukan contoh spasi pertama, kedua, dan ketiga.

    Rumus mengekstrak dua karakter dari tengah, dimulai dari posisi kesepuluh.

    Rumus untuk memisahkan nama depan, nama tengah, inisial tengah, dan nama belakang

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai untuk start_num:

    Cari posisi numerik spasi pertama dalam A2, dimulai dari karakter pertama dari kiri. (5)

  5. Tambahkan 1 untuk mendapatkan karakter setelah spasi pertama (K). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (5 + 1 = 6)

  6. Cari posisi contoh spasi kedua di A2, dimulai dari posisi keenam (K) yang ditemukan di langkah 2. Hasilnya adalah jumlah karakter yang diekstrak LEFT dari kiri. (9)

  7. Tambahkan 1 untuk mendapatkan karakter setelah spasi kedua (D). Hasilnya adalah posisi awal nama tengah. (9 + 1 = 10)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Mencari posisi numerik karakter setelah spasi kedua (D). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari spasi ketiga. (10)

  8. Cari posisi numerik spasi ketiga di A2, dimulai dari kiri. Hasilnya adalah posisi akhir nama tengah. (12)

  9. Mencari posisi numerik karakter setelah spasi kedua (D). Hasilnya adalah posisi awal nama tengah. (10)

  10. Ambil nomor karakter spasi ketiga, yang ditemukan di langkah 6, dan kurangi nomor karakter "D", yang ditemukan di langkah 7. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks dimulai dari posisi kesepuluh yang ditemukan di langkah 4. (12 - 10 = 2)

  11. Nama belakang

    Nama belakang dimulai delapan karakter dari kanan. Rumus ini melibatkan PENCARIAN bertumpuk untuk menemukan contoh spasi pertama, kedua, dan ketiga dalam posisi kelima, kesembilan, dan kedua belas.

    Rumus ini mengekstrak delapan karakter dari kanan.

    Rumus untuk memisahkan nama depan, nama tengah, inisial tengah, dan nama belakang

    Gunakan fungsi SEARCH bertumpuk dan LEN untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (5)

  12. Tambahkan 1 untuk mendapatkan karakter setelah spasi pertama (K). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari spasi. (5 + 1 = 6)

  13. Cari spasi kedua di A2, dimulai dari posisi keenam (K) yang ditemukan di langkah 2. (9)

  14. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi kedua (D). Hasilnya adalah posisi awal nama tengah. (9 + 1 = 10)

  15. Cari posisi numerik spasi ketiga di A2, dimulai dari kiri. Hasilnya adalah posisi akhir nama tengah. (12)

  16. Hitung panjang total string teks di A2, lalu kurangi jumlah karakter dari kiri ke spasi ketiga yang ditemukan di langkah 5. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (20 - 12 = 8)

Contoh ini menggunakan nama belakang tiga bagian: Barreto de Mattos. Spasi pertama menandai akhir nama depan dan awal nama belakang.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Paula Barreto de Mattos

Nama belakang tiga bagian

Rumus

Hasil (nama depan)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (nama belakang)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Nama depan

    Nama depan dimulai dengan karakter pertama dari kiri (P) dan berakhir pada karakter keenam (spasi pertama). Rumus ini mengekstrak enam karakter dari kiri.

    Rumus untuk memisahkan nama depan, dan tiga bagian nama belakang

    Gunakan fungsi Pencarian untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  2. Nama belakang

    Nama belakang memulai tujuh belas karakter dari kanan (B) dan diakhiri dengan karakter pertama dari kanan (s). Rumus ini mengekstrak tujuh belas karakter dari kanan.

    Rumus untuk memisahkan nama depan, dan tiga bagian nama belakang

    Gunakan fungsi LEN dan SEARCH untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  3. Hitung total panjang string teks di A2, lalu kurangi jumlah karakter dari kiri ke atas ke spasi pertama, yang ditemukan di langkah 1. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (23 - 6 = 17)

Contoh ini menggunakan nama belakang dua bagian: van Eaton. Spasi pertama menandai akhir nama depan dan awal nama belakang.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

James van Eaton

Nama belakang dua bagian

Rumus

Hasil (nama depan)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (nama belakang)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Nama depan

    Nama depan dimulai dengan karakter pertama dari kiri (J) dan berakhir pada karakter kedelapan (spasi pertama). Rumus ini mengekstrak enam karakter dari kiri.

    Rumus untuk memisahkan nama depan dan dua bagian nama belakang

    Gunakan fungsi SEARCH untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  2. Nama belakang

    Nama belakang dimulai dengan karakter kesembilan dari kanan (v) dan berakhir di karakter pertama dari kanan (n). Rumus ini mengekstrak sembilan karakter dari sebelah kanan nama lengkap.

    Rumus untuk memisahkan nama depan dan dua bagian nama belakang

    Gunakan fungsi LEN dan SEARCH untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  3. Hitung total panjang string teks di A2, lalu kurangi jumlah karakter dari kiri ke atas ke spasi pertama, yang ditemukan di langkah 1. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (15 - 6 = 9)

Dalam contoh ini, nama belakang muncul terlebih dahulu, diikuti dengan akhiran. Tanda koma memisahkan nama belakang dan akhiran dari nama depan dan inisial tengah.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Bacon Jr., Dan K.

Nama belakang dan akhiran terlebih dahulu, dengan koma

Rumus

Hasil (nama depan)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Rumus

Hasil (inisial tengah)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Rumus

Hasil (nama belakang)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (akhiran)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. Nama depan

    Nama depan dimulai dengan karakter kedua belas (D) dan diakhiri dengan karakter kelima belas (spasi ketiga). Rumus mengekstrak tiga karakter, dimulai dari posisi kedua belas.

    Rumus untuk memisahkan nama belakang dan akhiran terlebih dahulu, dengan koma

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai untuk start_num:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  2. Tambahkan 1 untuk mendapatkan karakter setelah spasi pertama (J). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (6 + 1 = 7)

  3. Cari spasi kedua di A2, dimulai dari posisi ketujuh (J), yang ditemukan di langkah 2. (11)

  4. Tambahkan 1 untuk mendapatkan karakter setelah spasi kedua (D). Hasilnya adalah posisi awal nama depan. (11 + 1 = 12)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Mencari posisi numerik karakter setelah spasi kedua (D). Hasilnya adalah nomor karakter di mana Anda ingin mulai mencari spasi ketiga. (12)

  5. Cari posisi numerik spasi ketiga di A2, dimulai dari kiri. Hasilnya adalah posisi akhir nama depan. (15)

  6. Mencari posisi numerik karakter setelah spasi kedua (D). Hasilnya adalah posisi awal nama depan. (12)

  7. Ambil nomor karakter spasi ketiga, yang ditemukan di langkah 6, dan kurangi nomor karakter "D", yang ditemukan di langkah 7. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks yang dimulai dari posisi kedua belas, yang ditemukan di langkah 4. (15 - 12 = 3)

  8. Nama tengah

    Nama tengah dimulai dengan karakter kedua dari kanan (K). Rumus ini mengekstrak dua karakter dari kanan.

    Rumus untuk memisahkan nama belakang dan akhiran terlebih dahulu, dengan koma

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  9. Tambahkan 1 untuk mendapatkan karakter setelah spasi pertama (J). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (6 + 1 = 7)

  10. Cari spasi kedua di A2, dimulai dari posisi ketujuh (J), yang ditemukan di langkah 2. (11)

  11. Tambahkan 1 untuk mendapatkan karakter setelah spasi kedua (D). Hasilnya adalah posisi awal nama depan. (11 + 1 = 12)

  12. Cari posisi numerik spasi ketiga di A2, dimulai dari kiri. Hasilnya adalah posisi akhir nama tengah. (15)

  13. Hitung total panjang string teks di A2, lalu kurangi jumlah karakter dari kiri ke spasi ketiga, yang ditemukan di langkah 5. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (17 - 15 = 2)

  14. Nama belakang

    Nama belakang dimulai dari karakter pertama dari kiri (B) dan berakhir pada karakter keenam (spasi pertama). Oleh karena itu, rumus mengekstrak enam karakter dari kiri.

    Rumus untuk memisahkan nama belakang dan akhiran terlebih dahulu, dengan koma

    Gunakan fungsi SEARCH untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  15. Suffix

    Akhiran dimulai dari karakter ketujuh dari kiri (J), dan berakhir pada karakter kesembilan dari kiri (.). Rumus mengekstrak tiga karakter, dimulai dari karakter ketujuh.

    Rumus untuk memisahkan nama belakang dan akhiran terlebih dahulu, dengan koma

    Gunakan fungsi SEARCH untuk menemukan nilai start_num:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  16. Tambahkan 1 untuk mendapatkan karakter setelah spasi pertama (J). Hasilnya adalah posisi awal akhiran. (6 + 1 = 7)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  17. Tambahkan 1 untuk mendapatkan posisi numerik karakter setelah spasi pertama (J). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (7)

  18. Cari posisi numerik spasi kedua di A2, dimulai dari karakter ketujuh yang ditemukan di langkah 4. (11)

  19. Kurangi 1 dari nomor karakter spasi kedua yang ditemukan di langkah 4 untuk mendapatkan nomor karakter ",". Hasilnya adalah posisi akhir akhiran. (11 - 1 = 10)

  20. Mencari posisi numerik spasi pertama. (6)

  21. Setelah menemukan spasi pertama, tambahkan 1 untuk menemukan karakter berikutnya (J), juga ditemukan di langkah 3 dan 4. (7)

  22. Ambil nomor karakter "," yang ditemukan di langkah 6, dan kurangi jumlah karakter "J", yang ditemukan di langkah 3 dan 4. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks yang dimulai dari posisi ketujuh, yang ditemukan di langkah 2. (10 - 7 = 3)

Dalam contoh ini, nama depan berada di awal string dan akhiran berada di akhir, sehingga Anda bisa menggunakan rumus yang mirip dengan Contoh 2: Gunakan fungsi LEFT untuk mengekstrak nama depan, fungsi MID untuk mengekstrak nama belakang, dan fungsi RIGHT untuk mengekstrak akhiran.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Gary Altman III

Nama depan dan belakang dengan akhiran

Rumus

Hasil (nama depan)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (nama belakang)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Rumus

Hasil (akhiran)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Nama depan

    Nama depan dimulai dari karakter pertama dari kiri (G) dan berakhir pada karakter kelima (spasi pertama). Oleh karena itu, rumus mengekstrak lima karakter dari kiri nama lengkap.

    Rumus untuk memisahkan nama depan dan nama belakang diikuti dengan akhiran

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (5)

  2. Nama belakang

    Nama belakang dimulai dari karakter keenam dari kiri (A) dan berakhir di karakter kesebelas (spasi kedua). Rumus ini melibatkan PENCARIAN bertumpuk untuk menemukan posisi spasi.

    Rumus ini mengekstrak enam karakter dari tengah, dimulai dari karakter keenam.

    Rumus untuk memisahkan nama depan dan nama belakang diikuti dengan akhiran

    Gunakan fungsi SEARCH untuk menemukan nilai start_num:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (5)

  3. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (A). Hasilnya adalah posisi awal nama belakang. (5 + 1 = 6)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (5)

  4. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (A). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (5 + 1 = 6)

  5. Cari posisi numerik spasi kedua di A2, dimulai dari karakter keenam yang ditemukan di langkah 4. Nomor karakter ini adalah posisi akhir nama belakang. (12)

  6. Mencari posisi numerik spasi pertama. (5)

  7. Tambahkan 1 untuk menemukan posisi numerik karakter setelah spasi pertama (A), juga ditemukan di langkah 3 dan 4. (6)

  8. Ambil nomor karakter spasi kedua, yang ditemukan di langkah 5, lalu kurangi nomor karakter "A", yang ditemukan di langkah 6 dan 7. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks, dimulai dari posisi keenam, yang ditemukan di langkah 2. (12 - 6 = 6)

  9. Suffix

    Akhiran dimulai tiga karakter dari kanan. Rumus ini melibatkan PENCARIAN bertumpuk untuk menemukan posisi spasi.

    Rumus untuk memisahkan nama depan dan nama belakang diikuti dengan akhiran

    Gunakan fungsi SEARCH bertumpuk dan LEN untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (5)

  10. Tambahkan 1 untuk mendapatkan karakter setelah spasi pertama (A). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (5 + 1 = 6)

  11. Cari spasi kedua di A2, dimulai dari posisi keenam (A), yang ditemukan di langkah 2. (12)

  12. Hitung total panjang string teks di A2, lalu kurangi jumlah karakter dari kiri ke atas ke spasi kedua, yang ditemukan di langkah 3. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (15 - 12 = 3)

Dalam contoh ini, nama lengkap didahului dengan prefiks, dan Anda menggunakan rumus yang mirip dengan Contoh 2: fungsi MID untuk mengekstrak nama depan, fungsi RIGHT untuk mengekstrak nama belakang.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Tn. Ryan Ihrig

Dengan prefiks

Rumus

Hasil (nama depan)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Rumus

Hasil (nama belakang)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Nama depan

    Nama depan dimulai dari karakter kelima dari kiri (R) dan berakhir pada karakter kesembilan (spasi kedua). Rumus menumpuk SEARCH untuk menemukan posisi spasi. Ini mengekstrak empat karakter, dimulai dari posisi kelima.

    Rumus untuk memisahkan nama depan yang didahului dengan prefiks

    Gunakan fungsi SEARCH untuk menemukan nilai untuk start_num:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (4)

  2. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (R). Hasilnya adalah posisi awal nama depan. (4 + 1 = 5)

    Gunakan fungsi SEARCH bertumpuk untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (4)

  3. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (R). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (4 + 1 = 5)

  4. Cari posisi numerik spasi kedua di A2, dimulai dari karakter kelima, yang ditemukan di langkah 3 dan 4. Nomor karakter ini adalah posisi akhir nama depan. (9)

  5. Mencari spasi pertama. (4)

  6. Tambahkan 1 untuk menemukan posisi numerik karakter setelah spasi pertama (R), juga ditemukan di langkah 3 dan 4. (5)

  7. Ambil nomor karakter spasi kedua, yang ditemukan di langkah 5, lalu kurangi nomor karakter "R", yang ditemukan di langkah 6 dan 7. Hasilnya adalah jumlah karakter yang diekstrak MID dari string teks, dimulai dari posisi kelima yang ditemukan di langkah 2. (9 - 5 = 4)

  8. Nama belakang

    Nama belakang memulai lima karakter dari kanan. Rumus ini melibatkan PENCARIAN bertumpuk untuk menemukan posisi spasi.

    Rumus untuk memisahkan nama depan yang didahului dengan prefiks

    Gunakan fungsi SEARCH bertumpuk dan LEN untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (4)

  9. Tambahkan 1 untuk mendapatkan posisi karakter setelah spasi pertama (R). Hasilnya adalah nomor karakter yang Anda inginkan untuk mulai mencari spasi kedua. (4 + 1 = 5)

  10. Cari spasi kedua di A2, dimulai dari posisi kelima (R), yang ditemukan di langkah 2. (9)

  11. Hitung total panjang string teks di A2, lalu kurangi jumlah karakter dari kiri ke atas ke spasi kedua, yang ditemukan di langkah 3. Hasilnya adalah jumlah karakter yang akan diekstrak dari kanan nama lengkap. (14 - 9 = 5)

Contoh ini menggunakan nama belakang yang dihubungkan. Spasi memisahkan setiap komponen nama.

Salin sel dalam tabel dan tempelkan ke lembar kerja Excel di sel A1. Rumus yang Anda lihat di sebelah kiri akan ditampilkan untuk referensi, sementara Excel akan secara otomatis mengonversi rumus di sebelah kanan menjadi hasil yang sesuai.

Petunjuk    Sebelum Anda menempelkan data ke lembar kerja, atur lebar kolom kolom A dan B ke 250.

Contoh nama

Deskripsi

Julie Taft-Rider

Nama belakang yang dihubungkan

Rumus

Hasil (nama depan)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Rumus

Hasil (nama belakang)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Nama depan

    Nama depan dimulai dari karakter pertama dari kiri dan berakhir di posisi keenam (spasi pertama). Rumus ini mengekstrak enam karakter dari kiri.

    Rumus untuk memisahkan nama depan dan nama belakang yang dihubungkan

    Gunakan fungsi SEARCH untuk menemukan nilai num_chars:

    Cari posisi numerik spasi pertama di A2, dimulai dari kiri. (6)

  2. Nama belakang

    Seluruh nama belakang dimulai sepuluh karakter dari kanan (T) dan berakhir di karakter pertama dari kanan (r).

    Rumus untuk memisahkan nama depan dan nama belakang yang dihubungkan

    Gunakan fungsi LEN dan SEARCH untuk menemukan nilai untuk num_chars:

    Cari posisi numerik spasi di A2, dimulai dari karakter pertama dari kiri. (6)

  3. Hitung total panjang string teks yang akan diekstrak, lalu kurangi jumlah karakter dari kiri ke spasi pertama, yang ditemukan di langkah 1. (16 - 6 = 10)

Membagi teks ke dalam kolom yang berbeda dengan Panduan Konversi Teks ke Kolom

Perlu bantuan lainnya?

Ingin opsi lainnya?

Jelajahi manfaat langganan, telusuri kursus pelatihan, pelajari cara mengamankan perangkat Anda, dan banyak lagi.

Komunitas membantu Anda bertanya dan menjawab pertanyaan, memberikan umpan balik, dan mendengar dari para ahli yang memiliki pengetahuan yang luas.

Apakah informasi ini berguna?

Seberapa puaskah Anda dengan kualitas bahasanya?
Apa yang memengaruhi pengalaman Anda?
Dengan menekan kirim, umpan balik Anda akan digunakan untuk meningkatkan produk dan layanan Microsoft. Admin TI Anda akan dapat mengumpulkan data ini. Pernyataan Privasi.

Terima kasih atas umpan balik Anda!

×