הפונקציה TEXT

הערה: אנו מעוניינים לספק לך את תוכן העזרה העדכני ביותר במהירות האפשרית, בשפה שלך. דף זה תורגם באמצעות אוטומציה והוא עשוי לכלול שגיאות דקדוק או אי-דיוקים. מטרתנו היא כי תוכן זה יהיה שימושי עבורך. האם תוכל לספר לנו אם המידע הועיל לך, בחלק התחתון של דף זה? לנוחותך, הנה המאמר באנגלית.

הפונקציה TEXT מאפשרת לך לשנות את אופן ההצגה של מספר על-ידי החלת עיצוב עליו באמצעות קודי עיצוב. דבר זה שימושי במצבים שבהם ברצונך להציג מספרים בתבנית קריאה יותר, או כשברצונך לשלב מספרים עם טקסט או עם סימנים.

הערה: הפונקציה TEXT תמיר מספרים לטקסט, דבר שעשוי להקשות מאוחר יותר בהפניה אליהם בחישובים. מומלץ להשאיר את הערך המקורי בתא אחד ולהשתמש בפונקציה TEXT בתא אחר. לאחר מכן, אם תצטרך לבנות נוסחאות אחרות, הפנה תמיד לערך המקורי ולא לתוצאה של הפונקציה TEXT.

תחביר

‎TEXT(value, format_text)‎

תחביר הפונקציה TEXT מכיל את הארגומנטים הבאים:

שם ארגומנט

תיאור

ערך

ערך מספרי שברצונך להמיר לטקסט.

format_text

מחרוזת טקסט המגדירה את העיצוב הרצוי שיש להחיל על הערך שסופק.

מבט כולל

בצורתה הפשוטה ביותר, הפונקציה TEXT מציינת:

  • =TEXT(ערך שברצונך לעצב, "קוד עיצוב שברצונך להחיל")

להלן כמה דוגמאות נפוצות, שתוכל להעתיק ישירות ל- Excel כדי להתנסות בעצמך. שים לב לקודי עיצוב התחומים בתוך מרכאות כפולות.

נוסחה

תיאור

‎=TEXT(1234.567,"$#,##0.00")‎

מטבע עם מפריד אלפים ושני מקומות עשרוניים, כגון ‎$1,234.57. שים לב כי Excel מעגל את הערך לשני מקומות עשרוניים.

‎=TEXT(TODAY(),"MM/DD/YY")‎

התאריך של היום בתבנית DD/MM/YY, כגון 14/03/12

‎=TEXT(TODAY(),"DDDD")‎

היום בשבוע שחל היום, כגון יום שני

‎=TEXT(NOW(),"H:MM AM/PM")‎

השעה הנוכחית, למשל 13:29

‎=TEXT(0.285,"0.0%")‎

אחוזים, למשל 28.5%

= TEXT(4.34,"# ?/?")

שבר, כמו ‎4 1/3‎

‎=TRIM(TEXT(0.34,"# ?/?"))‎

שבר, כמו 1/3. שים לב שבנוסחה זו נעשה שימוש בפונקציה TRIM כדי להסיר את הרווח המוביל עם ערך עשרוני.

‎=TEXT(12200000,"0.00E+00")‎

סימון מדעי, כמו 1.22E+07

‎=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")‎

(מספר טלפון) מיוחד, כגון ‎(123) 456-7898‎

‎=TEXT(1234,"0000000")‎

הוספת אפסים מובילים (0), כגון 0001234

‎=TEXT(123456,"##0° 00' 00''")‎

התאמה אישית - קו רוחב/קו אורך

הערה: למרות שבאפשרותך להשתמש בפונקציה TEXT כדי לשנות את העיצוב, היא אינה הדרך היחידה. באפשרותך לשנות את העיצוב ללא נוסחה על-ידי הקשת CTRL + 1 (או תמונה של סמל לחצן הפקודה ב- MAC +1 ב- Mac) ולאחר מכן בחר את התבנית הרצויה מתוך עיצוב תאים > הדו-שיח מספר.

הורד את הדוגמאות שלנו

באפשרותך להוריד חוברת עבודה לדוגמה עם כל הדוגמאות הפונקציה טקסט, שתוכל למצוא במאמר זה, בתוספת כמה תוספות. באפשרותך לעקוב אחריך, או ליצור משלך בפונקציה TEXT קודי תבנית.

להוריד טקסט Excel הדוגמאות לפונקציות

קודי עיצוב זמינים אחרים

