Propriété AllowBypassKey

Vous pouvez utiliser la propriété AllowBypassKey afin de déterminer si la touche MAJ doit être activée pour ignorer les propriétés de démarrage et la macro AutoExec. Par exemple, vous pouvez définir la propriété AllowBypassKey sur False pour empêcher un utilisateur d’ignorer les propriétés de démarrage et la macro AutoExec.

Paramètre

La propriété AllowBypassKey utilise les paramètres suivants.

Paramètre

Description

Vrai

Activez la touche Maj pour permettre à l’utilisateur d’ignorer les propriétés de démarrage et la macro AutoExec.

Faux

Désactivez la touche Maj pour empêcher l’utilisateur d’ignorer les propriétés de démarrage et la macro AutoExec.


Vous pouvez définir cette propriété à l’aide d’une macro ou d’un code Visual Basic pour Applications (VBA).

Pour définir la propriété AllowBypassKey au moyen d’une macro ou d’un code Visual Basic pour Applications (VBA), vous devez créer la propriété en procédant comme suit :

  • Dans une base de données Microsoft Access (.mdb ou .accdb), vous pouvez ajouter la propriété en utilisant la méthode CreateProperty puis en l’attachant à la collection Properties de l’objet Database.

  • Dans un projet Microsoft Access (.adp), vous pouvez l’ajouter à la collection AccessObjectProperties de l’objet CurrentProject en utilisant la méthode Add.

Remarques

Lorsque vous déboguez une application, vous devez vous assurer que la propriété AllowBypassKey est définie sur True.

Le paramètre de la propriété AllowBypassKey ne prendra effet qu’à la prochaine ouverture de la base de données d’application.

Exemple

L’exemple suivant illustre une procédure nommée SetBypassProperty qui transmet le nom de la propriété à définir, son type de données et le paramètre. La procédure à usage général ChangeProperty tente de définir la propriété AllowBypassKey et, si la propriété n’est pas trouvée, utilise la méthode CreateProperty pour ajouter la propriété à la collection Properties. Cette procédure est nécessaire car la propriété AllowBypassKey n’apparaît dans la collection Properties qu’après y avoir été ajoutée.

Sub SetBypassProperty()
Const DB_Boolean As Long = 1
ChangeProperty "AllowBypassKey", DB_Boolean, False
End Sub
Function ChangeProperty(strPropName As String, _
varPropType As Variant, _
varPropValue As Variant) As Integer
Dim dbs As Object, prp As Variant
Const conPropNotFoundError = 3270
Set dbs = CurrentDb
On Error GoTo Change_Err
dbs.Properties(strPropName) = varPropValue
ChangeProperty = True
Change_Bye:
Exit Function
Change_Err:
If Err = conPropNotFoundError Then ' Property not found.
Set prp = dbs.CreateProperty(strPropName, _
varPropType, varPropValue)
dbs.Properties.Append prp
Resume Next
Else
' Unknown error.
ChangeProperty = False
Resume Change_Bye
End If
End Function
Développez vos compétences dans Office
Découvrez des formations
Accédez aux nouvelles fonctionnalités en avant-première
Rejoignez le programme Office Insider

Ces informations vous ont-elles été utiles ?

Nous vous remercions pour vos commentaires.

Merci pour vos commentaires. Il serait vraisemblablement utile pour vous de contacter l’un de nos agents du support Office.

×