NB.SI (NB.SI, fonction)

NB.SI, l’une des fonctions Statistiques, permet de compter le nombre de cellules qui répondent à un critère ; par exemple, pour compter le nombre de fois où le nom d’une ville apparaît dans une liste de clients.

Dans sa forme la plus simple, la fonction NB.SI se décompose ainsi :

  • =NB.SI(où voulez-vous rechercher ?;que voulez-vous rechercher ?)

Par exemple :

  • =NB.SI(A2:A5;"Londres")

  • =NB.SI(A2:A5;A4)

Votre navigateur ne prend pas en charge la vidéo. Installez Microsoft Silverlight, Adobe Flash Player ou Internet Explorer 9.

En savoir plus sur la manière dont vous pouvez utiliser les fonctions SOMME.SI et NB.SI et les fonctions liées pour analyser rapidement vos données

Développez vos connaissances des fonctions SOMME.SI et NB.SI et des fonctions liées avec LinkedIn Learning. Découvrez comment utiliser la fonction NB.SI afin d’effectuer une analyse rapide des données.

Regarder gratuitement un aperçu >

NB.SI(plage; critères)

Argument

Description

plage    (obligatoire)

Le groupe de cellules à compter. Plage peut contenir des nombres, des matrices, une plage nommée ou des références qui contiennent des nombres. Les valeurs vides et textuelles sont ignorées.

Découvrez comment sélectionner des plages dans une feuille de calcul.

critères    (obligatoire)

Nombre, expression, référence de cellule ou chaîne de texte qui détermine les cellules à compter.

Par exemple, les critères peuvent être exprimés sous les formes suivantes : un nombre, comme 32, une comparaison, comme ">32", une cellule, comme B4, ou un mot, comme "pommes".

NB.SI utilise un seul critère. Utilisez NB.SI.ENS Si vous voulez utiliser plusieurs critères.

Exemples

Pour utiliser ces exemples dans Excel, copiez les données dans le tableau ci-dessous, puis collez-les dans la cellule A1 d’une nouvelle feuille de calcul.

Données

Données

pommes

32

oranges

54

pêches

75

pommes

86

Formule

Description

=NB.SI(A2:A5;"pommes")

Compte le nombre de cellules contenant « pommes » dans les cellules A2 à A5. Le résultat est 2.

=NB.SI(A2:A5;A4)

Compte le nombre de cellules contenant « pêches » (soit la valeur en cellule A4) dans les cellules A2 à A5. Le résultat est 1.

=NB.SI(A2:A5;A2)+NB.SI(A2:A5;A3)

Compte le nombre de « pommes » (soit la valeur en cellule A2) et d’« oranges » (soit la valeur en cellule A3) dans les cellules A2 à A5. Le résultat est 3. Cette formule utilise la fonction NB.SI à deux reprises pour spécifier plusieurs critères, un seul critère par l’expression. Vous pouvez également utiliser la fonction NB.SI.ENS.

=NB.SI(B2:B5;">55")

Compte le nombre de cellules dont la valeur est supérieure à 55 dans les cellules B2 à B5. Le résultat est 2.

=NB.SI(B2:B5;"<>"&B4)

Compte le nombre de cellules dont la valeur n’est pas égale à 75 dans les cellules B2 à B5. L’esperluette (&) fusionne l’opérateur de comparaison (<>) et la valeur de B4 pour lire =NB.SI(B2:B5;"<>75"). Le résultat est 3.

=NB.SI(B2:B5;">=32")-NB.SI(B2:B5;">85")

Compte le nombre de cellules dont la valeur est supérieure (>) ou égale à (=) 32 et inférieure (<) ou égale à (=) 85 dans les cellules B2 à B5. Le résultat est 3.

=NB.SI(A2:A5;"*")

Compte le nombre de cellules contenant du texte dans les cellules A2 à A5. L’astérisque * est utilisée comme caractère générique pour correspondre à n’importe quel caractère. Le résultat est 4.

=NB.SI(A2:A5;"?????es")

Compte le nombre de cellules se terminant par les lettres « es » et ayant exactement 7 lettres dans les cellules A2 à A5. Le point d’interrogation (?) est utilisé comme caractère générique pour correspondre à des caractères individuels. Le résultat est 2.

Problèmes courants

Problème

Cause

La valeur renvoyée pour les longues chaînes n’est pas correcte.

La fonction NB.SI renvoie des résultats incorrects lorsque vous l’utilisez pour mettre en correspondance des chaînes comportant plus de 255 caractères.