באפשרותך להשתמש בתיבת הדו-שיח עיצוב תאים כדי למצוא את קודי העיצוב הזמינים האחרים:

  1. לחץ על Ctrl+1 (או על תמונה של סמל לחצן הפקודה ב- MAC ‎+1 ב- Mac) כדי להעלות את תיבת הדו-שיח עיצוב תאים.

  2. בחר את התבנית הרצויה בכרטיסיה מספר.

  3. בחר באפשרות מותאם אישית.

  4. קוד העיצוב הרצוי מוצג כעת בתיבה סוג. במקרה זה, בחר כל מה שמופיע בתיבה סוג, למעט תו הנקודה-פסיק (;) והסימן @. בדוגמה שלהלן, בחרנו והעתקנו רק את mm/dd/yy.

  5. לחץ על Ctrl+C כדי להעתיק את קוד העיצוב ולאחר מכן לחץ על ביטול כדי לשחרר את תיבת הדו-שיח עיצוב תאים.

  6. כעת, כל שעליך לעשות הוא ללחוץ על Ctrl+V כדי להדביק את קוד העיצוב בנוסחת TEXT שלך, כך: ‎=TEXT(B2,"mm/dd/yy")‎. הקפד להדביק את קוד העיצוב בין מרכאות ("קוד עיצוב"), אחרת Excel יציג הודעת שגיאה.

דוגמה לשימוש בתיבת הדו-שיח ’עיצוב’ > ’תאים’ > ’מספר’ > ’מותאם אישית’ כדי ש- Excel ייצור עבורך מחרוזות תבנית.

קודי עיצוב לפי קטגוריה

להלן כמה דוגמאות לאופן בו ניתן להחיל תבניות מספר שונות על הערכים שלך על-ידי שימוש בתיבת הדו-שיח עיצוב תאים ולאחר מכן שימוש באפשרות מותאם אישית כדי להעתיק קודי עיצוב אלה לפונקציה TEXT שלך.

מדוע Excel מוחק את האפסים המובילים שלי?

Excel הוא המתמחים כדי לחפש את המספרים המוזנים בתאים, לא במספרים הנראים טקסט, כגון מספרי חלקים או של SKU. כדי לשמור אפסים מובילים, עצב את טווח הקלט כטקסט לפני הדבקה או הזן ערכים. בחר את העמודה, או טווח שבו אתה ניתן העברת הערכים, לאחר מכן השתמש CTRL + 1 כדי להציג עיצוב > תאים הדו-שיח ובחר Number הכרטיסיהטקסט. כעת Excel ישמור את ריווח שורות של 0.

אם כבר הזנת נתונים ו- Excel הסיר את האפסים המובילים, תוכל להשתמש בפונקציה TEXT כדי להוסיף אותם שוב. באפשרותך להפנות לתא העליון עם הערכים ולהשתמש בנוסחה ‎=TEXT(value,"00000")‎, כאשר מספר האפסים בנוסחה מייצג את המספר הכולל של התווים הרצויים, ולאחר מכן להעתיק ולהדביק בשאר הטווח.

דוגמאות לשימוש בפונקציה TEXT לעיצוב אפסים מובילים.  ‎=TEXT(A2,"00000")‎

אם מסיבה כלשהי, עליך להמיר ערכי טקסט בחזרה למספרים, באפשרותך להכפיל ב- 1, למשל ‎=D4*1 או להשתמש באופרטור אונרי כפול (--), למשל ‎=--D4.

