DARABTELI függvény

A DARABTELI függvénnyel, amely a statisztikai függvények körébe tartozik, megállapíthatja az egy adott kritériumnak megfelelő cellák számát; például hogy egy adott város hány alkalommal jelenik meg egy ügyféllistában.

A legegyszerűbb DARABTELI függvény így néz ki:

  • =DARABTELI(Hol szeretne keresni?, Mit szeretne keresni?)

Például:

  • =DARABTELI(A2:A5,"London")

  • =DARABTELI(A2:A5;A4)

Ez a böngésző nem támogatja a videók lejátszását. Telepítse a Microsoft Silverlightot, az Adobe Flash Playert vagy az Internet Explorer 9-es verzióját.

DARABTELI(tartomány; kritérium)

Argumentum neve

Leírás

tartomány    (kötelező)

A megszámolni kívánt cellák csoportja. A tartomány tartalmazhat számokat, tömböket, egy névvel ellátott tartományt vagy számokat tartalmazó hivatkozásokat. Az üres és a szöveges értékeket figyelmen kívül hagyja a program.

Tudnivalók a tartományok kijelöléséről munkalapon.

kritérium    (kötelező)

Egy szám, kifejezés, cellahivatkozás vagy szöveges karakterlánc, amely meghatározza, hogy mely cellák lesznek megszámlálva.

Használhat például számot (32) vagy összehasonlítást (">32"), cellát (B4), illetve szót ("alma").

A DARABTELI csak egyetlen kritériumot használ. Ha több kritériumot szeretne használni, használja a DARABHATÖBB függvényt.

Példák

Ha használni szeretné ezeket a példákat az Excelben, másolja a vágólapra az alábbi táblázatban látható adatokat, és illessze be őket egy új munkalap A1 cellájába.

Adatok

Adatok

alma

32

narancs

54

barack

75

alma

86

Képlet

Leírás

=DARABTELI(A2:A5;"alma")

Megszámolja az A2-től A5-ig terjedő tartomány alma szót tartalmazó celláit. Az eredmény 2.

=DARABTELI(A2:A5;A4)

Megszámolja az A2-től A5-ig terjedő tartomány barack szót tartalmazó celláit (az A4 cellában megadott érték). Az eredmény 1.

=DARABTELI(A2:A5,A2)+DARABTELI(A2:A5,A3)

Megszámolja az A2-től A5-ig terjedő tartomány alma szót (az A2 cella értéke) és narancs szót (az A3 cella értéke) tartalmazó celláit. Az eredmény 3. Ez a képlet kétszer használja a DARABTELI függvényt több kritérium (kifejezésenként egy kritérium) megadásához. A DARABHATÖBB függvényt is használhatja.

=DARABTELI(B2:B5;">55")

Megszámolja a B2-től B5-ig terjedő tartomány 55-nél nagyobb értéket tartalmazó celláit. Az eredmény 2.

=DARABTELI(B2:B5;"<>"&B4)

Megszámolja a B2-től B5-ig terjedő tartomány 75-tel nem egyenlő értéket tartalmazó celláit. Az és (&) jel a nem egyenlő (<>) összehasonlító operátort és a B4 cellában szereplő értéket a következőképpen egyesíti: =DARABTELI(B2:B5;"<>75"). Az eredmény 3.

=DARABTELI(B2:B5;">=32")-DARABTELI(B2:B5;">85")

Megszámolja a B2-től B5-ig terjedő tartomány 32-vel egyenlő (=) vagy azt meghaladó (>), illetve 85-tel egyenlő (=) vagy annál kisebb (<) értéket tartalmazó celláit. Az eredmény 3.

=DARABTELI(A2:A5;"*")

Megszámolja az A2-től A5-ig terjedő tartomány szöveget tartalmazó celláit. A csillag (*) helyettesítő karakter egy tetszőleges karakter helyettesítésére szolgál. Az eredmény 4.

=DARABTELI(A2:A5;"?????es")

Megszámolja az A2-től A5-ig terjedő tartomány pontosan 7 karaktert tartalmazó, „es” betűkkel végződő celláit. A kérdőjel (?) helyettesítő karakter egyéni karakterek helyettesítésére szolgál. Az eredmény 2.

Gyakori problémák

Probléma

A probléma oka

Hosszú karakterláncok esetén nem megfelelő a visszaadott érték.

A DARABTELI függvény helytelen eredményt ad, ha 255 karakternél hosszabb karakterláncokat egyeztet vele.

Ha 255 karakternél hosszabb karakterláncokat szeretne egyeztetni, használja az ÖSSZEFŰZ függvényt vagy az & összefűző operátort. Például: =DARABTELI(A2:A5;"hosszú karakterlánc"&"másik hosszú karakterlánc").

Várt érték esetén nem ad vissza értéket.

Győződjön meg arról, hogy idézőjelek közé foglalta a kritérium argumentumot.

A DARABTELI függvényt tartalmazó képlet #ÉRTÉK! hibát ad vissza másik munkalapra hivatkozáskor.

Ez a hiba akkor fordul elő, ha a függvényt tartalmazó képlet egy bezárt munkafüzetben lévő cellákra vagy tartományra hivatkozik, és a cellák számítottak. Ahhoz, hogy ez a funkció működjön, a hivatkozott munkafüzetnek megnyitva kell lennie.

Tanácsok

Művelet

Indoklás

Annak figyelembe vétele, hogy a DARABTELI függvény figyelmen kívül hagyja a kis- és a nagybetűket a szöveges karakterláncokban

A kritériumok nem tesznek különbségek a kis- és a nagybetűk között. Másként fogalmazva: az „alma” és az „ALMA” karakterlánc ugyanazokat a cellákat fogja megtalálni.

Helyettesítő karakterek használata

A kritériumargumentumban helyettesítő karaktereket is használhat: a kérdőjelet (?) és a csillagot (*). A kérdőjel egyetlen karaktert, míg a csillag tetszőleges számú karaktert helyettesíthet. Ha magát a helyettesítő karaktert keresi, írjon be elé egy tilde karaktert (~).

Az =DARABTELI(A2:A5;"alm?") az „alm” karakterlánc összes előfordulását megszámolja úgy, hogy az utolsó betű tetszőleges lehet.

Győződjön meg arról, hogy az adatokban nincsenek elírások.

Szöveges értékek számlálásakor gondoskodjon arról, hogy az adatok ne tartalmazzanak szóközöket a karakterlánc elején vagy végén, ne szerepeljenek bennük nem egységes módon használt egyenes vagy nyomdai idézőjelek, továbbá nem nyomtatható karakterek. Ilyenkor a DARABTELI függvény váratlan eredményt adhat vissza.

Erre használhatja a TISZTÍT függvényt vagy a KIMETSZ függvényt.

Kényelmesebb, ha névvel ellátott tartományokat használ.

A DARABTELI függvény támogatja a névvel ellátott tartományok használatát a képletekben (például =DARABTELI(gyümölcs;">=32")-DARABTELI(gyümölcs;">85"). A névvel ellátott tartomány lehet az aktuális munkalapon, ugyanannak a munkafüzetnek egy másik munkalapján, illetve akár egy másik munkafüzetben is. Másik munkafüzetre való hivatkozáshoz a hivatkozott munkafüzetnek is megnyitva kell lennie.

Megjegyzés : A DARABTELI függvény nem tudja háttérszín vagy betűszín alapján megszámolni a cellákat. Az Excelben azonban definiálhat egyéni felhasználói függvényeket, melyekkel hajthat végre Microsoft Visual Basic for Applications- (VBA-) műveleteket a cellákon azok háttérszíne vagy betűszíne alapján. Példaként lásd a következő cikket: Bizonyos színű cellák megszámolása VBA-kód segítségével.

További segítségre van szüksége?

Bármikor segítséget kérhet az Excel technikai közösségétől és az Answers-közösségtől, az Excel User Voice webhelyen pedig új funkciókra vagy fejlesztésekre tehet javaslatot.

Lásd még

Nem üres cellák megszámolása a DARAB2 függvénnyel

Több feltételnek megfelelő értékek megszámolása a DARABHATÖBB függvénnyel

Videó a DARABHATÖBB függvény használatáról

Egyetlen feltételnek megfelelő értékek összeadása a SZUMHA függvénnyel

Több feltételnek megfelelő értékek összeadása a SZUMHATÖBB függvénnyel

HAELSŐIGAZ függvény (Office 365, Excel 2016 és újabb verziók)

Kezdő és záró szóközök eltávolítása a cellákból a KIMETSZ függvénnyel

Nem nyomtatható karakterek eltávolítása a cellákból a TISZTÍT függvénnyel

A képletek áttekintése az Excelben

Képlethibák elkerülése

A képlethibák feltárása

Statisztikai függvények

Az Excel függvényeinek betűrendes listája

Az Excel függvényeinek kategória szerinti listája

A SZUMHA, a DARABTELI és más kapcsolódó függvények használata az adatok gyors elemzéséhez (ingyenes bemutató)

Ismeretek bővítése
Oktatóanyagok megismerése
Új szolgáltatások listájának lekérése
Részvétel az Office Insider programban

Hasznos volt az információ?

Köszönjük a visszajelzését!

Köszönjük visszajelzését. Jobbnak látjuk, ha az Office egyik támogatási szakemberéhez irányítjuk.

×