Megjegyzés: Szeretnénk, ha minél gyorsabban hozzáférhetne a saját nyelvén íródott súgótartalmakhoz. Ez az oldal gépi fordítással lett lefordítva, ezért nyelvtani hibákat és pontatlanságokat tartalmazhat. A célunk az, hogy ezek a tartalmak felhasználóink hasznára váljanak. Kérjük, hogy a lap alján írja meg, hogy hasznos volt-e az Ön számára az itt található információ. Az eredeti angol nyelvű cikket itt találja .
Ha Excel-táblázat létrehozása, az Excel rendel nevét a táblázat, és a táblázat minden egyes oszlop fejlécére. Képlet hozzáadása Excel-táblázat, amikor azokat a neveket is jelennek meg automatikusan, írja be a képletet, és jelölje ki a cellahivatkozások a táblázatban őket manuális beírása helyett. Íme egy példa Excel leírása:
A közvetlen cellahivatkozások használata helyett |
az Excel táblázat- és oszlopneveket használ |
=SZUM(C2:C7) |
=SZUM(Bevételek[Értékesítési mennyiség]) |
A táblázat- és oszlopnevek kombinációját strukturált hivatkozásnak nevezzük. A hivatkozásban lévő nevek mindig igazodnak, amikor adatokkal bővíti a táblázatot, vagy éppen adatokat töröl.
Strukturált hivatkozások jelennek meg akkor is, amikor az Excel-táblázaton kívül hoz létre olyan képletet, amely a táblázat adataira hivatkozik. A hivatkozások segítségével könnyebb megtalálni a táblázatokat a nagy munkafüzetekben.
Ha strukturált hivatkozásokat szeretne használni a képletben, a cellahivatkozások képletbe írása helyett kattintson a hivatkozni kívánt táblázatcellákra. Példaként használjuk az alábbi adatokat egy olyan képlet beírásához, amely automatikusan strukturált hivatkozásokat használ az értékesítési jutalék összegének kiszámítására.
Értékesítés Személy |
Régió |
Értékesítési mennyiség |
Jutalék% |
Jutalékok |
András |
Észak |
260 |
10% |
|
Péter |
Dél |
660 |
15% |
|
Balázs |
Kelet |
940 |
15% |
|
Szabolcs |
Nyugat |
410 |
12% |
|
Ágnes |
Észak |
800 |
15% |
|
Zoltán |
Dél |
900 |
15% |
-
Másolja a vágólapra mintaadatokat fent, a táblázat az oszlopfejlécekkel együtt, és illessze be egy új Excel-munkalap A1 cellájába.
-
A táblázat létrehozásához jelölje ki az adattartomány bármelyik celláját, és nyomja le a Ctrl + T billentyűkombinációt.
-
Győződjön meg arról, hogy a Táblázat rovatfejekkel jelölőnégyzetet, és kattintson az OK gombra.
-
Írjon be egy egyenlőségjelet (=) az E2 cellába, majd kattintson a C2 cellára.
Ekkor a szerkesztőlécen, az egyenlőségjel után megjelenik az [@[Értékesítési mennyiség]] strukturált hivatkozás.
-
Írjon be egy csillagot (*) közvetlenül a záró zárójel után, és kattintson a D2 cellára.
Ekkor a szerkesztőlécen, a csillag után megjelenik a [@[Jutalék%]] strukturált hivatkozás.
-
Nyomja meg az Enter.
Az Excel automatikusan létrehoz egy számított oszlopot, és az oszlop minden egyes cellájába bemásolja a képletet, az egyes sorokhoz igazítva.
Mi történik, ha közvetlen cellahivatkozásokat használok?
Ha egy számított oszlopba közvetlen cellahivatkozásokat ír, akkor nehezebb lehet meghatározni, hogy mit számít ki a képlet.
-
A mintamunkalapon kattintson az E2 cellára
-
Írja be a szerkesztőlécen = C2 * D2 , és nyomja le az ENTER billentyűt.
Figyelje meg, hogy bár az Excel az oszlop minden cellájára alkalmazza a képletet, mégsem használ strukturált hivatkozást. Ha most beszúrna egy oszlopot a meglévő C és D oszlop közé, akkor át kellene írnia a képletet.
Hogyan tudom módosítani a táblázatok nevét?
Az Excel minden létrehozott Excel-táblázathoz társít egy alapértelmezett táblázatnevet (Táblázat1, Táblázat2 stb.). Ezt a nevet módosíthatja, hogy leíróbb legyen.
-
Jelöljön ki egy cellát a táblázatban kattintva jelenítse meg a Táblázateszközök > Tervezés lap a menüszalagon.
-
Írja be a nevet, amelyet a Táblázat neve mezőbe, és nyomja le az ENTER billentyűt.
A példaadatokban ez a név a Bevételek.
Táblanevek használja a következő szabályokat:
-
Érvényes karakterek használata Mindig indítsa el a nevét az betű, az aláhúzásjelet (_), vagy fordított perjelet (\). Használja a betűk, számok, időszakok, és aláhúzás karakterek – a többség nevét. Nem használható a "C"; "c", "R" vagy "r" a jelölőnégyzetét, mert már az aktív cella sor vagy oszlop kijelölése, a név vagy Ugrás mezőbe írva billentyűparancsként éppen kijelölt.
-
Nem lehet cellahivatkozással azonos A nevek nem lehetnek azonosak cellahivatkozásokkal például Z$ 100 vagy S1O1.
-
Nem tartalmazhat szóközt külön szavakra Szóköz nem használható a nevében. Használhatja a word elválasztójelek az aláhúzásjelet (_) és a pont (.). Ha például bevételek,: forgalmi.adó vagy First.Quarter.
-
Nem lehet 255 karakternél hosszabb: A táblázatok neve legfeljebb 255 karakterből állhat.
-
Egyedinek kell lennie: Nem lehet több táblázatnak ugyanaz a neve. Az Excel a beírt nevekben nem különbözteti meg a nagy és kis betűket. Ha például az „Eladások” nevet írja be, de létezik már egy „ELADÁSOK” táblázat ugyanabban a munkafüzetben, akkor az alkalmazás kérni fogja egy egyedi név megadását.
-
Objektumazonosító használata Ha a kombinálja a táblázatok, kimutatások és a diagramok problémákat, célszerű az előtag a nevek, az objektum típusa. Példa: egy értékesítési táblában, egy kimutatás értékesítések pt_Sales és értékesítési diagram chrt_Sales vagy értékesítési kimutatásdiagram ptchrt_Sales tbl_Sales. Ez tartja a nevek, az összes olyan rendezett listát a Névkezelő.
A strukturált hivatkozások szintaktikai szabályai
Is adja meg, illetve módosíthatja a strukturált hivatkozások manuális a képletben, de ehhez azonban segít megérteni a strukturált hivatkozások szintaktikai. A következő képlet például nézzünk:
=SZUM(Bevételek[[#Összegek];[Értékesítési mennyiség]];Bevételek[[#Adatok];[Jutalékok]])
A képlet a strukturált hivatkozások alábbi összetevőit tartalmazza:
-
Táblanév: Bevételek egyéni táblázatnév. A táblázat adatait, anélkül, hogy minden élőfej vagy az összeg sor hivatkozik. Alapértelmezett táblázat, tábla1, például a nevet, vagy módosításáról az egyéni nevet.
-
Oszlopkijelölő: [Értékesítési mennyiség]és[Jutalékok], hogy a név, az oszlopok jelölnek oszlopkijelölők vannak. Azok a hivatkozás az oszlop adatai nélkül oszlop élőfej vagy az összeg sor. Mindig zárójelben kijelölőkről látható módon.
-
Elemkijelölő: [#Totals] és [#Data] olyan speciális Elemkijelölők, amelyek, például az összesítősorra a táblázat adott részeire hivatkozik.
-
Táblázatkijelölő: Az [[#Összegek];[Értékesítési mennyiség]] és [[#Adatok];[Jutalékok]] táblázatkijelölők, amelyek a strukturált hivatkozás külső részeire hivatkoznak. A külső hivatkozások a táblázat nevét követik, és szögletes zárójelek közé kell tenni őket.
-
Strukturált hivatkozás: (Bevételek [[#Totals], [értékesítési mennyiség]] és bevételek [[#Data], [jutalékok]] strukturált hivatkozás – olyan karakterlánc, amely a táblázat nevével kezdődik és az oszlopkijelölővel fejeződik.
A strukturált hivatkozások manuális létrehozásakor és szerkesztésekor a következő szintaktikai szabályokat alkalmazza:
-
Zárójelek használata a körül: Táblázat, oszlop és speciális elemek azonosítója kell egyező szögletes zárójel ([]) idézőjelekbe kell foglalni. Egy másik kijelölőkről tartalmazó módosulnak az idézőjelek közé kell tenni a belső zárójelek a kijelölőkben: a megfelelő külső egyező szögletes zárójelek között van szükség. Példa: = bevételek [[értékesítő]: [Körzet]]
-
Az összes az oszlopfejlécek szöveges karakterláncok De árajánlatok azok nincs szükség, ha azokat a strukturált hivatkozások megszokott. Számok vagy dátumok, például 2014-es vagy az 1/1/2014-es, is figyelembe szöveges karakterláncot. Az oszlopfejlécek nem használhatók a kifejezések. Ha például a kifejezés Pénzügyiévekbevételei [[2014-es]: [2012]] nem fog működni.
Szögletes zárójelek a speciális karaktereket tartalmazó oszlopfejlécek körül: Ha speciális karaktereket tartalmaz, a teljes oszlopfejléc szögletes zárójelek közé írandó. Az ilyen oszlopfejlécet tartalmazó oszlopkijelölőnél tehát dupla szögletes zárójelre van szükség. Például: =PénzügyiÉvekBevételei[[Össz Ft bevétel]]
Az alábbi listában szereplő speciális karakterek esetén van szükség szögletes zárójelre:
-
TAB
-
Új sor (LF)
-
Kocsi vissza (CR)
-
Vessző (,)
-
Kettőspont (:)
-
Pont (.)
-
Bal oldali szögletes zárójel ([)
-
Jobb oldali szögletes zárójel (])
-
Kettős kereszt (#)
-
Aposztróf (')
-
Idézőjel (")
-
Bal oldali kapcsos zárójel ({)
-
Jobb oldali kapcsos zárójel (})
-
Dollárjel ($)
-
Kalap (^)
-
És-jel (&)
-
Csillag (*)
-
Pluszjel (+)
-
Egyenlőségjel (=)
-
Mínuszjel (-)
-
Nagyobb, mint jel (>)
-
Kisebb, mint jel (<)
-
Osztásjel (/)
-
Escape-karakter használata bizonyos speciális karakternél az oszlopfejlécben: Bizonyos karakterek különleges jelentéssel bírnak, és ezért aposztróf (') karaktert szükséges írni eléjük escape-karakterként. Például: =PénzügyiÉvekBevételei['#Tétel]
Az alábbiakban a listában szereplő speciális karakterek esetén van szükség escape-karakterre (') a képlet:
-
Bal oldali szögletes zárójel ([)
-
Jobb oldali szögletes zárójel (])
-
Kettős kereszt(#)
-
Aposztróf (')
Szóköz használata a strukturált hivatkozások olvashatóságának javítására: Szóközök segítségével javíthatja a strukturált hivatkozások olvashatóságát az alábbi módon: Példa: =Bevételek[ [Értékesítő]:[Körzet] ] vagy =Bevételek[[#Fejlécek]; [#Adatok]; [Jutalék%]]
Az alábbi helyeken ajánlott egy szóközkarakter használata:
-
Az első bal oldali kapcsolatos zárójel ([) után.
-
Az utolsó jobb oldali kapcsos zárójel (]) előtt.
-
Vessző után.
Hivatkozási operátorok
A cellatartományok rugalmasabb megadását segítik az oszlopkijelöléseket kombináló alábbi hivatkozási operátorok.
Strukturált hivatkozás |
Hivatkozott elem |
Operátor |
Megfelelő cellatartomány |
=Bevételek[[Értékesítő]:[Körzet]] |
Szomszédos oszlopok összes cellája |
: (kettőspont) tartományoperátor |
A2:B7 |
=Bevételek[Értékesítési mennyiség];Bevételek[Jutalékok] |
Oszlopok együttese |
; (pontosvessző) összevonási operátor |
C2:C7; E2:E7 |
=Bevételek[[Értékesítő]:[Értékesítési mennyiség]] Bevételek[[Körzet]:[Jutalék%]] |
Oszlopok metszete |
(szóköz) metszetoperátor |
B2:C7 |
Hivatkozás speciális táblázatelemekre
Ha a táblázat bizonyos részeire akar hivatkozni, például csak az összesítősorra, használja az alábbi speciális elemkijelölőket a strukturált hivatkozásában:
Speciális kijelölő |
Hivatkozott elem |
#Minden |
A teljes táblázat az oszlopfejlécekkel, adatokkal és összesítésekkel együtt (ha vannak). |
#Adatok |
Csak az adatsorok. |
#Fejlécek |
Csak a táblázat fejlécsora. |
#Összegek |
Csak az összesítősor. Ha nincs összesítősor, null a visszaadott érték. |
#Ez a sor vagy @ vagy @[Oszlopnév] |
Csak a képlettel azonos sorban lévő cellák. Ezek a kijelölők nem használhatók egyéb speciális elemkijelölőkkel együtt. A kijelölő implicit módon előállítja a hivatkozott elemek metszetét, illetve az implicit metszet felülbírálására is alkalmas. A kijelölővel egyenként hivatkozhatók egy oszlop értékei. Az Excel automatikusan módosítja az #Ez a sor kijelölőket a @ kijelölőre a táblázatokban, amelyekben több adatsor található. De ha táblázatában egyetlen sor található, az Excel nem cseréli le az #Ez a sor kijelölőt, ami több sor hozzáadásakor váratlan számítási eredményekkel járhat. A számítási problémák elkerülése végett a strukturált hivatkozásokat tartalmazó képletek megadása előtt vegyen fel több sort a táblázatába. |
Strukturált hivatkozások minősítése számított oszlopokban
A számított oszlopokban célszerű strukturált hivatkozással megadni a képleteket. A strukturált hivatkozás minősítés nélküli vagy teljesen minősített lehet. A jutalékot forintban kiszámító „Jutalék” számított oszlop képlete például a következő táblázatban látható formákban adható meg.
Strukturált hivatkozás típusa |
Példa |
Megjegyzés |
Nem minősített |
=[Értékesítési mennyiség]*[Jutalék%] |
Az aktuális sor megfelelő értékeinek szorzata |
Teljesen minősített |
=Bevételek[Értékesítési mennyiség]*Bevételek[Jutalék%] |
A két oszlop megfelelő értékeinek soronkénti szorzata |
Az általánosan követendő szabály a következő: ha egy táblázaton belül strukturált hivatkozásokat használ, például számított oszlop létrehozásakor, használhat nem minősített strukturált hivatkozást, de ha a strukturált hivatkozást a táblázaton kívül használja fel, teljesen minősített strukturált hivatkozásra van szüksége.
Példák a strukturált hivatkozások használatára
Az alábbi példák bemutatják, hogyan használhatja a strukturált hivatkozásokat.
Strukturált hivatkozás |
Hivatkozott elem |
Megfelelő cellatartomány |
=Bevételek[[#Minden];[Értékesítési mennyiség]] |
Az Értékesítési mennyiség oszlopban lévő összes cella. |
C1:C8 |
=Bevételek[[#Fejlécek];[Jutalék%]] |
A Jutalék% oszlop fejléce. |
D1 |
=Bevételek[[#Összegek];[Körzet]] |
A Körzet oszlop összesítése. Ha nincs összesítősor, a kifejezés eredménye null. |
B8 |
=Bevételek[[#Minden];[Értékesítési mennyiség]:[Jutalék%]] |
Az Értékesítési mennyiség és a Jutalék% oszlopban lévő összes cella. |
C1:D8 |
=Bevételek[[#Adatok];[Jutalék%]:[Jutalékok]] |
Csak a Jutalék% és a Jutalékok oszlop adatai. |
D2:E7 |
=Bevételek[[#Fejlécek];[Körzet]:[Jutalékok]] |
Csak a Körzet és a Jutalék oszlop közötti oszlopok fejlécei. |
B1:E1 |
=Bevételek[[#Összegek];[Értékesítési mennyiség]:[Jutalékok]] |
Az Értékesítési mennyiség és a Jutalékok oszlop összesítése. Ha nincs összesítősor, a visszaadott érték null. |
C8:E8 |
=Bevételek[[#Fejlécek];[#Adatok];[Jutalék%]] |
Csak a Jutalék% oszlop fejléce és adatai. |
D1:D7 |
=Bevételek[[#Ez a sor]; [Jutalékok]] vagy =Bevételek[@Jutalékok] |
Az aktuális sor és a jutalék oszlop metszeténél található cella. Ha használja az élőfejbe vagy az összeg sor ugyanebben a sorban, ez ad vissza egy #VALUE! hiba. Ha ennek a strukturált hivatkozásnak (#Ez a sor) a hosszabb formáját írja be egy több adatsort tartalmazó táblázatba, az Excel automatikusan helyettesíti azt a rövidebb formával (@). Mindkettő ugyanúgy működik. |
E5 (ha az aktuális sor az 5.) |
Stratégiák a strukturált hivatkozások használatára
Az alábbiakban néhány tanácsot és más tudnivalókat talál a strukturált hivatkozások használatához.
-
Automatikus Képletkiegészítés használata Előfordulhat, hogy az automatikus Képletkiegészítés használata nagyon hasznos a strukturált hivatkozások beírásakor, mivel a helyes szintaxis. További tudnivalókért olvassa el a Képletkiegészítés használatacímű témakört.
-
Döntés a strukturált hivatkozások előnyben félig körét Alapértelmezés szerint létrehozásakor a egyik cellájába képletet belül egy táblázat félig kiválasztása tartományba a cellákat, és automatikusan beírja a képlet a strukturált hivatkozások helyett a cellatartományt. Ez a jelenség részesítése megkönnyíti sokkal adja meg a strukturált hivatkozások. Úgy kapcsolhatja be- és kikapcsolása a jelenség, hogy bejelölésével, illetve törölje a jelet a Képletek használata a táblanevek jelölőnégyzetet, a fájl > Beállítások > képletek > Képletek használata párbeszédpanel.
-
Használja a más munkafüzetek Excel-táblázataira mutató külső hivatkozásokat tartalmazó munkafüzetek Ha a munkafüzet egy másik munkafüzetben lévő Excel-táblázathoz külső hivatkozást tartalmaz, a csatolt forrásként használt munkafüzetben kell lennie elkerülése érdekében az Excel alkalmazásban megnyitott #REF! hibákat a célként megadott munkafüzetet, amely hivatkozásokat tartalmaz. Ha először nyitja meg a célként megadott munkafüzetet, és #REF! hibák jelennek meg ezek lesznek megoldott Ha, majd nyissa meg a forrásul szolgáló munkafüzetet. Ha először nyissa meg a forrásul szolgáló munkafüzetet, meg kell jelennie nincs hibakódok.
-
Átalakítása tartománnyá, illetve táblázat átalakítása tartománnyá Táblázat átalakítása tartománnyá, ha az összes cellahivatkozások a egyenértékű abszolút A1 típusú hivatkozássá módosításával. Tartomány átalakítása táblázattá, amikor az Excel nem automatikusan értékre bármelyik cellára mutató hivatkozások e tartomány az egyenértékű a strukturált hivatkozások.
-
Oszlopfejlécek kikapcsolása Lehet váltani a táblázatok oszlopfejléceiben be- és kikapcsolása a Tervezés lap táblázat > Táblázat fejlécsora. Ha kikapcsolja a táblázatok oszlopfejléceiben, nincsenek hatással a strukturált hivatkozások, amelyek az oszlopnevek, és továbbra is használhatja őket a képletekben. Strukturált hivatkozások használatára, amelyek közvetlenül hivatkoznak a táblázat fejlécein (pl. = bevételek [[#Headers], [jutalék %]]) #REFeredményez.
-
Hozzáadása vagy a táblázat sorok és oszlopok törlése Táblázat adattartományok gyakran módosíthatja, mert a cellahivatkozások strukturált hivatkozásokat automatikusan alkalmazkodik. Például a táblázatok nevét egy képletben használt a táblázat celláinak összes adatokat tartalmazó cellákat számlálnia, és kattintson egy adatsor felvétele, a cellahivatkozás automatikusan módosul.
-
Táblázat vagy oszlop átnevezése: Ha egy oszlopot vagy táblázatot átnevez, az Excel automatikusan módosítja az adott táblázat és oszlopfejléc nevét a munkafüzet összes érintett strukturált hivatkozásában.
-
Áthelyezése, másolása, és töltse ki a strukturált hivatkozások használatára A strukturált hivatkozások változatlan marad, amikor másolása és áthelyezése a strukturált hivatkozások használó képlet is.
Megjegyzés: A strukturált hivatkozások másolásával, és hajtsa végre a strukturált hivatkozások kitöltés sem a célt szolgálja. Másolásakor a strukturált hivatkozások nem változnak, míg ha kitöltése képletekkel, a teljesen minősített strukturált hivatkozások módosítsa az alábbi táblázatban ismertetett módon sorozatszerűen változnak.
A kitöltés iránya |
Kitöltés közben használandó billentyű |
Eredmény |
Fel vagy le |
(Nincs) |
Nem módosulnak az oszlopkijelölők |
Fel vagy le |
Ctrl |
Az oszlopkijelölők sorozatszerűen változnak meg |
Jobb vagy bal |
(Nincs) |
Az oszlopkijelölők sorozatszerűen változnak meg |
Fel, le, jobb vagy bal |
Shift |
Az aktuális cellák értékeinek felülírása helyett az alkalmazás áthelyezi az aktuális cellaértékeket, és ennek során beilleszti a megfelelő oszlopkijelölőket |
További segítségre van szüksége?
Bármikor segítséget kérhet az Excel technikai közösségétől és az Answers-közösségtől, az Excel User Voice webhelyen pedig új funkciókra vagy fejlesztésekre tehet javaslatot.
Kapcsolódó témakörök
Excel-táblázatok – áttekintés
Videó: létrehozása és az Excel-táblázat formázása
Excel-táblázatban lévő adatok összegzése
Excel-táblázat formázása
hozzáadásával és eltávolításával a sorok és oszlopok táblázat átméretezése
a tartomány vagy táblázat adatainak szűrése
tartománnyá táblázatok
Excel táblázatokkal kapcsolatos kompatibilitási problémák
SharePoint Excel-táblázat exportálása
tekintse át a képletek Az Excel