הפונקציה SUM

הפונקציה SUM, אחת מפונקציות המתמטיקה והטריגונומטריה, מחברת ערכים. באפשרותך לחבר ערכים בודדים, הפניות לתאים או טווחי תאים, או שילוב של כל השלושה.

לדוגמה:

  • ‎=SUM(A2:A10)‎

  • ‎=SUM(A2:A10, C2:C10)‎

הדפדפן שלך אינו תומך בווידאו. התקן את Microsoft Silverlight‏, Adobe Flash Player או Internet Explorer 9.

סרטון וידאו זה מהווה חלק מקורס הדרכה בשם חיבור מספרים ב- Excel 2013‏.

SUM(number1,[number2],...)

שם ארגומנט

תיאור

number1    (חובה)

המספר הראשון שברצונך לחבר. המספר יכול להיות כמו 4, הפניה לתא כמו B6 או טווח של תאים כמו B2:B8.

number2-255    (אופציונלי)

זהו המספר השני שברצונך לחבר. באפשרותך לציין עד 255 מספרים באופן זה.

אם ברצונך לקבל במהירות את הסכום של טווח תאים, כל שעליך לעשות הוא לבחור את הטווח ולהביט בחלק השמאלי התחתון של חלון Excel.

צילום מסך של בחירת טווח של תאים ולאחר מכן עיון בשורת המצב
שורת המצב


זוהי שורת המצב, המציגה מידע בנוגע לפריטים שבחרת, בין אם מדובר בתא בודד או בתאים מרובים. אם תלחץ באמצעות לחצן העכבר הימני על שורת המצב, תוקפץ תיבת דו-שיח של תכונות המציגה את כל האפשרויות שתוכל לבחור. שים לב כי היא תציג גם ערכים עבור הטווח שבחרת, אם מאפיינים אלה מסומנים. קבל מידע נוסף על שורת המצב.

הדרך הקלה ביותר להוסיף נוסחת SUM לגליון העבודה היא להשתמש באשף סכום אוטומטי. בחר תא ריק שנמצא מעל או מתחת לטווח שברצונך לסכם ולאחר מכן, בכרטיסיות 'בית' או 'נוסחה' ברצועת הכלים, הקש על סכום אוטומטי > סכום. אשף סכום אוטומטי יזהה באופן אוטומטי את הטווח שיש לסכם ויבנה את הנוסחה עבורך. ניתן להשתמש באפשרות זו גם לסיכום אופקי, אם תבחר תא משמאל או מימין לטווח שיש לסכם. שים לב שאפשרות זו אינה פועלת בטווחים שאינם רציפים, אבל נדון בכך בסעיף הבא.

ניתן להשתמש באשף סכום אוטומטי לבניית נוסחת SUM באופן אוטומטי.  בחר טווח מעל/מתחת או משמאל/מימין לטווח שיש לסכם ולאחר מכן עבור לכרטיסיה ’נוסחה’ ברצועת הכלים ובחר 'סכום אוטומטי' ו- SUM.
שימוש באשף סכום אוטומטי לסיכום מהיר של טווחים רציפים


תיבת הדו-שיח 'סכום אוטומטי' גם מאפשרת לך לבחור פונקציות נפוצות אחרות, כגון:

סכום אוטומטי של טווח אנכי

תא B6 מציג את נוסחת Sum בשם סכום אוטומטי: ‎=SUM(B2:B5)‎

אשף סכום אוטומטי זיהה באופן אוטומטי את התאים B2:B5 כטווח שיש לסכם. כל שעליך לעשות הוא להקיש Enter כדי לאשר זאת. אם אתה צריך להוסיף עוד תאים/להסיר תאים, באפשרותך להחזיק את מקש Shift > מקש חץ על התאים הרצויים עד שהטווח הנבחר יתאים לטווח הרצוי. עם סיום, הקש Enter.

