Scinder le texte en plusieurs colonnes en utilisant des fonctions

Scinder le texte en plusieurs colonnes en utilisant des fonctions

Important :  Cet article a été traduit automatiquement, voir l’avertissement. Vous pouvez consulter la version en anglais de cet article ici.

Vous pouvez utiliser les fonctions de texte GAUCHE, STXT, DROITE, RECHERCHE et NBCAR pour manipuler des chaînes de texte dans vos données. Par exemple, vous pouvez distribuer le prénom, le deuxième prénom et le nom de famille d’une même cellule dans trois colonnes distinctes.

La distribution des composants de nom en utilisant des fonctions texte est déterminée par la position de chaque caractère dans la chaîne de texte. L’emplacement des espaces dans la chaîne est aussi important, car il indique le début ou la fin du composant de nom dans la chaîne.

Par exemple, dans une cellule qui contient uniquement un nom et un prénom, le nom commence après la première instance d’un espace. Certains noms de votre liste peuvent contenir un deuxième prénom et, dans ce cas, le nom commence après la deuxième instance de l’espace.

Cet article vous explique comment extraire divers composants d’un large éventail de formats de nom en utilisant ces fonctions. Vous pouvez également scinder du texte dans différentes colonnes à l’aide de l’Assistant Conversion.

Exemple de nom

Description

Prénom

Deuxième prénom

Nom

Suffixe

1

Jeff Smith

Aucun deuxième prénom

Jeff

Smith

2

Eric S. Kurjan

Une initiale au milieu

Eric

S.

Kurjan

3

Janaina B. G. Bueno

Deux initiales au milieu

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

Nom en premier suivi d’une virgule

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

Prénom en deux parties

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

Nom en trois parties

Paula

Barreto de Mattos

7

James van Eaton

Nom en deux parties

James

van Eaton

8

Bacon Jr., Dan K.

Nom et suffixe en premier, suivis d’une virgule

Dan

K.

Bacon

Jr.

9

Gary Altman III

Avec suffixe

Gary

Altman

III

10

Mr. Ryan Ihrig

Avec préfixe

Ryan

Ihrig

11

Julie Taft-Rider

Nom avec trait d’union

Julie

Taft-Rider

Remarque : Dans les graphiques figurant dans les exemples suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule CHERCHE.

Exemple 1 : séparation de Jeff et Smith

Cet exemple permet de séparer deux composants : un prénom et un nom. Un seul espace sépare les deux noms.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Jeff Smith

Aucun deuxième prénom

Formule

