Fractionner le texte en colonnes en utilisant des fonctions

Les fonctions de texte sont utiles pour manipuler des chaînes dans des données et par exemple, pour distribuer le nom, le prénom et le deuxième prénom d’une cellule sur trois colonnes différentes.

Cet article explique comment utiliser des combinaisons de fonctions de texte afin d’extraire et de copier des parties de noms dans des cellules différentes.

Fonction

Syntaxe

GAUCHE

GAUCHE(texte,no_car)

STXT

STXT(texte,no_départ,no_car)

DROITE

DROITE(texte,no_car)

RECHERCHE

RECHERCHE (texte_cherché,texte,no_départ)

NBCAR

NBCAR(texte)

Extraction des composants de nom

La distribution des composants de nom lorsque vous utilisez des fonctions de texte est déterminée par la position de chaque caractère dans la chaîne de texte. L’emplacement des espaces dans la chaîne est important car il indique le début ou la fin du composant de nom dans la chaîne.

Par exemple, dans une cellule qui contient uniquement un nom et un prénom, le nom commence après la première instance d’un espace. Certains noms de votre liste peuvent contenir un deuxième prénom et, dans ce cas, le nom commence après la deuxième instance de l’espace.

Cet article explique comment extraire plusieurs composants de nom à partir d’une variété de formats de noms. Sélectionnez un exemple de nom dans le tableau qui suit pour afficher les formules permettant d’extraire les composants de ce nom.

Remarque   Les formules de ces exemples vous paraîtront plus simples à comprendre si vous les copiez dans une feuille de calcul vide.