מדריך פונקציות Intellisense: התגית הצפה SUM(number1,[number2], …)‎ מתחת לפונקציה היא מדריך Intellisense שלה. אם תלחץ על SUM או על שם הפונקציה, הם יהפכו להיפר-קישור כחול, אשר יעביר אותך אל נושא העזרה עבור פונקציה זו. אם תלחץ על רכיבים ספציפיים של הפונקציה, החלקים המקבילים שלהם בנוסחה יודגשו. במקרה זה, רק הטווח B2:B5 יסומן מאחר שקיימת בנוסחה זו הפניה אחת בלבד למספרים. תגית Intellisense תופיע עבור כל פונקציה.

סכום אוטומטי של טווח אופקי

תא D2 מציג את נוסחת Sum בשם סכום אוטומטי: ‎=SUM(B2:C2)‎

שימוש ב- SUM עם טווחים שאינם רציפים.  הנוסחה בתא C8 היא ‎=SUM(C2:C3,C5:C6)‎. ניתן גם להשתמש בטווחים בעלי שם, כך שהנוסחה תהיה ‎=SUM(Week1,Week2)‎.

אשף סכום אוטומטי עובד בדרך כלל רק עבור טווחים רציפים, ולכן אם יש לך שורות או עמודות ריקות בטווח שיש לסכם, Excel יעצור בתא הריק הראשון. במקרה זה, יהיה עליך לסכם לפי טווחים נבחרים, כלומר להוסיף את הטווחים הנפרדים בזה אחר זה. בדוגמה זו, אם היו לך נתונים בתא B4‏, Excel היה יוצר את הנוסחה ‎=SUM(C2:C6)‎ מאחר שהוא היה מזהה טווח רציף.

