Définir des étiquettes de données personnalisées dans un graphique

La procédure VBA (Visual Basic pour Applications) suivante vous permet d’utiliser des valeurs de cellule comme étiquettes de données dans vos graphiques dans Excel pour Mac. Pour utiliser la procédure, procédez comme suit :

1. Dans Excel, cliquez sur Outils > Macros > Enregistrer une nouvelle macro.

2. Dans la zone de liste déroulante Stocker la macro dans : , sélectionnez Classeur de macros personnelles.

   Remarque : En stockant la procédure VBA dans le classeur de macros personnelles, vous pouvez l’utiliser dans n’importe quel instance d’Excel. Cela signifie qu’il n’est pas limité à l’utilisation dans un seul classeur.

3. Appuyez sur OK.

4. Accédez à Outils > Macros > Arrêter l’enregistrement.

5. Accédez à Outils > Macros > Visual Basic Editor.

6. Visual Basic Editor (VBE) s’ouvre au-dessus d’Excel. Dans le volet de navigation à gauche, développez vbaProject (PERSONAL). XLSB) pour afficher Module1.

7. Double-cliquez sur Module1 pour afficher le volet Code, qui s’ouvre sur le côté droit de la fenêtre VBE.

8. Le code VBA créé lors de l’enregistrement d’une nouvelle macro n’est pas nécessaire. Sélectionnez-la, puis appuyez sur Suppr. 

9. Ensuite, sélectionnez le code VBA dans la zone de texte ci-dessous, appuyez sur CMD+C pour le copier, puis collez-le à nouveau dans le volet Code avec CMD+V. Vous pouvez maintenant quitter Visual Basic Editor et revenir à Excel.

10. Testez la macro en créant un graphique avec des étiquettes de données. Ensuite, sélectionnez une étiquette de données sur le graphique, puis exécutez la macro en cliquant sur Outils > Macros > Macros. Sélectionnez SetCustomDataLabels, puis appuyez sur Exécuter. Vous serez automatiquement invité à sélectionner votre plage d’étiquettes de données. Pour cela, appuyez sur OK.  

    Remarque : Les procédures VBA ne peuvent pas être annulées. Veillez donc à essayer cette opération sur une copie d’un classeur. Si vous exécutez le code et que vous ne souhaitez pas conserver les résultats, vous devez fermer le classeur sans l’enregistrer.

11. Lorsque vous quittez Excel, veillez à choisir d’enregistrer les modifications dans PERSONAL. XLSB afin que la macro soit disponible à l’avenir.

12. Chaque fois que vous souhaitez ajouter ou supprimer des étiquettes de données d’un graphique, sélectionnez les étiquettes de données et exécutez la macro.

13. Vous pouvez utiliser Excel > Préférences > ruban & Barre d’outils pour ajouter un bouton permettant d’exécuter la macro à partir du ruban ou de la barre d’outils.

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub