Funkcija SUM

Funkcija SUM, jedna od matematičkih i trigonometrijskih funkcija, služi za zbrajanje vrijednosti. Možete zbrajati pojedinačne vrijednosti, reference na ćelije, raspone ili pak kombinaciju sve tri vrste.

Na primjer:

  • =SUM(A2:A10)

  • =SUM(A2:A10; C2:C10)

Novi zadatak

Ovaj je videozapis dio tečaja naziva Dodavanje brojeva u Excel 2013.

SUM(broj1;[broj2];...)

Naziv argumenta

Opis

broj1    (obavezan)

Prvi broj koji se zbraja. Broj može biti, primjerice, 4, adresa ćelije, npr. B6, ili raspon ćelija, npr. B2:B8.

broj2 – 255    (neobavezno)

To je drugi broj koji želite zbrojiti. Na taj način možete navesti do 255 brojeva.

Ako želite na brzinu saznati zbroj raspona ćelija, dovoljno je odabrati raspon te pogledati donji desni kut prozora programa Excel.

Snimka zaslona odabira raspona ćelija i pogleda na traku stanja
Traka stanja


To je traka stanja na kojoj se prikazuju informacije o tome što ste odabrali, bilo da je u pitanju jedna ćelija ili više njih. Ako desnom tipkom miša kliknete traku stanja, iskočit će dijaloški okvir sa značajkama i mogućnostima koje možete odabrati. Primijetit ćete i da se u njemu prikazuju vrijednosti iz odabranog raspona ako ste potvrdili te atribute. Dodatno se informirajte o traci stanja.

Formulu SUM na radni list najlakše ćete dodati pomoću čarobnjaka za automatski zbroj. Odaberite praznu ćeliju izravno iznad ili ispod raspona koji želite zbrojiti pa na vrpci na kartici Polazno ili Formula odaberite Automatski zbroj > Zbroj. Čarobnjak za automatski zbroj automatski će prepoznati koji raspon želite zbrojiti te za vas sastaviti formulu. Funkcionira i vodoravno ako odaberete ćeliju lijevo ili desno od raspona koji želite zbrojiti. Imajte na umu da to neće funkcionirati na rasponima u kojima ćelije nisu susjedne, no u sljedećem ćemo odjeljku objasniti kako ćemo to učiniti.

Formulu zbroja možete automatski sastaviti pomoću čarobnjaka za automatski zbroj.  Odaberite raspon ispod/iznad raspona na koji se pozivate ili lijevo/desno od njega pa idite na karticu Formula na vrpci i odaberite Automatski zbroj pa Zbroj.
Na brzinu zbrojite raspone sa susjednim ćelijama pomoću čarobnjaka za automatski zbroj


U dijaloškom okviru Automatski zbroj možete odabrati i druge česte funkcije kao što su:

Okomito automatsko zbrajanje

Ćelija B6 prikazuje formulu zbroja funkcije automatskog zbroja: =SUM(B2:B5)

Čarobnjak za automatski zbroj automatski je prepoznao ćelije B2:B5 kao raspon koji je potrebno zbrojiti. Dovoljno je pritisnuti Enter i potvrditi. Ako želite dodati još ćelija ili neke izuzeti, pritisnite tipku Shift > tipku sa strelicom u željenom smjeru dok ne odaberete željeni raspon, a zatim pritisnite Enter.

Vodič za funkcije Intellisense: oznaka SUM(broj1;[broj2];…) koju vidite ispod funkcije vodič je Intellisense. Ako kliknete SUM ili naziv funkcije, pretvorit će se u plavu hipervezu koja će vas odvesti na temu pomoći za tu funkciju. Ako kliknete neki od elemenata funkcije, istaknut će se dijelovi formule koji ih predstavljaju. U ovom bi se slučaju istaknulo samo B2:B5 jer u formuli postoji samo jedna referenca na broj. Oznaka Intellisense prikazivat će se za sve funkcije.

Vodoravno automatsko zbrajanje

