Pregled formula u programu Excel

Pregled formula u programu Excel

Ako još ne znate raditi u programu Excel, ubrzo ćete saznati da to nije tek rešetka u koju unosite brojeve u stupce i retke. Istina, Excel možete koristiti za izračun zbroja vrijednosti u stupcu ili retku, ali vam može poslužiti i za izračun otplata rata kredita, rješavanje matematičkih i inženjerskih problema te nalaženje najpovoljnijeg scenarija na temelju varijabli koje unesete.

Excel to postiže pomoću formula u ćelijama. Formula obavlja izračune i druge akcije na podacima na radnom listu. Formula započinje znakom jednakosti (=) nakon kojeg mogu slijediti brojevi, matematički operatori (npr. znak plus ili minus za dodavanje ili oduzimanje) te ugrađene funkcije programa Excel, koje doista mogu proširiti mogućnosti formule.

Sljedećom formulom, primjerice, množi se 2 s 3, a zatim se umnožak zbraja s 5 da bi se dobio rezultat 11.

=2*3+5

Evo još nekih primjera formula koje možete unijeti na radni list.

  • =A1+A2+A3    Zbraja vrijednosti u ćelijama A1, A2 i A3.

  • =SUM(A1:A10)    Koristi funkciju SUM za vraćanje zbroja vrijednosti u ćelijama od A1 do A10.

  • =TODAY()    Vraća trenutni datum.

  • =UPPER("pozdrav")     Pretvara tekst "pozdrav" u "POZDRAV" pomoću funkcije UPPER.

  • =IF(A1>0)    Koristi funkciju IF da bi se utvrdilo sadrži li ćelija A1 vrijednost veću od 0.

Formula može sadržavati i funkcije, reference, operatore i konstante.

Dijelovi formule   

Dijelovi formule

1. Funkcije: funkcija PI() vraća vrijednost pi: 3,142...

2. Reference: A2 vraća vrijednost u ćeliji A2.

3. Konstante: brojevi ili tekstne vrijednosti uneseni izravno u formulu, na primjer 2.

4. Operatori: operator ^ (karet) služi za izračun potencije broja, a operator * (zvjezdica) za množenje brojeva.

Konstanta je vrijednost koja se ne izračunava, već je uvijek ista. Na primjer, datum 10/9/2008, broj 210 i tekst "Kvartalna zarada" su konstante. izraz ili vrijednost koja je rezultat izraza nije konstanta. Ako u formuli koristite konstante umjesto referenci na ćelije (na primjer =30+70+110), rezultat se mijenja samo ako izmijenite formulu. U pravilu je najbolje konstante staviti u pojedinačne ćelije u kojima se jednostavno po potrebi mogu promijeniti, a zatim se u formulama referirati na te ćelije.

Operatori određuju vrstu izračuna koji želite izvesti na elementima u formuli. Excel slijedi osnovna matematička pravila za izračune, a to su Zagrade, Eksponenti, Množenje i dijeljenje i Zbrajanje i oduzimanje. Korištenje zagrada omogućuje promjenu redoslijeda izračuna.

