Calculer la différence entre deux dates

Calculer la différence entre deux dates

La fonction DATEDIF permet de calculer la différence entre deux dates. Placez une date de début dans une cellule et une date de fin dans une autre. Tapez ensuite une formule semblable à la suivante.

Différence en jours

=DATEDIF(D9;E9;"d") avec le résultat 856

Dans cet exemple, la date de début apparaît dans la cellule D9 et la date de fin dans la cellule E9. La formule apparaît dans la cellule F9. La valeur « j » renvoie le nombre de jours entiers entre les deux dates.

Différence en semaines

=(DATEDIF(D13;E13;"d")/7) avec le résultat : 122,29

Dans cet exemple, la date de début apparaît dans la cellule D13 et la date de fin dans la cellule E13. La valeur « j » renvoie le nombre de jours. Remarquez la valeur /7 à la fin. Celle-ci permet de diviser le nombre de jours par 7, chaque semaine comportant 7 jours. Notez que ce résultat doit également être mis en forme comme un nombre. Appuyez sur Ctrl+1. Cliquez ensuite sur Nombre > Nombre de décimales : 2.

Différence en mois

=DATEDIF(D5;E5;"m") avec le résultat : 28

Dans cet exemple, la date de début apparaît dans la cellule D5 et la date de fin dans la cellule E5. Dans la formule, la valeur « m » renvoie le nombre de mois entiers entre les deux jours.

Différence en années

=DATEDIF(D2;E2;"y") avec le résultat : 2

Dans cet exemple, la date de début apparaît dans la cellule D2 et la date de fin dans la cellule E2. La valeur « a » renvoie le nombre d’années entières entre les deux jours.

Calculer un âge en années, mois et jours cumulés

Vous pouvez également calculer un âge ou les années de service d’une personne. Par exemple, le résultat peut être « 2 années, 4 mois, 5 jours ».

1. Utilisez la fonction DATEDIF pour rechercher le nombre total d’années.

=DATEDIF(D17;E17;"y") avec le résultat : 2

Dans cet exemple, la date de début apparaît dans la cellule D17 et la date de fin dans la cellule E17. Dans la formule, la valeur « a » renvoie le nombre d’années entières entre les deux jours.

2. Utilisez de nouveau la fonction DATEDIF avec « am » pour rechercher les mois.

=DATEDIF(D17;E17;"ym") avec le résultat : 4

Dans une autre cellule, utilisez la formule DATEDIF avec le paramètre « am ». La valeur « am » renvoie le nombre de mois restants au-delà de la dernière année entière.

3. Utilisez une autre formule pour rechercher les jours.

=DATEDIF(D17;E17;"md") avec le résultat : 5

Nous devons à présent trouver le nombre de jours restants. Pour ce faire, nous allons écrire un autre type de formule (illustrée ci-dessus). Cette formule soustrait le premier jour du mois de fin (05/01/2016) de la date de fin d’origine dans la cellule E17 (06/05/2016). Voici comment cela fonctionne : La fonction DATE crée tout d’abord la date (05/01/2016). Pour cela, elle utilise l’année et le mois dans la cellule E17. La valeur 1 représente le premier jour du mois. Le résultat de la fonction DATE est 05/01/2016. Ce résultat est soustrait de la date de fin d’origine dans la cellule E17 (06/05/2016). 06/05/2016 moins 01/05/2016 équivaut à 5 jours.

Remarque : Il n’est pas recommandé d’utiliser l’argument « mj » pour la fonction DATEDIF, car il peut générer des résultats incorrects.

4. Facultatif : combinez trois formules en une.

=DATEDIF(D17;E17;"y")&" an(s), "&DATEDIF(D17;E17;"ym")&" mois, "&DATEDIF(D17;E17;"md")&" jour(s)" avec le résultat : 2 an(s), 4 mois, 5 jour(s)

Vous pouvez placer les trois calculs dans une cellule comme dans cet exemple. Utilisez des esperluettes, des guillemets et du texte. Cette formule est plus longue à taper, mais elle inclut tout. Conseil : appuyez sur Alt+Entrée pour insérer des sauts de ligne dans votre formule. Cela facilite la lecture. Appuyez sur Ctrl+Maj+U si la formule entière n’apparaît pas.

