IF (Fungsi IF)

Artikel ini menguraikan sintaks rumus dan penggunaan fungsiIF dalam Microsoft Excel.

Deskripsi

Fungsi IF mengembalikan satu nilai jika kondisi yang Anda tentukan mengevaluasi ke TRUE, dan nilai lain jika kondisi itu mengevaluasi ke FALSE. Misalnya, rumus =IF(A1>10,"Over 10","10 or less") mengembalikan "Over 10" jika A1 lebih besar dari 10, dan "10 or less" jika A1 kurang dari atau sama dengan 10.

Sintaks

IF(logical_test, [value_if_true], [value_if_false])

Sintaks fungsi IF memiliki argumen berikut.

  • Logical_test    Diperlukan. Nilai atau ekspresi yang bisa dievaluasi ke TRUE atau FALSE. Misalnya, A10=100 adalah ekspresi logika; jika nilai di dalam sel A10 sama dengan 100, ekspresi mengevaluasi ke TRUE. Kalau tidak, ekspresi mengevaluasi ke FALSE. Argumen ini dapat menggunakan operator kalkulasi perbandingan.

  • Value_if_true    Opsional. Nilai yang ingin Anda kembalikan jika argumen logical_test mengevaluasi ke TRUE. Misalnya, nilai argumen ini adalah string teks "Within budget" dan argumen logical_test mengevaluasi ke TRUE, fungsi IF mengembalikan teks "Within budget." Jika logical_test mengevaluasi ke TRUE dan argumen value_if_true dihilangkan (yaitu, hanya ada satu koma setelah argumen logical_test), maka fungsi IF mengembalikan 0 (nol). Untuk menampilkan kata TRUE, gunakan nilai logika TRUE untuk argumen value_if_true.

  • Value_if_false    Opsional. Nilai yang ingin Anda kembalikan jika argumen logical_test mengevaluasi ke FALSE. Misalnya, nilai argumen ini adalah string teks "Over budget" dan argumen logical_test mengevaluasi ke FALSE, fungsi IF mengembalikan teks "Over budget." Jika logical_test mengevaluasi ke FALSE dan argumen value_if_true dihilangkan (yaitu, hanya ada satu koma setelah argumen logical_test), maka fungsi IF mengembalikan nilai logika FALSE. Jika logical_test mengevaluasi ke FALSE dan nilai argumen value_if_false dihilangkan (yaitu, hanya ada satu koma setelah argumen value_if_true), maka fungsi IF mengembalikan nilai 0 (nol).

Keterangan

  • Hingga 64 fungsi IF dapat ditumpukkan sebagai argumen Value_if_true dan Value_if_false untuk menyusun ujian-ujian lain yang lebih terperinci. (Lihat Contoh 3 untuk contoh fungsi-fungsi IF.) Alternatifnya, untuk menguji banyak kondisi, pertimbangkan penggunaan fungsi LOOKUP, VLOOKUP, HLOOKUP, atau CHOOSE. (Lihat Contoh 4 untuk contoh fungsi LOOKUP.)

  • Jika argumen untuk IF adalah array, maka setiap elemen array dievaluasi ketika pernyataan IF dilakukan.

  • Excel menyediakan fungsi tambahan yang dapat digunakan untuk menganalisis data Anda berdasarkan sebuah kondisi. Misalnya, untuk menghitung jumlah kemunculan string teks atau angka di dalam rentang sel, gunakan fungsi lembar kerja COUNTIF atau COUNTIFS. Untuk menghitung jumlah berdasarkan sebuah string teks atau angka di dalam rentang, gunakan fungsi lembar kerja SUMIF atau SUMIFS.

Contoh

Buku kerja di bawah memperlihatkan contoh fungsi ini. Periksalah contohnya, ubah rumus yang ada, atau masukkan rumus Anda sendiri untuk mempelajari cara kerja fungsi ini.

Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan lebar kolom untuk melihat semua data.

Data

50

23

33175

Rumus

Deskripsi

Hasil

=IF(A2<=100,"Within budget","Over budget")

Jika angka dalam sel A2 kurang dari atau sama dengan 100, rumus mengembalikan "Within budget." Jika tidak, fungsi menampilkan "Over budget."

Within budget

=IF(A2=100,A2+B2,"")

Jika angka dalam sel A2 sama dengan 100, A2 + B2 dihitung dan dikembalikan. Jika tidak, teks kosong ("") dikembalikan.

0

=IF(3<1,"OK")

Jika hasilnya False dan tidak ada argumen value_if_false yang disediakan untuk hasil Falses, maka FALSE dikembalikan.

FALSE

Jika hasilnya False dan argumen value_if_false kosong dikembalikan untuk hasil False (sebuah koma mengikuti argumen value_if_true), maka 0 dikembalikan.

0

Untuk bekerja secara lebih mendalam dengan data contoh di Excel, unduh buku kerja yang disematkan ke komputer Anda, lalu buka di Excel.

Contoh 2

Pengeluaran Aktual

Prediksi Pengeluaran

$1.500

$900

$500

$900

$500

$925

Rumus

Deskripsi

Hasil

=IF(A2>B2,"Over Budget","OK")

Memeriksa apakah pengeluaran aktual di baris 2 lebih besar dari prediksi pengeluaran. Mengembalikan "Over Budget" karena hasil ujinya adalah True.

Over Budget

=IF(A3>B3,"Over Budget","OK")

Memeriksa apakah pengeluaran aktual di baris 3 lebih besar dari prediksi pengeluaran. Mengembalikan "OK" karena hasil ujinya adalah False.

OK)

Contoh 3

Skor

45

90

78

Rumus

Deskripsi

Hasil

=IF(A2>89,"A",IF(A2>79,"B", IF(A2>69,"C",IF(A2>59,"D","F"))))

Menggunakan kondisi IF bertumpuk untuk menetapkan huruf mutu ke skor dalam sel A2.

F

=IF(A3>89,"A",IF(A3>79,"B", IF(A3>69,"C",IF(A3>59,"D","F"))))

Menggunakan kondisi IF bertumpuk untuk menetapkan huruf mutu ke skor dalam sel A3.

A

=IF(A4>89,"A",IF(A4>79,"B", IF(A4>69,"C",IF(A4>59,"D","F"))))

Menggunakan kondisi IF yang ditumpuk untuk menetapkan huruf mutu ke skor dalam sel A4.

C

Contoh 4

Skor

45

90

78

Rumus

Deskripsi

Hasil

=LOOKUP(A2,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Alih-alih menggunakan beberapa fungsi IF bertumpuk, rumus menggunakan fungsi LOOKUP untuk mencari peringkat huruf yang terkait dengan skor numerik yang disimpan dalam array di rumus.

F

=LOOKUP(A3,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Alih-alih menggunakan beberapa fungsi IF bertumpuk, rumus menggunakan fungsi LOOKUP untuk mencari peringkat huruf yang terkait dengan skor numerik yang disimpan dalam array di rumus.

A-

=LOOKUP(A4,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Alih-alih menggunakan beberapa fungsi IF bertumpuk, rumus menggunakan fungsi LOOKUP untuk mencari peringkat huruf yang terkait dengan skor numerik yang disimpan dalam array di rumus.

C+

Terapkan Ke: Excel 2013, Excel Online



Apakah informasi ini bermanfaat?

Ya Tidak

Bagaimana kami dapat meningkatkannya?

255 karakter tersisa

Untuk memproteksi privasi Anda, jangan menyertakan informasi kontak dalam umpan balik Anda. Tinjau kebijakan privasi.

Terima kasih atas umpan balik Anda!

Sumber daya dukungan

Ganti bahasa