Pour faire correspondre des chaînes comportant plus de 255 caractères, utilisez la fonction CONCATENER ou l’opérateur de concaténation « & ». Par exemple, =NB.SI(A2:A5;"chaîne longue"&"autre chaîne longue").

Aucune valeur n’est renvoyée alors que vous en attendez une.

Veillez à placer l’argument critères entre guillemets.

Une formule NB.SI reçoit une erreur #VALEUR! lors d’une référence à une autre feuille de calcul.

Cette erreur se produit lorsque la formule qui contient la fonction fait référence à des cellules ou une plage dans un classeur fermé et les cellules sont calculées. Pour utiliser cette fonctionnalité, le classeur doit être ouvert.

Meilleures pratiques

Procédez comme suit

Pourquoi

N’oubliez pas que NB.SI ignore la casse inférieure et supérieure des chaînes de texte.

Les Critères ne respectent pas la casse ; par exemple, la chaîne "pommes" et la chaîne "POMMES" donneront les mêmes cellules.

Utilisez des caractères génériques.

Vous pouvez utiliser les caractères génériques [le point d’interrogation (?) et l’astérisque (*)]  dans l’argument critère. Un point d’interrogation correspond à un caractère quelconque et un astérisque à une séquence de caractères. Si vous recherchez un point d’interrogation ou un astérisque, tapez un tilde (~) devant ce caractère.

Par exemple, =NB.SI(A2:A5;"pomme?") comptera toutes les instances de « pomme » avec une dernière lettre pouvant varier.

Vérifiez que vos données ne contiennent pas des caractères erronés.

Si vous comptez des valeurs textuelles, vérifiez que les données sont exemptes de tout espace d’en-tête, espace de fin, et que vous ne remarquez aucune utilisation incohérente des guillemets ou apostrophes droits et courbes. Si c’est le cas, il se peut que NB.SI renvoie des valeurs incorrectes ou inattendues.

Essayez d’utiliser la fonction EPURAGE ou la fonction SUPPRESPACE.

Pour simplifier la tâche, utilisez des plages nommées

NB.SI prend en charge les plages nommées dans une formule (telle que =NB.SI(fruit,">=32")-NB.SI(fruit,">85"). La plage nommée peut figurer dans la feuille de calcul active, une autre feuille de calcul du même classeur, ou dans un autre classeur. Pour établir une référence à partir d’un autre classeur, celui-ci doit également être ouvert.

Remarque : La fonction NB.SI ne comptabilise pas les cellules sur la base de leur arrière-plan ou de leur couleur de police. Toutefois, Excel prend en charge les fonctions définies par l’utilisateur (UDF) à l’aide d’opérations Microsoft Visual Basic pour Applications (VBA) sur les cellules en fonction de l’arrière-plan ou de la couleur de police. Voici un exemple de la manière dont vous pouvez compter le nombre de cellules utilisant une couleur spécifique à l’aide de VBA.

Vous avez besoin d’une aide supplémentaire ?

Vous pouvez toujours consulter un expert de la communauté technique Excel, obtenir une assistance dans la communauté Answers ou suggérer une nouvelle fonctionnalité ou une amélioration sur le forum Excel User Voice.

Voir aussi

Pour calculer les cellules non vides, utilisez la fonction NBVAL

Pour calculer les cellules qui répondent à plusieurs critères, utilisez la fonction NB.SI

Consultez une vidéo sur l’utilisation de la fonction NB.SI

La fonction SOMME.SI additionne uniquement les valeurs qui répondent à un critère unique

La fonction SOMME.SI.ENS additionne uniquement les valeurs qui répondent à plusieurs critères

Fonction SI.CONDITIONS (Office 365, Excel 2016 et version ultérieure)

Utilisation de la fonction SUPPRESPACE pour supprimer les espaces de début et de fin des cellules

Utilisation de la fonction EPURAGE pour supprimer les caractères non imprimables des cellules

Vue d’ensemble des formules dans Excel

Comment éviter les formules incorrectes

Détecter les erreurs dans les formules

Fonctions statistiques

Fonctions Excel (par ordre alphabétique)

Fonctions Excel (par catégorie)

Utilisation des fonctions SOMME.SI et NB.SI et des fonctions liées afin d’effectuer une analyse rapide des données (aperçu gratuit)

Développez vos compétences
Découvrez des formations
Accédez aux nouvelles fonctionnalités en avant-première
Rejoignez le programme Office Insider

Ces informations vous ont-elles été utiles ?

Nous vous remercions pour vos commentaires.

Merci pour vos commentaires. Il serait vraisemblablement utile pour vous de contacter l’un de nos agents du support Office.

×