Télécharger nos exemples

Vous pouvez télécharger un classeur incluant tous les exemples décrits dans cet article. Vous pouvez consulter les exemples ou créer vos propres formules.

Télécharger des exemples de calcul de date

Autres calculs de date et d’heure

Comme vous l’avez vu ci-dessus, la fonction DATEDIF calcule la différence entre une date de début et une date de fin. Au lieu de taper des dates spécifiques, vous pouvez également utiliser la fonction AUJOURDHUI() dans la formule. Lorsque vous utilisez la fonction AUJOURDHUI(), Excel utilise la date actuelle de votre ordinateur comme date. N’oubliez pas que celle-ci change lorsque le fichier est rouvert un autre jour.

=DATEDIF(AUJOURDHUI();D28;"y") avec le résultat : 984

Veuillez noter que cet article a été rédigé le 6 octobre 2016.

Utilisez la fonction NB.JOURS.OUVRES.INTL pour calculer le nombre de jours ouvrés entre deux dates. Vous pouvez également exclure les week-ends et les jours fériés.

Avant de commencer : décidez si vous voulez exclure les jours fériés. Dans ce cas, tapez la liste des dates correspondant à des jours fériés dans une zone ou une feuille distincte. Placez chaque date correspondant à un jour férié dans sa propre cellule. Sélectionnez ensuite ces cellules, puis Formules > Définir un nom. Nommez la plage JoursFériés, puis cliquez sur OK. Créez ensuite la formule à l’aide de la procédure ci-dessous.

1. Tapez une date de début et une date de fin.

La date de début dans la cellule D53 est 01/01/2016 ; la date de fin dans la cellule E53 est 31/12/2016

Dans cet exemple, la date de début apparaît dans la cellule D53 et la date de fin dans la cellule E53.

2. Dans une autre cellule, tapez une formule comme suit :

=NB.JOURS.OUVRES.INTL(D53;E53;1) avec le résultat : 261

Tapez une formule, comme dans l’exemple ci-dessus. La valeur 1 dans la formule établit les samedis et dimanches comme jours de week-end et permet d’exclure ceux-ci du total.

Remarque : Excel 2007 n’inclut pas la fonction NB.JOURS.OUVRES.INTL, mais NB.JOURS.OUVRES. L’exemple ci-dessus se présenterait comme suit dans Excel 2007 : =NB.JOURS.OUVRES(D53;E53). Vous ne spécifiez pas la valeur 1, car la fonction NB.JOURS.OUVRES suppose que les jours de week-end correspondent aux samedis et dimanches.

3. Modifiez la valeur 1 si nécessaire.

Liste IntelliSense affichant 2 - Dimanche, Lundi ; 3 - Lundi, Mardi, etc.

Si les samedis et dimanches ne correspondent pas à vos jours de week-end, remplacez la valeur 1 par un autre numéro de la liste IntelliSense. Par exemple, la valeur 2 définit les dimanches et lundis comme jours de week-end.

Si vous utilisez Excel 2007, ignorez cette étape. La fonction NB.JOURS.OUVRES d’Excel 2007 suppose toujours que les jours de week-end correspondent aux samedis et dimanches.

4. Tapez le nom de la plage de jours fériés.

=NB.JOURS.OUVRES.INTL(D53;E53;1,MesVacances) avec le résultat : 252

Si vous avez créé un nom de plage de jours fériés dans la section « Avant de commencer » ci-dessus, tapez-le à la fin comme suit. Si vous n’avez pas de jours fériés, vous pouvez omettre le point-virgule et la valeur JoursFériés. Si vous utilisez Excel 2007, la formule dans l’exemple ci-dessus serait la suivante : =NB.JOURS.OUVRES(D53;E53;JoursFériés).

