COUNTIF (Fungsi COUNTIF)

COUNTIF (Fungsi COUNTIF)

Gunakan COUNTIF, salah satu fungsi statistik, untuk menghitung jumlah sel yang memenuhi kriteria; misalnya, untuk menghitung berapa kali kota tertentu muncul dalam daftar pelanggan.

Secara sederhana, COUNTIF berbentuk sebagai berikut:

  • =COUNTIF(Tempat Anda ingin mencari?, Apa yang ingin dicari?)

Misalnya:

  • =COUNTIF(A2:A5,"London")

  • =COUNTIF(A2:A5,A4)

Browser Anda tidak mendukung video. Menginstal Microsoft Silverlight, Adobe Flash Player, atau Internet Explorer 9.

COUNTIF(rentang, kriteria)

Nama argumen

Deskripsi

rentang    (diperlukan)

Kelompok sel yang ingin Anda hitung. Rentang dapat berisi angka, larik, rentang bernama, atau referensi yang berisi angka. Nilai kosong dan nilai teks diabaikan.

Pelajari cara memilih rentang di lembar kerja.

criteria    (diperlukan)

Angka, ekspresi, referensi sel, atau string teks yang menentukan sel yang akan dihitung.

Misalnya, Anda dapat menggunakan angka seperti 32, perbandingan seperti ">32", sel seperti B4, atau kata seperti "apel".

COUNTIF hanya menggunakan kriteria tunggal. Gunakan COUNTIFS jika Anda ingin menggunakan beberapa kriteria.

Contoh

Untuk menggunakan contoh ini di Excel, salin data dalam tabel di bawah ini, dan tempelkan ke dalam sel A1 lembar kerja baru.

Data

Data

apel

32

jeruk

54

persik

75

apel

86

Rumus

Deskripsi

=COUNTIF(A2:A5,"apel")

Menghitung jumlah sel yang berisi apel di sel A2 hingga A5. Hasilnya adalah 2.

=COUNTIF(A2:A5,A4)

Menghitung jumlah sel yang berisi persik (nilai di A4) di sel A2 hingga A5. Hasilnya adalah 1.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

Menghitung jumlah apel (nilai di A2) dan jeruk (nilai di A3) di sel A2 hingga A5. Hasilnya adalah 3. Rumus ini menggunakan COUNTIF dua kali untuk menentukan beberapa kriteria, satu kriteria per ekspresi. Anda juga dapat menggunakan fungsi COUNTIFS.

=COUNTIF(B2:B5,">55")

Menghitung jumlah sel dengan nilai yang lebih besar dari 55 di sel B2 hingga B5. Hasilnya adalah 2.

=COUNTIF(B2:B5,"<>"&B4)

Menghitung jumlah sel dengan nilai yang tidak sama dengan 75 di sel B2 hingga B5. Ampersand (&) menggabungkan operator perbandingan tidak sama dengan (<>) dan nilai di B4 untuk dibaca =COUNTIF(B2:B5,"<>75"). Hasilnya adalah 3.

=COUNTIF(B2:B5,">=32")-COUNTIF(B2:B5,">85")

Menghitung jumlah sel dengan nilai lebih besar dari (>) atau sama dengan (=) 32 dan kurang dari (<) atau sama dengan (=) 85 di sel B2 hingga B5. Hasilnya adalah 3.

=COUNTIF(A2:A5,"*")

Menghitung jumlah sel yang berisi teks di sel A2 hingga A5. Karakter tanda bintang (*) digunakan sebagai karakter wildcard untuk mencocokkan karakter apa saja. Hasilnya adalah 4.

=COUNTIF(A2:A5,"????es")

Menghitung jumlah sel yang memiliki tepat 7 karakter berakhiran huruf "es" di sel A2 hingga A5. Tanda tanya (?) digunakan sebagai karakter wildcard untuk mencocokkan setiap karakter. Hasilnya adalah 2.

Masalah Umum

Masalah

Apa yang salah

Nilai yang salah dikembalikan untuk string yang panjang.

Fungsi COUNTIF akan menghasilkan hasil yang tidak benar ketika Anda menggunakannya untuk mencocokkan string yang lebih dari 255 karakter.

Untuk mencocokkan string yang lebih panjang dari 255 karakter, gunakan fungsi CONCATENATE atau operator concatenate &;. Misalnya, =COUNTIF(A2:A5,"long string"&"another long string").

Tidak ada nilai yang dikembalikan saat Anda mengharapkan nilai.

Pastikan Anda memasukkan argumen kriteria dalam tanda petik.

Rumus COUNTIF menerima kesalahan #VALUE! saat merujuk ke lembar kerja lain.

Kesalahan ini terjadi saat rumus yang berisi fungsi merujuk ke sel atau rentang dalam buku kerja tertutup dan sel dihitung. Agar fitur ini berfungsi, buku kerja yang lain harus terbuka.

Praktik terbaik

Lakukan ini

Mengapa

Ketahuilah bahwa COUNTIF mengabaikan huruf besar dan huruf kecil di string teks.

Kriteria tidak peka huruf besar dan kecil. Dengan kata lain, string "apel" dan string "APEL" akan dianggap sel yang sama.

Menggunakan karakter wildcard.

Karakter wildcard —tanda tanya (?) dan bintang (*)—dapat digunakan di kriteria. Tanda tanya cocok dengan karakter tunggal apa pun; tanda bintang cocok dengan urutan karakter apa pun. Jika Anda ingin menemukan tanda tanya atau tanda bintang yang sesungguhnya, ketikkan tilde (~) sebelum karakter.

Misalnya, =COUNTIF(A2:A5, "apel?") akan menghitung seluruh kemunculan "apel" dengan huruf terakhir yang berbeda-beda.

Pastikan data Anda tidak mengandung karakter yang salah.

Ketika menghitung nilai teks, pastikan data di kolom pertama tidak berisi spasi awal, spasi akhir, penggunaan tanda kutip lurus dan lengkung yang tidak konsisten, atau karakter non-cetak. Dalam kasus ini, COUNTIF mungkin mengembalikan nilai yang salah atau tidak diharapkan.

Coba menggunakan fungsi CLEAN atau fungsi TRIM.

Demi kenyamanan, gunakan rentang bernama

COUNTIF mendukung rentang bernama dalam rumus (seperti = COUNTIF (buah,"> = 32")-COUNTIF(buah,"> 85"). Rentang bernama dapat berada di lembar kerja saat ini, lembar kerja lain dalam buku kerja yang sama, atau dari buku kerja berbeda. Untuk mereferensikan dari buku kerja lain, buku kerja kedua juga harus terbuka.

Catatan: Fungsi COUNTIF tidak akan menghitung sel berdasarkan latar belakang atau warna font sel. Namun, Excel mendukung Fungsi Didefinisikan Pengguna (UDF) menggunakan operasi Microsoft Visual Basic for Applications (VBA) di sel berdasarkan latar belakang atau warna font. Berikut contoh bagaimana Anda dapat Menghitung jumlah sel dengan warna sel tertentu menggunakan VBA.

Perlu bantuan lainnya?

Anda selalu dapat bertanya kepada pakar di Komunitas Teknologi Excel, mendapatkan dukungan di Komunitas Jawaban, atau menyarankan fitur maupun fitur baru di Suara Pengguna Excel.

Lihat Juga

Untuk menghitung sel yang tidak kosong, gunakan fungsi COUNTA

Untuk menghitung sel menggunakan beberapa kriteria, gunakan fungsi COUNTIFS

Tonton video tentang cara menggunakan fungsi COUNTIFS

Fungsi SUMIF hanya menambahkan nilai yang memenuhi kriteria tunggal

Fungsi SUMIFS hanya menambahkan nilai yang memenuhi beberapa kriteria

Fungsi IFS (Office 365, Excel 2016, dan yang lebih baru)

Menggunakan fungsi TRIM untuk menghapus spasi dari sebelum dan sesudahnya dari sel

Menggunakan fungsi CLEAN untuk menghapus karakter non-cetak dari sel

Gambaran umum rumus di Excel

Cara menghindari kesalahan rumus

Mendeteksi kesalahan dalam rumus

Fungsi statistik

Fungsi Excel (alfabetis)

Fungsi Excel (menurut Kategori)

Menggunakan SUMIF, COUNTIF, dan fungsi yang terkait untuk analisis data cepat (pratinjau gratis)

Kembangkan keterampilan Anda
Jelajahi pelatihan
Dapatkan fitur baru terlebih dahulu
Gabung ke Office Insiders

Apakah informasi ini bermanfaat?

Terima kasih atas umpan balik Anda!

Terima kasih atas umpan balik Anda! Sepertinya menghubungkan Anda ke salah satu agen dukungan Office kami akan sangat membantu.

×