Excel מפריד אלפים באמצעות פסיקים אם התבנית מכילה פסיק (,) המוקף על-ידי סימני המספר (#) או על-ידי אפסים. לדוגמה, אם מחרוזת התבנית היא ‎"#,###"‎‏, Excel יציג את המספר 12200000 כ- 12,200,000.

פסיק שבא לאחר מציין מיקום של ספרה מגדיל את המספר ב- 1,000. לדוגמה, אם מחרוזת התבנית היא ‎"#,###.0"‎‏, Excel יציג את המספר 12200000 כ- 12,200.0.

דוגמאות של הפונקציה TEXT עם המפריד 'אלפים'

הערות: 

  • מפריד האלפים תלוי בהגדרות האזוריות שלך. בארה"ב הוא מוצג כפסיק, אך באזורים אחרים הוא יכול להיות מוצג כנקודה (.).

  • מפריד האלפים זמין עבור התבניות 'מספר', 'מטבע' ו'חשבונאות'.

להלן דוגמאות של התבניות מספר רגיל (מפריד אלפים ומספרים עשרוניים בלבד), 'מטבע' ו'חשבונאות'. התבנית 'מטבע' מאפשרת לך להוסיף את סמל המטבע שבחרת ומיישרת אותו לצד הערך שלך, ואילו בתבנית 'חשבונאות', סמל המטבע מיושר לשמאל והערך המספרי לימין. שים לב להבדל בין קודי העיצוב 'מטבע' ו'חשבונאות' להלן. בקוד 'חשבונאות' נעשה שימוש בכוכבית (*) כדי ליצור הפרדה בין הסימן לבין הערך.

דוגמאות של הפונקציה TEXT עם תבניות 'מספר', 'מטבע' ו'חשבונאות'

כדי למצוא את קוד העיצוב עבור סמל מטבע, לחץ תחילה על Ctrl+1 (או על תמונה של סמל לחצן הפקודה ב- MAC ‎+1 ב- Mac), בחר את העיצוב הרצוי ולאחר מכן בחר סמל מטבע מתוך הרשימה הנפתחת סימן:

בחירת סמל מטבע מתוך תיבת הדו-שיח 'עיצוב תאים'

לאחר מכן, לחץ על מותאם אישית מימין באזור קטגוריה והעתק את קוד העיצוב, כולל סמל המטבע.

הפונקציה TEXT - מטבע מותאם אישית עם סמל

הערה: הפונקציה TEXT אינה תומכת בעיצוב צבעים, ולכן, אם אתה מעתיק מתיבת הדו-שיח 'עיצוב תאים' קוד עיצוב של מספר הכולל צבע, כגון: ‎$#,##0.00_);[Red]($#,##0.00)‎, הפונקציה TEXT תקבל את קוד העיצוב, אך לא תציג את הצבע.

ניתן לשנות את אופן ההצגה של תאריך באמצעות שילוב של "M" עבור חודש, "D" עבור ימים ו- "Y" עבור שנים.

קודי התבניות 'חודש', 'יום' ו'שנה'

קודי עיצוב בפונקציה TEXT אינם תלויי רישיות, כך שניתן להשתמש באותה מידה ב- "M" או "m", ב- "D" או "d" או ב- "Y" או "y".

מינדה טריסי - Excel MVP

מינדה ממליצה...

אם אתה משתף קבצי Excel ודוחות עם משתמשים ממדינות שונות, ייתכן שתרצה לתת לו דוח בשפה שלהם. Excel MVP, Mynda Treacy יש פתרון נהדר המפורטים במאמר זה מוצג תאריכים Excel בשפות שונות . הוא כולל גם חוברת עבודה לדוגמה שבאפשרותך להוריד.

ניתן לשנות את אופן ההצגה של השעה באמצעות שילוב של "H" עבור שעות, "M" עבור דקות או "S" עבור שניות, ו- "AM/PM" עבור שעון של 12 שעות.

תבניות שעה עבור שעות, דקות ושניות

אם תשמיט את "AM/PM" או "A/P", השעה תוצג בהתבסס על שעון של 24 שעות.

קודי עיצוב בפונקציה TEXT אינם תלויי רישיות, כך שניתן להשתמש באותה מידה ב- "H" או "h", ב- "M" או "m", ב- "S" או "s" או ב- "AM/PM" או "am/pm".

ניתן לשנות את אופן ההצגה של ערכים עשרוניים באמצעות תבניות אחוזים (%).

קודי תבנית עבור אחוזים

ניתן לשנות את אופן ההצגה של ערכים עשרוניים באמצעות תבניות שברים (?/?).

קודי תבנית עבור שברים

סימון מדעי הוא דרך להצגת מספרים במונחים של מספר עשרוני בין 1 ל- 10, מוכפל בחזקת 10. הוא משמש לעתים קרובות כדי לקצר את אופן ההצגה של מספרים גדולים.

קודי תבנית עבור סימון מדעי

Excel מספק ארבע תבניות מיוחדות:

  • מיקוד - "00000"

  • מיקוד + 4 - "00000-0000"

  • מספר טלפון - "‎[<=9999999]###-####;(###) ###-####‎"

  • מספר תעודת זהות - "000-00-0000"

תבניות מיוחדות עבור הפונקציה TEXT

התבניות המיוחדות משתנות בהתאם לאזור; אם אין אף תבנית מיוחדת עבור האזור שלך, או אם התבניות המיוחדות שישנן אינן עונות על הצרכים שלך, תוכל ליצור תבניות משלך בתיבת הדו-שיח עיצוב תאים > מותאם אישית.

תרחיש נפוץ

הפונקציה TEXT נמצא בשימוש לעתים נדירות בפני עצמו ולאחר לעתים קרובות נעשה בו שימוש בשילוב עם משהו אחר. נניח שברצונך לשלב את הטקסט ואת ערך מספרי, כגון "דוח מודפס על: 14/03/12", או "הכנסה שבועי: $66,348.72". באפשרותך להקליד שבה לתוך Excel באופן ידני, אך זה defeats המטרה של Excel נתקל לעשות זאת עבורך. למרבה הצער, בעת שילוב טקסט ומספרים מעוצב, כגון תאריכים, שעות, מטבע, וכן הלאה, Excel אינו יודע כיצד ברצונך להציג אותם, כך הוא משמיט את תבנית המספר. זהו שבו בפונקציה TEXT שימושי ביותר, מאחר שהיא מאפשרת לך לכפות Excel כדי לעצב את הערכים באופן שהרצוי לך באמצעות קוד תבנית, כגון "MM/DD/YY" עבור תבנית התאריך.

בדוגמה הבאה, תוכל לראות מה קורה אם אתה מנסה להצטרף טקסט ומספר מבלי להשתמש בפונקציה TEXT . במקרה זה, אנו משתמשים אמפרסנד (&) כדי לשרשר מחרוזת טקסט, רווח (""), וערך עם = A2 & "" & B2.

דוגמה של צירוף טקסט ללא הפונקציה TEXT

כפי שניתן לראות, Excel הסיר את העיצוב מהתאריך בתא B2. בדוגמה הבאה, תראה כיצד הפונקציה TEXT מאפשרת לך להחיל את התבנית הרצויה.

דוגמה של צירוף טקסט עם הפונקציה TEXT

הנוסחה המעודכנת שלנו היא:

  • תא C2:‏‎=A2&" "&TEXT(B2,"mm/dd/yy")‎ - תבנית תאריך

שאלות נפוצות

לצערנו, אין באפשרותך לבצע כי עם הפונקציה TEXT , עליך להשתמש ב- Visual Basic for Applications (VBA) קוד. שיטה מכיל הקישור הבא: כיצד ניתן להמיר ערך מספרי לתוך מילים באנגלית ב- Excel

כן, באפשרותך להשתמש בפונקציות UPPER‏, LOWER ו- PROPER. למשל, ‎=UPPER("hello")‎ יחזיר "HELLO".

כן, אך יהיה עליך לבצע כמה שלבים. ראשית, בחר את התא או התאים שבו ברצונך זו מתרחשת ולהשתמש Ctrl + 1 כדי להציג עיצוב > תאים הדו-שיח, לאחר מכן יישור > פקד טקסט > סמן את האפשרות גלישת טקסט. בשלב הבא, התאם את הפונקציה TEXT שהושלמו כדי לכלול את הפונקציה ASCII char (10) שבו ברצונך מעבר שורה. ייתכן שיהיה עליך להתאים את רוחב העמודה בהתאם כיצד מיישרת התוצאה הסופית.

דוגמה לשימוש בפונקציה TEXT עם CHAR(10)‎ כדי להוסיף מעבר שורה. ‎="Today is: "&CHAR(10))&TEXT(TODAY(),"DD/MM/YY")‎