Résultat (prénom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (nom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

  1. Prénom

    Le prénom débute par le premier caractère de la chaîne (J) et se termine au cinquième caractère (l’espace). La formule renvoie cinq caractères dans la cellule A2, en commençant par la gauche.

    Formule permettant d’extraire un prénom

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Recherche la position numérique de l’espace dans la cellule A2, en commençant par la gauche.

  2. Nom

    Le nom commence à l’espace, cinq caractères en partant de la droite, et se termine au dernier caractère à droite (h). La formule extrait cinq caractères dans la cellule A2, en commençant par la droite.

    Formule permettant d’extraire un nom

    Utiliser les fonctions CHERCHE et NBCAR pour rechercher la valeur de no_car :

    Rechercher la position numérique de l’espace dans la cellule A2, en commençant par la gauche. (5)

  3. Calcule la longueur totale de la chaîne de texte, puis soustrait le nombre de caractères à gauche du premier espace trouvé à l’étape 1.

Haut de la page

Exemple 2 : Eric S. Kurjan : extraire le prénom, le nom et l’initiale du deuxième prénom

Cet exemple utilise un prénom, une initiale de deuxième prénom et un nom. Un espace sépare chaque composant du nom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Eric S. Kurjan

Une initiale au milieu

Formule

Résultat (prénom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (initiale du deuxième prénom)

'=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-CHERCHE(" ";A2;1))

=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-CHERCHE(" ";A2;1))

Formule

Résultat en direct (nom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

  1. Prénom

    Le prénom débute par le premier caractère à gauche (E) et se termine au cinquième caractère (le premier espace). La formule extrait les cinq premiers caractères dans la cellule A2, en commençant par la gauche.

    Formule pour séparer un prénom d’un nom, et une initiale au milieu

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique de l’espace dans la cellule A2, en commençant par la gauche. (5)

  2. Deuxième prénom

    Le deuxième prénom commence au sixième caractère (S) et se termine à la huitième position (le deuxième espace). Cette formule implique l’imbrication des fonctions CHERCHE pour rechercher la deuxième instance d’un espace.

    La formule extrait trois caractères en partant de la sixième position.

    Détails d’une formule pour séparer un prénom, un deuxième prénom et un nom de famille

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5).

  3. Ajoute 1 pour trouver la position du caractère après le premier espace (S). Cette position numérique correspond à la position de départ du deuxième prénom. (5 + 1 = 6)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

  4. Ajouter 1 pour trouver la position du caractère après le premier espace (S). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez rechercher la deuxième instance de l’espace. (5 + 1 = 6)

  5. Rechercher la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (S). Ce numéro de caractère correspond à la position de fin du deuxième prénom. (8)

  6. Rechercher la position numérique de l’espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

  7. Extraire le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustraire le numéro de caractère du premier espace trouvé à l’étape 6. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la sixième position trouvée à l’étape 2. (8 – 5 = 3)

  8. Nom

    Le nom commence six caractères en partant de la droite (K) et se termine au premier caractère en partant de la droite (n). Cette formule implique l’imbrication des fonctions CHERCHE pour rechercher la deuxième et la troisième instance d’un espace (respectivement en cinquième et huitième position en partant de la gauche).

    La formule extrait six caractères dans la cellule A2, en commençant par la droite.

    La deuxième fonction Recherche dans une formule pour séparer le prénom, le second prénom et le nom

  9. Utiliser la fonction NBCAR et les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique de l’espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

  10. Ajouter 1 pour obtenir la position du caractère après le premier espace (S). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez rechercher la deuxième instance de l’espace. (5 + 1 = 6)

  11. Recherche la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (S) trouvée à l’étape 2. Ce numéro de caractère correspond à la position de fin du deuxième prénom. (8)

  12. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’à la deuxième instance de l’espace trouvée à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet. (14 - 8 = 6).

Haut de la page

Exemple 3 : Janaina B. G. Bueno

Cet exemple montre comment extraire un nom comportant deux initiales pour le deuxième prénom. La deuxième et la troisième instance de l’espace séparent les composants.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Janaina B. G. Bueno

Deux initiales au milieu

Formule

Résultat (prénom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (initiales des autres prénoms)

'=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1)-CHERCHE(" ";A2;1))

=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1)-CHERCHE(" ";A2;1))

Formule

Résultat en direct (nom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

  1. Prénom

    Le prénom débute par le premier caractère à gauche (J) et se termine au huitième caractère (le premier espace). La formule extrait les huit premiers caractères dans la cellule A2, en commençant par la gauche.

    Formule pour séparer le prénom, le nom et deux initiales au milieu

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (8)

  2. Deuxième prénom

    Le deuxième prénom commence à la neuvième position (B) et se termine à la quatorzième position (au troisième espace). Cette formule implique l’imbrication de la fonction CHERCHE pour rechercher la première, la deuxième et la troisième instance d’un espace à la huitième, onzième et quatorzième position.

    La formule extrait cinq caractères à partir de la neuvième position.

    Formule pour séparer le prénom, le nom et deux initiales au milieu

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (8)

  3. Ajouter 1 pour obtenir la position du caractère après le premier espace (B). Cette position numérique correspond à la position de départ du deuxième prénom. (8 + 1 = 9)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (8)

  4. Ajouter 1 pour obtenir la position du caractère après le premier espace (B). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez rechercher la deuxième instance de l’espace. (8 + 1 = 9)

  5. Rechercher le deuxième espace dans la cellule A2, en commençant par la neuvième position (B) trouvée à l’étape 4. (11).

  6. Ajoute 1 pour trouver la position du caractère après le deuxième espace (G). Ce numéro de caractère correspond à la position de départ à partir de laquelle vous souhaitez commencer la recherche du troisième espace. (11 + 1 = 12)

  7. Rechercher le troisième espace dans la cellule A2, en commençant par la douzième position trouvée à l’étape 6. (14)

  8. Rechercher la position numérique du premier espace dans la cellule A2. (8)

  9. Extraire le numéro de caractère du troisième espace trouvé à l’étape 7, puis soustraire le numéro de caractère du premier espace trouvé à l’étape 6. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la neuvième position trouvée à l’étape 2.

  10. Nom

    Le nom commence cinq caractères en partant de la droite (B) et se termine au premier caractère en partant de la droite (o). Cette formule implique l’imbrication de la fonction CHERCHE pour rechercher la première, deuxième et troisième instance de l’espace.

    La formule extrait cinq caractères dans la cellule A2, en commençant par la droite du nom complet.

    Formule pour séparer le prénom, le nom et deux initiales au milieu

    Utiliser les fonctions CHERCHE et NBCAR pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (8)

  11. Ajouter 1 pour obtenir la position du caractère après le premier espace (B). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez rechercher la deuxième instance de l’espace. (8 + 1 = 9)

  12. Rechercher le deuxième espace dans la cellule A2, en commençant par la neuvième position (B) trouvée à l’étape 2. (11)

  13. Ajouter 1 pour obtenir la position du caractère après le deuxième espace (G). Ce numéro de caractère correspond à la position de départ à partir de laquelle vous souhaitez commencer la recherche de la troisième instance d’espace. (11 + 1 = 12)

  14. Rechercher le troisième espace dans la cellule A2, en commençant par la douzième position (G) trouvée à l’étape 6. (14)

  15. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au troisième espace trouvé à l’étape 5. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(19 -14 = 5)

Haut de la page

Exemple 4 : Kahn, Wendy Beth

Dans cet exemple, le nom vient avant le prénom et le deuxième prénom apparaît à la fin. La virgule marque la fin du nom et un espace sépare chaque composant du nom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Kahn, Wendy Beth

Nom en premier suivi d’une virgule

Formule

Résultat (prénom)

'=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-CHERCHE(" ";A2;1))

=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-CHERCHE(" ";A2;1))

Formule

Résultat (deuxième prénom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

Formule

Résultat en direct (nom)

'=GAUCHE(A2;CHERCHE(" ";A2;1)-2)

=GAUCHE(A2;CHERCHE(" ";A2;1)-2)

  1. Prénom

    Le prénom débute par le septième caractère à gauche (W) et se termine au douzième caractère (deuxième espace). Étant donné que le prénom se trouve au milieu du nom complet, vous devez utiliser la fonction STXT pour extraire le prénom.

    La formule extrait six caractères à partir de la septième position.

    Formule pour séparer un nom suivi d’un prénom et d’un second prénom

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

  2. Ajouter 1 pour trouver la position du caractère après le premier espace (W). Cette position numérique correspond à la position de départ du prénom. (6 + 1 = 7)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

  3. Ajouter 1 pour trouver la position du caractère après le premier espace (W). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

    Rechercher le deuxième espace dans la cellule A2, en commençant par la septième position (W) trouvée à l’étape 4. (12)

  4. Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

  5. Extraire le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustraire le numéro de caractère du premier espace trouvé à l’étape 6. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la sixième position trouvée à l’étape 2. (12 – 6 = 6)

  6. Deuxième prénom

    Le deuxième prénom commence quatre caractères en partant de la droite (B) et se termine au premier caractère en partant de la droite (h). Cette formule implique l’imbrication de la fonction CHERCHE pour rechercher la première et la deuxième instance d’un espace à la sixième et douzième position en partant de la gauche.

    La formule extrait quatre caractères, en commençant par la droite.

    Formule pour séparer un nom suivi d’un prénom et d’un second prénom

    Utiliser les fonctions CHERCHE et NBCAR pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

  7. Ajouter 1 pour trouver la position du caractère après le premier espace (W). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

  8. Rechercher la deuxième instance de l’espace dans la cellule A2, en commençant par la septième position (W) trouvée à l’étape 2. (12)

  9. Calculer la longueur totale de la chaîne de texte dans la cellule A2, puis soustraire le nombre de caractères en partant de la gauche jusqu’au second espace trouvé à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet. (16 -12 = 4)

  10. Nom

    Le nom débute par le premier caractère à gauche (K) et se termine au quatrième caractère (n). La formule extrait quatre caractères, en commençant par la gauche.

    Formule pour séparer un nom suivi d’un prénom et d’un second prénom

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

  11. Soustrait 2 pour trouver la position numérique du caractère de fin du nom (n). Le résultat correspond au nombre de caractères que la fonction GAUCHE doit extraire. (6 - 2 = 4)

Haut de la page

Exemple 5 : Mary Kay D. Andersen

Cet exemple utilise un prénom en deux parties : Mary Kay. Le deuxième et le troisième espace séparent les deux composants du nom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Mary Kay D. Andersen

Prénom en deux parties

Formule

Résultat (prénom)

GAUCHE(A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

=GAUCHE(A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

Formule

Résultat (initiale du deuxième prénom)

'=STXT(A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

=STXT(A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1)-(CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

Formule

Résultat en direct (nom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

  1. Prénom

    Le prénom commence au premier caractère à gauche et se termine au neuvième caractère (le deuxième espace). Cette formule implique l’imbrication de la fonction CHERCHE pour rechercher la deuxième instance de l’espace à gauche.

    La formule extrait neuf caractères, en commençant par la gauche.

    Formule pour séparer un prénom, un second prénom, une initiale au milieu et le nom de famille

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

  2. Ajouter 1 pour obtenir la position du caractère après le premier espace (K). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez rechercher la deuxième instance de l’espace. (5 + 1 = 6)

  3. Rechercher la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (K) trouvée à l’étape 2. Le résultat correspond au nombre de caractères extraits par la fonction GAUCHE dans la chaîne de texte. (9)

  4. Deuxième prénom

    Le deuxième prénom commence à la neuvième position (D) et se termine à la douzième position (au troisième espace). Cette formule implique l’imbrication de la fonction CHERCHE pour rechercher la première, la deuxième et la troisième instance d’un espace.

    La formule extrait deux caractères au milieu, à partir de la dixième position.

    Formule pour séparer un prénom, un second prénom, une initiale au milieu et le nom de famille

    Utiliser les fonctions imbriquées CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

  5. Ajouter 1 pour trouver le caractère après le premier espace (K). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (5 + 1 = 6)

  6. Rechercher la position de la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (K) trouvée à l’étape 2. Le résultat correspond au nombre de caractères extraits à gauche par la fonction GAUCHE. (9)

  7. Ajouter 1 pour trouver le caractère après le deuxième espace (D). Le résultat correspond à la position de départ du deuxième prénom. (9 + 1 = 10)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du caractère après le deuxième espace (D). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du troisième espace. (10)

  8. Rechercher la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du deuxième prénom. (12)

  9. Rechercher la position numérique du caractère après le deuxième espace (D). Le résultat indique la position de début du deuxième prénom. (10)

  10. Extraire le numéro de caractère du troisième espace trouvé à l’étape 6 et soustraire le numéro de caractère de la lettre « D » trouvé à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la dixième position trouvée à l’étape 4. (12 -10 = 2)

  11. Nom

    Le nom débute huit caractères à droite. Cette formule implique l’imbrication de la fonction CHERCHE pour rechercher la première, la deuxième et la troisième instance d’un espace à la cinquième, neuvième et douzième position.

    La formule extrait huit caractères à partir de la droite.

    Formule pour séparer un prénom, un second prénom, une initiale au milieu et le nom de famille

    Utiliser les fonctions CHERCHE et NBCAR pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

  12. Ajouter 1 pour trouver le caractère après le premier espace (K). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche de l’espace. (5 + 1 = 6)

  13. Rechercher le deuxième espace dans la cellule A2, en commençant par la sixième position (K) trouvée à l’étape 2. (9)

  14. Ajouter 1 pour trouver la position du caractère après le deuxième espace (D). Le résultat indique la position de départ du deuxième prénom. (9 + 1 = 10)

  15. Rechercher la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du deuxième prénom. (12)

  16. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au troisième espace trouvé à l’étape 5. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(20 -12 = 8)

Haut de la page

Exemple 6 : Paula Barreto de Mattos

Cet exemple utilise un nom en trois parties : Barreto de Mattos. Le premier espace marque la fin du prénom et le début du nom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Paula Barreto de Mattos

Nom en trois parties

Formule

Résultat (prénom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (nom)

DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

  1. Prénom

    Le prénom débute par le premier caractère à gauche (P) et se termine au sixième caractère (le premier espace). La formule extrait six caractères à partir de la gauche.

    Formule pour séparer un prénom et un nom de famille composé de trois parties

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  2. Nom

    Le nom commence dix-sept caractères en partant de la droite (B) et se termine au premier caractère à droite (s). La formule extrait dix-sept caractères à partir de la droite.

    Formule pour séparer un prénom et un nom de famille composé de trois parties

    Utiliser les fonctions NBCAR et CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  3. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au premier espace trouvé à l’étape 1. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(23 - 6 = 17)

Haut de la page

Exemple 7 : James van Eaton

Cet exemple utilise un nom en deux parties : van Eaton. Le premier espace marque la fin du prénom et le début du nom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

James van Eaton

Nom en deux parties

Formule

Résultat (prénom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (nom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

  1. Prénom

    Le prénom débute par le premier caractère en partant de la gauche (J) et se termine au huitième caractère (le premier espace). La formule extrait six caractères à partir de la gauche.

    Formule pour séparer un prénom et un nom de famille composé de deux parties

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  2. Nom

    Le nom débute par le neuvième caractère en partant de la droite (v) et se termine au premier caractère en partant de la droite (n). La formule extrait neuf caractères en partant de la droite du nom complet.

    Formule pour séparer un prénom et un nom de famille composé de deux parties

    Utiliser les fonctions NBCAR et CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  3. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au premier espace trouvé à l’étape 1. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(15 - 6 = 9)

Haut de la page

Exemple 8 : Bacon Jr., Dan K.

Dans cet exemple, le nom est indiqué en premier, suivi d’un suffixe. La virgule sépare le nom et le suffixe du prénom et de l’initiale du deuxième prénom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Bacon Jr., Dan K.

Nom et suffixe en premier, suivis d’une virgule

Formule

Résultat (prénom)

'=STXT(A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1)-(CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

=STXT(A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

Formule

Résultat (initiale du deuxième prénom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)+1))

Formule

Résultat (nom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (suffixe)

'=STXT(A2;CHERCHE(" ";A2;1)+1;(CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-2)-CHERCHE(" ";A2;1))

=STXT(A2;CHERCHE(" ";A2;1)+1;(CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-2)-CHERCHE(" ";A2;1))

  1. Prénom

    Le prénom débute par le douzième caractère (D) et se termine par le quinzième caractère (le troisième espace). La formule extrait trois caractères à partir de la douzième position.

    Formule permettant d’extraire le prénom dans l’exemple 8 : Bacon Jr., Dan K.

    Utiliser les fonctions imbriquées CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  2. Ajouter 1 pour trouver le caractère après le premier espace (J). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

  3. Rechercher le deuxième espace dans la cellule A2, en commençant par la septième position (J) trouvée à l’étape 2. (11)

  4. Ajouter 1 pour trouver le caractère après le deuxième espace (D). Le résultat correspond à la position de départ du prénom. (11 + 1 = 12)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du caractère après le deuxième espace (D). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du troisième espace. (12)

  5. Rechercher la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du prénom. (15)

  6. Rechercher la position numérique du caractère après le deuxième espace (D). Le résultat indique la position de début du prénom. (12)

  7. Extraire le numéro de caractère du troisième espace trouvé à l’étape 6 et soustraire le numéro de caractère de la lettre « D » trouvé à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la douzième position trouvée à l’étape 4. (15 -12 = 3)

  8. Deuxième prénom

    Le deuxième prénom commence par le deuxième caractère en partant de la droite (K). La formule extrait deux caractères en partant de la droite.

    Formule permettant d’extraire le deuxième prénom dans l’exemple 8 : Bacon Jr., Dan K. Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  9. Ajouter 1 pour trouver le caractère après le premier espace (J). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

  10. Rechercher le deuxième espace dans la cellule A2, en commençant par la septième position (J) trouvée à l’étape 2. (11)

  11. Ajoute 1 pour trouver le caractère après le deuxième espace (D). Le résultat correspond à la position de départ du prénom. (11 + 1 = 12)

  12. Recherche la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du deuxième prénom. (15)

  13. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au troisième espace trouvé à l’étape 5. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(17 -15 = 2)

  14. Nom

    Le nom débute au premier caractère en partant de la gauche (B) et se termine au sixième caractère (le premier espace). Par conséquent, la formule extrait six caractères en partant de la gauche.

    Formule permettant d’extraire le nom dans l’exemple 8 : Bacon Jr., Dan K.

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  15. Suffixe

    Le suffixe débute au septième caractère en partant de la gauche (J) et se termine au neuvième caractère en partant de la gauche. La formule extrait trois caractères, en commençant par le septième caractère.

    Formule permettant d’extraire le suffixe dans l’exemple 8 : Bacon Jr., Dan K.

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  16. Ajouter 1 pour obtenir le caractère après le premier espace (J). Le résultat correspond à la position de départ du suffixe. (6 + 1 = 7)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  17. Ajouter 1 pour trouver la position numérique du caractère après le premier espace (J). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (7)

  18. Rechercher la position numérique du deuxième espace dans la cellule A2, en commençant par le septième caractère trouvé à l’étape 4. (11)

  19. Soustrait 1 du numéro de caractère du deuxième espace trouvé à l’étape 4 pour trouver le numéro de caractère de « , ». Le résultat correspond à la position de fin du suffixe. (11 -1 = 10)

  20. Rechercher la position numérique du premier espace. (6)

  21. Après avoir trouvé le premier espace, ajouter 1 pour trouver le caractère suivant (J), également trouvé aux étapes 3 et 4. (7)

  22. Extrait le numéro de caractère de « , » trouvé à l’étape 6 et soustrait le numéro de caractère de la lettre « J » trouvé à l’étape 3 et à l’étape 4. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la septième position trouvée à l’étape 2. (10 - 7 = 3)

Haut de la page

Exemple 9 : Gary Altman III

Dans cet exemple, le prénom se trouve au début de la chaîne et le suffixe se trouve à la fin ; vous pouvez donc utiliser des formulas semblables à celles de l’Exemple 2 : utiliser la fonction GAUCHE pour extraire le prénom, la fonction STXT pour extraire le nom et la fonction DROITE pour extraire le suffixe.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Gary Altman III

Prénom et nom avec suffixe

Formule

Résultat (prénom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (nom)

'=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-(CHERCHE(" ";A2;1)+1))

=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-(CHERCHE(" ";A2;1)+1))

Formule

Résultat (suffixe)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

  1. Prénom

    Le prénom débute au premier caractère en partant de la gauche (G) et se termine au cinquième caractère (le premier espace). Par conséquent, la formule extrait cinq caractères à gauche du nom complet.

    Formule pour séparer un prénom, un nom et un titre

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

  2. Nom

    Le nom commence au sixième caractère en partant de la gauche (A) et se termine au onzième caractère (le deuxième espace). Cette formule implique l’imbrication de la fonction CHERCHE pour rechercher la position des espaces.

    La formule extrait six caractères au milieu, à partir du sixième caractère.

    Formule pour séparer un prénom, un nom et un titre

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

  3. Ajouter 1 pour trouver la position du caractère après le premier espace (A). Le résultat correspond à la position de départ du prénom. (5 + 1 = 6)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

  4. Ajouter 1 pour trouver la position du caractère après le premier espace (A). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (5 + 1 = 6)

  5. Recherche la position numérique du deuxième espace dans la cellule A2, en commençant par le sixième caractère trouvé à l’étape 4. Ce numéro de caractère correspond à la position de fin du nom. (12)

  6. Rechercher la position numérique du premier espace. (5)

  7. Ajoute 1 pour rechercher la position numérique du caractère après le premier espace (A), également trouvé aux étapes 3 et 4. (6)

  8. Extrait le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustrait le numéro de caractère de la lettre « A » trouvé à l’étape 6 et à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la sixième position trouvée à l’étape 2. (12 - 6 = 6)

  9. Suffixe

    Le suffixe débute trois caractères en partant de la droite. Cette formule implique l’imbrication de la fonction CHERCHE pour trouver la position des espaces.

    Formule pour séparer un prénom, un nom et un titre

    Utiliser les fonctions CHERCHE et NBCAR pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

  10. Ajouter 1 pour trouver le caractère après le premier espace (A). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (5 + 1 = 6)

  11. Rechercher le deuxième espace dans la cellule A2, en commençant par la sixième position (A) trouvée à l’étape 2. (12)

  12. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au deuxième espace trouvé à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(15 - 12 = 3)

Haut de la page

Exemple 10 : Mr. Ryan Ihrig

Dans cet exemple, le nom complet est précédé d’un préfixe et l’on utilise des formules semblables à celles de l’Exemple 2 : la fonction STXT pour extraire le prénom et la fonction DROITE pour extraire le nom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Mr. Ryan Ihrig

Avec préfixe

Formule

Résultat (prénom)

'=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-(CHERCHE(" ";A2;1)+1))

=STXT(A2;CHERCHE(" ";A2;1)+1;CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1)-(CHERCHE(" ";A2;1)+1))

Formule

Résultat (nom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;CHERCHE(" ";A2;1)+1))

  1. Prénom

    Le prénom commence au cinquième caractère en partant de la gauche (R) et se termine au neuvième caractère (le deuxième espace). La formule imbrique la fonction CHERCHE pour rechercher la position des espaces. Elle extraie 4 caractères, en commençant à partir de la 5e position.

    Formule permettant d’extraire le prénom dans l’exemple 10 : Mr. Ryan Ihrig.

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_départ :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (4)

  2. Utiliser nAjouter 1 pour trouver la position du caractère après le premier espace (R). Le résultat indique la position de départ du nom. (4 + 1 = 5)

    Utiliser les fonctions CHERCHE imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (4)

  3. Ajouter 1 pour trouver la position du caractère après le premier espace (R). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (4 + 1 = 5)

  4. Recherche la position numérique du deuxième espace dans la cellule A2, en commençant par le cinquième caractère trouvé à l’étape 3 et à l’étape 4. Ce numéro de caractère correspond à la position de fin du prénom. (9)

  5. Rechercher le premier espace. (4)

  6. Ajouter 1 pour rechercher la position numérique du caractère après le premier espace (R), également trouvé aux étapes 3 et 4. (5)

  7. Extrait le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustrait le numéro de caractère de la lettre « R » trouvé à l’étape 6 et à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la cinquième position trouvée à l’étape 2. (9 - 5 = 4)

  8. Nom

    Le nom débute cinq caractères en partant de la droite. Cette formule implique l’imbrication de la fonction CHERCHE pour trouver la position des espaces.

    Formule permettant d’extraire le nom dans l’exemple 10 : Mr. Ryan Ihrig. Utiliser des fonctions CHERCHE et NBCAR imbriquées pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (4)

  9. Ajouter 1 pour trouver la position du caractère après le premier espace (R). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (4 + 1 = 5)

  10. Rechercher le deuxième espace dans la cellule A2, en commençant par la cinquième position (R) trouvée à l’étape 2. (9)

  11. Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au deuxième espace trouvé à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet. (14 - 9 = 5)

Haut de la page

Exemple 11 : Julie Taft-Rider

Cet exemple utilise un nom contenant un trait d’union. Un espace sépare chaque composant du nom.

Copiez les cellules du tableau et collez-les dans une feuille de calcul Excel au niveau de la cellule A1. La formule qui apparaît sur la gauche ne s’affiche que pour référence. Excel convertit automatiquement la formule située à droite pour afficher le résultat approprié.

Conseil    Avant de coller les données dans la feuille de calcul, définissez la largeur des colonnes A et C sur 250 pixels.

Exemple de nom

Description

Julie Taft-Rider

Nom avec trait d’union

Formule

Résultat (prénom)

'=GAUCHE(A2;CHERCHE(" ";A2;1))

=GAUCHE(A2;CHERCHE(" ";A2;1))

Formule

Résultat (nom)

'=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

=DROITE(A2;NBCAR(A2)-CHERCHE(" ";A2;1))

  1. Prénom

    Le prénom débute au premier caractère en partant de la gauche et se termine à la sixième position (le premier espace). La formule extrait six caractères en partant de la gauche.

    Formule permettant d’extraire le prénom dans l’exemple 11 : Julie Taft-Rider

    Utiliser la fonction CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

  2. Nom

    Le nom complet commence dix caractères en partant de la droite (T) et se termine au premier caractère en partant de la droite (r).

    Formule permettant d’extraire le nom complet dans l’exemple 11 : Julie Taft-Rider

    Utiliser les fonctions NBCAR et CHERCHE pour rechercher la valeur de no_car :

    Rechercher la position numérique de l’espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

  3. Calcule la longueur totale de la chaîne de texte à extraire, puis soustrait le nombre de caractères en partant de la gauche jusqu’au premier espace, trouvé à l’étape 1. (16 - 6 = 10)

Haut de la page

Remarque : Avertissement traduction automatique : cet article a été traduit par un ordinateur, sans intervention humaine. Microsoft propose cette traduction automatique pour offrir aux personnes ne maîtrisant pas l’anglais l’accès au contenu relatif aux produits, services et technologies Microsoft. Comme cet article a été traduit automatiquement, il risque de contenir des erreurs de grammaire, de syntaxe ou de terminologie.

Voir aussi

Scinder du texte dans différentes colonnes à l’aide de l’Assistant Conversion

Partager Facebook Facebook Twitter Twitter E-mail E-mail

Ces informations vous ont-elles été utiles ?

Très bien ! Vous avez d’autres commentaires ?

Comment pouvons-nous l’améliorer ?

Nous vous remercions pour vos commentaires.

×