המאפיין PrtDevMode

חל על

אובייקט Form

אובייקט Report

באפשרותך להשתמש במאפיין PrtDevMode כדי להגדיר או להחזיר מידע על מצב התקן ההדפסה שצוין עבור טופס או דוח בתיבת הדו-שיח הדפסה. קריאה/כתיבה Variant.

expression.PrtDevMode

ביטוי נדרש. ביטוי המחזיר אחד מהאובייקטים ברשימה 'חל על'.

הערות

מומלץ מאוד לעיין בערכת פיתוח התוכנה של Win32 לקבלת תיעוד מלא על המאפיינים PrtDevMode‏, PrtDevNames ו- PrtMip.

הגדרת המאפיין PrtDevMode היא מבנה של 94 בתים שמשקף את המבנה של DEVMODE שהוגדרו בערכת פיתוח התוכנה של Win32. לקבלת מידע מלא אודות PrtDevMode חברים מאפיין, השתמש ערכת פיתוח תוכנה של Win32.

המאפיין PrtDevMode משתמש בחברים הבאים.

חבר

תיאור

DeviceName

מחרוזת עם מספר מרבי של 32 בתים מציין שם ההתקן שנתמך על-ידי מנהל ההתקן — לדוגמה, "HP LaserJet IIISi" אם Hewlett-Packard LaserJet IIISi היא המדפסת שצוינה. לכל מנהל מדפסת יש מחרוזת ייחודית.

SpecVersion

מספר שלם שמציין את מספר הגירסה של מבנה ה-DEVMODE הערכת פיתוח התוכנה של Win32.

DriverVersion

מספר שלם שמציין את מספר הגירסה של מנהל המדפסת שהוקצה על-ידי המפתח של מנהל המדפסת.

Size

מספר שלם שמציין את הגודל, בבתים, של מבנה DEVMODE. (ערך זה אינו כולל את החבר האופציונלי dmDriverData עבור נתוני ספציפיים להתקן, שיכול לעקוב אחר מבנה זה.) אם יישום מטפל רק בחלק של הנתונים שאינו תלוי במנהל ההתקן, באפשרותך להשתמש בחבר זה כדי למצוא את האורך של מבנה זה בלי להתייחס לגירסאות שונות.

DriverExtra

מספר שלם שמציין את הגודל, בבתים, של החבר האופציונלי dmDriverData עבור נתוני ספציפיים להתקן, שיכול לעקוב אחר מבנה זה. אם היישום אינו משתמש במידע ספציפי להתקן, הגדר חבר זה כ- 0.

Fields

ערך ארוך שמציין אילו מהחברים הנותרים במבנה DEVMODE אותחלו.

Orientation

מספר שלם שמציין את כיוון הנייר. ערך זה יכול להיות 1 (לאורך) או 2 (לרוחב).

PaperSize

מספר שלם שמציין את גודל הנייר שעליו יש להדפיס. אם תגדיר חבר זה כ- 0 או 256, האורך והרוחב של הנייר יצוינו על-ידי החברים PaperLength ו- PaperWidth, בהתאמה. אחרת, תוכל להגדיר חבר PaperSize לערך מוגדר מראש.

PaperLength

מספר שלם שמציין את אורך הנייר ביחידות של 1/10 המילימטר. חבר זה עוקף את אורך הנייר שצוין על-ידי החבר PaperSize עבור גדלי נייר מותאמים אישית או עבור התקנים כגון מדפסות סיכות שיכולות להדפיס על מגוון של גדלי נייר.

PaperWidth

מספר שלם שמציין את רוחב הנייר ביחידות של 1/10 המילימטר. חבר זה עוקף את רוחב הנייר המצוין על-ידי החבר PaperSize.

Scale

מספר שלם שמציין את המקדם שלפיו ישתנה קנה המידה של הפלט המודפס. גודל העמוד הנראה לעין משתנה מגודל הדף הפיזי במקדם של Scale/100. לדוגמה, פיסת נייר שגודלה 8.5 על 11 אינצ'ים (גודל letter) עם ערך Scale של 50 תכיל כמות נתונים שנכנסת בדף בגודל 17 על 22 אינץ', מכיוון שהטקסט והגרפיקה של הפלט יוצגו בחצי הגובה והרוחב המקוריים שלהם.

Copies

מספר שלם שמציין את מספר העותקים שיודפסו אם התקן ההדפסה תומך בעותקים מרובי עמודים.

DefaultSource

