Szöveg felosztása oszlopokba Excel-függvényekkel

Szöveg felosztása oszlopokba Excel-függvényekkel

A BAL, KÖZÉP, JOBB, SZÖVEG.KERES és HOSSZ szövegfüggvényekkel az adatok között előforduló szöveges értékeket kezelheti. Ezekkel megoldható például, hogy egy névlista értékeit felbontsa vezetéknévre, középső névre és utónévre, majd ezeket külön oszlopokba másolja.

Egy név elemeinek szövegfüggvényekkel történő felosztásának kulcsa az egyes karakterek karakterláncon belüli elhelyezkedése. A karakterláncon belüli szóközök elhelyezkedése is fontos, mivel a szóközök jelzik a karakterlánc elemeinek a kezdetét, illetve végét.

Az alábbi listában az egy vezeték- és egy utónevet tartalmazó cellában például a vezetéknév az első szóköz után található. A lista egyes nevei középső nevet is tartalmaznak, és ez esetben a vezetéknév a második szóköz után áll.

Ez a cikk bemutatja, hogy ezeket a praktikus funkciókat használva miként vonhat ki eltérő összetevőket a különféle névformátumokból. A Szövegdaraboló varázsló segítségével is feloszthat szöveget különböző oszlopokba.

Példa neve

Leírás

Vezetéknév

Középső név

Utónév

Utótag

1

Jeff Smith

Nincs középső név

Jeff

Szabó

2

Eric S. Kurjan

Egyetlen középső névkezdő betű

Eric

S.

Kurjan

3

Janaina B. G. Bueno

Két középső név kezdőbetűje

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

Vezetéknév elsőként, vesszővel elválasztva

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

Kéttagú utónév

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

Háromtagú vezetéknév

Paula

Barreto de Mattos

7

James van Eaton

Kéttagú vezetéknév

James

van Eaton

8

Bacon Jr., Dan K.

Vezetéknév és utótag elsőként, vesszővel elválasztva

Dan

K.

Bacon

Ifj.

9

Gary Altman III

Utótag

Gary

Altman

III

10

Mr. Ryan Ihrig

Előtag

Ryan

Ihrig

11

Julie Taft-Rider

Kötőjeles vezetéknév

Julie

Taft-Rider

Megjegyzés : Az alábbi példák ábráin az a karakter van kiemelve a teljes névben, amelyet a SZÖVEG.KERES függvény keresni fog.

Ebben a példában két összetevő szétválasztása látható: a vezetéknév és az utónév. A két nevet egyetlen szóköz választja el.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Jeff Smith

Nincs középső név

Képlet

