Utilisation de SI avec les fonctions ET, OU et NON

La fonction SI permet d’effectuer une comparaison logique entre une valeur et une hypothèse en testant une condition et en renvoyant un résultat Vrai ou Faux.

  • =SI(quelque chose est vrai, effectuer telle action, sinon effectuer telle autre action)

Mais que faire si vous devez tester plusieurs conditions et que toutes les conditions doivent retourner un résultat Vrai ou Faux (et), ou qu’une seule condition doit retourner un résultat Vrais ou Faux (OU), ou si vous voulez vérifier si une condition ne satisfait PAS votre critère ? Les 3 fonctions peuvent être utilisées isolément, mais il est beaucoup plus fréquent de les voir associées à des fonctions SI.

Utilisez la fonction SI avec les fonctions ET, OU et NON pour effectuer plusieurs évaluations si les conditions retournent Vrai ou Faux.

Syntaxe

  • SI(ET()) - SI(ET(valeur_logique1, [valeur_logique2],...);valeur_si_vrai;[valeur_si_faux]))

  • SI(OU()) - SI(OU(valeur_logique1, [valeur_logique2],...);valeur_si_vrai;[valeur_si_faux]))

  • SI(NON()) - SI(NON(valeur_logique1);valeur_si_vrai;[valeur_si_faux]))

Argument

Description

test_logique (obligatoire)

Condition que vous souhaitez tester.

valeur_si_vrai (obligatoire)

Valeur que vous voulez retourner si le résultat de test_logique est VRAI.

valeur_si_faux (facultatif)

Valeur que vous voulez retourner si le résultat de test_logique est FAUX.

Voici une vue d’ensemble de la manière de structurer individuellement les fonctions ET, OU et NON. Lorsque vous les combinez avec une instruction SI, elles ressemblent à ceci :

  • ET – =SI(ET (Une chose est vraie, Une autre est fausse), Valeur si vrai, Valeur si faux)

  • OU – =SI(OU (Une chose est vraie, Une autre est fausse), Valeur si vrai, Valeur si faux)

  • NON – =SI(NON(Une chose est vraie), Valeur si vrai, Valeur si faux)

Exemples

Voici des exemples d’instructions SI(ET()), SI(OU()) et SI(NON()) imbriquées courantes. Les fonctions ET et OU peuvent prendre en charge jusqu’à 255 conditions individuelles, mais il n’est pas conseillé d’en utiliser un grand nombre, car les formules complexes imbriquées peuvent devenir très difficiles à générer, tester et mettre à jour. La fonction NON ne prend qu’une seule condition.

Exemples d’utilisation de la fonction SI avec les fonctions ET, OU et NON pour évaluer des valeurs numériques et du texte

Voici les formules explicitées en fonction de leur logique :

Formule

Description

=SI(ET(A2>0;B2<100);VRAI;FAUX)

IF A2 (25) est supérieur à 0, ET B2 (75) est inférieur à 100, retourner VRAI, sinon retourner FAUX. Dans ce cas, les deux conditions étant vraies, la valeur VRAI est retournée.

=SI(ET(A3="Rouge";B3="Vert");VRAI;FAUX)

Si A3 (« Bleu ») = « Rouge », ET B3 (« Vert ») est égal à « Vert », retourner VRAI, sinon retourner FAUX. Dans ce cas, seule la première condition étant vraie, FAUX est retourné.

=SI(OU(A4>0;B4<50);VRAI;FAUX)

SI A4 (25) est supérieur à 0, OU B4 (75) est inférieur à 50, retourner VRAI, sinon retourner FAUX. Dans ce cas, seul le résultat de la première condition est VRAI, mais comme la fonction OU requiert uniquement un argument VRAI, la formule retourne VRAI.

=SI(OU(A5="Rouge";B5="Vert");VRAI;FAUX)

IF A5 (« Bleu ») est égal à « Rouge », OU B5 (« Vert ») est égal à « Vert », retourner VRAI, sinon retourner FAUX. Dans ce cas, le deuxième argument étant VRAI, la formule retourne VRAI.

= SI(NON(A6>50);VRAI;FAUX)

SI A6 (25) est NON supérieur à 50, retourner VRAI, sinon retourner FAUX. Dans ce cas, 25 n’étant pas supérieur à 50, la formule retourne VRAI.

=SI(NON(A7="Rouge");VRAI;FAUX)

SI A7 (« Bleu ») est NON égal à « Rouge », retourner VRAI, sinon retourner FAUX.

Notez que tous les exemples ont une parenthèse fermante après les conditions entrées. Les autres arguments VRAI/FAUX sont ainsi clairement associés à l’instruction SI externe. Vous pouvez également substituer des valeurs textuelles ou numériques aux valeurs VRAI/FAUX à retourner dans les exemples.

Voici quelques exemples d’utilisation des fonctions ET, OU et NON pour évaluer les dates.

