Fonction TEXTE

Contributeurs : Alexandre « Alex » Chauvin Blaise Richer

La fonction TEXTE vous permet de modifier la manière dont un nombre est affiché en lui appliquant une mise en forme qui utilise des codes de format. Cela peut vous être utile lorsque vous souhaitez afficher des nombres dans un format plus lisible, ou quand vous souhaitez combiner des nombres à du texte ou des symboles.

Remarque : Étant donné que la fonction TEXTE convertit les nombres en texte, vous risquez de rencontrer des difficultés pour y faire référence dans des calculs futurs. Aussi, nous vous conseillons de conserver la valeur d’origine dans une cellule, puis d’utiliser la fonction TEXTE dans une autre cellule. Ensuite, si vous avez besoin de créer d’autres formules, faites référence à la valeur d’origine et non au résultat de la fonction TEXTE.

Syntaxe

TEXTE(valeur; format_texte)

La syntaxe de la fonction TEXTE utilise les arguments suivants :

Nom de l’argument

Description

valeur

Valeur numérique à convertir en texte.

format_texte

Chaîne de texte qui définit la mise en forme que vous souhaitez appliquer à la valeur fournie.

Vue d’ensemble

Dans sa forme la plus simple, la fonction TEXTE a la signification suivante :

  • =TEXTE(valeur à mettre en forme; "Code de format à appliquer")

Voici quelques exemples courants que vous pouvez copier directement dans Excel pour tester la fonction par vous-même. Notez que les codes de format sont placés entre guillemets.

Formule

Description

=TEXTE(1234,567;"# ##0,00 €")

Devise avec un séparateur des milliers et 2 décimales : 1 234,57 €. Notez qu’Excel arrondit la valeur à 2 décimales.

=TEXTE(AUJOURDHUI();"JJ/MM/AA")

Date du jour au format JJ/MM/AA (par exemple, 14/03/12)

=TEXTE(AUJOURDHUI();"JJJJ")

Date du jour de la semaine (par exemple, Lundi)

=TEXTE(MAINTENANT();"HH:MM")

Heure actuelle (par exemple, 13:29)

=TEXTE(0,285;"0,0 %")

Pourcentage (par exemple, 28,5 %)

=TEXTE(4,34 ;"# ?/?")

Fraction (par exemple, 4 1/3)

=SUPPRESPACE(TEXTE(0,34;"# ?/?"))

Fraction (par exemple, 1/3) Notez que cette formule utilise la fonction SUPPRESPACE pour supprimer l’espace de début dans le cas d’une valeur décimale.

=TEXTE(12200000;"0,00E+00")

Notation scientifique (par exemple, 1,22E+07)

=TEXTE(1234567898;"[<=9999999]###-####;(###) ###-####")

Spécial (numéro de téléphone) (par exemple, (123) 456-7898)

=TEXTE(1234;"0000000")

Ajouter des zéros (0) de début (par exemple, 0001234)

=TEXTE(123456;"##0° 00' 00''")

Personnalisée - Latitude/Longitude

Remarque : bien que vous puissiez utiliser la fonction TEXTE pour modifier la mise en forme, ce n’est pas la seule corde à votre arc. Vous pouvez modifier le format sans utiliser de formule en appuyant sur Ctrl+1 (ou Image de l’icône du bouton Cmd sur Mac +1 sur Mac), puis en choisissant le format souhaité dans la boîte de dialogue Format de cellule > Nombre.

Télécharger nos exemples

Vous pouvez télécharger un exemple de classeur contenant entre autres tous les exemples de fonctions TEXTE que vous trouverez dans cet article. Vous pouvez les réutiliser, ou créer vos propres codes de format de fonction TEXTE.

Télécharger les exemples de fonctions TEXTE Excel

Autres codes de format disponibles

