SZÖVEG függvény

Közreműködők: Lukács „Luka” Miklós Király Vince

A SZÖVEG függvény lehetővé teszi a számok megjelenítésének módosítását. Ehhez formátumkódok segítségével formázza a számokat. Ez olyankor hasznos, amikor olvashatóbb formátumban szeretné megjeleníteni a számokat, illetve a számokat szöveggel vagy szimbólumokkal szeretné ötvözni.

Megjegyzés : A SZÖVEG függvény a számokat szöveggé alakítja, ami megnehezítheti, hogy a későbbi számításokban hivatkozzon rájuk. Érdemes az eredeti értéket megtartani egy cellában, majd a SZÖVEG függvényt egy másik cellában használni. Így ha később további képleteket kell készítenie, a SZÖVEG függvény eredménye helyett mindig hivatkozhat az eredeti értékre.

Szintaxis

SZÖVEG(érték; formátum_szöveg)

A SZÖVEG függvény szintaxisa az alábbi argumentumokat foglalja magában:

Argumentum neve

Leírás

érték

A szöveggé alakítható számérték.

formátum_szöveg

Egy szöveges karakterlánc, amely meghatározza a megadott értékhez alkalmazandó formázást.

Áttekintés

A SZÖVEG függvény legegyszerűbben az alábbi módon értelmezhető:

  • =SZÖVEG(Formázandó érték; "Az alkalmazandó formátumkód")

Az alábbiakban néhány gyakori példát talál, amelyeket közvetlenül az Excelbe másolhat, hogy saját maga kísérletezzen velük. Figyelje meg az idézőjelek között látható formátumkódokat.

Képlet

Leírás

=SZÖVEG(1234,567;"# ##0,00 Ft")

Pénznem ezreselválasztóval és két tizedesjeggyel, például 1 234,57 Ft. Figyelje meg, hogy az Excel 2 tizedesjegyre kerekíti az értéket.

=SZÖVEG(MA();"ÉÉÉÉ.HH.NN.")

Az aktuális dátum ÉÉÉÉ.HH.NN. formátumban, például 2012.03.14.

=SZÖVEG(MA();"NNNN")

A hét aktuális napja, például hétfő

=SZÖVEG(MOST();"Ó:PP de./du.")

Aktuális időpont, például 1:29 du.

=SZÖVEG(0,285;"0,0%")

Százalékos érték, például 28,5%

=SZÖVEG(4,34 ;"# ?/?")

Tört, például 4 1/3

=KIMETSZ(SZÖVEG(0,34;"# ?/?"))

Tört, például 1/3. Ez a képlet a KIMETSZ függvényt használja a kezdő szóköz eltávolításához a decimális értékkel.

=SZÖVEG(12200000;"0,00E+00")

Tudományos jelölés, például 1,22E+07

=SZÖVEG(1234567898;"[<=9999999]###-####;(###) ###-####")

Speciális (telefonszám), például (123) 456-7898

=SZÖVEG(1234;"0000000")

Bevezető nullák (0) hozzáadása, például 0001234

=SZÖVEG(123456;"##0° 00' 00''")

Egyéni – földrajzi szélesség/hosszúság

Megjegyzés : Bár a SZÖVEG függvénnyel módosíthatja a formázást, nem ez az egyetlen lehetőség. A formátumot képlet nélkül is módosíthatja, ha lenyomja a CTRL+1 (vagy Macen a A Mac gépek Command billentyűjének ikonja +1) billentyűkombinációt, majd a Cellák formázása > Szám párbeszédpanelen kiválasztja a formátumot.

Példák letöltése

Letöltheti példamunkafüzetünket, amely tartalmazza többek között a jelen cikkben a SZÖVEG függvényt használó összes példát. Követheti a példákat, vagy létrehozhat saját formátumkódokat a SZÖVEG függvényhez.

Az Excel SZÖVEG függvénypéldáinak letöltése

Egyéb elérhető formátumkódok