מספר שלם המציין את סל ברירת המחדל שממנו יוזן הנייר.

PrintQuality

מספר שלם שמציין את הרזולוציה של המדפסת. הערכים הם - 4 (גבוהה), 3 (בינונית), 2 (נמוכה) ו-1 (טיוטה).

Color

מספר שלם. עבור מדפסת צבע, מציין אם הפלט יודפס בצבע. הערכים הם 1 (צבע) ו- 2 (שחור-לבן).

Duplex

מספר שלם. עבור מדפסת עם יכולת להדפסה דו-צדדית, מציין אם הפלט יודפס משני צדי הנייר. הערכים הם 1 (צד אחד), 2 (אופקי) ו- 3 (אנכי).

YResolution

מספר שלם שמציין את הרזולוציה של ציר y של המדפסת בנקודות לאינץ ' (dpi). אם המדפסת מאתחלת חבר זה, החבר PrintQuality מציין את הרזולוציה על ציר x של המדפסת ב- dpi.

TTOption

מספר שלם שמציין כיצד גופני TrueType יודפסו.

Collate

מספר שלם שמציין אם יש לבצע איסוף בעת הדפסת עותקים מרובים. שימוש בעותקים ללא איסוף מספק פלט מהיר יותר ויעיל יותר, מאחר שהנתונים נשלחים למדפסת פעם אחת בלבד.

FormName

מחרוזת עם מספר מרבי של 16 תווים, שמציינת את גודל הנייר שזו נעשה שימוש; לדוגמה, "Letter" או "Legal".

Pad

ערך אורך ערך שנעשה בו שימוש כדי להשלים רווחים, תווים או ערכים עבור גירסאות עתידיות.

Bits

ערך אורך שמציין בסיביות לפיקסל את רזולוציית הצבע של התקן התצוגה.

PW

ערך אורך ערך המציין את הרוחב, בפיקסלים, של משטח ההתקן הגלוי (מסך או מדפסת).

PH

ערך אורך ערך המציין את הגובה, בפיקסלים, של משטח ההתקן הגלוי (מסך או מדפסת).

DFI

ערך אורך שמציין את מצב התצוגה של ההתקן.

DFR

ערך אורך שהמציין את התדר, בהרץ (מחזורים לשנייה), של התקן התצוגה במצב מסוים.


הערה: באפשרותך להגדיר את המאפיין PrtDevMode על-ידי שימוש בקוד Visual Basic for Applications‏ (VBA).

הגדרת מאפיין זה זמינה לקריאה/כתיבה בתצוגת עיצוב או בתצוגת פריסה, ולקריאה בלבד בתצוגות אחרות.

מנהלי המדפסות יכולים להוסיף נתונים ייחודיים להתקן מיד לאחר 94 הבתים של מבנה ה- DEVMODE. מסיבה זו, חשוב שנתוני DEVMODE המפורטים לעיל לא יחרגו מ-94 בתים.

רק מנהלי מדפסות שמייצאים את הפנוקציה ExtDeviceMode משתמשים במבנה ה-DEVMODE.

יישום יכול לאחזר את גדלי נייר ושמות הנייר הנתמכים על-ידי המדפסת על-ידי שימוש בערכים DC_PAPERS‏, DC_PAPERSIZE ו- DC_PAPERNAMES כדי לקרוא לפונקציה DeviceCapabilities.

לפני הגדרת הערך של החבר TTOption, היישומים צריכים לברר כיצד מנהל המדפסת יכול להשתמש בגופני TrueType באמצעות הערך DC_TRUETYPE כדי לקרוא לפונקציה DeviceCapabilities.

דוגמה

הדוגמה הבאה משתמשת במאפיין PrtDevMode כדי לבדוק את גודל הדף המוגדר על-ידי המשתמש עבור דוח:

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

הדוגמה הבאה מראה כיצד לשנות את הכיוון של הדוח. דוגמה זו תשנה את הכיוון מכיוון 'לאורך' לכיוון 'לרוחב' או מכיוון 'לרוחב' לכיוון 'לאורך', בהתאם לכיוון הנוכחי של הדוח.

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub
הרחב את הכישורים שלך
סייר בהדרכה
קבל תכונות חדשות לפני כולם
הצטרף למשתתפי Office Insider

האם מידע זה היה שימושי?

תודה על המשוב!

תודה על המשוב! נראה שכדאי לקשר אותך לאחד מנציגי התמיכה של Office.

×