Izračun razlike između dva datuma

Izračun razlike između dva datuma

Funkciju DATEDIF koristite kada želite izračunati razliku između dvaju datuma. Najprije unesite datum početka u jednu ćeliju i datum završetka u drugu ćeliju. Zatim upišite formulu kao što je neka od navedenih u nastavku.

Razlika u danima

=DATEDIF(D9,E9,"d") i rezultat 856

U ovom se primjeru datum početka nalazi u ćeliji D9, a datum završetka u ćeliji E9. Formula se nalazi u ćeliji F9. Parametar "d" vraća broj cijelih dana između dvaju datuma.

Razlika u tjednima

=(DATEDIF(D13,E13,"d")/7) i rezultat: 122,29

U ovom se primjeru datum početka nalazi u ćeliji D13, a datum završetka u ćeliji E13. Parametar "d" vraća broj dana. No obratite pozornost na /7 na kraju formule. Time se broj dana dijeli sa 7, jer tjedan ima sedam dana. Imajte na umu da je i taj rezultat potrebno oblikovati kao broj. Pritisnite CTRL + 1. Zatim kliknite Brojčana > Decimalna mjesta: 2.

Razlika u mjesecima

=DATEDIF(D5,E5,"m") i rezultat: 28

U ovom se primjeru datum početka nalazi u ćeliji D5, a datum završetka u ćeliji E5. U formuli parametar "m" vraća broj cijelih mjeseci između dvaju datuma.

Razlika u godinama

=DATEDIF(D2,E2,"y") i rezultat: 2

U ovom se primjeru datum početka nalazi u ćeliji D2, a datum završetka u ćeliji E2. Parametar "y" vraća broj cijelih godina između dvaju datuma.

Izračunavanje starosti u navršenim godinama, mjesecima i danima

Možete izračunati dob ili nečiji radni staž. Rezultat može biti nešto kao "2 godine, 4 mjeseca, 5 dana".

1. Utvrdite ukupan broj godina pomoću funkcije DATEDIF.

=DATEDIF(D17,E17,"y") i rezultat: 2

U ovom se primjeru datum početka nalazi u ćeliji D17, a datum završetka u ćeliji E17. U formuli parametar "y" vraća broj cijelih godina između dvaju datuma.

2. Utvrdite broj mjeseci ponovnim korištenjem funkcije DATEDIF s parametrom "ym".

=DATEDIF(D17,E17,"ym") i rezultat: 4

U nekoj drugoj ćeliji upotrijebite formulu DATEDIF s parametrom "ym". Parametar "ym" vraća broj preostalih mjeseci nakon zadnje cijele godine.

3. Utvrdite broj dana pomoću druge formule.

=DATEDIF(D17,E17,"md") i rezultat: 5

Sada moramo utvrditi broj preostalih dana. To ćemo učiniti tako što ćemo napisati drugu vrstu formule, prikazanu gore. Ta formula oduzima prvi dan posljednjeg mjeseca (1.5.2016.) od izvornog datuma završetka u ćeliji E17 (6.5.2016.). Evo kako to čini: Najprije funkcija DATE stvara datum, 1.5.2016. Stvara ga pomoću godine u ćeliji E17 i mjeseca u ćeliji E17. Zatim slijedi parametar 1, koji predstavlja prvi dan tog mjeseca. Rezultat funkcije DATE jest 1.5.2016. Zatim se to oduzima od izvornog datuma završetka u ćeliji E17, 6.5.2016. 6.5.2016. minus 1.5.2016. iznosi 5 dana.

Napomena : ne preporučujemo korištenje argumenta "md" funkcije DATEDIF jer on može izračunati netočne rezultate.

4. Neobavezno: objedinite tri formule u jednu.

=DATEDIF(D17,E17,"y")&" godine, "&DATEDIF(D17,E17,"ym")&" mjeseca, "&DATEDIF(D17,E17,"md")&" dana" i rezultat: 2 godine, 4 mjeseca, 5 dana