A Cellák formázása párbeszédpanelen megkeresheti a többi elérhető formátumkódot:

  1. A Ctrl+1 (vagy Macen a A Mac gépek Command billentyűjének ikonja +1) billentyűkombinációt lenyomva nyissa meg a Cellák formázása párbeszédpanelt.

  2. Jelölje ki a kívánt formátumot a Szám lapon.

  3. Jelölje ki az Egyéni lehetőséget.

  4. A kívánt formátumkód most a Típus mezőben látható. Ebben az esetben a pontosvessző (;) és az @ jel kivételével jelöljön ki mindent a Típus mezőben. Az alábbi példában csak az éééé.hh.nn. formátumot jelöltük ki és másoltuk.

  5. A Ctrl+C billentyűkombinációt lenyomva másolja a vágólapra a formátumkódot, majd a Mégse gombot lenyomva zárja be a Cellák formázása párbeszédpanelt.

  6. Most csak annyit kell tennie, hogy a Ctrl+V billentyűkombinációt lenyomva a formátumkódot beilleszti a SZÖVEG függvényt használó képletbe, például: =SZÖVEG(B2;"éééé.hh.nn."). Ügyeljen arra, hogy a formátumkódot idézőjelek közé illessze be ("formátumkód"), ellenkező esetben az Excel hibát ad vissza.

Példa arról, hogy hogyan használhatja a Cellák formázása > Szám > Egyéni lehetőséget arra, hogy az Excel formázza Önnek a karakterláncokat.

Formátumkódok kategória szerint

Az alábbiakban azt szemléltetjük néhány példával, hogy miként alkalmazhat eltérő számformátumot az értékeire a Cellák formázása párbeszédpanelen az Egyéni lehetőséget választva, és az adott formátumkódokat a SZÖVEG függvénybe másolva.

Miért törli az Excel a bevezető nullákat?

Az Excel arra van felkészítve, hogy a cellákban nem szövegnek látszó számokat, például cikkszámokat vagy termékváltozatokat, hanem megadott számokat keressen. A bevezető nullák megőrzéséhez az értékek beillesztése vagy megadása előtt formázza a bemeneti tartományt. Jelölje ki az oszlopot vagy tartományt, amelybe értékeket szeretne bevinni, majd a CTRL+1 billentyűkombinációt lenyomva nyissa meg a Cellák formázása párbeszédpanelt, és a Szám lapon válassza a Szöveg lehetőséget. Az Excel ekkor megőrzi a bevezető nullákat.

Ha már bevitte az adatokat, és az Excel eltávolította a bevezető nullákat, akkor a SZÖVEG függvénnyel visszahelyezheti őket. Az értékeket tartalmazó tartomány felső cellájához használja a =SZÖVEG(érték;"00000") képletet, melyben a nullák száma a megjeleníteni kívánt számjegyek száma legyen. Ezután a képlet másolásával és beillesztésével formázza a tartomány többi celláját is.

Példa arra, hogy hogyan formázhat értékeket kezdő nullákkal a SZÖVEG függvénnyel.  =SZÖVEG(A2;"00000")

Ha bizonyos okokból a szöveges értékeket vissza kell alakítania számokká, szorozhat 1-gyel, például =D4*1, illetve használhatja a dupla egyoperandusú operátort (--), például =--D4.