Ćelija D2 prikazuje formulu zbroja funkcije automatskog zbroja: =SUM(B2:C2)

Korištenje funkcije SUM u nesusjednim rasponima.  Formula u ćeliji C8 jest =SUM(C2:C3;C5:C6). Možete koristiti i imenovane raspone, pa će formula tada biti =SUM(Tjedan1;Tjedan2).

Čarobnjak za automatski zbroj obično funkcionira samo uz raspone sa susjednim ćelijama, pa ako u rasponu za zbrajanje postoje prazni reci ili stupci, Excel će se zaustaviti na prvoj praznini. U tom ćete slučaju funkciju SUM morati koristiti po odabiru te jedan po jedan dodavati zasebne raspone. U ovom slučaju, da u ćeliji B4 postoje podaci, Excel bi generirao funkciju =SUM(C2:C6) jer bi prepoznao raspon sa susjednim ćelijama.

Više raspona s nesusjednim ćelijama brzo možete odabrati tako da pritisnete Ctrl + lijevu tipku miša. Najprije unesite “=SUM(“, potom odaberite različite raspone i Excel će automatski između raspona umjesto vas dodati točku sa zarezom. Kad završite, pritisnite Enter.

SAVJET: da biste u ćeliju brzo dodali funkciju SUM, pritisnite ALT + =. Potom morate samo odabrati raspone.

Napomena: primijetit ćete da je Excel različitim bojama istaknuo različite raspone iz funkcije koje su u skladu s bojama unutar same formule, tj. C2:C3 jedne je boje, a C5:C6 druge. Excel to radi za sve funkcije, osim kad je raspon iz reference na drugom radnom listu ili u drugoj radnoj knjizi. Da biste povećali pristupačnost uz upotrebu pomoćne tehnologije za osobe s posebnim potrebama, možete koristiti imenovane raspone, npr. “Tjedan1”, “Tejadan2” itd. pa njih unijeti kao reference u formulu:

=SUM(Tjedan1;Tjedan2)

Jednostavno izvodite matematičke operacije uz Excel samostalno ili uz funkcije programa Excel, kao što je SUM. U sljedećoj su tablici navedeni operatori koje možete koristiti uz neke povezane funkcije. Operatore možete unijeti iz retka broj na tipkovnici ili tipkovnice s 10 tipki ako je imate. Shift + 8, na primjer, unijet će zvjezdicu (*) za množenje.

Operator

Operacija

Primjeri

+

zbrajanje

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

oduzimanje

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

množenje

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1;1) - funkcija PRODUCT

/

dijeljenje

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1;1) - funkcija QUOTIENT

^

potencija

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1;1) - funkcija POWER

Da biste saznali više, pročitajte članak Korištenje programa Excel kao kalkulatora.

Ostali primjeri

  1. Pretpostavimo da na raspon zbrojenih ćelija želite primijeniti određeni postotak popusta.

    Korištenje operatora uz funkciju SUM.  Formula u ćeliji B16 jest =SUM(A2:A14)*-25%.  Formula bi bila pravilno sastavljena da je vrijednost -25% referenca na ćeliju, npr. =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Ta će vam formula kao rezultat dati 25 % zbroja raspona, no time se 25 % izričito unosi u formulu te bi se kasnije moglo dogoditi da ga ne možete pronaći ako morate promijeniti postotak. Mnogo je bolje 25 % unijeti u ćeliju, a zatim unijeti referencu na tu ćeliju jer je iznos postotka izvan formule i možete ga jednostavno promijeniti. Na primjer:

    • =SUM(A2:A14)*E2

    Da biste iznos podijelili, a ne pomnožili, jednostavno znak “*” zamijenite znakom “/”: =SUM(A2:A14)/E2

  2. Zbrajanje i oduzimanje unutar formule SUM

    i. Unutar formule SUM jednostavno možete koristiti zbrajanje i oduzimanje pomoću znakova + i -. To izgleda ovako:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

U ovom odjeljku donosimo praktične savjete za rad s funkcijom SUM. Većina se tih savjeta odnosi i na druge funkcije.