Vrste operatora. Postoje četiri različite vrste računskih operatora: aritmetički operatori, operatori usporedbe, operatori spajanja teksta i operatori referenci.

  • Aritmetički operatori

    Za izvođenje osnovnih matematičkih operacija zbrajanja, oduzimanja, množenja i dijeljenja, kombiniranje brojeva te dobivanje brojčanih rezultata koristite sljedeće aritmetičke operatore.

    Aritmetički operator

    Značenje

    Primjer

    + (znak plus)

    Zbrajanje

    =3+3

    - (znak minus)

    oduzimanje
    negativna vrijednost

    =3–3
    =-3

    * (zvjezdica)

    Množenje

    =3*3

    / (kosa crta)

    Dijeljenje

    =3/3

    % (znak postotka)

    Postotak

    30 %

    ^ (karet)

    Potencija

    =3^3

  • Operatori usporedbe

    Dvije vrijednosti možete usporediti pomoću sljedećih operatora. Kada se dvije vrijednosti uspoređuju pomoću tih operatora, rezultat je logička vrijednost – TRUE ili FALSE.

    Operator usporedbe

    Značenje

    Primjer

    = (znak jednako)

    Jednako je

    =A1=B1

    > (znak veće od)

    veće od

    =A1>B1

    < (znak manje od)

    manje od

    =A1<B1

    >= (znak veće od ili jednako)

    veće od ili jednako

    =A1>=B1

    <= (znak manje od ili jednako)

    manje od ili jednako

    =A1<=B1

    <> (znak nije jednako)

    nije jednako

    =A1<>B1

  • Operator spajanja teksta

    Pomoću znaka & pridružite (sjedinite) tekstne nizove da biste stvorili jednodijelni tekst.

    Tekstni operator

    Značenje

    Primjer

    & (ampersand)

    Povezuje ili spaja dvije vrijednosti i daje jednu neprekidnu tekstnu vrijednost.

    ="North"&"wind" daje "Northwind".
    Ako A1 sadrži "Prezime", a B1 sadrži "Ime", =A1&", "&B1 daje "Ime, prezime".

  • Operatori referenci

    Rasponi ćelija za izračune kombiniraju se pomoću sljedećih operatora.

    Operator referenci

    Značenje

    Primjer

    : (dvotočka)

    Operator raspona koji stvara jednu referencu na sve ćelije između dviju referenci, uključujući i te dvije reference.

    B5:B15

    , (zarez)

    Operator unije koji više referenci spaja u jednu.

    =SUM(B5:B15;D5:D15)

    (razmak)

    Operator presjeka koji kao rezultat stvara jednu referencu na ćelije koje su zajedničke dvjema referencama.

    B7:D7 C6:C8

Vrh stranice

U nekim slučajevima redoslijed izvođenja izračuna može utjecati na vrijednost koju će formula vratiti, pa je radi postizanja željenog rezultata važno znati kako se određuje i mijenja redoslijed.

  • Redoslijed izračuna

    Formule izračunavaju vrijednosti određenim redoslijedom. Formula u programu Excel uvijek započinje znakom jednakosti (=). Znak jednakosti govori programu Excel da znakovi koji slijede čine formulu. Nakon znaka jednakosti slijede elementi koje treba izračunati (operandi), primjerice konstante ili reference na ćelije. Oni su razdvojeni operatorima izračuna. Excel izračunava formulu slijeva nadesno, prema određenom redoslijedu za svaki operator u formuli.

  • Prioritet operatora u formulama programa Excel

    Ako kombinirate više operatora u jednoj formuli, Excel će operacije izvoditi redoslijedom koji je prikazan u sljedećoj tablici. Ako formula sadrži operatore s istim prioritetom,  npr. operator množenja i operator dijeljenja, Excel operatore obrađuje slijeva nadesno.

    Operator

    Opis

    : (dvotočka)

    (jednostruki razmak)

    ; (točka sa zarezom)

    operatori reference

    -

    negativni broj (kao u -1)

    %

    postotak

    ^

    potencija

    * i /

    množenje i dijeljenje

    + i -

    Zbrajanje i oduzimanje

    &

    povezivanje dva niza teksta (spajanje)

    =
    < >
    <=
    >=
    <>

    Usporedba

  • Korištenje zagrada u formulama programa Excel

    Da biste promijenili redoslijed procjene, u zagrade stavite onaj dio formule koji se treba izračunati prvi. Sljedeća formula, primjerice, daje rezultat 11 jer Excel množenje izvodi prije zbrajanja. Formula množi 2 i 3, a zatim rezultatu pribraja 5.

    =5+2*3

    Nasuprot tome, koristite li zagrade za promjenu sintakse, Excel zbraja 5 i 2 a zatim rezultat množi s 3, čime se dobiva 21.

    =(5+2)*3

    U sljedećem primjeru zagrada oko prvog dijela formule navodi Excel da najprije izračuna B4+25, a da zatim rezultat podijeli sa zbrojem vrijednosti u ćelijama D5, E5 i F5.

    =(B4+25)/SUM(D5:F5)

    Vrh stranice

Funkcije su unaprijed definirane formule koje izvode izračune pomoću određenih vrijednosti, koje se zovu argumenti, u točno zadanom redoslijedu ili strukturi. Funkcije se mogu koristiti za izvođenje jednostavnih ili kompleksnih izračuna. Sve funkcije programa Excel možete pronaći na vrpci na kartici Formule:

Kartica Formule na vrpci u programu Excel
  • Sintaksa funkcije programa Excel

    Slijedeći primjer funkcije ROUND koja zaokružuje broj u ćeliji A10 prikazuje sintaksu funkcije.

    Struktura funkcije

    1. Struktura. Struktura funkcije započinje znakom jednakosti (=), iza čega slijedi naziv funkcije, otvorena zagrada, argumenti funkcije odvojeni točkama sa zarezima i zatvorena zagrada.

    2. Naziv funkcije. Da bi vam se prikazao popis dostupnih funkcija, kliknite ćeliju, a zatim pritisnite SHIFT + F3, čime ćete otvoriti dijaloški okvir Umetanje funkcije.

    Formule u programu Excel – dijaloški okvir Umetanje funkcije

    3. Argumenti. Argumenti mogu biti brojevi, tekst, logičke vrijednosti kao što su TRUE ili FALSE, polja, vrijednosti pogreške, npr. #N/A, ili reference ćelija. Postavljeni argument mora davati valjanu vrijednost za taj argument. Argumenti mogu biti i konstante, formule ili druge funkcije.

    4. Opis elementa za argument. Opis elementa sa sintaksom i argumentima pojavit će se za vrijeme upisivanja funkcija. Ako upišete, primjerice, =ROUND(, pojavit će se opis elementa. Opisi elementa prikazuju se samo za ugrađene funkcije.

    Napomena : Funkcije ne morate unijeti velikim slovima, npr. = ROUND, jer Excel nazive funkcija automatski pretvara u velika slova čim pritisnete Enter. Ako pogrešno napišete naziv funkcije, npr. =SUME(A1:A10) umjesto =SUM(A1:A10), Excel će vratiti pogrešku #NAZIV?.

  • Unos funkcija programa Excel

    Kada stvorite formulu koja sadrži funkciju, pomoću dijaloškog okvira Umetanje funkcije možete unositi funkcije radnog lista. Kada odaberete funkciju u dijaloškom okviru Umetanje funkcije, Excel će pokrenuti čarobnjak za funkciju, koji prikazuje naziv funkcije, sve njezine argumente, opis funkcije i svakog argumenta, trenutni rezultat funkcije i trenutni rezultat cijele formule.

    Čarobnjak za funkcije programa Excel

    Da biste pojednostavnili stvaranje i uređivanje formula i minimizirali pogreške sintakse i upisa, koristite mogućnost Samodovršavanje formule. Kada upišete = (znak jednakosti) i početna slova funkcije, Excel prikazuje dinamički padajući popis valjanih funkcija, argumenata i naziva koji se podudaraju sa slovima. Tada možete odabrati neku stavku s padajućeg popisa i Excel će je unijeti umjesto vas.

    Samodovršetak formule u programu Excel

  • Ugnježđivanje funkcija programa Excel

    U nekim je slučajevima potrebno kao jedan od argumenata funkcije koristiti drugu funkciju. U sljedećoj se formuli, primjerice, koristi ugniježđena funkcija AVERAGE, a rezultat se uspoređuje s vrijednošću 50.

    ugniježđene funkcije

    1. Funkcije AVERAGE i SUM ugniježđene su unutar funkcije IF.

    Valjane vraćene vrijednosti    Kada se ugniježđena funkcija koristi kao argument, mora vratiti istu vrstu vrijednosti koju koristi argument. Ako, primjerice, argument vraća vrijednost TRUE ili FALSE, ugniježđena funkcija mora vratiti vrijednost TRUE ili FALSE. Ako to ne učini, Excel prikazuje vrijednost pogreške #VALUE!.

    Ograničenja razine gniježđenja    Formula može sadržavati najviše sedam razina ugniježđenih funkcija. Kada se neka funkcija (nazovimo je funkcija B) koristi kao argument druge funkcije (nazovimo je funkcija A), funkcija B ponaša se kao funkcija druge razine. Na primjer, funkcija AVERAGE i funkcija SUM obje su funkcije druge razine ako se koriste kao argumenti funkcije IF. Funkcija koja je ugniježđena unutar ugniježđene funkcije AVERAGE tada je funkcija treće razine i tako dalje.

    Vrh stranice

Referenca je identifikator ćelije ili raspona ćelija na radnom listu, a programu Excel govori gdje treba tražiti vrijednosti ili podatke koje želite koristiti u formuli. Pomoću referenci možete u jednoj formuli koristiti podatke sadržane u raznim dijelovima radnog lista ili pak u nekoliko formula koristiti vrijednost iz jedne ćelije. Možete se pozivati i na ćelije na drugim listovima iste radne knjige i u drugim radnim knjigama. Reference na ćelije u drugim radnim knjigama zovu se veze ili vanjske reference.

  • Stil reference A1

     Po zadanom Excel koristi stil reference A1, koji se odnosi na stupce sa slovima (A do XFD, za ukupno 16 384 stupca) i na retke s brojevima (1 do 1 048 576). Ta slova i brojevi zovu se zaglavlja redaka i stupaca. Da biste unijeli referencu na neku ćeliju, unesite slovo stupca i nakon njega broj retka. Tako B2 upućuje na ćeliju na presjeku stupca B i retka 2.

    Da biste se pozvali na

    Koristite značajku

    ćeliju u stupcu A i retku 10

    A10

    raspon ćelija u stupcu A i recima 10 do 20

    A10:A20

    raspon ćelija u retku 15 i stupcima B do E

    B15:E15

    sve ćelije u retku 5

    5:5

    sve ćelije u recima od 5 do 10

    5:10

    sve ćelije u stupcu H

    H:H

    sve ćelije u stupcima od H do J

    H:J

    raspon ćelija u stupcima od A do E i recima od 10 do 20

    A10:E20

  • Stvaranje reference na ćeliju ili raspon ćelija na drugom radnom listu u istoj radnoj knjizi

    U sljedećem primjeru funkcija AVERAGE izračunava prosječnu vrijednost raspona B1:B10 na radnom listu naziva Marketing u istoj radnoj knjizi.

    Primjer reference lista

    1. Upućuje na radni list pod nazivom Marketing

    2. Upućuje na raspon ćelija od B1 do B10

    3. Znak upitnika (!) odjeljuje referencu radnog lista od reference raspona ćelija

    Napomena : Ako referencirani radni list sadrži razmake ili brojeve, morate dodati apostrofe (') prije i nakon naziva radnog lista, npr. = '123'!A1 ili = 'Siječanj, prihod'!A1.

  • Razlike između apsolutnih, relativnih i mješovitih referenci

    1. Relativne reference    Relativna referenca na ćeliju u formuli, kao što je A1, temelji se na relativnom položaju ćelije koja sadrži formulu i ćelije na koju se referenca poziva. Ako se položaj ćelije koja sadrži formulu promijeni, mijenja se i referenca. Ako kopirate ili ispunite formulu po recima ili niz stupce, referenca se prilagođava automatski. Nove formule po zadanom koriste relativne reference. Na primjer, ako kopirate ili ispunite relativnu referencu iz ćelije B2 u ćeliju B3, ona se automatski prilagođava sa =A1 na =A2.

      Kopirana formula s relativnom referencom   

      Kopirana formula s relativnom referencom

    2. Apsolutne reference    Apsolutna referenca na ćeliju u nekoj formuli, npr $A$1, uvijek se poziva na ćeliju na točno određenom mjestu. Ako se promijeni položaj ćelije koja sadrži formulu, apsolutna referenca ostaje ista. Ako kopirate formulu po recima ili niz stupce, apsolutna se referenca ne prilagođava. Po zadanom, nove formule koriste relativne reference, pa ćete ih po potrebi morati pretvoriti u apsolutne reference. Ako, primjerice, kopirate apsolutnu referencu iz ćelije B2 u ćeliju B3, ona u obje ćelije ostaje ista: =$A$1.

      Kopirana formula s apsolutnom referencom   

      Kopirana formula s apsolutnom referencom
    3. Mješovite reference    Mješovita referenca ima ili apsolutni stupac i relativni redak ili apsolutni redak i relativni stupac. Apsolutna referenca stupca ima oblik $A1, $B1 i tako dalje. Apsolutna referenca retka ima oblik A$1, B$1 i tako dalje. Ako se položaj ćelije koja sadrži formulu promijeni, mijenja se i relativna referenca, a apsolutna se referenca ne mijenja. Ako kopirate formulu ili je ispunite po recima ili niz stupce, relativna referenca se automatski prilagođava, a apsolutna se referenca ne prilagođava. Ako, primjerice, kopirate ili ispunite mješovitu referencu iz ćelije A2 u ćeliju B3, ona se mijenja iz =A$1 u =B$.

      Kopirana formula s mješovitom referencom   

      Kopirana formula s mješovitom referencom

  • Trodimenzionalni stil reference

    Praktične reference na više radnih listova    Ako želite analizirati podatke u istoj ćeliji ili rasponu ćelija na više radnih listova u jednoj radnoj knjizi, koristite 3D referencu. 3D referenca obuhvaća referencu ćelije ili raspona kojoj prethodi raspon naziva radnih listova. Excel koristi sve radne listove spremljene između početnih i završnih naziva reference. Na primjer, =SUM(List2:List13!B5) zbraja sve vrijednosti sadržane u ćeliji B5 na svim radnim listovima između listova 2 i 13, uključujući ta dva lista.

    • Pomoću 3D referenci možete se referencirati na ćelije na drugim listovima, definirati nazive i stvarati formule koristeći sljedeće funkcije: SUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA i VARPA.

    • 3D reference ne mogu se koristiti u formulama polja.

    • 3D reference ne mogu se koristiti s operator presjeka (jednostruki razmak) ili u formulama koje koriste implicitno sjecište.

    Što se događa prilikom premještanja, kopiranja, umetanja ili brisanja radnih listova    Sljedeći primjeri objašnjavaju što se događa kad premještate, kopirate, umećete ili brišete radne listove obuhvaćene 3D referencama. U primjerima se koristi formula =SUM(List2:List6!A2:A5) za zbrajanje ćelija od A2 do A5 na radnim listovima od 2 do 6.

    • Umetanje ili kopiranje    Ako umetnete ili kopirate list između listova List2 i List6 (krajnjih točaka u ovom primjeru) u radnoj knjizi, Excel u izračune uvrštava sve vrijednosti u ćelijama od A2 do A5 na dodanim listovima.

    • Brisanje    Ako izbrišete listove između listova List2 i List6, Excel njihove vrijednosti uklanja iz izračuna.

    • Premještanje    Ako premjestite listove između listova List2 i List6 na mjesto izvan raspona listova na koji upućuje referenca, Excel njihove vrijednosti uklanja iz izračuna.

    • Premještanje krajnje točke    Ako premjestite List2 ili List6 na drugo mjesto u istoj radnoj knjizi, Excel prilagođava izračun kako bi odgovarao novom rasponu listova.

    • Brisanje krajnje točke    Ako izbrišete List2 ili List6, Excel prilagođava izračun kako bi odgovarao rasponu listova između njih.

  • Stil reference R1C1

    Možete koristiti i stil reference u kojem su i reci i stupci na radnom listu numerirani. Stil reference R1C1 koristan je pri izračunavanju položaja redaka i stupaca u makronaredbama. Ako se radi o stilu R1C1, Excel upućuje na mjesto ćelije s "R" iza kojega stoji broj retka te "C" iza kojega stoji broj stupca.

    Referenca

    Značenje

    R[-2]C

    relativna referenca na ćeliju dva retka iznad u istom stupcu

    R[2]C[2]

    relativna referenca na ćeliju dva retka ispod i dva stupca desno

    R2C2

    apsolutna referenca na ćeliju u drugom retku i drugom stupcu

    R[-1]

    relativna referenca na cijeli redak iznad aktivne ćelije

    R

    apsolutna referenca na trenutni redak

    Prilikom snimanja makronaredbe Excel neke naredbe snima pomoću stila reference R1C1. Ako, primjerice, snimate naredbu kao što je umetanje formule koja zbraja neki raspon ćelija klikom na gumb Automatski zbroj, Excel formulu snima pomoću referenci stila R1C1, a ne A1.

    Stil reference R1C1 možete uključiti ili isključiti tako da potvrdite ili poništite potvrdni okvir Stil referenci R1C1 u odjeljku Rad s formulama u kategoriji Formule u dijaloškom okviru Mogućnosti. Da biste prikazali taj dijaloški okvir, kliknite karticu Datoteka.

    Vrh stranice

Možete stvoriti definirane nazive koji će predstavljati ćelije, raspone ćelija, formule, konstante ili tablice programa Excel. Naziv je smislena kratica koja olakšava razumijevanje svrhe naizgled teško razumljivih referenci ćelija, konstanti, formula ili tablica. Informacije koje slijede prikazuju uobičajene primjere naziva i načina na koji njihovo korištenje poboljšava jasnoću i pojednostavnjuje razumijevanje formula.

Primjer 1

Vrsta primjera

Primjer u kojem se umjesto naziva koriste rasponi

Primjer u kojem se koriste nazivi

Referenca

=SUM(A16:A20)

=SUM(Prodaja)

Konstanta

=PRODUCT(A12;9,5%)

=PRODUCT(Cijena;Porezna stopa)

Formula

=TEXT(VLOOKUP(MAX(A16;A20);A16:B20;2;FALSE);"m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Prodaja);PodaciOProdaji;2;FALSE);"m/dd/yyyy")

Tablica

A22:B25

=PRODUCT(Cijena;Tablica1[@Porezna stopa])

Primjer 2

Ogledne podatke kopirajte u sljedeću tablicu i zalijepite ih u ćeliju A1 novog radnog lista programa Excel. Da biste koristili formule za prikaz rezultata, odaberite ih pa pritisnite tipku F2, a zatim Enter. Ako je potrebno, prilagodite širine stupaca da biste vidjeli sve podatke.

Napomena :  U formulama u stupcima C i D definirani naziv "Prodaja" zamijenjen je referencom na (raspon) A9:A13, a naziv "PodaciOProdaji" zamijenjen je rasponom A9:B13. Ako ne stvorite te nazive u testnoj radnoj knjizi, formule u rasponu D2:D3 vratit će pogrešku #NAZIV?.

Vrsta primjera

Primjer, bez naziva

Primjer, s nazivom

Formula i rezultat, s nazivom

Referenca

'=SUM(A9:A13)

'=SUM(Prodaja)

=SUM(Prodaja)

Formula

'=TEXT(VLOOKUP(MAX(A9:13);A9:B13;2;FALSE),"m/dd/yyyy")

'=TEXT(VLOOKUP(MAX(Prodaja);PodaciOProdaji;2;FALSE);"m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Prodaja);PodaciOProdaji;2;FALSE);"m/dd/yyyy")

Cijena

995 kuna

Prodaja

Datum prodaje

249 kuna

17. 3. 2011.

399 kuna

2. 4. 2011.

643 kune

23. 4. 2011.

275 kuna

30. 4. 2011.

447 kuna

4. 5. 2011.

  • Vrste naziva

    Postoji nekoliko vrsta naziva koje možete stvoriti i koristiti.

    • Definirani naziv    Naziv koji predstavlja ćeliju, raspon ćelija, formulu ili vrijednost konstante. Možete stvoriti vlastiti definirani naziv. Excel katkad stvara definirani naziv umjesto vas, npr. prilikom postavljanja područja ispisa.

    • Naziv tablice    Naziv tablice programa Excel, koja je skup podataka o određenoj temi spremljenih u zapisima (reci) i poljima (stupci). Excel stvara zadani naziv tablice programa Excel kao "Tablica1", "Tablica2" i tako dalje prilikom svakog umetanja tablice programa Excel, ali te nazive možete i zamijeniti smislenijim varijantama.

      Dodatne informacije o tablicama programa Excel potražite u članku Korištenje strukturiranih referenci s tablicama programa Excel.

  • Stvaranje i unos naziva

    Naziv se stvara pomoću:

    • okvira naziva na traci formule    To je najbolji način u slučaju stvaranja naziva na razini radne knjige za odabrani raspon.

    • stvaranja naziva iz odabira    Nazive možete praktično stvarati iz oznaka postojećeg retka i stupca putem odabira ćelija na radnom listu.

    • Dijaloškog okvira Novi naziv    Ovo je najbolje koristiti u slučaju ako trebate više fleksibilnosti u stvaranju naziva, primjerice pri određivanju djelokruga razine lokalnog radnog lista ili pri stvaranju komentara naziva.

    Napomena : Nazivi po zadanom koriste apsolutne reference ćelija.

    Naziv možete unijeti na sljedeće načine:

    • Upisivanjem     Upišite naziv, npr. kao argument za formulu.

    • Korištenjem samodovršetka formule    Koristite padajući popis samodovršetka formule na kojem se automatski navode valjani nazivi.

    • odabirom naredbe Koristi u formuli    Odaberite definirani naziv s dostupnog popisa iz naredbe Koristi u formuli u grupi Definirani nazivi na kartici Formula.

Dodatne informacije potražite u članku Definiranje i korištenje naziva u formulama.

Vrh stranice

Formula polja može izvesti višestruke izračune i vratiti jedan ili više rezultata. Formula polja djeluje na dva ili više skupova vrijednosti, poznatih kao argumenti polja. Svaki argument polja mora imati jednak broj stupaca i redaka. Formule polja se stvaraju na isti način kao i druge formule, osim što se za unos formule mora pritisnuti CTRL+SHIFT+ENTER. Neke od ugrađenih funkcija su formule polja, i za dobivanje točnih rezultata moraju se unijeti kao polja.

Konstante polja mogu se koristiti umjesto referenci kad ne želite unositi svaku vrijednost konstante u zasebnu ćeliju na radnom listu.

Korištenje formula polja za izračunavanje jednostrukih i višestrukih rezultata

Napomena : Kada unosite formula polja, Excel automatski umeće formulu u vitičaste zagrade – { }. Ako ih pokušate sami unijeti, Excel će prikazati formulu kao tekst.

  • Formula područja koja daje jedan rezultat    Ta vrsta formule polja može pojednostavniti model radnog lista jer nekoliko formula zamjenjuje jedinstvenom formulom polja.

    Npr. sljedeća formula računa ukupni iznos niza cijena dionica i udjela, bez korištenja retka ćelija za izračun i prikaz pojedinačnih iznosa za svaku dionicu.

    formula polja koja daje jedan rezultat

    Unesete li formulu ={SUM(B2:D2*B3:D3)} kao formula polja, ona će pomnožiti Dionice i Cijenu za svaku dionice, a zatim zbrojiti rezultate tih izračuna.

  • Formula polja koja daje više rezultata    Neke funkcije radnog lista vraćaju polja vrijednosti ili kao argument zahtijevaju niz vrijednosti. Da biste izračunali više rezultata pomoću formule polja, morate unijeti niz u raspon ćelija koji ima isti broj redaka i stupaca kao i argumenti niza.

    Ako, primjerice, postoji niz od tri iznosa prodaje (u stupcu B) za niz od tri mjeseca (u stupcu A), funkcija TREND određuje pravocrtne vrijednosti za iznose prodaje. Da bi se prikazali svi rezultati formule, unosi se u tri ćelije u stupcu C (C1:C3).

    Formula polja koja daje više rezultata

    Unesete li formulu =TREND(B1:B3,A1:A3) kao formulu polja, ona će dati tri zasebna rezultata (22.196, 17.079 i 11.962) koja se temelje na tri iznosa prodaje i tri mjeseca.

Korištenje konstanti polja

U običnu formulu možete unijeti referencu na ćeliju koja sadrži neku vrijednost ili na samu vrijednost, što se naziva i konstanta. Na sličan način, u formulu polja možete unijeti referencu na polje ili unijeti samo polje vrijednosti sadržanih u ćelijama, što se naziva i konstanta polja. Formule polja prihvaćaju konstante na isti način kao što to čine i ostale formule, ali konstante polja moraju se unijeti u određenom obliku

Konstante polja mogu sadržavati brojeve, tekst, logičke vrijednosti kao što su TRUE ili FALSE te vrijednosti pogrešaka, npr. #N/A. U istoj konstanti polja mogu se nalaziti različite vrste vrijednosti – na primjer {1,3,4;TRUE,FALSE,TRUE}. Brojevi u konstantama polja mogu biti u cjelobrojnom, decimalnom ili znanstvenom obliku. Tekst mora biti unesen u dvostrukim navodnicima – na primjer "utorak".

Konstante polja ne smiju sadržavati reference ćelija, stupaca ili redaka nejednakih duljina, formule ili posebne znakove $ (znak dolara), zagrade ili % (znak postotka).

Prilikom oblikovanja konstanti polja svakako učinite sljedeće:

  • Stavite ih u vitičaste zagrade ({ } ).

  • Vrijednosti u različitim stupcima odijelite zarezima (,). Da biste, primjerice, prikazali vrijednosti 10, 20, 30 i 40, unesite {10,20,30,40}. Ta se konstanta polja naziva polje 1-sa-4 i ekvivalentna je referenci 1-redak-sa-4-stupca.

  • Vrijednosti u različitim recima odijelite točkom sa zarezom (;). Da biste, primjerice, prikazali vrijednosti 10, 20, 30 i 40 u jednom retku, a 50, 60, 70 i 80 u retku neposredno ispod njega, unesite konstantu polja 2-sa-4: {10,20,30,40;50,60,70,80}.

Vrh stranice

Kada izbrišete formulu, brišu se i izračunate vrijednosti rezultata formule. No možete ukloniti samo formulu i ostaviti izračunatu vrijednost formule koja se prikazuje u ćeliji.

  • Da biste izbrisali formulu zajedno s njezinim izračunatim vrijednostima, učinite sljedeće:

    1. Odaberite ćeliju ili raspon ćelija koji sadrži formulu.

    2. Pritisnite tipku DELETE.

  • Da biste izbrisali formulu bez njezinih izračunatih vrijednosti, učinite sljedeće:

    1. Odaberite ćeliju ili raspon ćelija koji sadrži formulu.

      Ako se radi o formuli polja, odaberite raspon ćelija koji sadrži formulu polja.

      Odabir raspona ćelija koji sadrži formulu polja

      1. Kliknite ćeliju u formuli polja.

      2. Na kartici Polazno u grupi Uređivanje kliknite Pronađi i odaberi, a zatim kliknite Idi na.

      3. Kliknite Posebno.

      4. Kliknite Trenutno polje.

    2. Na kartici Polazno u grupi Međuspremnik kliknite Kopiraj Slika gumba .
      slika trake programa excel

      Tipkovni prečac    Možete i pritisnuti CTRL + C.

    3. Na kartici Polazno u grupi Međuspremnik kliknite strelicu ispod naredbe Zalijepi Slika gumba , a potom kliknite Zalijepi vrijednosti.

Vrh stranice

U sljedećoj tablici sažete su neke od uobičajenih pogrešaka pri unosu formula i kako ih izbjeći:

Za uvjet

Dodatne informacije

Sve otvorene zagrade uparite sa zatvorenima u formuli    

Sve zagrade dio su odgovarajućeg para u formulama. Pri stvaranju formule Excel prikazuje zagrade u boji nakon što ih unesete.

Pri navođenju raspona u formuli koristite dvotočku   

Dvotočke (:) se koriste za odvajanje reference na prvu i zadnju ćeliju u rasponu. Npr. A1:A5.

Unesite sve potrebne argumente    

Funkcije mogu imati obavezne i neobavezne argumente (naznačuju ih uglate zagrade u sintaksi). Moraju se unijeti svi obavezni argumenti. Provjerite i niste li unijeli previše argumenata.

U formule nemojte ugnježđivati više od 64 funkcije   

Ugnježđivanje funkcija unutar funkcije ograničeno je na 64 razine.

Obuhvatite nazive radne knjige ili lista pomoću jednostrukog navodnika    

Prilikom referiranja na vrijednosti ili ćelije na drugim radnim listovima ili u drugim radnim knjigama koje u svojim nazivima sadrže znakove koji nisu slova, nazivi moraju biti omeđeni jednostrukim navodnicima ( ' ).

Uvrstite put do vanjskih radnih knjiga    

Vanjske reference moraju sadržavati naziv radne knjige i put do nje.

Brojeve unosite bez oblikovanja    

Brojevi koje unosite u formulu ne smiju biti oblikovani kao brojevi s razdjelnikom tisućica ili znakom dolara ($) jer se zarezi već koriste kao razdjelnici agrumenata u formulama, a znakovi dolara kao oznake apsolutne reference. Na primjer, umjesto da unesete $1.000, u formulu unesite 1000.

Vrh stranice

Važno : Izračunati rezultati formula i nekih funkcija radnog lista programa Excel na računalu sa sustavom Windows koje koristi arhitekturu x86 ili x86-64 mogu se neznatno razlikovati od onih na računalu sa sustavom Windows RT s arhitekturom ARM. Saznajte više o tim razlikama.

Imate pitanje o određenoj funkciji?

Objavite pitanje na forumu zajednice korisnika programa Excel

Doprinos poboljšanju programa Excel

Imate li prijedloge kako unaprijediti novu verziju programa Excel? Ako imate, pročitajte teme na stranici Excel User Voice

Vidi također

Pregled formula u programu Excel

Izbjegavanje neispravnih formula

Traženje i ispravljanje uobičajenih pogrešaka u formulama

Tipkovni prečaci i funkcijske tipke u programu Excel

Funkcije programa Excel (abecednim redoslijedom)

Funkcije programa Excel (po kategorijama)

Proširite svoje vještine
Istražite osposobljavanje

Jesu li vam ove informacije bile korisne?

Hvala vam na povratnim informacijama!

Hvala vam na povratnim informacijama! Čini se da bi vam pomoglo kad bismo vas povezali s nekim od naših agenata podrške za Office.

×