Sva tri izračuna možete unijeti u jednu ćeliju kao u ovom primjeru. Koristite znakove ampersand, navodnike i tekst. To je dulja formula za upisivanje, ali je barem u jednom dijelu. Savjet: pritisnite ALT + ENTER da biste u formulu dodali prijelome stranica. Tako će biti čitkija. Uz to, ako ne vidite cijelu formulu, pritisnite CTRL + SHIFT + U.

Preuzimanje naših primjera

Možete preuzeti oglednu radnu knjigu sa svim primjerima iz ovog članka. Možete pratiti primjere ili stvoriti vlastite formule.

Preuzmite primjere izračuna datuma

Ostali izračuni datuma i vremena

Kao što ste vidjeli, funkcija DATEDIF izračunava razliku između datuma početka i datuma završetka. No umjesto upisivanja trenutnog datuma u formuli možete koristiti funkciju TODAY(). Kada koristite funkciju TODAY(), Excel koristi trenutni datum na računalu. Imajte na umu da će se taj datum promijeniti kada ponovno otvorite datoteku neki drugi dan.

=DATEDIF(TODAY(),D28,"y") i rezultat: 984

Imajte na umu da je ovaj članak napisan 6. listopada 2016.

Funkciju NETWORKDAYS.INTL koristite kada želite izračunati broj radnih dana između dvaju datuma. Možete i odrediti da izuzme vikende i praznike.

Prije početka: odlučite želite li izuzeti praznike. Ako želite, popis datuma praznika upišite u zasebno područje ili na zaseban list. Svaki datum praznika unesite u zasebnu ćeliju. Nakon toga odaberite te ćelije pa Formule > Definiraj naziv. Nazivu dodijelite naziv MojiPraznici pa kliknite U redu. Zatim stvorite formulu slijedeći upute u nastavku.

1. Upišite datum početka i datum završetka.

Datum početka u ćeliji D53 jest 1.1.2016., a datum završetka u ćeliji E53 jest 31.12.2016.

U ovom se primjeru datum početka nalazi u ćeliji D53, a datum završetka u ćeliji E53.

2. U drugu ćeliju upišite ovakvu formulu:

=NETWORKDAYS.INTL(D53,E53,1) i rezultat: 261

Upišite formulu kao u gornjem primjeru. Parametar 1 u formuli određuje subote i nedjelje kao dane vikenda i izuzima ih ukupnog zbroja.

Napomena: u programu Excel 2007 funkcija NETWORKDAYS.INTL nije dostupna. No dostupna je funkcija NETWORKDAYS. U programu Excel 2007 gornji primjer bi izgledao ovako: =NETWORKDAYS(D53,E53). Parametar 1 ne navodi se jer funkcija NETWORKDAYS podrazumijeva da su dani vikenda subota i nedjelja.

3. Po potrebi promijenite parametar 1.

Popis značajke Intellisense na kojem se prikazuje 2 - nedjelja, ponedjeljak, 3 - ponedjeljak, utorak itd.

Ako subota i nedjelja nisu vaši dani vikenda, promijenite parametar 1 u neki drugi broj s popisa značajke IntelliSense. Npr. parametar 2 određuje nedjelje i ponedjeljke kao dane vikenda.

Ako koristite Excel 2007, preskočite ovaj korak. Funkcija NETWORKDAYS programa Excel 2007 uvijek podrazumijeva da su dani vikenda subota i nedjelja.

4. Upišite naziv raspona praznika.

=NETWORKDAYS.INTL(D53,E53,1,MojiPraznici) i rezultat: 252

Ako ste u odjeljku "Prije početka" stvorili naziv raspona praznika, upišite ga na kraju, ovako. Ako nemate praznike, izostavite zarez i parametar MojiPraznici. Ako koristite Excel 2007, gornji primjer izgleda ovako: =NETWORKDAYS(D53,E53,MyHolidays).

Savjet: ako ne želite referencirati naziv raspona praznika, možete i upisati raspon, npr. D35:E:39. Možete i upisati svaki praznik u formulu. Da su praznici bili, primjerice, 1. i 2. siječnja 2016., upisali biste ih ovako: =NETWORKDAYS.INTL(D53,E53,1,{"1.1.2016.","2.1.2016."}). U programu Excel 2007 formula bi izgledala ovako: =NETWORKDAYS(D53,E53,{"1.1.2016.","2.1.2016."})