Metoda =1+2 ili =A+B – premda u ćeliju možete unijeti =1+2+3 ili =A1+B1+C2 i dobiti potpuno točne rezultate, te su metode zbog nekoliko razloga sklone pogreškama:

  1. Pogreške u pisanju – zamislite da morate unijeti više vrijednosti ili mnogo veće vrijednosti, kao što su ove:

    • =14598,93+65437,90+78496,23

    Pokušajte nakon toga provjeriti jeste li sve točno upisali. Mnogo je lakše vrijednosti unijeti u pojedinačne ćelije te se poslužiti formulom SUM. Vrijednosti u ćelijama, k tome, možete i oblikovati da bi bile mnogo razumljive kad ih unesete u formulu.

    U formulama koristite funkciju SUM umjesto fiksno kodiranih vrijednosti.  Formula u ćeliji D5 jest =SUM(D2:D4)
  2. Pogreške #VRIJEDNOST! zbog referenci na tekst umjesto na brojeve

    Ako upišete formulu koja izgleda ovako:

    • =A1+B1+C1 ili =A1+A2+A3

    Primjer loše sastavljene formule.  Formula u ćeliji D2 jest =A2+B2+C2

    formula može vratiti pogrešku #VRIJEDNOS! ako su u referentnim ćelijama vrijednosti koje nisu brojčane (već tekstne). Funkcija SUM zanemarit će tekstne vrijednosti te vam prikazati samo zbroj brojčanih vrijednosti.

    Pravilno sastavljanje formule.  Umjesto =A2+B2+C2, formula u ćeliji D2 jest =SUM(A2:C2)
  3. Pogreška #REF! zbog brisanja redaka ili stupaca

    Pogreška #REF! uzrokovana brisanjem stupca.  Oblik formule promijenio se u =A2+#REF!+B2

    Ako izbrišete neki redak ili stupac, formula se neće ažurirati i izbaciti izbrisani redak, već će vratiti pogrešku #REF!, a funkcija SUM automatski će se ažurirati.

    Funkcija SUM automatski će se prilagoditi umetnutim ili izbrisanim recima i stupcima
  4. Formule ne ažuriraju reference prilikom umetanja redaka ili stupaca

    Formule oblika =A+B+C neće se ažurirati prilikom dodavanja redaka

    Ako umetnete redak ili stupac, formula se neće ažurirati i obuhvatiti dodani redak, a funkcija SUM automatski će se ažurirati (ako to nije izvan raspona na koji postoji referenca u formuli). To je osobito važno ako očekujete da će se formula ažurirati, a ona to ne učini jer nećete imati potpuni rezultat, a to možda nećete primijetiti.

    U primjeru se prikazuje formula SUM čiji se oblik automatski proširio iz =SUM(A2:C2) u =SUM(A2:D2) prilikom umetanja stupca
  5. SUM s referencama na pojedinačne ćelije i s referencama na raspone

    Ako koristite formulu kao što je ova:

    • =SUM(A1;A2;A3;B1;B2;B3)

    postoji jednako velika mogućnost da dođe do pogreške kad umetnete ili izbrišete retke unutar raspona iz reference, a razlozi su jednaki kao prethodno navedeni. Mnogo je bolje unijeti pojedinačne raspone, npr.

    • =SUM(A1:A3;B1:B3)

    Oni će se ažurirati kad dodate ili izbrišete retke.

  1. SUM uvijek možete koristiti u kombinaciji s drugim funkcijama. Evo primjera u kojem se računa mjesečni prosjek:

    Korištenje funkcije SUM uz ostale funkcije.  Formula u ćeliji M2 jest =SUM(A2:L2)/COUNTA(A2:L2).  Napomena: stupci Svibanj – Studeni skriveni su radi preglednosti.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. U tom se primjeru zbroj raspona A2:L2 dijeli s brojem popunjenih ćelija u rasponu A2:L2 (od svibnja do prosinca ćelije su prazne).

  1. Katkad je potrebno zbrojiti određene ćelije koje se nalaze na više radnih listova. Možda vam je prvi instinkt kliknuti svaki list, a zatim i željenu ćeliju pa koristiti običan „+” da biste zbrojili vrijednosti ćelija, no to je naporno i takvim pristupom lako može doći do pogrešaka.

    • =List1!A1+List2!A1+List3!A1

    To možete mnogo jednostavnije postići funkcijom 3D SUM za trodimenzionalno zbrajanje:

    3D Sum – formula u ćeliji D2 jest =SUM(List1:List3!A2)
    • =SUM(List1:List3!A1)

    Ta će funkcija zbrojiti ćelije A1 na svim listovima od lista 1 do lista 3.

    To je osobito praktično kad za svaki mjesec imate zaseban list (od siječnja do prosinca) i želite ih sve zbrojiti na listu sažetka.

    3D SUM na imenovanim listovima.  Formula u D2 jest =SUM(Siječanj:Prosinac!A2)
    • =SUM(Siječanj:Prosinac!A2)

    Ta će formula zbrojiti ćelije A2 na svim listovima od siječnja do prosinca.

    Napomene : Ako u nazivima radnih listova postoje razmaci, npr. „Prodaja za siječanj”, morat ćete koristiti apostrof kad u formulu umećete referencu na naziv lista. Obratite pozornost na apostrof PRIJE naziva prvog radnog lista i ponovno NAKON posljednjeg.

    • =SUM(‘Prodaja za siječanj:Prodaja za prosinac’!A2)

    3D metoda funkcionira i za druge funkcije, kao što su AVERAGE, MIN, MAX itd:

    • =AVERAGE(List1:List3!A1)

    • =MIN(List1:List3!A1)

    • =MAX(List1:List3!A1)

