SZUM függvény

A matematikai függvények közé tartozó SZUM függvény értékek összeadására szolgál. Összeadhat egyedi értékeket, cellahivatkozásokat, tartományokat vagy akár a három kombinációját is.

Például:

  • =SZUM(A2:A10)

  • =SZUM(A2:A10; C2:C10)

Ez a böngésző nem támogatja a videók lejátszását. Telepítse a Microsoft Silverlightot, az Adobe Flash Playert vagy az Internet Explorer 9-es verzióját.

Ez a videó a Számok összeadása az Excel 2013-ban című tanfolyam része.

SZUM(szám1;[szám2];...)

Argumentum neve

Leírás

szám1    (Kötelező)

Az összeadás első tagja. A szám lehet például a 4, lehet egy cellahivatkozás, például B6 vagy egy cellatartomány, például B2:B8.

szám2–255    (Nem kötelező)

Az összeadás második tagja. Ily módon megadhat legfeljebb 255 további számot.

Ha szeretné gyorsan megkapni egy cellatartomány összegét, elég egyszerűen kijelölnie a tartományt, és egy pillantást vetnie az Excel ablakának jobb alsó részére.

Képernyőkép: cellatartomány kijelölése, majd az állapotsáv tartalmának megnézése
Állapotsor


Ez az állapotsor, amely információkat jelenít meg a kijelölt elemekről, legyen szó egy vagy akár több celláról. Ha a jobb gombbal az állapotsorra kattint, megjelenik egy menü, amelyben az összes kiválasztható lehetőség látható. A kijelölt tartományra vonatkozóan is jelennek meg itt értékek, ha be van kapcsolva ezek megjelenítése. További tudnivalók az állapotsorról.

Legkönnyebben az AutoSzum varázslóval adhat hozzá SZUM képletet a munkalapjához. Jelöljön ki egy üres cellát közvetlenül az összeadni kívánt tartomány fölött vagy alatt, majd válassza a Kezdőlap vagy a Képletek lapon az AutoSzum > Szum lehetőséget. Az AutoSzum varázsló automatikusan érzékeli, hogy milyen tartományt szeretne összeadni, és létrehozza Ön helyett a képletet. Vízszintesen is működik, ha az összeadandó tartománytól jobbra vagy balra eső cellát jelöli ki. A nem folytonos tartományokon azonban nem működik, de a következő szakaszban bemutatjuk, hogyan küszöbölheti ezt ki.

Az AutoSzum varázslóval automatikusan felépíthet egy összegző képletet.  Jelöljön ki egy tartományt az összesítendő tartomány felett/alatt vagy attól balra/jobbra a menüszalag Képlet lapján, és válassza az AutoSzum, majd a SZUM elemet.
Folytonos tartományok gyors összeadása az AutoSzum varázslóval


Az AutoSzum párbeszédpanel egyéb gyakori függvények kiválasztását is lehetővé teszi, például:

AutoSzum függőlegesen

A B6 cella megjeleníti az AutoSzum összegző képletet: =SZUM(B2:B5)

Az AutoSzum varázsló észlelte a B2:B5 tartományt összeadandó cellatartományként. Egyszerűen csak le kell nyomnia az Enter billentyűt a jóváhagyáshoz. Ha több cellát szeretne összeadni, vagy ha cellákat kell kizárnia, akkor a Shift billentyűt lenyomva tartva és a kívánt nyílbillentyűt lenyomva létrehozhatja a megfelelő kijelölést. Ha végzett, nyomja le az Enter billentyűt.

Intellisense függvénysúgó: A függvény alatt látható „SZUM(szám1;[szám2]; …)” címke az Intellisense függvénysúgó. Ha a SZUM vagy más függvény nevére viszi az egérmutatót, az kék hivatkozássá változik, melyre kattintva megjelenik az adott függvényhez tartozó súgótémakör. A függvény egyes elemeire kattintva pedig kiemeli a program az adott elemnek megfelelő képletrészt. Jelen esetben a program csak a B2:B5 részt tudná kiemelni, mert csak egy számhivatkozást tartalmaz a képlet. Az Intellisense-címke minden függvénynél megjelenik.

AutoSzum vízszintesen

A D2 cella megjeleníti az AutoSzum összegző képletet: =SZUM(B2:C2)

A SZUM használata nem folytonos tartományokkal.  A C8 cellában szereplő képlet a következő: =SUM(C2:C3;C5:C6). Használhat elnevezett tartományokat is, így a képlet ilyen lesz: =SZUM(Hét1;Hét2).

Az AutoSzum varázsló csak folytonos tartományokkal működik, ezért ha üres sorok vagy oszlopok találhatók az összeadandó tartományában, az Excel meg fog állni az első üres területnél. Ilyen esetben manuális kijelöléssel kell használnia a SZUM függvényt: egyenként hozzá kell adnia a kívánt tartományokat. Ha a fenti példában a B4 cella tartalmazna adatot, az Excel a =SZUM(C2:C6) képletet hozná létre, mert felismerné a folytonos tartományt.

Gyorsan kijelölhet több, nem folytonos tartományt a Ctrl+Bal egérgomb lenyomásával. Először írja be a „=SZUM(” kezdőrészt, majd jelölje ki a kívánt tartományokat, és az Excel automatikusan hozzáadja az elválasztó pontosvesszőt a tartományok közé. Ha elkészült, nyomja le az Enter billentyűt.

Tipp: Az ALT+= billentyűkombinációval gyorsan beírhatja a SZUM függvényt az aktuális cellába. Ezután egyszerűen csak ki kell jelölnie a kívánt tartományt vagy tartományokat.

Megjegyzés: Megfigyelheti, hogy az Excel a függvényben megadott tartományokat különböző színnel emeli ki, és ugyanezeket a színeket használja a függvényen belül is, így a C2:C3 tartomány más színű, mint a C5:C6 tartomány. Az Excel az összes függvény használatakor így tesz, kivéve ha a hivatkozott tartomány másik munkalapon vagy másik munkafüzetben található. Ha szeretné, hogy a munkafüzete jobban együtt tudjon működni a kisegítő technológiákkal, használhat névvel ellátott tartományokat, például „Hét1” és „Hét2”, majd hivatkozhat ezekre a képletében:

=SZUM(Hét1;Hét2)

Egyszerűen végrehajthat matematikai műveleteket az Excellel külön vagy a SZUM függvényhez hasonló Excel-függvényekkel együtt. Az alábbi táblázatban megtalálja a használható operátorokat, valamint néhány kapcsolódó függvényt. Az operátorokat a billentyűzet számsora vagy, ha van ilyenje, a 10 billentyűs számbillentyűzet használatával írhatja be. A Shift+8 billentyűkombinációval például a szorzáshoz használható csillag (*) karaktert adhatja meg.

Operátor

Művelet

Példák

+

Összeadás

=1+1

=A1+B1

=SZUM(A1:A10)+10

=SZUM(A1:A10)+B1

-

Kivonás

=1-1

=A1-B1

=SZUM(A1:A10)-10

=SZUM(A1:A10)-B1

*

Szorzás

=1*1

=A1*B1

=SZUM(A1:A10)*10

=SZUM(A1:A10)*B1

=SZORZAT(1,1) - SZORZAT függvény

/

Osztás

=1/1

=A1/B1

=SZUM(A1:A10)/10

=SZUM(A1:A10)/B1

=KVÓCIENS(1,1) - KVÓCIENS függvény

^

Hatványra emelés

=1^1

=A1^B1

=SZUM(A1:A10)^10

=SZUM(A1:A10)^B1

=HATVÁNY(1,1) - HATVÁNY függvény

További információt Az Excel használata számológépként című témakörben talál.

Egyéb példák

  1. Tegyük fel, hogy szeretné csökkenteni bizonyos százalékkal egy cellatartomány összegét.

    Operátorok használata a SZUM függvénnyel.  A B16 cellában szereplő képlet =SZUM(A2:A14)*-25%.  A képlet kialakítása nem lesz megfelelő, ha a -25% cellahivatkozás volt a =SZUM(A2:A14)*E2 helyett
    • =SZUM(A2:A14)*-25%

    Ez a képlet 25%-kal csökkenti a tartomány összegét, de a 25% közvetlenül a képletbe lett beírva, ami miatt nehéz lehet később megtalálni és módosítani. Érdemesebb a 25% értéket egy cellában elhelyezni, majd hivatkozni az adott cellára; így az érték később könnyen megtalálható és módosítható:

    • =SZUM(A2:A14)*E2

    Ha osztani szeretne szorzás helyett, egyszerűen cserélje a „*” operátort a „/” operátorra: =SZUM(A2:A14)/E2

  2. A SZUM függvény kombinálása hozzáadással vagy kivonással

    Példa: A SZUM függvény eredményét könnyedén módosíthatja hozzáadással (+) vagy kivonással (-), például:

    • =SZUM(A1:A10)+E2

    • =SZUM(A1:A10)-E2

Ebben a szakaszban megismerhet néhány ajánlott eljárást a SZUM függvény használatára vonatkozóan. Az eljárások többségének a más függvényekkel való munka során is hasznát veheti.

Az =1+2 vagy =A+B módszer – Még ha az „=1+2+3” vagy az „=A1+B1+C2” képlet egyszerűen beírhatónak és pontosnak is tűnik, ez a módszer több szempontból is problematikus:

  1. Elírások – Gondoljon bele, hogy mi lenne, ha sokkal több vagy nagyobb értékeket kellene beírnia, például:

    • =14598,93+65437,90+78496,23

    Nem könnyű ilyen esetben ellenőrizni az értékek helyességét. Sokkal egyszerűbb, ha elhelyezi ezeket az értékeket egy-egy cellában, és a SZUM függvénnyel adja őket össze. A cellában elhelyezett értékeket emellett formázhatja is, és így sokkal olvashatóbbá teheti őket, mintha közvetlenül a képletben szerepelnének.

    A képletekben fixen kódolt értékek helyett használja a SZUM függvényt.  A D5 cellában szereplő képlet a következő: =SZUM(D2:D4)
  2. #ÉRTÉK! hiba – Ha szövegre hivatkozik számok helyett.

    Ha például az alábbi képletet használja:

    • =A1+B1+C1 vagy =A1+A2+A3

    Nem megfelelő képletszerkesztés példája.  A képlet a D2 cellában =A2+B2+C2

    A képlete #ÉRTÉK! hibát adhat, ha a hivatkozott cellákban akár egyetlen nem szám (vagyis szöveges) érték is szerepel. A SZUM függvény ezzel szemben figyelmen kívül hagyja a szöveges értékeket, és csak a számértékeket adja össze.

    Helyes képletszerkesztés.  Az =A2+B2+C2 helyett a D2 cellában szereplő képlet a következő: =SZUM(A2:C2)
  3. #HIV! hiba – Ha sorokat vagy oszlopokat töröl.

    Oszlop törlésével okozott #HIV! hiba.  A képlet a következőre változott: =A2+#HIV!+B2

    Ha töröl egy sort vagy oszlopot, a képlet nem fog frissülni a törölt elem kizárásához, és ezért #HIV! hibát ad, míg a SZUM függvény automatikusan képes igazodni az ilyen változásokhoz.

    A SZUM függvény automatikusan módosul a beszúrt vagy törölt soroknak és oszlopoknak megfelelően
  4. Nem frissülő hivatkozások sorok vagy oszlopok beszúrásakor

    =A+B+C képletek nem frissülnek, ha sorokat vesz fel

    Ha beszúr egy sort vagy oszlopot, a képlet nem fog frissülni a hozzáadott sor vagy oszlop belefoglalásához, míg a SZUM függvény automatikusan igazodik az ilyen változásokhoz (kivéve, ha a változás a képletben hivatkozott tartományon kívül történik). Ezt fontos észben tartani, mert ha azt feltételezi, hogy a képlet frissül, akkor előfordulhat, hogy észre sem veszi, amikor hiányos eredményt kap.

    A példa egy oszlop beszúrásakor a =SZUM(A2:C2) képletről automatikusan a =SZUM(A2:D2) képletre bővülő SZUM képletet szemléltet
  5. SZUM egyéni cellahivatkozásokkal vagy tartományokkal

    Vessen egy pillantást az alábbi képletre:

    • =SZUM(A1;A2;A3;B1;B2;B3)

    Ez a képlet ugyanannyi hibalehetőséget rejt sorok hozzáadásakor vagy törlésekor, ugyanazon okból kifolyólag. Biztonságosabb, ha tartományokat használ:

    • =SZUM(A1:A3;B1:B3)

    Ezek frissülnek sorok hozzáadásakor és törlésekor.

  1. A SZUM függvényt más függvényekkel is kombinálhatja. Az alábbi képlet például havi átlagszámítást végez:

    A SZUM használata egyéb függvényekkel.  Az M2 cellában lévő képlet =SZUM(A2:L2)/DARAB2(A2:L2) .  Megjegyzés: az átláthatóság érdekében a május és november közötti hónapok rejtve vannak.
    • =SZUM(A2:L2)/DARAB2(A2:L2)

  2. Ez a képlet az A2:L2 tartomány összegét elosztja az A2:L2 tartomány nem üres celláinak számával (a képen a májustól decemberig tartó időszak üres).

  1. Időnként szükség lehet arra, hogy összeadja több munkalap ugyanazon celláját. Első pillantásra jó megoldásnak tűnhet egyenként rákattintani a kívánt cellára az összes munkalapon, majd a „+” operátorral összeadni őket. Ez azonban hosszadalmas, és hibalehetőségeket rejt.

    • =Munka1!A1+Munka2!A1+Munka3!A1

    Sokkal egyszerűbben megteheti ugyanezt háromdimenziós SZUM függvénnyel:

    3D Szum – A D2 cellában lévő képlet =SZUM(Munka1:Munka3!A2)
    • =SZUM(Munka1:Munka3!A1)

    Ez a képlet összeadja az A1 cellát a Munka1 munkalaptól a Munka3 munkalapig.

    Különösen hasznos lehet olyan esetekben, amikor az egyes hónapok számára külön munkalapot hozott létre, és egy összesítő munkalapon szeretne összegző adatokat megjeleníteni.

    3D SZUM elnevezett munkalapokon.  A D2 cellában szereplő képlet a következő: =SZUM(Január:December!A2)
    • =SZUM(Január:December!A2)

    Ez a képlet összeadja az A2 cellákat a Január munkalaptól a December munkalapig.

    Megjegyzések: Ha a munkalapjai nevében szóköz szerepel (például „Januári értékesítés”), akkor idézőjelekbe kell foglalnia a munkalapneveket a képletében. Figyelje meg az aposztróf karaktert az első munkalap neve előtt és az utolsó munkalap neve után.

    • =SZUM('Januári értékesítés:Decemberi értékesítés'!A2)

    A háromdimenziós módszer más függvényekkel is működik, ideértve például az ÁTLAG, a MIN és a MAX függvényt.

    • =ÁTLAG(Munka1:Munka3!A1)

    • =MIN(Munka1:Munka3!A1)

    • =MAX(Munka1:Munka3!A1)

Probléma

A probléma oka

A SZUM függvényem a ##### értéket mutatja az eredmény helyett.

Ellenőrizze az oszlop szélességét. A ##### érték általában azt jelzi, hogy az oszlop túl keskeny a képlet eredményének megjelenítéséhez.

A SZUM függvényem magát a beírt képletet mutatja szövegként az eredmény helyett.

Győződjön meg arról, hogy a cella nem szövegként van formázva. Jelölje ki a szóban forgó cellát vagy tartományt, a Ctrl+1 billentyűkombinációval nyissa meg a Cellák formázása párbeszédpanelt, és válassza ki a megfelelő formátumot a Szám lapon. Ha a cella szövegként volt formázva, és nem lát változást a formátum módosítása után, akkor előfordulhat, hogy az F2 > Enter billentyű lenyomásával kell kényszerítenie a formátum frissítését.

A SZUM függvényem nem frissül.

Győződjön meg arról, hogy a Számítás beállítás Automatikus értékre van állítva. Válassza a Képlet lapon a Számolási beállítások lehetőséget. Az F9 billentyű lenyomásával is kényszerítheti a munkafüzet kiszámítását.

Győződjön meg róla, hogy a Számítás beállítás Automatikus értékre van állítva.  Ezt a Képlet lap Számolási beállítások menüjében ellenőrizheti.

Egyes értékek kimaradnak a számításból.

Csak a hivatkozásban vagy a tartományban szereplő számértékek adhatók össze. Az üres cellákat, a logikai értékeket (például IGAZ) és a szöveget a függvény figyelmen kívül hagyja.

A várt eredmény helyett a #NÉV? hiba jelenik meg.

Ez általában azt jelzi, hogy a függvény neve hibásan lett beírva, például „=szumm(A1:A10)” a „=SZUM(A1:A10)” helyett.

A SZUM függvényem egész számot jelenít meg tizedesek helyett

Gondoskodjon arról, hogy a cellaformázás tizedeseket jelenítsen meg. Jelölje ki a kérdéses cellát vagy tartományt, a Ctrl+1 billentyűkombinációval nyissa meg a Cellák formázása párbeszédpanelt, és válassza a megfelelő formátumot a Szám lapon. Ezzel jelezheti a kívánt tizedeshelyek számát.

  1. Csak összeadni, kivonni, szorozni vagy osztani szeretnék számokat – Tekintse meg a Matematikai alapműveletek az Excelben című videosorozatunkat, vagy olvassa el Az Excel használata számológépként című témakört.

  2. Hogyan jeleníthetek meg több vagy kevesebb tizedeshelyet? – Módosíthatja a számformátumot. Jelölje ki a szóban forgó cellát vagy tartományt, a Ctrl+1 billentyűkombinációval nyissa meg a Cellák formázása párbeszédpanelt, és válassza a megfelelő formátumot a Szám lapon. Ezzel jelezheti a kívánt tizedeshelyek számát.

  3. Hogyan adhatok hozzá vagy vonhatok ki időértékeket? – Időértékeket több különböző módon adhat össze vagy vonhat ki. Ha például a 8 és 12 óra közötti különbséget szeretné megkapni bérszámfejtési célokból, a következő képletet kell használnia: =("12:00"-"8:00")*24, amely kivonja a záró időpontból a kezdő időpontot. Vegye figyelembe, hogy az Excel az időértékeket a nap részeként számítja ki, ezért az órák összegének megkapásához 24-gyel való szorzás szükséges. Az első példában a =((B2-A2)+(D2-C2))*24 képletet használjuk a kezdéstől a befejezésig tartó órák összegének ebédszünet nélküli kiszámításához (összesen 8,5 óra).

    Ha csak órákat és perceket ad hozzá, és így szeretné megjeleníteni őket, akkor egyszerű összeadást végezhet a 24-gyel való szorzás nélkül. Ezért a második példában a =SZUM(A6:C6) képletet használjuk, mivel csak a hozzárendelt feladatok összes órájának és percének a számára van szükségünk (5:36, illetve 5 óra, 36 perc).

    Idő számítása

    További információ: Időértékek összegzése és kivonása.

  4. Hogyan számíthatom ki dátumok különbségét? Az időpontokhoz hasonlóan a dátumokat is összeadhatja és kivonhatja egymásból. Az alábbi példa kiszámítja, hogy hány napnyi különbség van két dátum között. A képlet itt egyszerűen =B2-A2. A legfontosabb szempont a dátumok és az időpontok számításával kapcsolatban, hogy a befejező dátummal vagy időponttal kell kezdeni, és abból kell kivonni a kezdő dátumot vagy időpontot.

    Dátumok közötti különbségek számítása

    A dátumokkal való munkáról bővebben a következő témakörben olvashat: Két dátum közötti napok számának kiszámítása.

  5. Hogyan adhatom össze csak a látható cellákat? Néha, amikor manuálisan rejt el sorokat, vagy az AutoSzűrő használatával jelenít meg csak bizonyos adatokat, csak a látható cellákat is összegezni szeretné. Ehhez a RÉSZÖSSZEG függvényt használhatja. Ha összegsort használ egy Excel-táblázatban, a program az összegeket tartalmazó legördülő listában Ön által kiválasztott függvényt írja be automatikusan részösszegként. Erről bővebben az Adatok összegzése Excel-táblázatban című témakörben olvashat.

További segítségre van szüksége?

Bármikor segítséget kérhet az Excel technikai közösségétől és az Answers-közösségtől, az Excel User Voice webhelyen pedig új funkciókra vagy fejlesztésekre tehet javaslatot.

Lásd még

Nézze meg a SZUM függvény használatát ismertető videót

A SZUMHA függvény csak a megadott feltételnek megfelelő értékeket adja össze

A SZUMHATÖBB függvény csak a több feltételnek megfelelő értékeket adja össze

A DARABTELI függvény csak a megadott feltételnek megfelelő értékeket számolja meg

A DARABHATÖBB függvény csak a megadott összes feltételnek megfelelő értékeket számolja meg

A képletek áttekintése az Excelben

Hibás képletek kiküszöbölése

Képletekben lévő hibák keresése és javítása

A Windows Excel billentyűparancsai

A Mac Excel billentyűparancsai

Matematikai és trigonometriai függvények

Az Excel függvényeinek betűrendes listája

Az Excel függvényeinek kategória szerinti listája

Ismeretek bővítése
Oktatóanyagok megismerése
Új szolgáltatások listájának lekérése
Részvétel az Office Insider programban

Hasznos volt az információ?

Köszönjük a visszajelzését!

Köszönjük visszajelzését. Jobbnak látjuk, ha az Office egyik támogatási szakemberéhez irányítjuk.

×