Fonction SOMME

La fonction SOMME, une des fonctions mathématiques et trigonométriques, permet d’additionner des valeurs. Vous pouvez ajouter des valeurs individuelles, des références ou des plages de cellules, ou une combinaison des trois.

Par exemple :

  • =SOMME(A2:A10)

  • =SOMME(A2:A10; C2:C10)

Votre navigateur ne prend pas en charge la vidéo. Installez Microsoft Silverlight, Adobe Flash Player ou Internet Explorer 9.

Cette vidéo fait partie d’un cours de formation intitulé Ajouter des nombres dans Excel 2013.

En savoir plus sur l’ajout de formules et de fonctions

Développez vos connaissances des formules et des fonctions avec LinkedIn Learning. Apprenez à utiliser la fonction SOMME pour additionner tous les nombres figurant dans une plage de cellules.

Regarder gratuitement un aperçu >

SOMME(nombre1;[nombre2];...)

Argument

Description

nombre1    (obligatoire)

Premier nombre à additionner. Le nombre peut être un 4, une référence de cellule comme B6 ou une plage de cellules comme B2:B8.

nombre2-255    (facultatif)

Il s’agit du deuxième nombre à additionner. Vous pouvez spécifier jusqu’à 255 nombres de cette façon.

Pour connaître rapidement la somme d’une plage de cellules, il vous suffit de sélectionner la plage et de jeter un coup d’œil dans le coin inférieur droit de la fenêtre d’Excel.

Capture d’écran de la sélection d’une plage de cellules, puis recherche dans la barre d’état
Barre d’état


Ceci est la barre d’état. Elle affiche des informations concernant les éléments que vous avez sélectionnés (cellule unique ou plusieurs cellules). Si vous cliquez avec le bouton droit sur la barre d’état, une boîte de dialogue de fonctionnalité s’affiche et contient toutes les options que vous pouvez sélectionner. Notez qu’elle affiche également les valeurs de la plage sélectionnée si vous avez coché ces attributs. En savoir plus sur la barre d’état.

La manière la plus simple d’ajouter une formule SOMME à votre feuille de calcul est d’utiliser l’Assistant Somme automatique. Sélectionnez une cellule vide directement au-dessus ou en dessous de la plage à additionner, puis dans l’onglet Accueil ou Formules du ruban, appuyez sur Somme automatique > Somme. L’Assistant Somme automatique détecte automatiquement la plage à additionner et crée la formule pour vous. Il peut également fonctionner de manière horizontale si vous sélectionnez une cellule à gauche ou à droite de la plage à additionner. Notez qu’il ne fonctionne pas sur des plages non contiguës, mais nous aborderons le sujet dans la section suivante.

Vous pouvez utiliser l’Assistant Somme automatique pour créer automatiquement une formule SOMME.  Sélectionnez une plage au-dessus/en dessous ou à gauche/à droite de la plage à additionner et accédez à l’onglet Formules du ruban, puis sélectionnez Somme automatique et Somme.
Utiliser l’Assistant Somme automatique pour additionner des plages contiguës


La boîte de dialogue Somme automatique vous permet également de sélectionner d’autres fonctions courantes telles que :

Somme automatique de manière verticale

La cellule B6 affiche la formule SOMME via la fonctionnalité Somme automatique : =SOMME(B2:B5)

L’Assistant Somme automatique a détecté automatiquement les cellules B2:B5 en tant que plage à additionner. Il vous suffit d’appuyer sur Entrée pour la confirmer. Si vous devez ajouter/exclure d’autres cellules, maintenez la touche Maj enfoncée et appuyez sur les touches de direction de votre choix jusqu’à ce que la sélection vous convienne, puis appuyez sur Entrée lorsque vous avez terminé.

Repère de fonction IntelliSense : la balise flottante SOMME(nombre1,[nombre2], …) s’affichant sous la fonction est son repère IntelliSense. Si vous cliquez sur SOMME ou le nom de la fonction, il se transforme en lien hypertexte bleu, via lequel vous pouvez accéder à la rubrique d’aide correspondant à cette fonction. Si vous cliquez sur les éléments individuels de la fonction, leur partie représentative dans la formule sera mise en surbrillance. Dans ce cas uniquement, la plage B2:B5 serait mise en surbrillance, car cette formule ne contient qu’une référence de nombre. La balise IntelliSense s’affiche pour n’importe quelle fonction.

Somme automatique de manière horizontale