Conseil : si vous ne voulez pas faire référence à un nom de plage de jours fériés, vous pouvez également taper une plage à la place (par exemple, D35:E39). Vous pouvez également taper chaque jour férié dans la formule. Par exemple, si les 1er et 2 janvier 2016 étaient fériés, vous devez les taper comme suit : =NB.JOURS.OUVRES.INTL(D53;E53;1;{"01/01/2016";"02/01/2016"}). Dans Excel 2007, la formule ressemblerait à ceci : =NB.JOURS.OUVRES(D53;E53;{"01/01/2016";"02/01/2016"})

Vous pouvez calculer le temps écoulé en soustrayant une heure d’une autre. Placez une heure de début dans une cellule et une heure de fin dans une autre. Veillez à taper une heure complète (heures et minutes). Voici comment procéder :

1. Tapez les heures de début et de fin.

Date/heure de début égale à 07:15 ; date/heure de fin égale à 16:30

Dans cet exemple, l’heure de début apparaît dans la cellule D80 et l’heure de fin dans la cellule E80. Veillez à taper les heures et les minutes.

2. Définissez le format hh:mm.

Boîte de dialogue Format de cellule, commande Personnalisé, type h:mm

Sélectionnez les deux heures, puis appuyez sur Ctrl+1 (ou Image de l’icône du bouton Cmd sur Mac +1 sur un Mac). Veillez à sélectionner Personnalisée > hh:mm le cas échéant.

3. Soustrayez les deux heures.

=E80-D80 avec le résultat : 09:15

Dans une autre cellule, soustrayez la cellule de l’heure de début de celle de l’heure de fin.

4. Définissez le format hh:mm.

Boîte de dialogue Format de cellule, commande Personnalisé, type hh:mm

Appuyez sur Ctrl+1 (ou Image de l’icône du bouton Cmd sur Mac +1 sur Mac). Sélectionnez Personnalisée > hh:mm.

Pour calculer le temps entre deux dates et heures, vous pouvez simplement en soustraire une de l’autre. Vous devez toutefois appliquer la mise en forme à chaque cellule pour garantir qu’Excel renvoie le résultat souhaité.

1. Tapez deux dates et heures complètes.

Date de début égale à 01/01/16 13:00 ; date de fin égale à 02/01/16 14:00

Dans une cellule, tapez une date/heure de début complète. Dans une autre cellule, tapez une date/heure de fin complète. Chaque cellule doit inclure un mois, un jour, une année, des heures et des minutes.

2. Définissez le format 14/3/12 13:30.

Boîte de dialogue Format de cellule, commande Date, type 14/03/12 13:30

Sélectionnez les deux cellules, puis appuyez sur Ctrl+1 (ou Image de l’icône du bouton Cmd sur Mac +1 sur un Mac). Sélectionnez Date > 14/3/12 13:30. Il ne s’agit pas la date que vous allez définir, mais simplement d’un aperçu de la mise en forme. Notez que dans les versions antérieures à Excel 2016, ce format peut utiliser une autre date d’exemple telle que 14/3/01 13:30.

3. Soustrayez les deux valeurs.

=E84-D84 avec le résultat 1,041666667

Dans une autre cellule, soustrayez la date/heure de début de celle de fin. Le résultat ressemblera probablement à un nombre et une valeur décimale. Vous corrigerez ceci dans l’étape suivante.

4. Définissez le format [h]:mm.

Boîte de dialogue Format de cellule, commande Personnalisé, type [hh]:mm

Appuyez sur Ctrl+1 (ou Image de l’icône du bouton Cmd sur Mac +1 sur Mac). Sélectionnez Personnalisée. Dans la zone Type, sélectionnez [h]:mm.

Voir aussi

Fonction DATEDIF

Fonction NB.JOURS.OUVRES.INTL

NB.JOURS.OUVRES

Autres fonctions de date et d’heure

Calculer la différence entre deux heures

Développez vos compétences
Découvrez des formations
Accédez aux nouvelles fonctionnalités en avant-première
Rejoignez le programme Office Insider

Ces informations vous ont-elles été utiles ?

Nous vous remercions pour vos commentaires.

Merci pour vos commentaires. Il serait vraisemblablement utile pour vous de contacter l’un de nos agents du support Office.

×