Propriété DialogueFichier

S’applique à

Objet Application

Renvoie un objet FileDialog représentant une seule instance d’une boîte de dialogue de fichier.

expression.FileDialog(dialogType)

expression Obligatoire. Expression qui renvoie l’un des objets figurant dans la liste S’applique à.

dialogType    Required MsoFileDialogType . Type de boîte de dialogue de fichier.

MsoFileDialogType peut être l’une des constantes MsoFileDialogType suivante.

msoFileDialogFilePicker

msoFileDialogFolderPicker

msoFileDialogOpen Non pris en charge dans Microsoft Access.

msoFileDialogSaveAs Non pris en charge dans Microsoft Access.

Remarques

Les constantes msoFileDialogOpen et msoFileDialogSaveAs ne sont pas pris en charge dans Microsoft Office Access 2007.

Exemple

Cet exemple montre comment utiliser l’objet FileDialog pour afficher une boîte de dialogue permettant à l’utilisateur de sélectionner un ou plusieurs fichiers. Les fichiers sélectionnés sont ensuite ajoutés à une zone de liste nommée FileList.

Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
Développez vos compétences
Découvrez des formations
Accédez aux nouvelles fonctionnalités en avant-première
Rejoignez le programme Office Insider

Ces informations vous ont-elles été utiles ?

Nous vous remercions pour vos commentaires.

Merci pour vos commentaires. Il serait vraisemblablement utile pour vous de contacter l’un de nos agents du support Office.

×