Az Excel az ezreseket közzel választja el, ha a formátum számjelekkel (#) vagy nullákkal határolt szóközt tartalmaz. Ha például a formátum-karakterlánc értéke "# ###", az Excel a 12200000 számot 12 200 000 formátumban jeleníti meg.

Egy számjegyhelyőrzőt követő pont 1000-rel osztja a számot. Ha például a formátum-karakterlánc értéke "#.###,0.", az Excel a 12200000 számot 12.200,0 formátumban jeleníti meg.

Példák a SZÖVEG függvény használatára az ezreselválasztóval

Megjegyzések: 

  • Az ezreselválasztó a területi beállításoktól függ. Az Amerikai Egyesült Államokban ez vessző, más területeken viszont lehet szóköz vagy pont(.).

  • Az ezreselválasztó szám-, pénznem- és könyvelési formátumokhoz érhető el.

Az alábbi példákban normál szám- (csak ezres- és tizedes elválasztó), pénznem- és könyvelési formátumok láthatók. A pénznemformátumok lehetővé teszik a tetszés szerinti pénznemszimbólum beszúrását, és az érték mellé igazítását. A könyvelési formátum például az értéket a cella a közepére igazítja, a pénznemszimbólumot pedig az érték mellé a jobb szélre helyezi. Figyelje meg a különbséget az alábbi pénznem- és könyvelési formátumkódok között, ahol a könyvelési formátumkód csillagot (*) használ a szimbólum és az érték közötti elválasztáshoz.

Példák a SZÖVEG függvény használatára a Szám, a Pénznem és a Könyvelési formátummal

A pénznemszimbólumok formátumkódjának kereséséhez nyomja le a Ctrl+1 (vagy Macen a A Mac gépek Command billentyűjének ikonja +1) billentyűkombinációt, jelölje ki a kívánt formátumot, majd válasszon szimbólumot a Pénznem legördülő listában:

Pénznemszimbólum-választék a Cellák formázása párbeszédpanelen

Ezután kattintson az Egyéni lehetőségre a bal oldalon található Kategória csoportban, és másolja a formátumkódot a pénznemszimbólummal együtt.

SZÖVEG függvény – Egyéni pénznem szimbólummal

Megjegyzés : A SZÖVEG függvény nem támogatja a színformázást, ezért ha a Cellák formázása párbeszédpanelról színt tartalmazó számformátumkódot másol (például: # ##0,00_ Ft);[Piros](# ##0,00 Ft)), a SZÖVEG függvény elfogadja a formátumkódot, de nem jeleníti meg a színt.

A dátumok megjelenítésének módját az "É" (év), a "H" (hónap) és az "N" (nap) kombinációjának használatával módosíthatja.

Formátumkódok hónaphoz, naphoz és évhez

A SZÖVEG függvényben használt formátumkódok nem különböztetik meg a kis- és a nagybetűket, így használhatja akár az "É" vagy "é", a "H" vagy "h", illetve az "N" vagy "n" betűt.

Mynda Treacy Excel MVP

Mynda javaslata...

Ha különböző országokban dolgozó felhasználókkal oszt meg Excel-fájlokat és -jelentéseket, előnyös lehet, ha mindenkinek a saját nyelvén küldi el a jelentést. Mynda Treacy (Excel MVP) nagyszerű megoldással szolgál erre Az Excelben szereplő dátumok megjelenítése különféle nyelveken című cikkben. A cikk egy letölthető mintamunkafüzetet is tartalmaz.

Az időpont megjelenítését az "Ó" (óra), "P" (perc) és "S" (másodperc), valamint a 12 órás formátum esetén a de./du. kombinációjának használatával módosíthatja.

Időformátumok órához, perchez és másodperchez

Ha kihagyja a de./du. jelölést, az időpont 24 órás formátumban jelenik meg.

A SZÖVEG függvényben használt formátumkódok nem különböztetik meg a kis- és a nagybetűket, így használhatja akár az "Ó" vagy "ó", a "P" vagy "p", illetve az "S" vagy "s" betűt, illetve a "DE./DU." vagy a "de./du." kódokat.

A százalékértékek megjelenítésének módját a százalék (%) formátumokkal módosíthatja.

Formátumkódok százalékhoz

A tizedesjegyek megjelenítésének módját a tört (?/?) formátumokkal módosíthatja.

Formátumkódok törtekhez

A tudományos jelölés a számok ábrázolásának módja, ahol egy 1 és 10 közötti decimális szám a 10 hatványával van szorozva. Ezt gyakran a nagy számok tömör megjelenítéséhez használják.

Formátumkódok a tudományos jelölésekhez

Az Excel 4 különleges formátumot kínál:

  • Irányítószám – "H-0736"

  • Irányítószám + 4 – "H-0736-0000"

  • Telefonszám – "[<=9999999]###-####;(###) ###-####"

  • Társadalombiztosítási szám – "000-000-000"

Speciális formátumok a SZÖVEG függvényhez

A különleges formátumok a területi beállításoktól függően eltérhetnek, ha azonban a területi beállításához nincsenek különleges formátumok, vagy nem felelnek meg az igényeinek, a Cellák formázása párbeszédpanel Egyéni lehetőségével saját formátumot is létrehozhat.

Gyakori eset

A SZÖVEG függvényt leggyakrabban mással együtt, és csak ritkán használják önmagában. Tegyük fel, hogy kombinálni szeretne egy szöveget és egy számértéket, például „Jelentés nyomtatva: 2012.03.14.” vagy „Heti bevétel: 6 634 872 Ft” formában. Beírhatná ezt kézzel is az Excelbe, de miért ne használná ki, hogy az Excel meg tudja tenni Ön helyett? A szöveg és a formázott számok – például dátumok, időpontok, pénznem stb. – kombinálásakor az Excel nem tudja, hogy miként szeretné megjeleníteni a számokat, ezért elveti azok formázását. Itt lesz nélkülözhetetlen a SZÖVEG függvény, mert a segítségével kikényszerítheti, hogy az Excel a formátumkódok használatával a kívánt módon formázza az értékeket, például a dátumformátum esetén az "ÉÉÉÉ.HH.NN." segítségével.

Az alábbi példában láthatja, hogy mi történik, ha a SZÖVEG függvény nélkül szöveget és számokat összekapcsolni. Itt az és (&) operátorral próbálunk meg összefűzni egy szöveges karakterláncot, egy szóközt (" ") és egy értéket a következő módon: =A2&" "&B2.

Példa szöveg egyesítésére a SZÖVEG függvény nélkül

Amint láthatja, az Excel eltávolította a formázást a B2 cellában lévő dátumból. A következő példában azt láthatja, hogy a SZÖVEG függvény miként teszi lehetővé a kívánt formátum alkalmazását.

Példa szöveg egyesítésére a SZÖVEG függvénnyel

A frissített képletünk a következő:

  • C2 cella: =A2&" "&SZÖVEG(B2;"éééé.hh.nn") – Dátumformátum

Gyakori kérdések

Erre sajnos nincs lehetősége a SZÖVEG függvénnyel. Az ilyen típusú átalakításhoz VBA- (Visual Basic for Applications) kódot kell használnia. A következő témakör a számok angol szöveggé alakítását tárgyalja, és így jó támpontot nyújthat: Numerikus értékek átalakítása angol szavakká az Excel programban

Igen, ehhez használhatja a NAGYBETŰS, a KISBETŰ és a TNÉV függvényt. A =NAGYBETŰS("szia") eredménye például "SZIA" lesz.

Igen, de több lépésben. Első lépésként jelölje ki a kívánt cellát vagy cellákat, majd a Ctrl+1 billentyűkombinációval nyissa meg a Cellák formázása párbeszédpanelt, és az Igazítás > A szöveg elhelyezése csoportban jelölje be a Sortöréssel több sorba jelölőnégyzetet. Következő lépésként egészítse ki a SZÖVEG függvényt a KARAKTER(10) függvénnyel ott, ahova a sortörést helyezni szeretné. A végleges érték méretétől függően szükség lehet az oszlopszélesség módosítására is.

Példa arra, hogy hogyan szúrhat be sortörést a SZÖVEG és a KARAKTER(10) függvénnyel.  ="A mai nap: "&KARAKTER(10)&SZÖVEG(MA();"éééé.hh.nn.")

A fenti példában a következő képletet használtuk: ="A mai nap: "&KARAKTER(10)&SZÖVEG(MA();"éééé.hh.nn")

Ez tudományos jelölés néven ismert, és az Excel automatikusan átalakítja az Általános formátumú cellák esetén a 12 számjegynél hosszabb számjegyeket, a Szám formátumú cellák esetén pedig a 15 számjegynél hosszabb számjegyeket. Ha hosszú numerikus karakterláncokat kell megadnia, de nem szeretné konvertálni őket, akkor formázza a szóban forgó cellákat Szöveg értékként, mielőtt beírná vagy beillesztené az értékeket az Excelbe.

Mynda Treacy Excel MVP

Mynda javaslata...

Ha különböző országokban dolgozó felhasználókkal oszt meg Excel-fájlokat és -jelentéseket, előnyös lehet, ha mindenkinek a saját nyelvén küldi el a jelentést. Mynda Treacy (Excel MVP) nagyszerű megoldással szolgál erre Az Excelben szereplő dátumok megjelenítése különféle nyelveken című cikkben. A cikk egy letölthető mintamunkafüzetet is tartalmaz.

Lásd még

Egyéni számformátum létrehozása és törlése

Szöveg átalakítása számokká

Az Excel függvényeinek kategória szerinti listája

Ismeretek bővítése
Oktatóanyagok megismerése
Új szolgáltatások listájának lekérése
Részvétel az Office Insider programban

Hasznos volt az információ?

Köszönjük a visszajelzését!

Köszönjük visszajelzését. Jobbnak látjuk, ha az Office egyik támogatási szakemberéhez irányítjuk.

×