Vous pouvez utiliser la boîte de dialogue Format de cellule pour rechercher les autres codes de format disponibles :

  1. Appuyez sur Ctrl+1 ( Image de l’icône du bouton Cmd sur Mac +1 sur Mac) pour ouvrir la boîte de dialogue Format de cellule.

  2. Sélectionnez le format à utiliser dans l’onglet Nombre.

  3. Sélectionnez l’option Personnalisée.

  4. Le code de format que vous voulez utiliser n’est pas affiché dans la zone Type. Dans ce cas, sélectionnez tout le contenu de la zone Type à l’exception du point-virgule (;) et du symbole @. Dans l’exemple ci-dessous, nous avons sélectionné et copié simplement jj/mm/aa.

  5. Appuyez sur Ctrl+C pour copier le code de format, puis appuyez sur Annuler pour fermer la boîte de dialogue Format de cellule.

  6. À présent, il vous suffit d’utiliser le raccourci Ctrl+V pour coller le code de format dans votre formule TEXTE, par exemple : =TEXTE(B2;"jj/mm/aa"). Veillez à coller le code de format entre guillemets ("code de format"), sinon Excel génère un message d’erreur.

Exemple d’utilisation de la boîte de dialogue Format > Cellules > Nombre > Personnalisée pour qu’Excel crée des chaînes de format automatiquement.

Codes de format par catégorie

Voici quelques exemples de la manière dont vous pouvez appliquer différents formats de nombre à vos valeurs à l’aide de la boîte de dialogue Format de cellule, puis utiliser l’option Personnalisée pour copier ces codes de format dans votre fonction TEXTE.

Pourquoi Excel supprime mes zéros non significatifs ?

Excel est programmé pour rechercher les nombres entrés dans les cellules, et non les nombres qui ressemblent à du texte, tels que des références ou des numéros d’article. Pour conserver les zéros non significatifs, mettez en forme la plage d’entrée en tant que texte avant de coller ou d’entrer des valeurs. Sélectionnez la colonne ou plage dans laquelle vous allez placer les valeurs, puis utilisez le raccourci Ctrl+1 pour ouvrir la boîte de dialogue Format de cellule. Dans l’onglet Nombre, sélectionnez Texte. Excel conservera désormais les zéros non significatifs.

Si vous avez déjà entré des données et qu’Excel a supprimé vos zéros non significatifs, vous pouvez utiliser la fonction TEXTE pour les rajouter. Vous pouvez référencer la cellule supérieure avec les valeurs, utiliser =TEXTE(valeur;"00000"), où le nombre de zéros dans la formule représente le nombre total de caractères souhaité, puis copier-coller dans le reste de la plage.

Exemples d’utilisation de la fonction TEXTE pour mettre en forme les zéros non significatifs : =TEXTE(A2;"00000")

Si, pour une raison quelconque, vous devez reconvertir des valeurs de texte en nombres, vous pouvez effectuer une multiplication avec le facteur 1 (par exemple, =D4*1), ou utiliser le double opérateur unaire (--) (par exemple, =--D4).

