הגדרת תוויות נתונים מותאמות אישית בתרשים

ההליך הבא של VBA (Visual Basic for Applications) יאפשר לך להשתמש בערכי תאים כתוויות נתונים בתרשימים שלך Excel עבור Mac. כדי להשתמש בהליך, בצע את הפעולות הבאות:

1. ב- Excel, לחץ על כלים > מאקרו> הקלט מאקרו חדש.

2. בתיבה הנפתחת אחסן מאקרו ב: , בחר חוברת מאקרו אישית.

   הערה: על-ידי אחסון הליך VBA בחוברת המאקרו האישית, תוכל להשתמש בה בכל מופע של Excel. משמעות הדבר היא שהיא אינה מוגבלת לשימוש בחוברת עבודה בודדת.

3. לחץ על אישור.

4. עבור אל כלים > מאקרו> עצור הקלטה.

5. עבור אל כלים > מאקרו> Visual Basic.

6. עורך Visual Basic (VBE) ייפתח מעל Excel. בחלונית הניווט מימין, הרחב את VBAProject (PERSONAL). תיקיית XLSB) כדי להציג את Module1.

7. לחץ פעמיים על Module1 כדי להציג את חלונית הקוד, שתיפתח בצד השמאלי של חלון VBE.

8. קוד ה- VBA שנוצר כאשר הקלטת מאקרו חדש אינו הכרחי, לכן בחר את הכל ולאחר מכן הקש Delete. 

9. לאחר מכן, בחר את קוד ה- VBA בתיבת הטקסט שלהלן, הקש CMD+C כדי להעתיק אותו ולאחר מכן הדבק אותו בחזרה בחלונית קוד עםCMD+V. כעת באפשרותך לצאת מעורך Visual Basic ונסה לחזור ל- Excel.

10. בדוק את המאקרו על-ידי יצירת תרשים עם תוויות נתונים. לאחר מכן, בחר תווית נתונים כלשהי בתרשים והפעל את המאקרו על-ידי לחיצה על כלים > מאקרו > מאקרו. בחר SetCustomDataLabels ולאחר מכן הקש Run. תתבקש באופן אוטומטי לבחור את טווח תוויות הנתונים, לכן עשה זאת ולאחר מכן לחץ על אישור.  

    הערה: לא ניתן לבטל הליכים של VBA, לכן הקפד לנסות זאת בעותק של חוברת עבודה. אם אתה מפעיל את הקוד ואינך מעוניין לשמור את התוצאות, יהיה עליך לסגור את חוברת העבודה מבלי לשמור אותה.

11. כאשר אתה עוזב את Excel, הקפד לבחור לשמור שינויים ב- PERSONAL. XLSB כך שהמאקרו יהיה זמין בעתיד.

12. בכל פעם שברצונך להוסיף או להסיר תוויות נתונים מתרשים, בחר את תוויות הנתונים והפעל את המאקרו.

13. באפשרותך להשתמש ב - Excel > Preferences > Ribbon & Toolbar כדי להוסיף לחצן להפעלת המאקרו מרצועת הכלים או מסרגל הכלים.

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub