Format függvény

Példák

A Format függvény használata kifejezésben:    A Format függvényt használhatja bárhol, ahol megadható kifejezés. Alkalmazhatja például lekérdezésben egy mező aliasának részeként, illetve az űrlapokon vagy jelentésekben szereplő szövegmezők Mező vagy kifejezés tulajdonságában. A következő példák egy olyan kifejezést mutatnak be, amellyel egy jelentés Szűrő tulajdonságában az előző hétre korlátozhatók a megjelenített rekordok.

Format([Dátum],"ww")=Format(Now(),"ww")-1

Ebben a példában a jelentés rekordforrásának van egy Date (Dátum) nevű mezője, amely tartalmazza az egyes rekordok módosításának dátumát, és amelyet a jelentés használ. A jelentés futtatásakor a rendszer úgy szűri az eredményeket, hogy csak azokat a rekordokat jelenítse meg, ahol a Dátum mező (Format([Date],"ww")) értékének hete megegyezik az előző hétvel (Format(Now(),"ww")-1.

A Format függvény használata VBA-kódban:    

Ebben a példában a Format függvény különféle alkalmazásait mutatjuk be, az elnevezett formátumokra és a felhasználói formátumokra is kiterjedően. A dátumelválasztó (/), az időelválasztó (:) és az AM/ PM literál esetében a rendszer által ténylegesen megjelenített formázott kimenet függ annak a számítógépnek a területi beállításaitól, amelyen fut a kód. A fejlesztőkörnyezetben a kód területi beállításának megfelelő rövid időformátum és rövid dátumformátum jelenik meg. Futó kódban a rendszer területi beállításának rövid időformátumát és rövid dátumformátumát használja a rendszer, ez pedig eltérő lehet a kód területi beállításától. A példa kedvéért az angol (Egyesült Államok) területi beállítást tételezzük fel.

A fejlesztőkörnyezetben a MyTime és a MyDate a rendszer aktuális rövid időformátum-beállítása és rövid dátumformátum-beállítása alapján jelenik meg.

Dim MyTime, MyDate, MyStr
MyTime = #17:04:23#
MyDate = #January 27, 1993#
' Returns current system time in the system-defined long time format.
MyStr = Format(Time, "Long Time")
' Returns current system date in the system-defined long date format.
MyStr = Format(Date, "Long Date")
MyStr = Format(MyTime, "h:m:s")    ' Returns "17:4:23".
MyStr = Format(MyTime, "hh:mm:ss AMPM")    ' Returns "05:04:23 PM".
MyStr = Format(MyDate, "dddd, mmm d yyyy")    ' Returns "Wednesday,
    ' Jan 27 1993".
' If format is not supplied, a string is returned.
MyStr = Format(23)    ' Returns "23".
' User-defined formats.
MyStr = Format(5459.4, "##,##0.00")    ' Returns "5,459.40".
MyStr = Format(334.9, "###0.00")    ' Returns "334.90".
MyStr = Format(5, "0.00%")    ' Returns "500.00%".
MyStr = Format("HELLO", "<")    ' Returns "hello".
MyStr = Format("This is it", ">")    ' Returns "THIS IS IT".

A Format használata nulla hosszúságú karakterláncokkal

A Microsoft Access 2.0-s és korábbi verzióiban a Format függvénnyel megoldható volt, hogy nulla hosszúságú karaktersorozat esetén visszaadjon egy értéket, érték esetén pedig egy másikat. Például a Format függvénnyel megadott következő formátumkifejezéssel vissza lehetett adni a megfelelő karakterláncértéket a kódból:

Dim varX As Variant
Dim varStrX As Variant
' Assign some value to varStrX and pass to Format function.
varX = Format(varStrX, "@;ZLS;Null")

A Microsoft Access 97-es és újabb verzióiban külön tesztelni kell, hogy nem Null-e az érték, majd az eredmény alapján kell visszaadni a megfelelő értéket. Például a következőképpen használható az IIf függvény egy kifejezésben a Format függvénnyel:

varX = IIf(IsNull(varStrX),"Null", Format(varStrX, "@;ZLS"))

Ez a változtatás csak arra az esetre érvényes, ha attól függően kíván megformázni egy karakterláncot a Format függvénnyel, hogy nulla hosszúságú karakterláncról vagy Null értékről van-e szó. A Format függvénnyel használt egyéb formátumkifejezések ugyanúgy működnek, mint a korábbi verziókban.

Ha konvertál egy adatbázist a Microsoft Access 2.0-s és korábbi verzióiról a Microsoft Access 2002-es vagy újabb verzióira, módosítania kell úgy a kódot, hogy külön megvizsgálja a Null érték esetét.