La cellule D2 affiche la formule SOMME via la fonctionnalité Somme automatique : =SOMME(B2:C2)

Utilisation de SOMME avec des plages non contiguës.  La cellule incluse dans la cellule C8 est =SOMME(C2:C3,C5:C6). Vous pouvez également utiliser des plages nommées de sorte que la formule soit =SOMME(Semaine1,Semaine2).

L’Assistant Somme automatique ne fonctionne généralement qu’avec des plages contiguës. Si vous avez des lignes ou des colonnes vides dans la plage de somme, Excel s’arrête à la première cellule vide. Dans ce cas, vous devez utiliser la fonction SOMME avec une sélection, où vous ajoutez les plages individuelles une par une. Dans cet exemple, si vous aviez des données dans la cellule B4, Excel générerait la formule =SOMME(C2:C6), car le programme reconnaîtrait une plage contiguë.

Vous pouvez sélectionner plusieurs plages non contiguës en utilisant le raccourci Ctrl+Clic gauche. Tout d’abord, entrez « =SOMME( », puis sélectionnez les plages de votre choix ; Excel ajoute automatiquement un séparateur de virgule entre les plages. Appuyez sur Entrée lorsque vous avez terminé.

CONSEIL : vous pouvez utiliser Alt+= pour ajouter en un clin d’œil la fonction SOMME à une cellule. Il vous suffit ensuite de sélectionner la ou les plages.

Remarque : notez la manière dont Excel a mis en surbrillance les différentes plages de la fonction en utilisant des couleurs, lesquelles sont également utilisées dans la formule elle-même, c’est-à-dire que C2:C3 est d’une couleur et C5:C6 d’une autre couleur. Excel agit de la sorte pour toutes les fonctions, sauf si la plage référencée se trouve dans une autre feuille de calcul ou un autre classeur. Pour optimiser l’accessibilité avec des technologies d’assistance, vous pouvez utiliser des plages nommées, telles que « Semaine1 », « Semaine2 », etc., puis les référencer dans votre formule :

=SOMME(Semaine1,Semaine2)

Vous pouvez facilement effectuer des opérations mathématiques dans Excel, seules ou conjointement avec des fonctions Excel telles que SOMME. Le tableau suivant répertorie les opérateurs que vous pouvez utiliser, conjointement avec certaines fonctions associées. Vous pouvez entrer les opérateurs à partir de la ligne des chiffres sur votre clavier ou à l’aide du pavé numérique à 10 chiffres si vous en avez un. Par exemple, Maj+8 insère l’astérisque (*) utilisé dans une multiplication.

Opérateur

Opération

Exemples

+

Addition

=1+1

=A1+B1

=SOMME(A1:A10)+10

=SOMME(A1:A10)+B1

-

Soustraction

=1-1

=A1-B1

=SOMME(A1:A10)-10

=SOMME(A1:A10)-B1

*

Multiplication

=1*1

=A1*B1

=SOMME(A1:A10)*10

=SOMME(A1:A10)*B1

=PRODUIT(1,1) - Fonction PRODUIT

/

Division

=1/1

=A1/B1

=SOMME(A1:A10)/10

=SOMME(A1:A10)/B1

=QUOTIENT(1,1) - Fonction QUOTIENT

^

Exposant

=1^1

=A1^B1

=SOMME(A1:A10)^10

=SOMME(A1:A10)^B1

=PUISSANCE(1,1) - Fonction PUISSANCE

Pour plus d’informations, voir Utiliser Excel en tant que calculatrice.

Autres exemples

  1. Imaginons que vous voulez appliquer un pourcentage de remise à une plage de cellules que vous avez additionnées.

    Utilisation d’opérateurs avec SOMME.  La formule incluse dans la cellule B16 est =SOMME(A2:A14)*-25%.  La formule aurait été construite correctement si -25% était une référence de cellule, par exemple, =SOMME(A2:A14)*E2
    • =SOMME(A2:A14)*-25%

    Le résultat obtenu représente 25 % de la plage additionnée. Toutefois, cela code en dur les 25 % dans la formule et cela peut compliquer leur recherche ultérieure si vous avez besoin de les modifier. Nous vous conseillons plutôt de placer les 25 % dans une cellule et de référencer celle-ci. Vous pourrez ainsi la modifier facilement, comme suit :

    • =SOMME(A2:A14)*E2

    Pour effectuer une division au lieu d’une multiplication, il vous suffit de remplacer le symbole « * » par « / » : =SOMME(A2:A14)/E2

  2. Addition ou soustraction à partir d’une fonction SOMME

    i. Vous pouvez facilement additionner ou soustraire des nombres dans une fonction SOMME à l’aide de l’opérateur + ou -, comme suit :

    • =SOMME(A1:A10)+E2

    • =SOMME(A1:A10)-E2

Cette section vous présente quelques recommandations pour l’utilisation de la fonction SOMME, qui peuvent également être appliquées à d’autres fonctions.

Méthode =1+2 ou =A+B - Bien que vous puissiez entrer =1+2+3 ou =A1+B1+C2 et obtenir des résultats précis, ces méthodes sont sujettes à des erreurs, et ce pour plusieurs raisons :

  1. Fautes de frappe - Imaginez que vous deviez entrer des valeurs longues telles que celle-ci :

    • =14598,93+65437,90+78496,23

    Essayez ensuite de vérifier l’exactitude de vos entrées. Nous vous conseillons de placer ces valeurs dans des cellules individuelles et d’utiliser une formule SOMME. De plus, vous pouvez mettre en forme les valeurs quand elles se trouvent dans des cellules, ce qui les rend ensuite beaucoup plus lisibles lorsqu’elles sont incluses dans une formule.

    Utilisez la fonction SOMME au lieu de valeurs codées de manière irréversible dans les formules.  La formule incluse dans la cellule D5 est =SOMME(D2:D4)
  2. Erreurs #VALEUR! générées suite au référencement de texte plutôt que de nombres

    Si vous utilisez une formule telle que :

    • =A1+B1+C1 ou =A1+A2+A3

    Exemple d’une construction de formule incorrecte.  La formule incluse dans la cellule D2 est =A2+B2+C2

    Votre formule peut être incorrecte si les cellules référencées incluent des valeurs non numériques (texte) et renvoyer une erreur #VALEUR!. La fonction SOMME ignore les valeurs de texte et calcule la somme des valeurs numériques uniquement.

    Construction adéquate des formules.  Au lieu de =A2+B2+C2, la formule incluse dans la cellule D2 est =SOMME(A2:C2)
  3. Erreur #REF! générée suite à la suppression de lignes ou de colonnes

    Erreur #REF! causée par la suppression d’une colonne.  La formule a changé en =A2+#REF!+B2

    Si vous supprimez une ligne ou une colonne, la formule ne se mettra pas à jour de manière à exclure la ligne ou la colonne supprimée et renverra une erreur #REF!, tandis qu’une fonction SOMME sera mise à jour automatiquement.

    La fonction SOMME s’ajuste automatiquement en fonction des lignes ou des colonnes insérées ou supprimées
  4. Les formules ne mettront pas à jour les références lors de l’insertion de lignes ou de colonnes

    Les formules =A+B+C ne sont pas mises à jour si vous ajoutez des lignes

    Si vous insérez une ligne ou une colonne, la formule ne sera pas mise à jour de manière à inclure la ligne ajoutée, tandis qu’une fonction SOMME sera mise à jour automatiquement (tant que vous n’êtes pas hors de la plage référencée dans la formule). Ce point est particulièrement important si vous vous attendez à ce que votre formule soit mise à jour et que ce n’est pas le cas, et votre résultat sera incorrect.

    Exemple illustrant une formule SOMME qui s’est développée automatiquement de =SOMME(A2:C2) en =SOMME(A2:D2) lorsqu’une colonne a été insérée
  5. SOMME utilisé avec des références de cellules individuelles et des plages

    En utilisant une formule telle que :

    • =SOMME(A1,A2,A3,B1,B2,B3)

    Pour les mêmes raisons, cette formule est également sujette à des erreurs lors de l’insertion ou de la suppression de lignes au sein de plage référencée. Nous vous conseillons d’utiliser des plages individuelles, par exemple :

    • =SOMME(A1:A3;B1:B3)

    Qui seront mises à jour lors de l’ajout ou de la suppression de lignes.

  1. Vous pouvez combiner SOMME à d’autres fonctions. Voici un exemple qui permet de créer un calcul de moyenne mensuelle :

    Utilisation de SOMME avec d’autres fonctions.  La formule incluse dans la cellule M2 est =SOMME(A2:L2)/NBVAL(A2:L2) .  Remarque : les colonnes Mai-Novembre sont masquées dans un souci de clarté.
    • =SOMME(A2:L2)/NBVAL(A2:L2)

  2. Cette formule calcule la SOMME de la plage A2:L2, puis divise le résultat obtenu par le nombre de cellules non vides en A2:L2 (les cellules de mai à décembre sont vides).

  1. Parfois, vous devez additionner une cellule spécifique sur plusieurs feuilles de calcul. Il peut être tentant de cliquer sur chaque feuille et la cellule de votre choix et d’utiliser simplement le signe « + » pour additionner les valeurs des cellules. Toutefois, ce procédé est fastidieux et peut être sujet à des erreurs.

    • =Feuil1!A1+Feuil2!A1+Feuil3!A1

    Vous pouvez effectuer ce calcul plus simplement avec une SOMME 3D (3 dimensions) :

    SOMME 3D - La formule incluse dans la cellule D2 est =SOMME(Feuil1:Feuil3!A2)
    • SOMME(Feuil1:Feuil3!A1)

    Cela additionne la cellule A1 dans toutes les feuilles de la plage Feuille 1 à Feuille 3.

    C’est particulièrement utile dans les cas où vous avez une seule feuille pour chaque mois (Janvier-Décembre) et où vous avez besoin d’effectuer un addition sur une feuille récapitulative.

    SOMME 3D entre feuilles nommées.  La formule incluse en D2 est =SOMME(Janvier:Décembre!A2)
    • =SOMME(Janvier:Décembre!A2)

    Cette formule additionne la cellule A2 dans chaque feuille pour la plage Janvier à Décembre.

    Remarques : Si vos feuilles de calcul comportent des espaces dans leur nom, par exemple, « Ventes du mois de janvier », vous devez utiliser une apostrophe lors du référencement des noms des feuilles dans une formule : Notez l’apostrophe AVANT le nom de la première feuille de calcul, puis de nouveau APRÈS la dernière.

    • =SOMME('Ventes du mois de janvier:Ventes du mois de décembre'!A2)

    La méthode 3D fonctionne également avec d’autres fonctions, telles que MOYENNE, MIN, MAX, etc. :

    • =MOYENNE(Feuil1:Feuil3!A1)

    • =MIN(Feuil1:Feuil3!A1)

    • =MAX(Feuil1:Feuil3!A1)

Problème

Cause

Ma fonction SOMME affiche #####, et non le résultat.

Vérifiez la largeur des colonnes. La valeur ##### indique généralement que la colonne est trop étroite pour afficher le résultat de la formule.

Ma fonction SOMME affiche la formule elle-même sous forme de texte, et non le résultat.

Vérifiez que la cellule n’est pas mise en forme en tant que texte. Sélectionnez la cellule ou plage en question et utilisez Ctrl+1 pour ouvrir la boîte de dialogue Format de cellule, puis cliquez sur l’onglet Nombre et sélectionnez le format souhaité. Si la cellule a été mise en forme en tant que texte et qu’elle ne change pas lorsque vous modifiez le format, vous devrez peut-être utiliser F2 > Entrée pour forcer la modification du format.

Ma fonction SOMME ne se met pas à jour.

Vérifiez que l’option Calcul est définie sur Automatique. Dans l’onglet Formule, accédez à Options de calcul. Vous pouvez également utiliser F9 pour forcer la feuille de calcul à effectuer le calcul.

Vérifiez que l’option Calcul est définie sur Automatique. Dans l’onglet Formule, accédez à Options de calcul.

Certaines valeurs ne sont pas additionnées.

Seules les valeurs numériques dans la référence ou la plage de la fonction peuvent être additionnées. Les cellules vides, les valeurs logiques comme VRAI ou le texte sont ignorés.

L’erreur #NOM? apparaît à la place du résultat attendu.

Cela signifie généralement que la formule est mal orthographiée, par exemple, =some(A1:A10) au lieu de =SOMME(A1:A10).

Ma fonction SOMME affiche un nombre entier alors qu’elle devrait afficher des décimales

Vérifiez la mise en forme de votre cellule pour vous assurer que vous affichez les décimales. Sélectionnez la cellule ou plage en question et utilisez Ctrl+1 pour ouvrir la boîte de dialogue Format de cellule, puis cliquez sur l’onglet Nombre et sélectionnez le format souhaité, en vous assurant d’indiquer le nombre de décimales voulu.

  1. Je souhaite simplement additionner/soustraire/multiplier/diviser des nombres - Regardez cette série de vidéos sur les opérations mathématiques de base dans Excel ou consultez la rubrique Utiliser Excel comme une calculatrice.

  2. Comment afficher plus ou moins de décimales ? Vous pouvez modifier le format de nombre. Sélectionnez la cellule ou plage en question et utilisez Ctrl+1 pour ouvrir la boîte de dialogue Format de cellule. Cliquez sur l’onglet Nombre et sélectionnez le format de votre choix, en vous assurant d’indiquer le nombre de décimales voulu.

  3. Comment additionner ou soustraire des heures ? Vous pouvez additionner et soustraire des heures de plusieurs manières. Par exemple, lors du calcul de la paie, pour obtenir la différence entre 08h00 et 12h00, vous utilisez la formule suivante : =("12:00"-"08:00")*24, soit la différence entre l’heure de fin et l’heure de début. Notez qu’Excel calcule les heures en tant que fraction d’une journée, c’est pourquoi vous devez multiplier par 24 pour obtenir le nombre total d’heures. Dans le premier exemple, nous utilisons =((B2-A2)+(D2-C2))*24 pour calculer la somme des heures comprises entre le début et la fin d’une journée, moins le temps consacré à une pause-déjeuner (8,50 heures au total).

    Si vous additionnez simplement des heures et des minutes et souhaitez les afficher de cette manière, vous pouvez effectuer une addition. Dans ce cas, vous n’avez pas besoin de multiplier le résultat obtenu par 24. Dans le deuxième exemple, nous utilisons la formule =SOMME(A6:C6) étant donné que nous souhaitons simplement calculer le nombre total d’heures et de minutes consacrées aux tâches attribuées (5h36, soit 5 heures et 36 minutes).

    Calculer des heures

    Pour plus d’informations, consultez : Additionner ou soustraire des heures

  4. Comment obtenir la différence entre des dates ? Comme pour les heures, vous pouvez additionner et soustraire des dates. Voici un exemple courant de calcul du nombre de jours entre deux dates. Il suffit d’utiliser la formule =B2-A2. Pour travailler avec des heures et des dates, il est important de commencer par Date/Heure de fin et de soustraire la Date/Heure de début.

    Calculer la différence entre des dates

    Pour découvrir d’autres façons de travailler avec des dates, voir : Calculer le nombre de jours entre deux dates

  5. Comment additionner les cellules visibles uniquement ? Parfois, lorsque vous masquez manuellement des lignes ou lorsque vous utilisez la fonctionnalité Filtre automatique de manière à afficher uniquement certaines données, vous souhaiterez additionner les cellules visibles uniquement. Vous pouvez utiliser la fonction SOUS.TOTAL pour ce faire. Si vous utilisez une ligne de totaux dans un tableau Excel, n’importe quelle cellule que vous sélectionnez dans la liste déroulante Total sera automatiquement entrée en tant que sous-total. Découvrez plus d’informations sur la manière de totaliser les données d’un tableau Excel.

Vous avez besoin d’une aide supplémentaire ?

Vous pouvez toujours consulter un expert de la communauté technique Excel, obtenir une assistance dans la communauté Answers ou suggérer une nouvelle fonctionnalité ou une amélioration sur le forum Excel User Voice.

Voir aussi

Regarder une vidéo sur l’utilisation de la fonction SOMME

La fonction SOMME.SI additionne uniquement les valeurs qui répondent à un critère unique

La fonction SOMME.SI additionne uniquement les valeurs qui répondent à plusieurs critères

La fonction NB.SI additionne uniquement les valeurs qui répondent à un critère unique

La fonction NB.SI.ENS additionne uniquement les valeurs qui répondent à plusieurs critères

Vue d’ensemble des formules dans Excel

Comment éviter les formules incorrectes

Détecter et corriger des erreurs dans les formules

Raccourcis clavier dans Excel pour Windows

Raccourcis clavier dans Excel pour Mac

Fonctions mathématiques et trigonométriques

Fonctions Excel (par ordre alphabétique)

Fonctions Excel (par catégorie)

Ajout de formules et de fonctions (aperçu gratuit)

Développez vos compétences
Découvrez des formations
Accédez aux nouvelles fonctionnalités en avant-première
Rejoignez le programme Office Insider

Ces informations vous ont-elles été utiles ?

Nous vous remercions pour vos commentaires.

Merci pour vos commentaires. Il serait vraisemblablement utile pour vous de contacter l’un de nos agents du support Office.

×