Eredmény (utónév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (vezetéknév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

  1. Vezetéknév

    Az utónév a karakterlánc első karakterétől (J) az ötödik karakteréig (szóköz) tart. A képlet az A2 cella balról számított első öt karakterét adja eredményül.

    Az utónevet kiolvasó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő szóköz balról számított helyének megkeresése.

  2. Utónév

    A vezetéknév a szóköznél kezdődik, öt karakter hosszú, és az utolsó karakterig (h) tart. A képlet az A2 cella jobb oldaltól számított első öt karakterét adja eredményül.

    A vezetéknevet kiolvasó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES és a HOSSZ függvénnyel keresse meg.

    Az A2 cellában szereplő szóköz balról számított helyének megkeresése (5).

  3. A szöveges karakterlánc teljes hosszának kiszámítása, majd ebből az 1. lépésben eredményül kapott, az első szóköztől balra vett karakterek számának kivonása.

Ez a példa a vezetéknevet, a középső kezdőbetűt és az utónevet használja. Egy szóköz választja el az egyes névösszetevőket.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Eric S. Kurjan

Egyetlen középső névkezdő betű

Képlet

Eredmény (utónév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (középső név kezdőbetűje)

'=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-SZÖVEG.KERES(" ";A2;1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-SZÖVEG.KERES(" ";A2;1))

Képlet

Dinamikus eredmény (vezetéknév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

  1. Vezetéknév

    Az utónév a karakterlánc balról számított első karakterétől (E) az ötödik karakteréig (az első szóközig) tart. A képlet az A2 cella balról számított első öt karakterét adja eredményül.

    Az utó- és a vezetéknevet, valamint a középső név kezdőbetűjét különválasztó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő szóköz balról számított helyének megkeresése (5).

  2. Középső név

    A középső név a hatodik karaktertől (S) a nyolcadik karakterig (a második szóközig) tart. A második szóköz megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet a hatodik karakterpozíciótól számított első három karaktert adja eredményül.

    Az utó- és a vezetéknevet, valamint a középső név kezdőbetűjét különválasztó képlet részletei

    A kezdet argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (5).

  3. Az eredmény növelése 1-gyel az első szóköz után található karakter (S) pozíciójának kiszámítása végett. Ez a szám a középső név kezdő karakterének pozíciója. (5 + 1 = 6)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (5).

  4. Az eredmény növelése 1-gyel az első szóköz után található karakter (S) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (5 + 1 = 6)

  5. Az A2 cellában található második szóköz megkeresése, a 4. lépésben eredményül kapott hatodik pozíciónál (S) kezdve. Ez a szám a középső név utolsó karakterének a pozíciója (8).

  6. Az A2 cellában szereplő szóköz helyének megkeresése a balról számított első karaktertől kezdve (5).

  7. Az első szóköz karakter 6. lépésben eredményül kapott pozícióértékének kivonása a második szóköz 5. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a karakterláncból a 2. lépésben eredményül kapott hatodik helytől kezdve. (8 - 5 = 3)

  8. Utónév

    A vezetéknév a jobbról számított hatodik karaktertől (K) a jobbról számított első karakterig (n) tart. A második és harmadik szóköz megkeresésére (amely a balról számított ötödik, illetve nyolcadik helyen található) a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet az A2 cella jobbról számított első hat karakterét adja eredményül.

    A második KERESÉS függvény az utó- és a vezetéknevet, valamint a középső név kezdőbetűjét különválasztó képletben
  9. A hány_karakter argumentum értékét a HOSSZ és a beágyazott SZÖVEG.KERES függvénnyel keresse meg.

    Az A2 cellában szereplő szóköz helyének megkeresése a balról számított első karaktertől kezdve (5).

  10. Az eredmény növelése 1-gyel az első szóköz után található karakter (S) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (5 + 1 = 6)

  11. Az A2 cellában található második szóköz megkeresése, a 4. lépésben eredményül kapott hatodik pozíciónál (S) kezdve. Ez a szám a középső név utolsó karakterének a pozíciója (8).

  12. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből a 3. lépésben eredményül kapott, a balról számított második szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (14-8 = 6).

A következő példa két középső név kiolvasásának módját mutatja be. Ezeket a névrészeket a szóköz első és a harmadik előfordulása határolja.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Janaina B. G. Bueno

Két középső név kezdőbetűje

Képlet

Eredmény (utónév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (középső nevek kezdőbetűi)

'=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1,SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1)-SZÖVEG.KERES(" ";A2;1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1,SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1)-SZÖVEG.KERES(" ";A2;1))

Képlet

Dinamikus eredmény (vezetéknév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

  1. Vezetéknév

    Az utónév a karakterlánc balról számított első karakterétől (J) a nyolcadik karakteréig (az első szóközig) tart. A képlet az A2 cella balról számított első nyolc karakterét adja eredményül.

    Utó- és vezetéknevet, valamint két középső név kezdőbetűjét különválasztó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (8).

  2. Középső név

    A középső név a kilencedik karaktertől (B) a tizennegyedik karakterig (a harmadik szóközig) tart. A nyolcadik, tizenegyedik és tizennegyedik helyen található első, második és harmadik szóköz megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet a kilencedik karakterpozíciótól számított első öt karaktert adja eredményül.

    Utó- és vezetéknevet, valamint két középső név kezdőbetűjét különválasztó képlet

    A kezdet argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz megkeresése a balról számított első karaktertől kezdve (8).

  3. Az eredmény növelése 1-gyel az első szóköz után található karakter (B) pozíciójának kiszámítása végett. Ez a szám a középső név kezdő karakterének pozíciója. (8 + 1 = 9)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz megkeresése a balról számított első karaktertől kezdve (8).

  4. Az eredmény növelése 1-gyel az első szóköz után található karakter (B) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (8 + 1 = 9)

  5. Az A2 cellában szereplő második szóköz helyének megkeresése, a 4. lépésben eredményül kapott kilencedik helytől (B) kezdve (11).

  6. Az eredmény növelése 1-gyel a második szóköz után található karakter (G) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a harmadik szóköz keresését. (11 + 1 = 12)

  7. Az A2 cellában szereplő harmadik szóköz helyének megkeresése, a 6. lépésben eredményül kapott tizenkettedik helytől kezdve (14).

  8. Az A2 cellában szereplő első szóköz helyének megkeresése (8).

  9. Az első szóköz 6. lépésben eredményül kapott pozícióértékének kivonása a harmadik szóköz 7. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a karakterláncból a 2. lépésben eredményül kapott hatodik helytől kezdve. (8 - 5 = 3)

  10. Utónév

    A vezetéknév a jobbról számított ötödik karaktertől (B) a jobbról számított első karakterig (o) tart. Az első, második és harmadik szóköz megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet az A2 cella jobbról számított első öt karakterét adja eredményül.

    Utó- és vezetéknevet, valamint két középső név kezdőbetűjét különválasztó képlet

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES és HOSSZ függvénnyel keresse meg.

    Az A2 cellában szereplő első szóköz megkeresése a balról számított első karaktertől kezdve (8).

  11. Az eredmény növelése 1-gyel az első szóköz után található karakter (B) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (8 + 1 = 9)

  12. Az A2 cellában szereplő második szóköz helyének megkeresése, a 2. lépésben eredményül kapott kilencedik helytől (B) kezdve (11).

  13. Az eredmény növelése 1-gyel a második szóköz után található karakter (G) pozíciójának kiszámítása végett. Az eredmény annak a kezdő karakternek a pozícióértéke, amelynél megkezdi a harmadik szóköz keresését. (11 + 1 = 12)

  14. Az A2 cellában szereplő harmadik szóköz helyének megkeresése, a 6. lépésben eredményül kapott tizenkettedik helytől (G) kezdve (14).

  15. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből az 5. lépésben eredményül kapott, a balról számított harmadik szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (19 -14 = 5)

Ebben a példában a vezetéknév megelőzi az utónevet, a középső név pedig hátulra kerül. A vessző a vezetéknév végét jelöli, és az egyes összetevőket szóköz választja el egymástól.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Kahn, Wendy Beth

Vezetéknév elsőként, vesszővel elválasztva

Képlet

Eredmény (utónév)

'=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-SZÖVEG.KERES(" ";A2;1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (második utónév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

Képlet

Dinamikus eredmény (vezetéknév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1)-2)

=BAL(A2; SZÖVEG.KERES(" ";A2;1)-2)

  1. Vezetéknév

    Az utónév a karakterlánc balról számított hetedik karakterétől (W) a tizenkettedik karakteréig (a második szóközig) tart. Mivel az utónév a teljes név közepénél kezdődik, kinyeréséhez használja a KÖZÉP függvényt.

    A képlet a hetedik karakterpozíciótól számított első hat karaktert adja eredményül.

    Vezetéknevet, valamint az utána álló utónevet és középső nevet különválasztó képlet

    A kezdet argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (6).

  2. Az eredmény növelése 1-gyel az első szóköz után található karakter (W) pozíciójának kiszámítása végett. Ez a szám az utónév kezdő karakterének pozíciója. (6 + 1 = 7)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (6).

  3. Az eredmény növelése 1-gyel az első szóköz után található karakter (W) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (6 + 1 = 7)

    Az A2 cellában szereplő második szóköz helyének megkeresése, a 4. lépésben eredményül kapott hetedik helytől (W) kezdve (12).

  4. Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (6).

  5. Az első szóköz karakter 6. lépésben eredményül kapott pozícióértékének kivonása a második szóköz 5. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a 2. lépésben eredményül kapott hetedik helytől kezdve. (12 - 6 = 6)

  6. Középső név

    A középső név a jobbról számított negyedik karaktertől (B) a jobbról számított első karakterig (h) tart. A balról számított hatodik, illetve tizenkettedik helyen található első, illetve második szóköz megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet a jobb oldaltól számított első négy karaktert adja eredményül.

    Vezetéknevet, valamint az utána álló utónevet és középső nevet különválasztó képlet

    A kezdet argumentum értékét a HOSSZ és a beágyazott SZÖVEG.KERES függvénnyel keresse meg.

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (6).

  7. Az eredmény növelése 1-gyel az első szóköz után található karakter (W) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (6 + 1 = 7)

  8. Az A2 cellában szereplő második szóköz helyének megkeresése, a 2. lépésben eredményül kapott hetedik helytől (W) kezdve (12).

  9. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből a 3. lépésben eredményül kapott, a balról számított második szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (16 -12 = 4)

  10. Utónév

    A vezetéknév a karakterlánc balról számított első karakterétől (K) a negyedik karakteréig (n) tart. A képlet a balról számított első négy karaktert adja eredményül.

    Vezetéknevet, valamint az utána álló utónevet és középső nevet különválasztó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (6).

  11. Az eredmény csökkentése 2-vel a vezetéknév utolsó karaktere (W) pozíciójának kiszámítása végett. Az eredmény azoknak a karakternek a száma, amelyeket ki szeretne nyerni a BAL függvénnyel. (6 - 2 = 4)

Ebben a példában az utónév két részből áll: Mary Kay. Az egyes névrészeket a második és a harmadik szóköz választja el egymástól.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Mary Kay D. Andersen

Kéttagú utónév

Képlet

Eredmény (utónév)

BAL(A2; SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

=BAL(A2; SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

Képlet

Eredmény (középső név kezdőbetűje)

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1)-(SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

Képlet

Dinamikus eredmény (vezetéknév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

  1. Vezetéknév

    Az utónév az első karaktertől a kilencedik karakterig (a második szóközig) tart. A második szóköz megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet a balról számított első kilenc karaktert adja eredményül.

    Utónevet, középső nevet, középső név kezdőbetűjét és vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (5).

  2. Az eredmény növelése 1-gyel az első szóköz után található karakter (K) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (5 + 1 = 6)

  3. Az A2 cellában található második szóköz megkeresése, a 2. lépésben eredményül kapott hatodik pozíciónál (K) kezdve. Az eredmény azoknak a karakternek a száma, amelyeket a BAL függvény kinyer a karakterláncból (9).

  4. Középső név

    A középső név a tizedik karaktertől (D) a tizenkettedik karakterig (a harmadik szóközig) tart. Az első, második és harmadik szóköz megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet középen található, a tizedik karakterpozíciótól számított első két karaktert adja eredményül.

    Utónevet, középső nevet, középső név kezdőbetűjét és vezetéknevet különválasztó képlet

    A kezdet argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz helyének megkeresése a balról számított első karaktertől kezdve (5).

  5. Az eredmény növelése 1-gyel az első szóköz után található karakter (K) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (5 + 1 = 6)

  6. Az A2 cellában található második szóköz megkeresése, a 2. lépésben eredményül kapott hatodik pozíciónál (K) kezdve. Az eredmény azoknak a karakternek a száma, amelyeket a BAL függvény kinyer, balról számítva (9).

  7. Az eredmény növelése 1-gyel a második szóköz után található karakter (D) pozíciójának kiszámítása végett. Az eredmény a középső név kezdő karakterének pozíciója. (9 + 1 = 10)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    A második szóköz után található karakter (D) pozíciójának megkeresése. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a harmadik szóköz keresését (10).

  8. Az A2 cellában szereplő, balról harmadik szóköz helyének megkeresése. Az eredmény a középső név utolsó karakterének pozíciója (12).

  9. Az A2 cellában szereplő, a második szóköz utáni karakter pozíciójának megkeresése. Az eredmény a középső név első karakterének pozíciója (10).

  10. A „D” karakter 7. lépésben eredményül kapott pozícióértékének kivonása a harmadik szóköz 6. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a karakterláncból a 4. lépésben eredményül kapott tizedik helytől kezdve. (12 -10 = 2)

  11. Utónév

    A vezetéknév a jobbról számított nyolcadik karakternél kezdődik. Az ötödik, kilencedik és tizenkettedik helyen található első, második és harmadik szóköz megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet a jobbról számított első nyolc karaktert adja eredményül.

    Utónevet, középső nevet, középső név kezdőbetűjét és vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a HOSSZ és a beágyazott SZÖVEG.KERES függvénnyel keresse meg.

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (5).

  12. Az eredmény növelése 1-gyel az első szóköz után található karakter (K) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (5 + 1 = 6)

  13. Az A2 cellában szereplő második szóköz helyének megkeresése, a 2. lépésben eredményül kapott hatodik helytől (K) kezdve (9).

  14. Az eredmény növelése 1-gyel a második szóköz után található karakter (D) pozíciójának kiszámítása végett. Az eredmény a középső név kezdő karakterének a pozíciója. (9 + 1 = 10)

  15. Az A2 cellában szereplő, balról harmadik szóköz helyének megkeresése. Az eredmény a középső név utolsó karakterének pozíciója (12).

  16. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből az 5. lépésben eredményül kapott, a balról számított harmadik szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (20 -12 = 8)

Ebben a példában három részből álló vezetéknév (Barreto de Mattos) szerepel. Az első szóköz jelöli az utónév végét és a vezetéknév kezdetét.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Paula Barreto de Mattos

Háromtagú vezetéknév

Képlet

Eredmény (utónév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (vezetéknév)

JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

  1. Vezetéknév

    Az utónév a karakterlánc balról számított első karakterétől (P) a hatodik karakteréig (az első szóközig) tart. A képlet a balról számított első hat karaktert adja eredményül.

    Utónevet és három részből álló vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  2. Utónév

    A vezetéknév a jobbról számított tizenhetedik karaktertől (B) a jobbról számított első karakterig (s) tart. A képlet a jobbról számított első tizenhét karaktert adja eredményül.

    Utónevet és három részből álló vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a HOSSZ és a SZÖVEG.KERES függvénnyel keresse meg.

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  3. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből az 1. lépésben eredményül kapott, a balról számított első szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (23 - 6 = 17)

Ebben a példában két részből álló vezetéknév (van Eaton) szerepel. Az első szóköz jelöli az utónév végét és a vezetéknév kezdetét.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

James van Eaton

Kéttagú vezetéknév

Képlet

Eredmény (utónév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (vezetéknév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

  1. Vezetéknév

    Az utónév a karakterlánc balról számított első karakterétől (J) a nyolcadik karakteréig (az első szóközig) tart. A képlet a balról számított első nyolc karaktert adja eredményül.

    Utónevet és két részből álló vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresheti meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  2. Utónév

    A vezetéknév a karakterlánc jobbról számított kilencedik karakterétől (v) a jobbról számított első karakteréig (n) tart. A képlet a teljes név jobbról számított első kilenc karakterét adja eredményül.

    Utónevet és két részből álló vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a HOSSZ és a SZÖVEG.KERES függvénnyel keresse meg.

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  3. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből az 1. lépésben eredményül kapott, a balról számított első szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (15 - 6 = 9)

Ebben a példában a vezetéknév áll elöl, és egy utótag követi. A vessző a vezetéknév és az utótag együttesét választja el az utónévből és a középső kezdőbetűből álló résztől.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Bacon Jr., Dan K.

Vezetéknév és utótag elsőként, vesszővel elválasztva

Képlet

Eredmény (utónév)

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

Képlet

Eredmény (középső név kezdőbetűje)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)+1))

Képlet

Eredmény (vezetéknév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (utótag)

'=KÖZÉP(A2;SZÖVEG.KERES(" "; A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-2)-SZÖVEG.KERES(" ";A2;1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;(SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-2)-SZÖVEG.KERES(" ";A2;1))

  1. Vezetéknév

    Az utónév a karakterlánc tizenkettedik karakterétől (D) a tizenötödik karakteréig (a harmadik szóközig) tart. A képlet a tizenkettedik karakterpozíciótól számított első három karaktert adja eredményül.

    Vezetéknevet és utótagot elsőként, vesszővel különválasztó képlet

    A kezdet argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  2. Az eredmény növelése 1-gyel az első szóköz után található karakter (J) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (6 + 1 = 7)

  3. Az A2 cellában szereplő második szóköz helyének megkeresése, a 2. lépésben eredményül kapott hetedik helytől (J) kezdve (11).

  4. Az eredmény növelése 1-gyel a második szóköz után található karakter (D) pozíciójának kiszámítása végett. Az eredmény az utónév kezdő karakterének pozíciója. (11 + 1 = 12)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    A második szóköz után található karakter (D) pozíciójának megkeresése. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a harmadik szóköz keresését (12).

  5. Az A2 cellában szereplő, balról harmadik szóköz helyének megkeresése. Az eredmény az utónév utolsó karakterének pozíciója (15).

  6. Az A2 cellában szereplő, a második szóköz utáni karakter pozíciójának megkeresése. Az eredmény az utónév első karakterének pozíciója (12).

  7. A „D” karakter 7. lépésben eredményül kapott pozícióértékének kivonása a harmadik szóköz 6. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a karakterláncból a 4. lépésben eredményül kapott tizenkettedik helytől kezdve. (15 -12 = 3)

  8. Középső név

    A középső név a jobbról számított második karakterrel (K) kezdődik. A képlet a jobbról számított első két karaktert adja eredményül.

    Vezetéknevet és utótagot elsőként, vesszővel különválasztó képlet

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  9. Az eredmény növelése 1-gyel az első szóköz után található karakter (J) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (6 + 1 = 7)

  10. Az A2 cellában szereplő második szóköz helyének megkeresése, a 2. lépésben eredményül kapott hetedik helytől (J) kezdve (11).

  11. Az eredmény növelése 1-gyel a második szóköz után található karakter (D) pozíciójának kiszámítása végett. Az eredmény az utónév kezdő karakterének pozíciója. (11 + 1 = 12)

  12. Az A2 cellában szereplő, balról harmadik szóköz helyének megkeresése. Az eredmény a középső név utolsó karakterének pozíciója (15).

  13. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből az 5. lépésben eredményül kapott, a balról számított harmadik szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (17 -15 = 2)

  14. Utónév

    A vezetéknév a karakterlánc balról számított első karakterétől (B) a hatodik karakteréig (az első szóközig) tart. A képlet tehát a balról számított első hat karaktert adja eredményül.

    Vezetéknevet és utótagot elsőként, vesszővel különválasztó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  15. Utótag

    Az utótag a karakterlánc balról számított hetedik karakterétől (J) a kilencedik karakteréig (.) tart. A képlet a hetedik karaktertől számított első három karaktert adja eredményül.

    Vezetéknevet és utótagot elsőként, vesszővel különválasztó képlet

    A kezdet argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  16. Az eredmény növelése 1-gyel az első szóköz után található karakter (J) pozíciójának kiszámítása végett. Az eredmény az utótag kezdő karakterének pozíciója. (6 + 1 = 7)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  17. Az eredmény növelése 1-gyel az első szóköz után található karakter (J) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését (7).

  18. Az A2 cellában szereplő második szóköz helyének megkeresése, a 4. lépésben eredményül kapott hetedik karaktertől kezdve (11).

  19. 1 kivonása a második szóköz 4. lépésben eredményül kapott pozíciójából a "," karakter pozícióértékének kiszámítása végett. Az eredmény az utótag utolsó karakterének a pozíciója. (11 - 1 = 10)

  20. Az első szóköz helyének megkeresése (6).

  21. Az első szóköz megtalálása után a következő karakter (J) pozíciójának megadása 1 hozzáadásával, amely megegyezik a 3. és 4. lépésben is kiszámított értékkel. (7)

  22. A „J” karakter 3. és 4. lépésben eredményül kapott pozícióértékének kivonása a „,” karakter 6. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a karakterláncból a 2. lépésben eredményül kapott hetedik karaktertől kezdve. (10 -7 = 3)

Ebben a példában az utónév a karakterlánc elején van, az utótag pedig a végén, így a 2. példáéhoz hasonló képletek használhatók: a BAL függvénnyel olvasható ki az utónév, a KÖZÉPSŐ függvénnyel a vezetéknév, a JOBB függvénnyel pedig az utótag.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Gary Altman III

Utónév és vezetéknév utótaggal

Képlet

Eredmény (utónév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (vezetéknév)

'=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-(SZÖVEG.KERES(" ";A2;1)+1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-(SZÖVEG.KERES(" ";A2;1)+1))

Képlet

Eredmény (utótag)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

  1. Vezetéknév

    Az utónév a karakterlánc balról számított első karakterétől (G) az ötödik karakteréig (az első szóközig) tart. A képlet tehát a teljes név balról számított első öt karakterét adja eredményül.

    Utónevet és vezetéknevet, valamint az utána álló utótagot különválasztó képlet

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (5).

  2. Utónév

    A vezetéknév a balról számított hatodik karaktertől (A) a tizenegyedik karakterig (a második szóközig) tart. A szóközök megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    A képlet a középen található, a hatodik karaktertől számított első hat karaktert adja eredményül.

    Utónevet és vezetéknevet, valamint az utána álló utótagot különválasztó képlet

    A kezdet argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (5).

  3. Az eredmény növelése 1-gyel az első szóköz után található karakter (A) pozíciójának kiszámítása végett. Az eredmény a vezetéknév kezdő karakterének a pozíciója. (5 + 1 = 6)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (5).

  4. Az eredmény növelése 1-gyel az első szóköz után található karakter (A) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (5 + 1 = 6)

  5. Az A2 cellában található második szóköz megkeresése, a 4. lépésben eredményül kapott hatodik karakternél kezdve. Ez a szám a vezetéknév utolsó karakterének a pozíciója (12).

  6. Az első szóköz helyének megkeresése (5).

  7. 1 hozzáadása az első szóköz utáni karakter (A) pozíciójának a meghatározásához a 3. és a 4. lépéshez hasonlóan (6).

  8. Az „A” karakter 6. és 7. lépésben eredményül kapott pozícióértékének kivonása a második szóköz 5. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a karakterláncból a 2. lépésben eredményül kapott hatodik helytől kezdve. (12 - 6 = 6)

  9. Utótag

    Az utótag a jobbról számított harmadik karakternél kezdődik. A szóközök megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    Utónevet és vezetéknevet, valamint az utána álló utótagot különválasztó képlet

    A hány_karakter argumentum értékét a HOSSZ és a beágyazott SZÖVEG.KERES függvénnyel keresse meg.

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (5).

  10. Az eredmény növelése 1-gyel az első szóköz után található karakter (A) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (5 + 1 = 6)

  11. Az A2 cellában szereplő második szóköz helyének megkeresése, a 2. lépésben eredményül kapott hatodik helytől (A) kezdve (12).

  12. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből a 3. lépésben eredményül kapott, a balról számított második szóközig vett karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (15 -12 = 3)

Ebben a példában a teljes nevet megelőzi egy előtag, és a 2. példáéhoz hasonló képletek használhatók: a KÖZÉP függvény olvassa ki az utónevet, a JOBB függvény pedig a vezetéknevet.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Mr. Ryan Ihrig

Előtag

Képlet

Eredmény (utónév)

'=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-(SZÖVEG.KERES(" ";A2;1)+1))

=KÖZÉP(A2;SZÖVEG.KERES(" ";A2;1)+1;SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1)-(SZÖVEG.KERES(" ";A2;1)+1))

Képlet

Eredmény (vezetéknév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;SZÖVEG.KERES(" ";A2;1)+1))

  1. Vezetéknév

    Az utónév a karakterlánc balról számított ötödik karakterétől (R) a kilencedik karakteréig (a második szóközig) tart. A szóközök megkeresésére a képletbe ágyazott SZÖVEG.KERES függvény szolgál. A képlet az ötödik helytől számított négy karaktert adja eredményül.

    Utónevet és az azt megelőző előtagot különválasztó képlet

    A kezdet argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (4).

  2. Az első szóköz utáni karakter (R) pozíciójának megadása 1 hozzáadásával. Az eredmény az utónév kezdő pozíciója. (4 + 1 = 5)

    A hány_karakter argumentum értékét a beágyazott SZÖVEG.KERES függvényekkel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (4).

  3. Az eredmény növelése 1-gyel az első szóköz után található karakter (R) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (4 + 1 = 5)

  4. Az A2 cellában található második szóköz megkeresése, a 3. és 4. lépésben eredményül kapott ötödik karakternél kezdve. Ez a szám az utónév utolsó karakterének a pozíciója (9).

  5. Az első szóköz pozíciójának megkeresése. (4)

  6. 1 hozzáadása az első szóköz utáni karakter (R) pozíciójának a meghatározásához a 3. és a 4. lépéshez hasonlóan (5).

  7. Az „R” karakter 6. és 7. lépésben eredményül kapott pozícióértékének kivonása a második szóköz 5. lépésben eredményül kapott pozícióértékéből. Az eredmény azoknak a karaktereknek a száma, amelyeket a KÖZÉP függvény kinyer a karakterláncból a 2. lépésben eredményül kapott ötödik helytől kezdve. (9 - 5 = 4)

  8. Utónév

    A vezetéknév a jobbról számított ötödik karakternél kezdődik. A szóközök megkeresésére a képletbe ágyazott SZÖVEG.KERES függvények szolgálnak.

    Utónevet és az azt megelőző előtagot különválasztó képlet

    A hány_karakter argumentum értékének meghatározása egymásba ágyazott SZÖVEG.KERES függvényekkel és a HOSSZ függvénnyel:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (4).

  9. Az eredmény növelése 1-gyel az első szóköz után található karakter (R) pozíciójának kiszámítása végett. Az eredmény annak a karakternek a pozícióértéke, amelynél megkezdi a második szóköz keresését. (4 + 1 = 5)

  10. Az A2 cellában szereplő második szóköz helyének megkeresése, a 2. lépésben eredményül kapott ötödik helytől (R) kezdve (9).

  11. Az A2 cellában található szöveges karakterlánc teljes hosszának kiszámítása, majd ebből a 3. lépésben eredményül kapott, a balról második szóközig számított karakterek számának kivonása. Az eredmény azoknak a karaktereknek a száma, amelyeket ki fog nyerni a teljes név jobb oldalától számítva. (14 - 9 = 5)

Ebben a példában a vezetéknév kötőjeles. A névrészeket szóköz választja el egymástól.

Másolja a cellákat a táblázatban, és illessze be egy Excel-munkalapba az A1 cellánál kezdődően. A bal oldalon látható képlet referenciaként jelenik meg, míg az Excel automatikusan a megfelelő eredménnyé konvertálja a jobb oldali képletet.

Tipp:    Mielőtt beillesztené az adatokat a munkalapra, állítsa az A és a B oszlop szélességét 250-re.

Példa neve

Leírás

Julie Taft-Rider

Kötőjeles vezetéknév

Képlet

Eredmény (utónév)

'=BAL(A2; SZÖVEG.KERES(" ";A2;1))

=BAL(A2; SZÖVEG.KERES(" ";A2;1))

Képlet

Eredmény (vezetéknév)

'=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

=JOBB(A2;HOSSZ(A2)-SZÖVEG.KERES(" ";A2;1))

  1. Vezetéknév

    Az utónév a karakterlánc balról számított első karakterétől a hatodik karakteréig (az első szóközig) tart. A képlet a balról számított első hat karaktert adja eredményül.

    Utónevet és kötőjeles vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a SZÖVEG.KERES függvénnyel keresse meg:

    Az A2 cellában szereplő első szóköz balról számított helyének megkeresése (6).

  2. Utónév

    A vezetéknév a jobbról számított tizedik karaktertől (T) a jobbról számított első karakterig (r) tart.

    Utónevet és kötőjeles vezetéknevet különválasztó képlet

    A hány_karakter argumentum értékét a HOSSZ és a SZÖVEG.KERES függvénnyel keresse meg.

    Az A2 cellában szereplő szóköz helyének megkeresése a balról számított első karaktertől kezdve (6).

  3. A szöveges karakterlánc teljes hosszának kiszámítása, majd ebből az 1. lépésben eredményül kapott, a balról számított első szóközig vett karakterek számának kivonása (16 - 6 = 10).

Lásd még

Szöveg felosztása különböző oszlopokba a Szövegdaraboló varázslóval

Ismeretek bővítése
Oktatóanyagok megismerése
Új szolgáltatások listájának lekérése
Részvétel az Office Insider programban

Hasznos volt az információ?

Köszönjük a visszajelzését!

Köszönjük visszajelzését. Jobbnak látjuk, ha az Office egyik támogatási szakemberéhez irányítjuk.

×