Comment copier un exemple

  1. Créez un classeur ou une feuille de calcul vide.

  2. Sélectionnez l’exemple de texte et les formules dans le tableau.

    Remarque   Ne sélectionnez pas les en-têtes des lignes ou des colonnes.

    Sélection d’un exemple de l’aide

  3. Appuyez sur Ctrl + C.

  4. Dans la feuille de calcul, sélectionnez la cellule A1 et appuyez sur CTRL+V.

  5. Pour passer de l’affichage des résultats à celui des formules qui ont permis d’obtenir les résultats affichés, appuyez sur Ctrl+` (accent grave) ou, sous l’onglet Formules, dans le groupe Audit des formules, cliquez sur le bouton Afficher les formules.

Exemple de nom

Description

Prénom

Deuxième prénom

Nom

Suffixe

1

Jeff Smith

Aucun deuxième prénom

Jeff

Durand

2

Eric S. Kurjan

Une initiale au milieu

Eric

S.

Kurjan

3

Janaina B. G. Bueno

Deux initiales au milieu

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

Nom en premier suivi d’une virgule

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

Prénom en deux parties

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

Nom en trois parties

Paula

Barreto de Mattos

7

James van Eaton

Nom en deux parties

James

van Eaton

8

Bacon Jr., Dan K.

Nom et suffixe en premier, suivis d’une virgule

Dan

K.

Bacon

Jr.

9

Gary Altman III

Avec suffixe

Gary

Altman

III

10

Mr. Ryan Ihrig

Avec préfixe

Ryan

Ihrig

11

Julie Taft-Rider

Nom avec trait d’union

Julie

Taft-Rider


Exemple 1 : Jeff Smith

Exemple de deux composants seulement : un prénom et un nom. Un seul espace sépare les deux composants.

1

2

A

B

C

Nom complet

Prénom

Nom

Jeff Smith

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute par le premier caractère de la chaîne (J) et se termine au cinquième caractère (l’espace). La formule renvoie cinq caractères dans la cellule A2, en commençant par la gauche.

Formule permettant d’extraire un prénom

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique de l’espace dans la cellule A2, en commençant par la gauche. (5)

Nom

Le nom commence à l’espace, cinq caractères en partant de la droite, et se termine au dernier caractère à droite (h). La formule extrait cinq caractères dans la cellule A2, en commençant par la droite.

Formule permettant d’extraire un nom

Utilisez les fonctions RECHERCHE et NBCAR pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique de l’espace dans la cellule A2, en commençant par la gauche. (5)

Légende 2 Calcule la longueur totale de la chaîne de texte, puis soustrait le nombre de caractères à gauche du premier espace trouvé à l’étape 1. (10 - 5 = 5)


Haut de la page

Exemple 2 : Eric S. Kurjan

Cet exemple montre un nom en trois parties : prénom, deuxième prénom et nom. Un espace sépare chaque composant.

1

2

A

B

C

D

Nom

Prénom (Eric)

Deuxième prénom (S.)

Nom (Kurjan)

Eric S. Kurjan

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=STXT(A2,RECHERCHE(" ",A2,1)+1,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)-RECHERCHE(" ",A2,1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute par le premier caractère à gauche (E) et se termine au cinquième caractère (le premier espace). La formule extrait les cinq premiers caractères dans la cellule A2, en commençant par la gauche.

Formule pour séparer un prénom d’un nom, et une initiale au milieu

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

Deuxième prénom

Le deuxième prénom commence au sixième caractère (S) et se termine à la huitième position (le deuxième espace). Cette formule implique l’imbrication des fonctions RECHERCHE pour rechercher la deuxième instance d’un espace.

La formule extrait trois caractères en partant de la sixième position.

Détails d’une formule pour séparer un prénom, un deuxième prénom et un nom de famille

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (S). Cette position numérique correspond à la position de départ du deuxième prénom. (5 + 1 = 6)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

Ajoute 1 pour trouver la position du caractère après le premier espace (S). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez rechercher la deuxième instance de l’espace. (5 + 1 = 6)

Recherche la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (S). Ce numéro de caractère correspond à la position de fin du deuxième prénom. (8)

Recherche la position numérique de l’espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

Extrait le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustrait le numéro de caractère du premier espace trouvé à l’étape 6. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la sixième position trouvée à l’étape 2. (8 – 5 = 3)

Nom

Le nom commence six caractères en partant de la droite (K) et se termine au premier caractère en partant de la droite (n). Cette formule implique l’imbrication des fonctions RECHERCHE pour rechercher la deuxième et la troisième instance d’un espace (respectivement en cinquième et huitième position en partant de la gauche).

La formule extrait six caractères dans la cellule A2, en commençant par la droite.

La deuxième fonction Recherche dans une formule pour séparer le prénom, le second prénom et le nom

Utilisez la fonction NBCAR et les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique de l’espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (S). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez rechercher la deuxième instance de l’espace. (5 + 1 = 6)

Recherche la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (S) trouvée à l’étape 2. Ce numéro de caractère correspond à la position de fin du deuxième prénom. (8)

Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’à la deuxième instance de l’espace trouvée à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet. (14 - 8 = 6)


Haut de la page

Exemple 3 : Janaina B. G. Bueno

Cet exemple montre un nom comportant deux initiales pour le deuxième prénom. La deuxième et la troisième instance de l’espace séparent les composants.

1

2

A

B

C

D

Nom

Prénom (Janaina)

Deuxième prénom (B. G.)

Nom (Bueno)

Janaina B. G. Bueno

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=STXT(A2,RECHERCHE(" ",A2,1)+1,RECHERCHE(" ",A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1)-RECHERCHE(" ",A2,1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute par le premier caractère à gauche (J) et se termine au huitième caractère (le premier espace). La formule extrait les huit premiers caractères dans la cellule A2, en commençant par la gauche.

Formule pour séparer le prénom, le nom et deux initiales au milieu

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (8)

Deuxième prénom

Le deuxième prénom commence à la neuvième position (B) et se termine à la quatorzième position (au troisième espace). Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la première, la deuxième et la troisième instance d’un espace à la huitième, onzième et quatorzième position.

La formule extrait cinq caractères à partir de la neuvième position.

Formule pour séparer le prénom, le nom et deux initiales au milieu

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (8)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (B). Cette position numérique correspond à la position de départ du deuxième prénom. (8 + 1 = 9)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (8)

Ajoute 1 pour trouver la position du caractère après le premier espace (B). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche de la deuxième instance de l’espace. (8 + 1 = 9)

Recherche le deuxième espace dans la cellule A2, en commençant par la neuvième position (B) trouvée à l’étape 4. (11)

Ajoute 1 pour trouver la position du caractère après le deuxième espace (G). Ce numéro de caractère correspond à la position de départ à partir de laquelle vous souhaitez commencer la recherche du troisième espace. (11 + 1 = 12)

Recherche le troisième espace dans la cellule A2, en commençant par la douzième position trouvée à l’étape 6. (14)

Recherche la position numérique du premier espace dans la cellule A2. (8)

Extrait le numéro de caractère du troisième espace trouvé à l’étape 7 et soustrait le numéro de caractère du premier espace trouvé à l’étape 6. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la neuvième position trouvée à l’étape 2.

Nom

Le nom commence cinq caractères en partant de la droite (B) et se termine au premier caractère en partant de la droite (o). Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la première, deuxième et troisième instance de l’espace.

La formule extrait cinq caractères dans la cellule A2, en commençant par la droite du nom complet.

Formule pour séparer le prénom, le nom et deux initiales au milieu

Utilisez les fonctions RECHERCHE et NBCAR pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (8)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (B). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche de la deuxième instance de l’espace. (8 + 1 = 9)

Recherche le deuxième espace dans la cellule A2, en commençant par la neuvième position (B) trouvée à l’étape 2. (11)

Ajoute 1 pour trouver la position du caractère après le deuxième espace (G). Ce numéro de caractère correspond à la position de départ à partir de laquelle vous souhaitez commencer la recherche de la troisième instance de l’espace. (11 + 1 = 12)

Recherche le troisième espace dans la cellule A2, en commençant par la douzième position (G) trouvée à l’étape 6. (14)

Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au troisième espace trouvé à l’étape 5. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(19 -14 = 5)


Haut de la page

Exemple 4 : Kahn, Wendy Beth

Dans cet exemple, le nom vient avant le prénom et le deuxième prénom apparaît à la fin. La virgule marque la fin du nom et un espace sépare chaque composant du nom.

1

2

A

B

C

D

Nom

Prénom (Wendy)

Deuxième prénom (Beth)

Nom (Kahn)

Kahn, Wendy Beth

=STXT(A2,RECHERCHE(" ",A2,1)+1,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)-RECHERCHE(" ",A2,1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1))

=GAUCHE(A2,RECHERCHE(" ",A2,1)-2)

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute par le septième caractère à gauche (W) et se termine au douzième caractère (deuxième espace). Étant donné que le prénom se trouve au milieu du nom complet, vous devez utiliser la fonction STXT pour extraire le prénom.

La formule extrait six caractères à partir de la septième position.

Formule pour séparer un nom suivi d’un prénom et d’un second prénom

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (W). Cette position numérique correspond à la position de départ du prénom. (6 + 1 = 7)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

Ajoute 1 pour trouver la position du caractère après le premier espace (W). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

Recherche le deuxième espace dans la cellule A2, en commençant par la septième position (W) trouvée à l’étape 4. (12)

Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

Extrait le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustrait le numéro de caractère du premier espace trouvé à l’étape 6. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la septième position trouvée à l’étape 2. (12 - 6 = 6)

Deuxième prénom

Le deuxième prénom commence quatre caractères en partant de la droite (B) et se termine au premier caractère en partant de la droite (h). Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la première et la deuxième instance d’un espace à la sixième et douzième position en partant de la gauche.

La formule extrait quatre caractères, en commençant par la droite.

Formule pour séparer un nom suivi d’un prénom et d’un second prénom

Utilisez les fonctions RECHERCHE et NBCAR pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (W). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

Recherche la deuxième instance de l’espace dans la cellule A2, en commençant par la septième position (W) trouvée à l’étape 2. (12)

Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au deuxième espace trouvé à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(16 -12 = 4)

Nom

Le nom débute par le premier caractère à gauche (K) et se termine au quatrième caractère (n). La formule extrait quatre caractères, en commençant par la gauche.

Formule pour séparer un nom suivi d’un prénom et d’un second prénom

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

Légende 2 Soustrait 2 pour trouver la position numérique du caractère de fin du nom (n). Le résultat correspond au nombre de caractères que la fonction GAUCHE doit extraire. (6 - 2 = 4)


Haut de la page

Exemple 5 : Mary Kay D. Andersen

Exemple de nom en deux parties : Mary Kay. Le deuxième et le troisième espace séparent les deux composants du nom.

1

2

A

B

C

D

Nom

Prénom (Mary Kay)

Deuxième prénom (D.)

Nom (Andersen)

Mary Kay D. Anderson

=GAUCHE(A2, RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1))

=STXT(A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1,RECHERCHE(" ",A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1)-(RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom commence au premier caractère à gauche et se termine au neuvième caractère (le deuxième espace). Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la deuxième instance de l’espace à gauche.

La formule extrait neuf caractères, en commençant par la gauche.

Formule pour séparer un prénom, un second prénom, une initiale au milieu et le nom de famille

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (K). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche de la deuxième instance de l’espace. (5 + 1 = 6)

Recherche la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (K) trouvée à l’étape 2. Le résultat correspond au nombre de caractères extraits par la fonction GAUCHE dans la chaîne de texte. (9)

Deuxième prénom

Le deuxième prénom commence à la neuvième position (D) et se termine à la douzième position (au troisième espace). Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la première, la deuxième et la troisième instance d’un espace.

La formule extrait deux caractères au milieu, à partir de la dixième position.

Formule pour séparer un prénom, un second prénom, une initiale au milieu et le nom de famille

Utilisez les fonctions imbriquées RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par le premier caractère à gauche. (5)

Légende 2 Ajoute 1 pour trouver le caractère après le premier espace (K). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (5 + 1 = 6)

Recherche la position de la deuxième instance de l’espace dans la cellule A2, en commençant par la sixième position (K) trouvée à l’étape 2. Le résultat correspond au nombre de caractères extraits à gauche par la fonction GAUCHE. (9)

Ajoute 1 pour trouver le caractère après le deuxième espace (D). Le résultat correspond à la position de départ du deuxième prénom. (9 + 1 = 10)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du caractère après le deuxième espace (D). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du troisième espace. (10)

Recherche la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du deuxième prénom. (12)

Recherche la position numérique du caractère après le deuxième espace (D). Le résultat indique la position de début du deuxième prénom. (10)

Extrait le numéro de caractère du troisième espace trouvé à l’étape 6 et soustrait le numéro de caractère de la lettre « D » trouvé à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la dixième position trouvée à l’étape 4. (12 -10 = 2)

Nom

Le nom débute huit caractères à droite. Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la première, la deuxième et la troisième instance d’un espace à la cinquième, neuvième et douzième position.

La formule extrait huit caractères à partir de la droite.

Formule pour séparer un prénom, un second prénom, une initiale au milieu et le nom de famille

Utilisez les fonctions RECHERCHE et NBCAR pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

Légende 2 Ajoute 1 pour trouver le caractère après le premier espace (K). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer à rechercher un espace. (5 + 1 = 6)

Recherche le deuxième espace dans la cellule A2, en commençant par la sixième position (K) trouvée à l’étape 2. (9)

Ajoute 1 pour trouver la position du caractère après le deuxième espace (D). Le résultat indique la position de départ du deuxième prénom. (9 + 1 = 10)

Recherche la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du deuxième prénom. (12)

Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au troisième espace trouvé à l’étape 5. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(20 -12 = 8)


Haut de la page

Exemple 6 : Paula Barreto de Mattos

Dans cet exemple, le nom est composé de trois parties : Barreto de Mattos. Le premier espace marque la fin du prénom et le début du nom.

1

2

A

B

D

Nom

Prénom (Paula)

Nom (Barreto de Mattos)

Paula Barreto de Mattos

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute par le premier caractère à gauche (P) et se termine au sixième caractère (le premier espace). La formule extrait six caractères à partir de la gauche.

Formule pour séparer un prénom et un nom de famille composé de trois parties

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Nom

Le nom commence dix-sept caractères en partant de la droite (B) et se termine au premier caractère à droite (s). La formule extrait dix-sept caractères à partir de la droite.

Formule pour séparer un prénom et un nom de famille composé de trois parties

Utilisez les fonctions NBCAR et RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Légende 2 Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au premier espace trouvé à l’étape 1. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(23 - 6 = 17)


Haut de la page

Exemple 7 : James van Eaton

Dans cet exemple, le nom est composé de deux parties : van Eaton. Le premier espace marque la fin du prénom et le début du nom.

1

2

A

B

D

Nom

Prénom (James)

Nom (van Eaton)

James van Eaton

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute par le premier caractère en partant de la gauche (J) et se termine au huitième caractère (le premier espace). La formule extrait six caractères à partir de la gauche.

Formule pour séparer un prénom et un nom de famille composé de deux parties

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Nom

Le nom débute par le neuvième caractère en partant de la droite (v) et se termine au premier caractère en partant de la droite (n). La formule extrait neuf caractères en partant de la droite du nom complet.

Formule pour séparer un prénom et un nom de famille composé de deux parties

Utilisez les fonctions NBCAR et RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Légende 2 Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au premier espace trouvé à l’étape 1. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(15 - 6 = 9)


Haut de la page

Exemple 8 : Bacon Jr., Dan K.

Dans cet exemple, le nom est indiqué en premier, suivi d’un suffixe. La virgule sépare le nom et le suffixe du prénom et de l’initiale du deuxième prénom.

1

2

A

B

C

D

E

Nom

Prénom (Dan)

Deuxième prénom (K.)

Nom (Bacon)

Suffixe (Jr.)

Bacon Jr., Dan K.

=STXT(A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1,RECHERCHE(" ",A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)+1))

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=STXT(A2,RECHERCHE(" ", A2,1)+1,(RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)-2)-RECHERCHE(" ",A2,1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute par le douzième caractère (D) et se termine par le quinzième caractère (le troisième espace). La formule extrait trois caractères à partir de la douzième position.

Formule permettant d’extraire le prénom dans l’exemple 8 : Bacon Jr., Dan K.

Utilisez les fonctions imbriquées RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Légende 2 Ajoute 1 pour trouver le caractère après le premier espace (J). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

Recherche le deuxième espace dans la cellule A2, en commençant par la septième position (J) trouvée à l’étape 2. (11)

Ajoute 1 pour trouver le caractère après le deuxième espace (D). Le résultat correspond à la position de départ du prénom. (11 + 1 = 12)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du caractère après le deuxième espace (D). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du troisième espace. (12)

Recherche la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du prénom. (15)

Recherche la position numérique du caractère après le deuxième espace (D). Le résultat indique la position de début du prénom. (12)

Extrait le numéro de caractère du troisième espace trouvé à l’étape 6 et soustrait le numéro de caractère de la lettre « D » trouvé à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la douzième position trouvée à l’étape 4. (15 - 12 = 3)

Deuxième prénom

Le deuxième prénom commence par le deuxième caractère en partant de la droite (K). La formule extrait deux caractères en partant de la droite.

Formule permettant d’extraire le deuxième prénom dans l’exemple 8 : Bacon Jr., Dan K.

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Légende 2 Ajoute 1 pour trouver le caractère après le premier espace (J). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (6 + 1 = 7)

Recherche le deuxième espace dans la cellule A2, en commençant par la septième position (J) trouvée à l’étape 2. (11)

Ajoute 1 pour trouver le caractère après le deuxième espace (D). Le résultat correspond à la position de départ du prénom. (11 + 1 = 12)

Recherche la position numérique du troisième espace dans la cellule A2, en commençant par la gauche. Le résultat indique la position de fin du deuxième prénom. (15)

Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au troisième espace trouvé à l’étape 5. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(17 -15 = 2)

Nom

Le nom débute au premier caractère en partant de la gauche (B) et se termine au sixième caractère (le premier espace). Par conséquent, la formule extrait six caractères en partant de la gauche.

Formule permettant d’extraire le nom dans l’exemple 8 : Bacon Jr., Dan K.

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Suffixe

Le suffixe débute au septième caractère en partant de la gauche (J) et se termine au neuvième caractère en partant de la gauche. La formule extrait trois caractères, en commençant par le septième caractère.

Formule permettant d’extraire le suffixe dans l’exemple 8 : Bacon Jr., Dan K.

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Légende 2 Ajoute 1 pour trouver le caractère après le premier espace (J). Le résultat correspond à la position de départ du suffixe. (6 + 1 = 7)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Ajoute 1 pour trouver la position numérique du caractère après le premier espace (J). Le résultat correspond au numéro de caractère à partir duquel vous souhaitez commencer à rechercher le deuxième espace. (7)

Recherche la position numérique du deuxième espace dans la cellule A2, en commençant par le septième caractère trouvé à l’étape 4. (11)

Soustrait 1 du numéro de caractère du deuxième espace trouvé à l’étape 4 pour trouver le numéro de caractère de « , ». Le résultat correspond à la position de fin du suffixe. (11 -1 = 10)

et Recherche la position numérique du caractère après le premier espace (J), également trouvé à l’étape 3 et à l’étape 4. (7)

Extrait le numéro de caractère de « , » trouvé à l’étape 6 et soustrait le numéro de caractère de la lettre « J » trouvé à l’étape 3 et à l’étape 4. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la septième position trouvée à l’étape 2. (10 - 7 = 3)


Haut de la page

Exemple 9 : Gary Altman III

Dans cet exemple, le prénom est indiqué au début de la chaîne et le suffixe à la fin du nom. La formule à utiliser pour les composants du nom est similaire à celle utilisée à l’exemple 2. Dans cet exemple, le prénom est extrait avec la fonction GAUCHE, le nom avec la fonction STXT et le suffixe avec la fonction DROITE.

1

2

A

B

C

D

Nom

Prénom (Gary)

Nom (Altman)

Suffixe (III)

Gary Altman III

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=STXT(A2,RECHERCHE(" ",A2,1)+1,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)-(RECHERCHE(" ",A2,1)+1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute au premier caractère en partant de la gauche (G) et se termine au cinquième caractère (le premier espace). Par conséquent, la formule extrait cinq caractères à gauche du nom complet.

Formule pour séparer un prénom, un nom et un titre

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

Nom

Le nom commence au sixième caractère en partant de la gauche (A) et se termine au onzième caractère (le deuxième espace). Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la position des espaces.

La formule extrait six caractères au milieu, à partir du sixième caractère.

Formule pour séparer un prénom, un nom et un titre

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (A). Le résultat indique la position de départ du nom. (5 + 1 = 6)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

Ajoute 1 pour trouver la position du caractère après le premier espace (A). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer à rechercher le deuxième espace. (5 + 1 = 6)

Recherche la position numérique du deuxième espace dans la cellule A2, en commençant par le sixième caractère trouvé à l’étape 4. Ce numéro de caractère correspond à la position de fin du nom. (12)

et Recherche la position numérique du caractère après le premier espace (A), également trouvé à l’étape 3 et à l’étape 4. (6)

Extrait le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustrait le numéro de caractère de la lettre « A » trouvé à l’étape 6 et à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la sixième position trouvée à l’étape 2. (12 - 6 = 6)

Suffixe

Le suffixe débute trois caractères en partant de la droite. Cette formule implique l’imbrication de la fonction RECHERCHE pour trouver la position des espaces.

Formule pour séparer un prénom, un nom et un titre

Utilisez les fonctions RECHERCHE et NBCAR pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (5)

Légende 2 Ajoute 1 pour trouver le caractère après le premier espace (A). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (5 + 1 = 6)

Recherche le deuxième espace dans la cellule A2, en commençant par la sixième position (A) trouvée à l’étape 2. (12)

Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au deuxième espace trouvé à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(15 - 12 = 3)


Haut de la page

Exemple 10 : Mr. Ryan Ihrig

Dans cet exemple, le nom complet est précédé d’un préfixe. Les formules à utiliser pour les composants du nom sont similaires à celles utilisées dans l’exemple 2. Dans cet exemple, le prénom est extrait avec la fonction STXT et le nom avec la fonction DROITE.

1

2

A

B

C

Nom

Prénom (Ryan)

Nom (Ihrig)

Mr. Ryan Ihrig

=STXT(A2,RECHERCHE(" ",A2,1)+1,RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1)-(RECHERCHE(" ",A2,1)+1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,RECHERCHE(" ",A2,1)+1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Nom

Le prénom commence au cinquième caractère en partant de la gauche (R) et se termine au neuvième caractère (le deuxième espace). Cette formule implique l’imbrication de la fonction RECHERCHE pour rechercher la position des espaces.

La formule extrait quatre caractères, en commençant par la cinquième position.

Formule permettant d’extraire le prénom dans l’exemple 10 : Mr. Ryan Ihrig.

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_départ :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (4)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (R). Le résultat indique la position de départ du prénom. (4 + 1 = 5)

Utilisez les fonctions RECHERCHE imbriquées pour rechercher la valeur de no_car :

Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (4)

Ajoute 1 pour trouver la position du caractère après le premier espace (R). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (4 + 1 = 5)

Recherche la position numérique du deuxième espace dans la cellule A2, en commençant par le cinquième caractère trouvé à l’étape 3 et à l’étape 4. Ce numéro de caractère correspond à la position de fin du prénom. (9)

et Recherche la position numérique du caractère après le premier espace (R), également trouvé à l’étape 3 et à l’étape 4. (5)

Extrait le numéro de caractère du deuxième espace trouvé à l’étape 5 et soustrait le numéro de caractère de la lettre « R » trouvé à l’étape 6 et à l’étape 7. Le résultat correspond au nombre de caractères que la fonction STXT extrait de la chaîne de texte en commençant à la cinquième position trouvée à l’étape 2. (9 - 5 = 4)

Nom

Le nom débute cinq caractères en partant de la droite. Cette formule implique l’imbrication de la fonction RECHERCHE pour trouver la position des espaces.

Formule permettant d’extraire le nom dans l’exemple 10 : Mr. Ryan Ihrig.

Utilisez les fonctions RECHERCHE et NBCAR pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (4)

Légende 2 Ajoute 1 pour trouver la position du caractère après le premier espace (R). Le résultat correspond au numéro du caractère à partir duquel vous souhaitez commencer la recherche du deuxième espace. (4 + 1 = 5)

Recherche le deuxième espace dans la cellule A2, en commençant par la cinquième position (R) trouvée à l’étape 2. (9)

Calcule la longueur totale de la chaîne de texte dans la cellule A2 puis soustrait le nombre de caractères en partant de la gauche jusqu’au deuxième espace trouvé à l’étape 3. Le résultat correspond au nombre de caractères extraits à droite du nom complet.(14 - 9 = 5)


Haut de la page

Exemple 11 : Julie Taft-Rider

Dans cet exemple, le nom contient un trait d’union. Un espace sépare chaque composant du nom.

1

2

A

B

C

Nom

Prénom (Julie)

Nom (Taft-Rider)

Julie Taft-Rider

=GAUCHE(A2, RECHERCHE(" ",A2,1))

=DROITE(A2,NBCAR(A2)-RECHERCHE(" ",A2,1))

Remarque   Dans les graphiques suivants, la surbrillance dans le nom complet montre le caractère qui correspond au résultat de la formule RECHERCHE.

Prénom

Le prénom débute au premier caractère en partant de la gauche et se termine à la sixième position (le premier espace). La formule extrait six caractères en partant de la gauche.

Formule permettant d’extraire le prénom dans l’exemple 11 : Julie Taft-Rider

Utilisez la fonction RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique du premier espace dans la cellule A2, en commençant par la gauche. (6)

Nom

Le nom complet commence dix caractères en partant de la droite (T) et se termine au premier caractère en partant de la droite (r).

Formule permettant d’extraire le nom complet dans l’exemple 11 : Julie Taft-Rider

Utilisez les fonctions NBCAR et RECHERCHE pour rechercher la valeur de no_car :

Légende 1 Recherche la position numérique de l’espace dans la cellule A2, en commençant par le premier caractère à gauche. (6)

Légende 2 Calcule la longueur totale de la chaîne de texte à extraire, puis soustrait le nombre de caractères en partant de la gauche jusqu’au premier espace, trouvé à l’étape 1. (16 - 6 = 10)


Haut de la page

S’applique à : Excel 2007



Ces informations vous ont-elles été utiles ?

Oui Non

Comment pouvons-nous nous améliorer ?

255 caractères restants

Afin de protéger votre vie privée, n’indiquez aucune information de contact dans vos commentaires. Lisez notre déclaration de confidentialité.

Nous vous remercions pour vos commentaires.

Ressources de support

Changer la langue