Excel sépare les milliers à l’aide d’espaces si le format contient un espace placé entre des signes (#) ou des zéros. Par exemple, si la chaîne de format est "# ###", Excel affiche le nombre 12200000 sous la forme 12 200 000.

Si vous placez un espace à la suite d’un espace réservé de nombre, cela a pour effet de diviser le nombre par 1 000. Par exemple, si la chaîne de format est "# ###,0,", Excel affiche le nombre 12200000 sous la forme 12 200,0.

Exemples de fonction TEXTE qui utilise le séparateur des milliers

Remarques : 

  • Le séparateur des milliers dépend de vos paramètres régionaux. Aux États-Unis, il s’agit d’une virgule, mais dans d’autres pays/régions, il peut s’agir d’un point (.).

  • Le séparateur des milliers est disponible pour les formats Nombre, Monétaire et Comptabilité.

Voici des exemples de formats Nombre (séparateur des milliers et décimales uniquement), Monétaire et Comptabilité standard. Le format Monétaire vous permet d’insérer le symbole de devise de votre choix et de l’aligner en regard de votre valeur, tandis que le format Comptabilité aligne le symbole de devise à gauche de la cellule et la valeur à droite de la cellule. Notez la différence entre les codes de format Monétaire et Comptabilité ci-dessous, où le format Comptabilité utilise un astérisque (*) pour créer une séparation entre le symbole et la valeur.

Exemples de la fonction TEXTE avec les formats Nombre, Monétaire et Comptabilité

Pour trouver le code de format applicable à un symbole monétaire, appuyez tout d’abord sur Ctrl+1 (ou Image de l’icône du bouton Cmd sur Mac +1 sur Mac), sélectionnez le format de votre choix, puis sélectionnez un symbole dans la liste déroulante Symbole :

Sélection du symbole monétaire dans la boîte de dialogue Format de cellule

Cliquez ensuite sur Personnalisée dans la section Catégorie située à gauche, puis copiez le code de format, avec le symbole monétaire.

Fonction TEXTE - Devise personnalisée avec symbole

Remarque : La fonction TEXTE ne prend pas en charge la mise en forme des couleurs. Par conséquent, si vous copiez un code de format de nombre qui inclut une couleur à partir de la boîte de dialogue Format de cellule (par exemple, # ##0,00_ €);[Rouge](# ##0,00 €)), la fonction TEXTE acceptera le code de format, mais sans afficher la couleur.

Vous pouvez modifier la façon dont une date est affichée à l’aide d’une combinaison des valeurs « M » pour le mois, « J » pour le jour et « A » pour l’année.

Codes de format Mois, Jour et Année

Les codes de format inclus dans la fonction TEXTE ne respectent pas la casse. Vous pouvez donc utiliser indifféremment « J » ou « j », « M » ou « m », « A » ou « a ».

MVP Excel Mynda Treacy

Mynda recommande...

Si vous partagez des fichiers et des rapports Excel avec des utilisateurs issus de différents pays, vous souhaiterez peut-être leur fournir un rapport dans leur langue. Excel MVP, Mynda Treacy propose une solution idéale dans cet article Dates Excel affichées dans différentes langues. Il contient également un exemple de classeur que vous pouvez télécharger.

Vous pouvez modifier la façon dont l’heure est affichée à l’aide d’une combinaison des valeurs « H » pour l’heure, « M » pour les minutes, « S » pour les secondes, et « AM/PM » pour un format horaire sur 12 heures.

Formats pour les heures, minutes et secondes

Si vous omettez « AM/PM » ou « A/P », l’heure est affichée selon un format horaire sur 24 heures.

Les codes de format inclus dans la fonction TEXTE ne respectent pas la casse. Vous pouvez donc utiliser indifféremment « H » ou « h », « M » ou « m », « S » ou « s », « AM/PM » ou « am/pm ».

Vous pouvez modifier la façon dont les valeurs décimales sont affichées avec des formats de pourcentage (%).

Codes de format pour les pourcentages

Vous pouvez modifier la façon dont les valeurs décimales sont affichées avec des formats de fraction (?/?).

Codes de format pour les fractions

La notation scientifique est une manière d’afficher les nombres en termes de décimale comprise entre 1 et 10, multipliée à une puissance de 10. Elle est souvent utilisée pour raccourcir la manière dont les grands nombres sont affichés.

Codes de format pour la notation Scientifique

Excel propose 4 formats spéciaux :

  • Code postal - « 00000 »

  • Code postal + 4 - « 00000-0000 »

  • Numéro de téléphone - « [<=9999999]###-####;(###) ###-#### »

  • Numéro de sécurité sociale - « 0000-00-0000 »

Formats spéciaux pour la fonction TEXTE

Les formats spéciaux sont différents en fonction du pays ou de la région, mais si aucun format spécial n’est disponible pour vos paramètres régionaux, ou s’ils ne répondent pas à vos besoins, vous pouvez créer les vôtres via la boîte de dialogue Format de cellule > Personnalisée.

Scénario courant

La fonction TEXTE est rarement utilisée toute seule. Elle est souvent utilisée conjointement avec d’autres éléments. Supposons que vous vouliez combiner du texte et une valeur numérique, par exemple « Rapport imprimé le : 14/03/12 », ou « Chiffre d’affaires hebdomadaire : 66 348,72 € ». Vous pouvez entrer cette chaîne dans Excel manuellement, mais cela irait à l’encontre de l’objectif qui est qu’Excel le fasse à votre place. Malheureusement, lorsque vous combinez du texte et des nombres mis en forme, tels que des dates, des heures, des devises, etc., Excel ne sait pas comment vous voulez les afficher et supprime le format de nombre. C’est là que la fonction TEXTE est utile, car elle permet de forcer Excel à mettre en forme les valeurs comme vous le souhaitez en utilisant un code de format, tel que « JJ/MM/AA » pour le format de date.

L’exemple suivant illustre ce qui se passe si vous essayez d’assembler du texte et un nombre sans utiliser la fonction TEXTE. Dans ce cas, nous utilisons l’esperluette (&) pour concaténer une chaîne de texte, un espace («   ») et une valeur avec =A2&" "&B2.

Exemple d’union de texte sans la fonction TEXTE

Comme vous le constatez, Excel a supprimé la mise en forme de la date dans la cellule B2. Dans le prochain exemple, vous découvrirez comment la fonction TEXTE vous permet d’appliquer le format de votre choix.

Exemple d’union de texte avec la fonction TEXTE

Notre formule mise à jour est :

  • Cellule C2 : =A2&" "&TEXTE(B2,"jj/mm/aa") - Format de date

Forum aux questions

Ce n’est malheureusement pas possible avec la fonction TEXTE. Pour cela, vous devez utiliser du code Visual Basic pour Applications (VBA). L’article suivant décrit une méthode : Comment faire pour convertir une valeur numérique en mots français dans Excel

Oui. Vous pouvez utiliser les fonctions MAJUSCULE, MINUSCULE et NOMPROPRE à cet effet. Par exemple, =MAJUSCULE("bonjour") renvoie « BONJOUR ».

Oui, mais quelques étapes sont nécessaires. Tout d’abord, sélectionnez les cellules dans lesquelles cela doit se produire et utilisez le raccourci Ctrl+1 pour ouvrir la boîte de dialogue Format de cellule, puis sélectionnez l’option Alignement > Contrôle du texte > Renvoyer à la ligne automatiquement. Ensuite, ajustez votre fonction TEXTE finalisée en incluant la fonction ASCII CHAR(10) à l’emplacement où vous souhaitez insérer le saut de ligne. Il se peut que vous deviez ajuster la largeur de votre colonne en fonction de la façon dont le résultat final s’aligne.

Exemple d’utilisation de la fonction TEXTE avec CAR(10) pour insérer un saut de ligne. ="Nous sommes le : "&CAR(10))&TEXTE(AUJOURDHUI();"JJ/MM/AA")

Dans ce cas, nous avons utilisé : ="Nous sommes aujourd’hui le : "&CHAR(10)&TEXTE(AUJOURDHUI();"jj/mm/aa")

Il s’agit de la notation scientifique. Excel convertit automatiquement les nombres de plus de 12 chiffres si une ou plusieurs cellules utilisent le format Standard et ceux de plus de 15 chiffres si une ou plusieurs cellules utilisent le format Nombre. Si vous avez besoin d’entrer de longues chaînes numériques, mais que vous ne souhaitez pas les convertir, nous vous conseillons de mettre en forme les cellules en question sous forme de texte avant d’entrer ou de coller vos valeurs dans Excel.

MVP Excel Mynda Treacy

Mynda recommande...

Si vous partagez des fichiers et des rapports Excel avec des utilisateurs issus de différents pays, vous souhaiterez peut-être leur fournir un rapport dans leur langue. Excel MVP, Mynda Treacy propose une solution idéale dans cet article Dates Excel affichées dans différentes langues. Il contient également un exemple de classeur que vous pouvez télécharger.

Voir aussi

Créer ou supprimer un format de nombre personnalisé

Convertir le texte en nombres

Toutes les fonctions Excel (par catégorie)

Développez vos compétences
Découvrez des formations
Accédez aux nouvelles fonctionnalités en avant-première
Rejoignez le programme Office Insider

Ces informations vous ont-elles été utiles ?

Nous vous remercions pour vos commentaires.

Merci pour vos commentaires. Il serait vraisemblablement utile pour vous de contacter l’un de nos agents du support Office.

×