במקרה זה, השתמשנו בנוסחה: ‎="Today is: "&CHAR(10)&TEXT(TODAY(),"dd/mm/yy")‎

דבר זה נקרא סימון מדעי. Excel ממיר באופן אוטומטי מספרים ארוכים יותר מ- 12 ספרות אם התא(ים) מעוצב(ים) ככללי ומספרים ארוכים יותר מ- 15 ספרות אם התא(ים) מעוצב(ים) כמספר. אם עליך להזין מחרוזות מספריות ארוכות, אך אינך מעוניין שהן יומרו, עצב את התאים הרלוונטיים כטקסט לפני שאתה מזין או מדביק את הערכים ב- Excel.

מינדה טריסי - Excel MVP

מינדה ממליצה...

אם אתה משתף קבצי Excel ודוחות עם משתמשים ממדינות שונות, ייתכן שתרצה לתת לו דוח בשפה שלהם. Excel MVP, Mynda Treacy יש פתרון נהדר המפורטים במאמר זה מוצג תאריכים Excel בשפות שונות . הוא כולל גם חוברת עבודה לדוגמה שבאפשרותך להוריד.

למידע נוסף

יצירה או מחיקה של תבנית מספר מותאמת אישית

המרת מספרים המאוחסנים כטקסט למספרים

פונקציות של Excel (לפי קטגוריה)

שפר את הכישורים שלך ב- Office
סייר בהדרכה
קבל תכונות חדשות לפני כולם
הצטרף למשתתפי Office Insider

האם מידע זה היה שימושי?

תודה על המשוב!

תודה על המשוב! נראה שכדאי לקשר אותך לאחד מנציגי התמיכה של Office.

×