Proteklo vrijeme možete izračunati oduzimanjem jednog vremena od drugog. Najprije unesite vrijeme početka u jednu ćeliju i vrijeme završetka u drugu ćeliju. Unesite cijelo vrijeme, uključujući sate, minute i razmak između oznake AM ili PM. Evo kako:

1. Upišite datum početka i datum završetka.

Datum/vrijeme početka 7:15 AM, datum/vrijeme završetka 4:30 PM

U ovom se primjeru vrijeme početka nalazi u ćeliji D80, a vrijeme završetka u ćeliji E80. Obavezno upišite sate, minute i razmak ispred oznake AM ili PM.

2. Postavite oblik h:mm AM/PM.

Dijaloški okvir Oblikovanje ćelija, naredba Korisnička, vrsta h:mm AM/PM

Odabrite oba datuma pa pritisnite CTRL + 1 (ili Slika ikone gumba MAC Command + 1 na Macu). Odaberite Korisnička > h:mm AM/PM, ako oblik nije još postavljen.

3. Oduzmite jedno vrijeme od drugog.

=E80-D80 i rezultat: 9:15 AM

U nekoj drugoj ćeliji oduzmite sadržaj ćelije s vremenom početka od sadržaja ćelije s vremenom završetka.

4. Postavite oblik h:mm.

Dijaloški okvir Oblikovanje ćelija, naredba Korisnička, vrsta h:mm

Pritisnite CTRL + 1 (ili Slika ikone gumba MAC Command + 1 na Macu). Odaberite Korisnička > h:mm da u rezultatu ne bude oznake AM ili PM.

Da biste izračunali vrijeme između dvaju datuma i vremena, jednostavno oduzmite jedan datum i vrijeme od drugog. No na svaku ćeliju morate primijeniti oblikovanje da biste bili sigurni da će Excel vratiti željeni rezultat.

1. Upišite dva cijela datuma i vremena.

Datum početka 1.1.16. 1:00 PM, datum završetka 1.2.16. 2:00 PM

U jednu ćeliju upišite cijeli datum/vrijeme početka. U drugu ćeliju upišite cijeli datum/vrijeme završetka. Svaka ćelija mora sadržavati mjesec, dan, godinu, sat, minutu i razmak ispred oznake AM ili PM.

2. Postavite oblik 14.3.12. 1:30 PM

Dijaloški okvir Oblikovanje ćelija, naredba Datum, vrsta 14.3.12. 1:30 PM

Odaberite obje ćelije pa pritisnite CTRL + 1 (ili Slika ikone gumba MAC Command + 1 na Macu). Zatim odaberite Datum > 14.3.12. 1:30 PM. To nije datum koji ćete postaviti, već samo primjer kako će oblik izgledati. Imajte na umu da u verzijama starijim od programa Excel 2016, taj oblik može imati neki drugi ogledni datum, npr. 14.3.01. 1:30 PM.

3. Oduzmite jedan datum/vrijeme od drugog.

=E84-D84 i rezultat 1,041666667

U nekoj drugoj ćeliji oduzmite datum/vrijeme početka od datuma/vremena završetka. Rezultat će vjerojatno biti decimalni broj. To ćete popraviti u sljedećem koraku.

4. Postavite oblik [h]:mm.

Dijaloški okvir Oblikovanje ćelija, naredba Korisnička, vrsta [h]:mm

Pritisnite CTRL + 1 (ili Slika ikone gumba MAC Command + 1 na Macu). Odaberite Korisnička. U okvir Vrsta upišite [h]:mm.

Dodatni sadržaji

Funkcija DATEDIF

Funkcija NETWORKDAYS.INTL

NETWORKDAYS

Dodatne funkcije datuma i vremena

Izračunavanje razlike između dvaju vremena

Proširite svoje vještine
Istražite osposobljavanje

Jesu li vam ove informacije bile korisne?

Hvala vam na povratnim informacijama!

Hvala vam na povratnim informacijama! Čini se da bi vam pomoglo kad bismo vas povezali s nekim od naših agenata podrške za Office.

×