NB.SI (NB.SI, fonction)

Cet article décrit la syntaxe de formule et l’utilisation de la fonctionNB.SI dans Microsoft Excel.

Description

La fonction NB.SI compte le nombre de cellules d’une plage qui répondent à un critère spécifique que vous spécifiez. Vous pouvez, par exemple, compter toutes les cellules qui commencent par une lettre donnée ou compter toutes les cellules qui contiennent un nombre supérieur ou inférieur à un nombre donné. Supposons que vous ayez une feuille de calcul contenant une liste de tâches dans la colonne A et le prénom de la personne affectée à chaque tâche dans la colonne B. La fonction NB.SI vous permet de compter combien de fois le nom d’une personne revient dans la colonne B et ainsi déterminer le nombre de tâches qui lui sont affectées. Par exemple :

=NB.SI(B2:B25;"Nancy")

Remarque   Pour compter les cellules d’après plusieurs critères, voir Fonction NB.SI.

Syntaxe

NB.SI(plage; critères)

La syntaxe de la fonction NB.SI contient les argumentsuivants :

  • plage    Obligatoire. Représente un certain nombre de cellules à compter, y compris des nombres ou des noms, des matrices ou des références qui contiennent des nombres. Les valeurs vides et textuelles seront ignorées.

  • critères    Obligatoire. Nombre, expression, référence de cellule ou chaîne de texte qui détermine les cellules à compter. Par exemple, les critères peuvent être exprimés sous les formes suivantes : 32, ">32", B4, "pommes" ou "32".

    Remarque   

    • Vous pouvez utiliser les caractères génériques (point d’interrogation (?) et astérisque (*)) dans les critères. Le point d’interrogation correspond à un caractère quelconque et l’astérisque correspond à une séquence de caractères quelconque. Si vous recherchez un point d’interrogation ou un astérisque en tant que tel, tapez un tilde (~) devant ce caractère.

    • Les critères ne respectent pas la casse ; par exemple, la chaîne "pommes" et la chaîne "POMMES" donneront les mêmes cellules.

Notes

  • La fonction NB.SI renvoie des résultats incorrects lorsque vous l’utilisez pour mettre en correspondance des chaînes comportant plus de 255 caractères avec la chaîne #VALEUR!.

Exemples

Le classeur ci-dessous montre des exemples de cette fonction. Consultez-les, modifiez les formules existantes ou entrez vos propres formules pour apprendre à maîtriser le fonctionnement de la formule.

Copiez les données d’exemple dans le tableau suivant, et collez-le dans la cellule A1 d’un nouveau classeur Excel. Pour que les formules affichent des résultats, sélectionnez-les, appuyez sur F2, et sur Entrée. Si nécessaire, vous pouvez modifier la largeur des colonnes pour afficher toutes les données.

Données

Données

pommes

32

oranges

54

pêches

75

pommes

86

Formule

Description

Résultat

=NB.SI(A2:A5;"pommes")

Nombre de cellules contenant « pommes » dans les cellules A2 à A5.

2

=NB.SI(A2:A5;A4)

Nombre de cellules contenant « pêches » dans les cellules A2 à A5.

1

=NB.SI(A2:A5,A3)+NB.SI(A2:A5;A2)

Nombre de cellules contenant « oranges » et « pommes » dans les cellules A2 à A5.

3

=NB.SI(B2:B5;">55")

Nombre de cellules dont la valeur est supérieure à 55 dans les cellules B2 à B5.

2

=NB.SI(B2:B5;"<>"&B4)

Nombre de cellules dont la valeur n’est pas égale à 75 dans les cellules B2 à B5.

3

=NB.SI(B2:B5;">=32")-NB.SI(B2:B5;">85")

Nombre de cellules dont la valeur est supérieure ou égale à 32 et inférieure ou égale à 85 dans les cellules B2 à B5.

3

Pour travailler de manière approfondie avec les données d’exemple dans Excel, téléchargez le classeur incorporé sur votre ordinateur, puis ouvrez-le dans Excel.

Exemple 2

Données

pommes

Oui

oranges

NON

pêches

Non

pommes

Oui

Formule

Description

Résultat

=NB.SI(A2:A7;"*es")

Nombre de cellules se terminant par les lettres « es » dans les cellules A2 à A7.

4

=NB.SI(A2:A7;"?????es")

Nombre de cellules se terminant par les lettres « es » et ayant exactement 7 lettres dans les cellules A2 à A7.

2

=NB.SI(A2:A7;"*")

Nombre de cellules contenant du texte dans les cellules A2 à A7.

4

=NB.SI(A2:A7;"<>"&"*")

Nombre de cellules ne contenant pas de texte dans les cellules A2 à A7.

2

=NB.SI(B2:B7;"Non") / LIGNES(B2:B7)

Nombre moyen de votes Non (y compris les cellules vides) dans les cellules B2 à B7.

0,33333333

=NB.SI(B2:B7;"Oui") / (LIGNES(B2:B7) -NB.SI(B2:B7; "<>"&"*"))

Nombre moyen de votes Oui (sans compter les cellules vides) dans les cellules B2 à B7.

0,5

S’applique à : Excel 2013, Excel Online



Ces informations vous ont-elles été utiles ?

Oui Non

Comment pouvons-nous nous améliorer ?

255 caractères restants

Afin de protéger votre vie privée, n’indiquez aucune information de contact dans vos commentaires. Lisez notre déclaration de confidentialité.

Nous vous remercions pour vos commentaires.

Ressources de support

Changer la langue