ניתן לבחור במהירות טווחים מרובים שאינם רציפים באמצעות הקשת Ctrl + לחיצה על לחצן העכבר השמאלי. תחילה, הזן ‎=SUM(‎, בחר את הטווחים השונים ו- Excel יוסיף באופן אוטומטי את מפריד הפסיקים בין הטווחים עבורך. כשתסיים, הקש Enter.

עצה: באפשרותך להשתמש בקיצור המקשים ALT+=‎ כדי להוסיף לתא את הפונקציה SUM במהירות. לאחר מכן, כל שעליך לעשות הוא לבחור את הטווחים הרצויים.

הערה: תוכל להבחין כיצד Excel הדגיש את הטווחים השונים בפונקציה לפי צבע, וכיצד הם תואמים בתוך הנוסחה עצמה, כך שהטווח C2:C3 הוא בצבע אחד, והטווח C5:C6 הוא בצבע אחר. Excel עושה זאת עבור כל הפונקציות, אלא אם הטווח שאליו מתבצעת ההפניה נמצא בגליון עבודה אחר או בחוברת עבודה אחרת. לצורך נגישות משופרת עם טכנולוגיה מסייעת, באפשרותך להשתמש בטווחים בעלי שם, כגון "Week1"‏, "Week2" וכדומה, ולאחר מכן להפנות אליהם בנוסחה שלך:

‎=SUM(Week1,Week2)‎

באפשרותך לבצע בקלות פעולות מתמטיות ב- Excel באופן עצמאי וכן בשילוב עם פונקציות של Excel, כגון SUM. הטבלה הבאה מפרטת את האופרטורים שבהם ניתן להשתמש, יחד עם כמה פונקציות קשורות. באפשרותך להזין את האופרטורים דרך שורת המספרים בלוח המקשים או דרך המקלדת הנומרית בת 10 המקשים, אם היא קיימת. לדוגמה, קיצור המקשים Shift+8 יזין את הכוכבית (*) עבור כפל.

אופרטור

פעולה

דוגמאות

+

חיבור

‎=1+1

‎=A1+B1

‎=SUM(A1:A10)+10

‎=SUM(A1:A10)+B1

-

חיסור

‎=1-1

‎=A1-B1

‎=SUM(A1:A10)-10

‎=SUM(A1:A10)-B1

*

כפל

‎=1*1

‎=A1*B1

‎=SUM(A1:A10)*10

‎=SUM(A1:A10)*B1

‎=PRODUCT(1,1)‎ - הפונקציה PRODUCT

/

חילוק

‎=1/1

‎=A1/B1

‎=SUM(A1:A10)/10

‎=SUM(A1:A10)/B1

‎=QUOTIENT(1,1)‎ - הפונקציה QUOTIENT

^

העלאה בחזקה

‎=1^1

‎=A1^B1

‎=SUM(A1:A10)^10

‎=SUM(A1:A10)^B1

‎=POWER(1,1)‎ - הפונקציה POWER

לקבלת מידע נוסף, ראה שימוש ב- Excel כמחשבון שלך.

דוגמאות אחרות

  1. נניח שברצונך להחיל אחוז הנחה כלשהו על טווח של תאים שסיכמת.

    שימוש באופרטורים עם SUM.  הנוסחה בתא B16 היא ‎=SUM(A2:A14)*-25%‎.  ניתן היה לבנות את הנוסחה כהלכה אם ‎-25% היה במקום זאת הפניה לתא, כגון ‎=SUM(A2:A14)*E2
    • ‎=SUM(A2:A14)*-25%‎

    יחזיר 25% מהטווח המסוכם, אך הדבר מבצע קידוד קשיח של ה- 25% בנוסחה, וייתכן שיהיה לך קשה למצוא נתון זה אם תרצה לשנותו במועד מאוחר יותר. עדיף בהרבה להציב את ה- 25% בתא ולהפנות לתא זה, מאחר שכך הנתון גלוי לעין וקל לשנותו, כך:

    • ‎=SUM(A2:A14)*E2‎

    כדי לחלק במקום להכפיל, עליך להחליף פשוט את "*" ב- ‎"/"‏: ‎=SUM(A2:A14)/E2

  2. הוספה ל- SUM או חיסור מ- SUM

    i. ניתן בקלות להוסיף ל- SUM או לחסר מ- SUM באמצעות + או -, כך:

    • ‎=SUM(A1:A10)+E2

    • ‎=SUM(A1:A10)-E2

סעיף זה דן בכמה משיטות העבודה המומלצות עבור הפונקציה SUM. רבות מהשיטות יכולות לשמש גם לעבודה עם פונקציות אחרות.

השיטות ‎=1+2 או ‎=A+B – למרות שניתן להזין ‎=1+2+3 או ‎=A1+B1+C2 ולקבל תוצאות מדויקות לגמרי, שיטות אלה מועדות לשגיאות ממספר סיבות:

  1. שגיאות הקלדה – דמיין את עצמך מנסה להזין מספר רב יותר של ערכים ו/או ערכים גדולים בהרבה, כגון:

    • ‎=14598.93+65437.90+78496.23

    לאחר מכן, נסה לאמת שהערכים נכונים. קל בהרבה להציב ערכים אלה בתאים בודדים ולהשתמש בנוסחת SUM. בנוסף, כאשר הערכים מוצבים בתאים, באפשרותך לעצב אותם, דבר ההופך אותם לקריאים בהרבה מאשר כשהם בנוסחה.

    שימוש בפונקציה SUM במקום לבצע קידוד קשיח של ערכים בנוסחאות.  הנוסחה בתא D5 היא ‎=SUM(D2:D4)‎
  2. שגיאות ‎#VALUE!‎ עקב הפניה לטקסט במקום למספרים

    אם אתה משתמש בנוסחה, כגון:

    • ‎=A1+B1+C1 או ‎=A1+A2+A3

    דוגמה של בניית נוסחה בצורה גרועה.  הנוסחה בתא D2 היא ‎=A2+B2+C2

    הנוסחה עלולה להתנתק אם קיימים בתאים שאליהם מתבצעת ההפניה ערכים שאינם מספריים (טקסט), אשר יחזירו שגיאת ‎#VALUE!‎. פונקציית SUM תתעלם מערכי טקסט ותספק לך את הסכום של הערכים המספריים בלבד.

    בניית נוסחה תקינה.  במקום ‎=A2+B2+C2, הנוסחה של תא D2 היא ‎=SUM(A2:C2)‎
  3. שגיאת ‎#REF!‎ עקב מחיקת שורות או עמודות

    שגיאת ‎#REF!‎ נגרמת כתוצאה ממחיקת עמודה.  הנוסחה השתנתה ל- ‎=A2+#REF!+B2

    אם אתה מוחק שורה או עמודה, הנוסחה לא תתעדכן על-ידי אי-כלילת השורה שנמחקה, ותחזיר שגיאת ‎#REF!‎. לעומת זאת, פונקציית SUM תתעדכן באופן אוטומטי.

    הפונקציה SUM תתאים את עצמה באופן אוטומטי עבור עמודות ושורות שיתווספו או יימחקו
  4. נוסחאות לא יעדכנו הפניות בעת הוספת שורות או עמודות

    נוסחאות ‎=A+B+C לא יתעדכנו אם תוסיף שורות

    אם תוסיף שורה או עמודה, הנוסחה לא תתעדכן כדי לשקף את השורה שנוספה, בעוד שפונקציית SUM תתעדכן באופן אוטומטי (כל עוד לא יצאת מהטווח שאליו הנוסחה מפנה). הדבר חשוב במיוחד אם אתה מצפה שהנוסחה תתעדכן, והדבר לא קורה, מאחר שאתה תישאר עם תוצאות חלקיות וייתכן שלא תשים לב לכך.

    הדוגמה מראה נוסחת SUM המשתרעת באופן אוטומטי מ- ‎=SUM(A2:C2)‎ ל- ‎=SUM(A2:D2)‎ כאשר נוספה עמודה
  5. SUM עם הפניות לתאים ספציפיים לעומת טווחים

    שימוש בנוסחה כגון:

    • ‎=SUM(A1,A2,A3,B1,B2,B3)‎

    מועד לשגיאות באותה מידה בעת הוספה או מחיקה של שורות בטווח שאליו מתבצעת הפניה, מאותן סיבות. עדיף להשתמש בטווחים בודדים, כגון:

    • ‎=SUM(A1:A3,B1:B3)‎

    אשר יתעדכנו בעת הוספה או מחיקה של שורות.

  1. ניתן להשתמש ב- SUM עם פונקציות אחרות. להלן דוגמה לחישוב ממוצע חודשי:

    שימוש ב- SUM עם פונקציות אחרות.  הנוסחה בתא M2 היא ‎=SUM(A2:L2)/COUNTA(A2:L2)‎.  הערה: העמודות May-November מוסתרות לצורך בהירות.
    • ‎=SUM(A2:L2)/COUNTA(A2:L2)‎

  2. הלוקח את הסכום של A2:L2 לחלק לספירת התאים שאינם ריקים ב- A2:L2 (מאי עד דצמבר ריקים).

  1. לעתים עליך לסכם תא מסוים בגליונות עבודה מרובים. אולי זה ייראה לך מפתה ללחוץ על כל גיליון ועל התא הרצוי, ופשוט להשתמש ב- "+" כדי לחבר את ערכי התאים, אך שיטה זו מתישה ומועדת לשגיאות.

    • ‎=Sheet1!A1+Sheet2!A1+Sheet3!A1

    תוכל לבצע זאת ביתר קלות באמצעות סכום תלת-ממדי:

    נוסחת סכום תלת-ממדי בתא D2 היא ‎=SUM(Sheet1:Sheet3!A2)‎
    • ‎=SUM(Sheet1:Sheet3!A1)‎

    אשר יסכם את תא A1 בכל הגליונות מגיליון 1 עד גיליון 3.

    פעולה זו שימושית במיוחד במצבים שבהם יש לך גיליון יחיד עבור כל חודש (ינואר-דצמבר) ועליך לסכם אותם בגיליון סיכום.

    סכום תלת-ממדי על-פני גליונות בעלי שם.  הנוסחה בתא D2 היא ‎=SUM(January:December!A2)‎
    • ‎=SUM(January:December!A2)‎

    אשר יסכם את תא A2 בכל אחד מהגליונות מינואר עד דצמבר.

    הערות: אם השמות של גליונות העבודה שלך כוללים רווחים, למשל "January Sales", עליך להשתמש בגרש בעת הפניה אל שם הגיליון בנוסחה: שים לב לגרש לפני שם גליון העבודה הראשון, ולגרש אחרי שם גליון העבודה האחרון.

    • ‎=SUM('January Sales:December Sales'!A2)‎

    השיטה התלת-ממדית תפעל גם עם פונקציות אחרות, כגון AVERAGE‏, MIN‏, MAX וכן הלאה:

    • ‎=AVERAGE(Sheet1:Sheet3!A1)‎

    • ‎=MIN(Sheet1:Sheet3!A1)‎

    • ‎=MAX(Sheet1:Sheet3!A1)‎

בעיה

מה השתבש

הפונקציה SUM מציגה #####, לא את התוצאה.

בדוק את רוחב העמודות. ##### פירושו בדרך כלל שהעמודה צרה מכדי להציג את תוצאת הנוסחה.

הפונקציה SUM מציגה את הנוסחה עצמה כטקסט, במקום את התוצאה.

בדוק שהתא אינו מעוצב כטקסט. בחר את התא או הטווח הרלוונטי והשתמש ב- Ctrl+1 כדי להציג את תיבת הדו-שיח עיצוב תאים. לאחר מכן לחץ על הכרטיסיה מספר ובחר את העיצוב הרצוי. אם התא עוצב כטקסט ואינו משתנה לאחר שינוי העיצוב, ייתכן שעליך להשתמש ב- F2 > Enter כדי לכפות על העיצוב להשתנות.

הפונקציה SUM אינה מתעדכנת.

ודא שחישוב מוגדר לאוטומטי. בכרטיסיה נוסחאות, עבור אל אפשרויות חישוב. באפשרותך להשתמש גם ב- F9 כדי לכפות את חישוב גליון העבודה.

ודא שהחישוב מוגדר כ'אוטומטי'.  מהכרטיסיה 'נוסחה' עבור אל 'אפשרויות חישוב'.

ערכים מסוימים אינם מסוכמים.

ניתן לסכם רק את הערכים המספריים בהפניה או בטווח של הפונקציה. הפונקציה מתעלמת מתאים ריקים, מערכים לוגיים כגון TRUE ומטקסט.

השגיאה ‎#NAME?‎ מופיעה במקום התוצאה הצפויה.

בדרך כלל פירוש הדבר שהנוסחה מאויתת באופן שגוי, למשל ‎=sume(A1:A10)‎ במקום ‎=SUM(A1:A10)‎.

הפונקציה SUM מציגה מספר שלם, אך היא אמורה להציג מספרים עשרוניים

בדוק את עיצוב התא כדי לוודא שאתה מציג מספרים עשרוניים. בחר את התא או הטווח הרלוונטי והשתמש בקיצור המקשים Ctrl+1 כדי להציג את תיבת הדו-שיח עיצוב תאים. לאחר מכן, לחץ על הכרטיסיה מספר ובחר את העיצוב הרצוי, והקפד לבחור את מספר המקומות העשרוניים הרצוי.

  1. אני רוצה רק לחבר/לחסר/להכפיל/לחלק מספרים צפה בסידרת סרטונים זו בנושא פעולות מתמטיות בסיסיות ב- Excel או שימוש ב- Excel כמחשבון שלך.

  2. כיצד להציג יותר/פחות מקומות עשרוניים? באפשרותך לשנות את עיצוב המספר. בחר את התא או הטווח הרלוונטי והשתמש בקיצור המקשים Ctrl+1 כדי להציג את תיבת הדו-שיח עיצוב תאים. לאחר מכן לחץ על הכרטיסיה מספר ובחר את העיצוב הרצוי, והקפד לבחור את מספר המקומות העשרוניים הרצוי.

  3. כיצד ניתן להוסיף או להחסיר שעות? באפשרותך לחבר ולחסר שעות בכמה דרכים שונות. לדוגמה, כדי לקבל את ההפרש בין 8:00-12:00 למטרות שכר, השתמש בנוסחה הבאה: ‎=("12:00"-"8:00")*24‎, עם שעת הסיום פחות זמן ההתחלה. שים לב ש- Excel מחשב שעות כשבר של יום, כך שיש להכפיל ב- 24 כדי לקבל את מספר השעות הכולל. בדוגמה הראשונה אנחנו משתמשים בנוסחה ‎=((B2-A2)+(D2-C2))*24 כדי לקבל את סכום השעות מההתחלה לסיום, פחות הפסקת צהריים (8.50 שעות בסך הכל).

    אם אתה מבצע חיבור פשוט של שעות ודקות וברצונך להציג את התוצאה באופן זה, תוכל לחשב את הסיכום ללא צורך בהכפלה ב- 24. לכן בדוגמה השניה אנחנו משתמשים בנוסחה ‎=SUM(A6:C6)‎, מכיוון שאנו זקוקים רק למספר הכולל של השעות והדקות עבור הפעילויות שהוקצו (5:36 או 5 שעות, 36 דקות).

    חישוב שעות

    לקבלת מידע נוסף, ראה: חיבור או חיסור של שעות.

  4. כיצד ניתן לחשב את ההפרש בין תאריכים? בדומה לשעות, באפשרותך לחבר ולחסר תאריכים. הנה דוגמה נפוצה מאוד לספירת הימים בין שני תאריכים. היא פשוטה כמו ‎=B2-A2. המפתח לעבודה עם תאריכים ושעות הוא להתחיל מהתאריך/השעה של הסיום ולהחסיר את התאריך/השעה של ההתחלה.

    חישוב הפרשים בין תאריכים

    לקבלת דרכים נוספות לעבודה עם תאריכים, ראה: חישוב מספר הימים בין שני תאריכים.

  5. כיצד ניתן לסכם תאים גלויים בלבד? לעתים, בעת הסתרת שורות באופן ידני או שימוש בסינון אוטומטי כדי להציג נתונים מסוימים בלבד, ברצונך לסכם רק את התאים הגלויים. באפשרותך להשתמש בפונקציה SUBTOTAL. אם אתה משתמש בשורת סכום בטבלת Excel, כל פונקציה שתבחר מהרשימה הנפתחת 'סך הכל' תוזן באופן אוטומטי כסכום ביניים. קבל מידע נוסף על סיכום נתונים בטבלת Excel.

זקוק לעזרה נוספת?

ניתן לשאול תמיד מומחה ב- Excel Tech Community, לקבל תמיכה בקהילת Answers או להציע תכונה חדשה או שיפור ב- Excel User Voice.

למידע נוסף

צפה בסרטון וידאו על אופן השימוש בפונקציה SUM

הפונקציה SUMIF מסכמת רק את הערכים העומדים בקריטריון יחיד

הפונקציה SUMIFS מסכמת רק את הערכים העומדים בקריטריונים מרובים

הפונקציה COUNTIF סופרת רק את הערכים העומדים בקריטריון יחיד

הפונקציה COUNTIFS סופרת רק את הערכים העומדים בקריטריונים מרובים

מבט כולל על נוסחאות ב- Excel

כיצד להימנע מנוסחאות שגויות

חיפוש ותיקון שגיאות בנוסחאות

קיצורי מקשים ב- Excel עבור Windows

קיצורי מקלדת ב- Excel עבור Mac

פונקציות מתמטיקה וטריגונומטריה

פונקציות של Excel (בסדר אלפביתי)

פונקציות של Excel (לפי קטגוריה)

הרחב את הכישורים שלך
סייר בהדרכה
קבל תכונות חדשות לפני כולם
הצטרף למשתתפי Office Insider

האם מידע זה היה שימושי?

תודה על המשוב!

תודה על המשוב! נראה שכדאי לקשר אותך לאחד מנציגי התמיכה של Office.

×