Exemples d’utilisation de la fonction SI avec les fonctions ET, OU et NON pour évaluer des dates

Voici les formules explicitées en fonction de leur logique :

Formule

Description

=SI(A2>B2;VRAI;FAUX)

Si A2 est supérieur à B2, retourner VRAI, sinon retourner FAUX. 12/03/14 étant supérieur à 01/01/14, la formule retourne VRAI.

=SI(ET(A3>B2;A3<C2);VRAI;FAUX)

Si A3 est supérieur à B2 ET A3 est inférieur à C2, retourner VRAI, sinon retourner FAUX. Dans ce cas, les deux arguments étant VRAI, la formule retourne VRAI.

=SI(OU(A4>B2;A4<B2+60);VRAI;FAUX)

Si A4 est supérieur à B2 OU A4 est inférieur à B2 + 60, retourner VRAI, sinon retourner FAUX. Dans ce cas, le premier argument est vrai, mais le deuxième est faux. Comme OR n’a besoin que d’un seul argument vrai, la formule retourne VRAI. Si vous utilisez l’Assistant Évaluer la formule à partir de l’onglet Formule, vous pouvez voir comment Excel évalue la formule.

=SI(NON(A5>B2);VRAI;FAUX)

SI A5 n’est pas supérieur à B2, retourner VRAI, sinon retourner FAUX. Dans ce cas, A5 étant supérieur à B2, la formule retourne FAUX.

Exemple d’utilisation de l’Assistant Évaluer la formule

Utilisation des fonctions ET, OU et NON avec une mise en forme conditionnelle

Vous pouvez également utiliser les fonctions ET, OU et NON pour définir des critères de mise en forme conditionnelle avec l’option de formule. En procédant de la sorte, vous pouvez omettre la fonction SI et utiliser les fonctions ET, OU et NON isolément.

Dans l’onglet Accueil, cliquez sur Mise en forme conditionnelle > Nouvelle règle. Ensuite, sélectionnez l’option « Utiliser une formule pour déterminer pour quelles cellules le format sera appliqué », entrez votre formule, puis appliquez le format de votre choix.

Mise en forme conditionnelle > boîte de dialogue Modifier la règle affichant la méthode Formule

En utilisant l’exemple Dates précédent, voici ce que les formules seraient.

Exemple d’utilisation des fonctions ET, OU et NON en tant que tests de mise en forme conditionnelle


Formule

Description

=A2>B2

Si A2 est supérieur à B2, mettre en forme la cellule, sinon ne rien faire.

=ET(A3>B2;A3<C2)

Si A3 est supérieur à B2 ET A3 est inférieur à C2, mettre en forme la cellule, sinon ne rien faire.

=OU(A4>B2;A4<B2+60)

Si A4 est supérieur à B2 ou A4 est inférieur à B2 plus 60 (jours), mettre en forme la cellule, sinon ne rien faire.

=NON(A5>B2)

Si A5 est NON supérieur à B2, mettre en forme de la cellule, sinon ne rien faire. Dans ce cas, A5 étant supérieur à B2, le résultat retourne FAUX. Si vous modifiez la formule en =NON(B2>A5), elle retourne VRAI et la cellule peut être mise en forme.

Remarque : Une erreur courante consiste à entrer la formule dans une mise en forme conditionnelle sans le signe égal (=). Dans ce cas, la boîte de dialogue Mise en forme conditionnelle ajoute le signe égal et les guillemets à la formule (="OU(A4>B2;A4<B2+60)"), de sorte que vous devez supprimer les guillemets pour que la formule réponde correctement.

Haut de la page

Vous avez besoin d’une aide supplémentaire ?

Vous pouvez toujours consulter un expert de la communauté technique Excel, obtenir une assistance dans la communauté Answers ou suggérer une nouvelle fonctionnalité ou une amélioration sur le forum Excel User Voice.

Voir aussi

Regardez une vidéo sur l’utilisation de la fonction SI

Découvrez comment utiliser des fonctions imbriquées dans une formule

Fonction SI

Fonction ET

Fonction OU

Fonction NON

Vue d’ensemble des formules dans Excel

Comment éviter les formules incorrectes

Corriger les erreurs courantes dans les formules à l’aide de la vérification des erreurs

Raccourcis clavier dans Excel pour Windows

Raccourcis clavier dans Excel pour Mac

Fonctions logiques (référence)

Fonctions Excel (par ordre alphabétique)

Fonctions Excel (par catégorie)

Développez vos compétences
Découvrez des formations
Accédez aux nouvelles fonctionnalités en avant-première
Rejoignez le programme Office Insider

Ces informations vous ont-elles été utiles ?

Nous vous remercions pour vos commentaires.

Merci pour vos commentaires. Il serait vraisemblablement utile pour vous de contacter l’un de nos agents du support Office.

×