Problem

Što nije uredu

Funkcija SUM prikazuje #####, a ne rezultat.

Promijenite širinu stupaca. ##### obično označava da je stupac preuzak da bi se prikazao rezultat formule.

U ćeliji s funkcijom SUM prikazuje se formula kao tekst, a ne rezultat.

Provjerite da ćelija nije oblikovana kao tekst. Odaberite ćeliju ili raspon u kojem se nalazi problem pa pomoću kombinacije tipki Ctrl + 1 otvorite dijaloški okvir Oblikovanje ćelija, a zatim kliknite karticu Broj i odaberite željeni oblik. Ako je ćelija bila oblikovana kao tekst, ali se ne promijeni nakon što promijenite oblik, možda ćete morati prisilno promijeniti oblik pritiskom na F2 > Enter.

Funkcija SUM ne ažurira se

Provjerite je li izračun postavljen na Automatski. Na kartici Formula otvorite Mogućnosti izračuna. Izračun možete prisilno pokrenuti i pomoću tipke F9.

Provjerite je li izračun postavljen na Automatski.  Na kartici Formule idite na Mogućnosti izračuna.

Neke vrijednosti nisu dodane

Zbrajati je moguće samo brojčane vrijednosti u referenci ili rasponu unutar funkcije. Prazne ćelije, logičke vrijednost kao što je TRUE i tekst zanemaruju se.

Umjesto očekivanog rezultata prikazuje se pogreška #NAME?.

To obično znači da je formula pogrešno napisana, npr. =sume(A1:A10) umjesto =SUM(A1:A10).

Funkcija SUM prikazuje cijeli broj, a treba decimalni broj

Provjerite oblikovanje ćelije da biste bili sigurni da se prikazuju decimalni brojevi. Odaberite ćeliju ili raspon u kojem se nalazi problem pa pomoću kombinacije tipki Ctrl + 1 otvorite dijaloški okvir Oblikovanje ćelija, a zatim kliknite karticu Broj i odaberite željeni oblik te provjerite prikazuje li se željeni broj decimalnih mjesta.

  1. Želim samo zbrojiti/oduzeti/pomnožiti/podijeliti brojeve Pogledajte ovu seriju videozapisa o osnovnim matematičkim radnjama u programu Excel ili članak Korištenje programa Excel kao kalkulatora.

  2. Kako prikazati više/manje decimalnih mjesta? Promijenite oblik broja. Odaberite ćeliju ili raspon u kojem se nalazi problem pa pomoću kombinacije tipki Ctrl + 1 otvorite dijaloški okvir Oblikovanje ćelija, a zatim kliknite karticu Broj i odaberite željeni oblik te provjerite prikazuje li se željeni broj decimalnih mjesta.

  3. Kako dodati ili oduzeti vrijeme? Vrijeme možete dodati ili oduzeti na različite načine, Da biste, na primjer, dobili razliku između 8.00 i 12.00 radi izračuna plaće, upotrijebit ćete: =("12.00"-"8.00")*24, oduzimajući od završnog vremena početno vrijeme. Imajte na umu da Excel vremenske vrijednosti računa kao dijelove dana, pa ih morate pomnožiti s 24 da biste dobili ukupan broj sati. U prvom primjeru koristimo =((B2-A2)+(D2-C2))*24 da bismo dobili zbroj sati od početka do kraja bez pauze (ukupno 8,5 sati).

    Ako jednostavno dodajete sate i minute i želite da se tako prikazuju, možete zbrojiti te ne morate množiti s 24, stoga u drugom primjeru koristimo =SUM(A6:C6) jer nam treba samo ukupan broj sati i minuta za dodijeljene zadatke (5.36, tj. 5 sati i 36 minuta).

    Izračunavanje vremena

    Dodatne informacije: Zbrajanje i oduzimanje vremena.

  4. Kako saznati razliku datuma? Datume možete, kao i vrijeme, zbrajati i oduzimati. Evo jednog vrlo čestog primjera u kojem se broje dani između dva datuma. Vrlo je jednostavno, a dovoljno je samo =B2-A2. Prilikom rada s datumima i vremenima najvažnije je da počnete s datumom/vremenom završetka pa od njega oduzmete datum/vrijeme početka.

    Izračunavanje razlike između datuma

    Dodatne načine rada s datuma potražite u članku: Izračun broja dana između dva datuma.

  5. Kako zbrojiti samo vidljive ćelije? Ponekad kada ručno sakrijete retke ili koristite automatski filtar radi prikaza samo nekih podataka, htjet ćete zbrojiti samo vidljive ćelije. Možete upotrijebite funkciju SUBTOTAL. Ako koristite redak s ukupnim zbrojem u tablici programa Excel, sve funkcije koje odaberete na padajućem izborniku Ukupni zbroj automatski će se unijeti kao podzbroj. Saznajte više o ukupnom zbroju podataka u tablici Excel.

Je li vam potrebna dodatna pomoć?

Postavite pitanje stručnjaku u tehničkoj zajednici za Excel, zatražite podršku u zajednici za odgovore ili predložite novu značajku ili poboljšanje na forumu za Excel User Voice.

Vidi također

Pogledajte videozapis o korištenju funkcije SUM

Funkcija SUMIF zbraja samo vrijednosti koje ispunjavaju jedan kriterij

Funkcija SUMIFS zbraja samo vrijednosti koje ispunjavaju više kriterija

Funkcija COUNTIF zbraja samo vrijednosti koje ispunjavaju jedan kriterij

Funkcija COUNTIFS zbraja samo vrijednosti koje ispunjavaju više kriterija

Pregled formula u programu Excel

Izbjegavanje neispravnih formula

Traženje i ispravljanje uobičajenih pogrešaka u formulama

Tipkovni prečaci u programu Excel za Windows

Tipkovni prečaci u programu Excel za Mac

Matematičke i trigonometrijske funkcije

Funkcije programa Excel (abecednim redoslijedom)

Funkcije programa Excel (po kategorijama)

Proširite svoje vještine
Istražite osposobljavanje

Jesu li vam ove informacije bile korisne?

Hvala vam na povratnim informacijama!

Hvala vam na povratnim informacijama! Čini se da bi vam pomoglo kad bismo vas povezali s nekim od naših agenata podrške za Office.

×